یک دنباله تاریخ در اکسل و سری تاریخ تکمیل خودکار ایجاد کنید

Michael Brown

14-09-2023 برتری داشتن
  • این را به اشتراک بگذارید
Michael Brown

این آموزش نشان می‌دهد که چگونه می‌توانید از تابع جدید SEQUENCE برای ایجاد سریع فهرستی از تاریخ‌ها در اکسل استفاده کنید و از ویژگی تکمیل خودکار برای پر کردن یک ستون با تاریخ، روزهای کاری، ماه یا سال استفاده کنید.

تا همین اواخر، فقط یک راه آسان برای تولید تاریخ در اکسل وجود داشت - ویژگی تکمیل خودکار. معرفی تابع جدید آرایه پویا SEQUENCE امکان ساخت یک سری تاریخ با فرمول را نیز فراهم کرده است. این آموزش نگاهی عمیق به هر دو روش دارد تا بتوانید بهترین روش را انتخاب کنید.

    چگونه سری تاریخ را در اکسل پر کنید

    زمانی که شما باید یک ستون را با تاریخ در اکسل پر کنید، سریع ترین راه استفاده از ویژگی تکمیل خودکار است.

    پر کردن خودکار یک سری تاریخ در اکسل

    پر کردن یک ستون یا ردیف با تاریخ هایی که افزایش می یابد یک روز بسیار آسان است:

    1. تاریخ اولیه را در سلول اول تایپ کنید.
    2. سلول را با تاریخ اولیه انتخاب کنید و دستگیره پر را بکشید (یک مربع سبز کوچک در پایین -گوشه سمت راست) پایین یا سمت راست.

    Excel فوراً مجموعه‌ای از تاریخ‌ها را با همان قالب اولین تاریخی که به صورت دستی تایپ کردید ایجاد می‌کند.

    یک ستون را با روزهای کاری، ماه ها یا سال ها پر کنید

    برای ایجاد مجموعه ای از روزهای کاری، ماه ها یا سال ها، یکی از موارد زیر را انجام دهید:

    • یک ستون را با تاریخ های متوالی همانطور که در بالا توضیح داده شد. پس از آن، روی دکمه AutoFill Options کلیک کنید و آن را انتخاب کنیدگزینه مورد نظر، بگویید پر کردن ماه ها :

    • یا می توانید اولین تاریخ خود را وارد کنید، روی دستگیره پر کلیک راست کنید، نگه دارید و از طریق تعداد زیادی سلول بکشید. به عنوان مورد نیاز. هنگامی که دکمه ماوس را رها می‌کنید، یک منوی زمینه ظاهر می‌شود که به شما امکان می‌دهد گزینه مورد نیاز را انتخاب کنید، سال‌ها را پر کنید در مورد ما:

    پر کردن یک سری از تاریخ ها با افزایش N روز

    برای ایجاد خودکار مجموعه ای از روزها، روزهای هفته، ماه ها یا سال ها با یک مرحله خاص ، این کاری است که باید انجام دهید:

    1. تاریخ اولیه را در سلول اول وارد کنید.
    2. آن سلول را انتخاب کنید، روی دستگیره پر کلیک راست کنید، آن را از میان سلول های مورد نیاز بکشید و سپس رها کنید.
    3. در منوی بازشو، Series (آخرین مورد) را انتخاب کنید.
    4. در کادر گفتگوی Series ، Date unit<2 را انتخاب کنید> مورد علاقه و مقدار مرحله را تنظیم کنید.
    5. OK را کلیک کنید.

    برای مثال های بیشتر، لطفاً به نحوه درج و تکمیل خودکار تاریخ ها در اکسل.

    نحوه ایجاد یک دنباله تاریخ در اکسل با فرمول

    در یکی از آموزش های قبلی، نحوه استفاده از تابع SEQUENCE آرایه پویا جدید را بررسی کردیم. یک دنباله اعداد ایجاد کنید از آنجایی که در داخل اکسل تاریخ ها به عنوان شماره سریال ذخیره می شوند، این تابع به راحتی می تواند یک سری تاریخ نیز تولید کند. تنها کاری که باید انجام دهید این است که آرگومان ها را همانطور که در مثال های زیر توضیح داده شده است به درستی پیکربندی کنید.

    توجه داشته باشید. تمام فرمول‌هایی که در اینجا مورد بحث قرار می‌گیرند، فقط در فرمول کار می‌کنندآخرین نسخه اکسل 365 که از آرایه های پویا پشتیبانی می کند. در اکسل 2019، اکسل 2016 و اکسل 2013 پیش پویا، لطفاً از ویژگی تکمیل خودکار همانطور که در قسمت اول این آموزش نشان داده شده است استفاده کنید.

    یک سری تاریخ در اکسل ایجاد کنید

    برای ایجاد یک دنباله ای از تاریخ ها در اکسل، آرگومان های زیر تابع SEQUENCE را تنظیم کنید:

    SEQUENCE(ردیف ها، [ستون ها]، [شروع]، [گام])
    • ردیف ها - تعداد ردیف هایی که باید با تاریخ پر شوند.
    • ستون ها - تعداد ستون هایی که باید با تاریخ پر شوند.
    • شروع - تاریخ شروع در قالبی که اکسل می تواند آن را درک کند، مانند "8/1/2020" یا "1-Aug-2020". برای جلوگیری از اشتباه، می توانید تاریخ را با استفاده از تابع DATE مانند DATE(2020, 8, 1) تهیه کنید.
    • Step - افزایش برای هر تاریخ بعدی در یک دنباله.

    به عنوان مثال، برای تهیه فهرستی از 10 تاریخ که از 1 آگوست 2020 شروع می شود و 1 روز افزایش می یابد، فرمول این است:

    =SEQUENCE(10, 1, "8/1/2020", 1)

    یا

    =SEQUENCE(10, 1, DATE(2020, 8, 1), 1)

    به‌طور متناوب، می‌توانید تعداد تاریخ‌ها (B1)، تاریخ شروع (B2) و مرحله (B3) را در سلول‌های از پیش تعریف‌شده وارد کنید و به آن سلول‌ها در فرمول خود اشاره کنید. از آنجایی که ما در حال تولید یک لیست هستیم، ستون های شماره (1) به صورت هاردکد هستند:

    =SEQUENCE(B1, 1, B2, B3)

    فرمول زیر را در بالاترین سلول (در مورد ما A6) تایپ کنید، کلید Enter را فشار دهید، و نتایج به طور خودکار در تعداد مشخصی از ردیف ها و ستون ها پخش می شود.

    توجه داشته باشید. با پیش‌فرض عمومی فرمت، نتایج به عنوان شماره سریال ظاهر می شود. برای اینکه آنها به درستی نمایش داده شوند، مطمئن شوید که قالب Date را در تمام سلول های محدوده ریخته شده اعمال کنید.

    یک سری روزهای کاری در اکسل بسازید

    برای دریافت فقط یک سری روزهای کاری، SEQUENCE را در تابع WORKDAY یا WORKDAY.INTL به این ترتیب بپیچید:

    WORKDAY( start_date -1, SEQUENCE( no_of_days ))

    از آنجایی که تابع WORKDAY تعداد روزهای مشخص شده در آرگومان دوم را به تاریخ شروع اضافه می کند، 1 را از آن کم می کنیم تا خود تاریخ شروع در آرگومان گنجانده شود. نتایج.

    به عنوان مثال، برای ایجاد یک توالی از روزهای کاری که از تاریخ در B2 شروع می شود، فرمول این است:

    =WORKDAY(B2-1, SEQUENCE(B1))

    که در آن B1 اندازه دنباله است.

    نکات و نکات:

    • اگر تاریخ شروع شنبه یا یکشنبه باشد، مجموعه در روز کاری بعدی شروع خواهد شد.
    • تابع Excel WORKDAY شنبه و یکشنبه را آخر هفته فرض می کند. برای پیکربندی آخر هفته ها و تعطیلات سفارشی، به جای آن از تابع WORKDAY.INTL استفاده کنید.

    تولید یک دنباله ماه در اکسل

    برای ایجاد مجموعه ای از تاریخ ها با افزایش یک ماهه، می توانید استفاده کنید این فرمول عمومی:

    DATE( سال ، SEQUENCE(12)، روز )

    در این مورد، سال هدف را در آرگومان اول و روز را در آرگومان اول قرار می دهید استدلال 3. برای آرگومان دوم، تابع SEQUENCE اعداد ترتیبی از 1 تا 12 را برمی گرداند. بر اساس پارامترهای بالا، تابع DATE یک سری ازتاریخ هایی که در قسمت سمت چپ تصویر زیر نشان داده شده است:

    =DATE(2020, SEQUENCE(12), 1)

    برای نمایش فقط نام ماه ، یکی از قالب های تاریخ سفارشی زیر را برای محدوده ریخته شده تنظیم کنید :

    • mmmm - فرم کوتاه مانند Jan ، Feb ، Mar ، و غیره.
    • mmmm - کامل شکلی مانند ژانویه ، فوریه ، مارس ، و غیره.

    در نتیجه، فقط نام ماه ها در سلول ها ظاهر می شود. اما مقادیر اساسی همچنان تاریخ های کامل خواهند بود. در هر دو سری در تصویر زیر، لطفاً به تراز پیش‌فرض راست که برای اعداد و تاریخ‌ها در اکسل معمول است توجه کنید:

    برای ایجاد یک توالی تاریخ که یک ماه و <17 افزایش می‌یابد>با یک تاریخ خاص شروع می شود ، از تابع SEQUENCE همراه با EDATE استفاده کنید:

    EDATE( start_date , SEQUENCE(12, 1, 0))

    عملکرد EDATE تاریخی را برمی گرداند که تعداد ماه های مشخص شده قبل یا بعد از تاریخ شروع است. و تابع SEQUENCE آرایه ای از 12 عدد (یا به همان تعداد که شما مشخص می کنید) تولید می کند تا EDATE را مجبور کند تا در افزایش یک ماهه به جلو حرکت کند. لطفا توجه داشته باشید که آرگومان start روی 0 تنظیم شده است، به طوری که تاریخ شروع در نتایج گنجانده می شود.

    با تاریخ شروع در B1، فرمول به این شکل است:

    =EDATE(B1, SEQUENCE(12, 1, 0))

    توجه. پس از تکمیل فرمول، لطفاً به یاد داشته باشید که یک قالب تاریخ مناسب را برای نتایج اعمال کنید تا به درستی نمایش داده شوند.

    یک دنباله سال در اکسل ایجاد کنید

    برای ساختمجموعه ای از تاریخ ها که بر اساس سال افزایش می یابد، از این فرمول عمومی استفاده کنید:

    DATE(SEQUENCE( n , 1, YEAR( start_date )), MONTH( start_date )، DAY( start_date ))

    که در آن n تعداد تاریخ هایی است که می خواهید ایجاد کنید.

    در این مورد، DATE(سال، ماه، روز) تابع تاریخ را به این صورت می سازد:

    • Year توسط تابع SEQUENCE که برای تولید یک ردیف n توسط 1 پیکربندی شده است، برگردانده می شود. آرایه ستونی از اعداد، با مقدار سال از تاریخ_شروع .
    • ماه و روز مستقیماً از تاریخ شروع خارج می شوند.

    به عنوان مثال، اگر تاریخ شروع را در B1 وارد کنید، فرمول زیر مجموعه ای از 10 تاریخ را در یک سال افزایش می دهد:

    =DATE(SEQUENCE(10, 1, YEAR(B1)), MONTH(B1), DAY(B1))

    بعد از در صورت فرمت کردن به صورت تاریخ، نتایج به صورت زیر خواهد بود:

    یک دنباله زمان در اکسل ایجاد کنید

    زیرا زمان ها در اکسل به صورت اعداد اعشاری ذخیره می شوند که نشان دهنده یک در کسری از روز، تابع SEQUENCE می تواند مستقیماً با زمان ها کار کند.

    A با فرض اینکه زمان شروع در B1 باشد، می توانید از یکی از فرمول های زیر برای تولید یک سری 10 بار استفاده کنید. تفاوت فقط در آرگومان step است. از آنجایی که 24 ساعت در روز وجود دارد، از 1/24 برای افزایش یک ساعت، 1/48 به افزایش 30 دقیقه و غیره استفاده کنید.

    30 دقیقه فاصله:

    =SEQUENCE(10, 1, B1, 1/48)

    1 ساعت فاصله:

    =SEQUENCE(10, 1, B1, 1/24)

    2 ساعت فاصله:

    =SEQUENCE(10, 1, B1, 1/12)

    عکس صفحه زیرنتایج:

    اگر نمی‌خواهید برای محاسبه دستی مرحله را به زحمت بیندازید، می‌توانید با استفاده از تابع TIME آن را تعریف کنید:

    SEQUENCE(ردیف‌ها، ستون‌ها، شروع، TIME( ساعت ، دقیقه ، ثانیه ))

    برای این مثال، همه متغیرها را در سلول‌های جداگانه مانند تصویر زیر وارد می‌کنیم. . و سپس، می‌توانید از فرمول زیر برای تولید یک سری زمانی با هر اندازه گام افزایشی که در سلول‌های E2 (ساعت)، E3 (دقیقه) و E4 (ثانیه) مشخص می‌کنید، استفاده کنید:

    =SEQUENCE(B2, B3, B4, TIME(E2, E3, E4))

    نحوه ایجاد یک تقویم ماهانه در اکسل

    در این مثال آخر، ما از تابع SEQUENCE به همراه DATEVALUE و WEEKDAY برای ایجاد یک تقویم ماهانه استفاده می کنیم که به روز می شود. به طور خودکار بر اساس سال و ماهی که شما مشخص می کنید.

    فرمول در A5 به شرح زیر است:

    =SEQUENCE(6, 7, DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1, 1)

    این فرمول چگونه کار می کند:

    شما از تابع SEQUENCE برای ایجاد 6 ردیف (حداکثر تعداد هفته های ممکن در یک ماه) با 7 ستون (تعداد روزها در هفته) آرایه تاریخ استفاده می کنید. 1 روز افزایش یافته است. بنابراین، آرگومان‌های ردیف‌ها ، ستون‌ها و step هیچ سوالی ایجاد نمی‌کنند.

    مشکل‌ترین بخش در آرگومان start . ما نمی توانیم تقویم خود را با روز اول ماه مورد نظر شروع کنیم زیرا نمی دانیم کدام روز هفته است. بنابراین از فرمول زیر برای یافتن اولین یکشنبه قبل از روز اول ماه مشخص شده استفاده می کنیمسال:

    DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

    اولین تابع DATEVALUE یک شماره سریال برمی گرداند که در سیستم اکسل داخلی، اولین روز ماه را در B2 و سال را در B1 نشان می دهد. در مورد ما، 44044 مربوط به 1 آگوست 2020 است. در این مرحله، ما داریم:

    44044 - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

    عملکرد WEEKDAY روز هفته را مطابق با اولین روز هدف برمی گرداند. ماه به عنوان یک عدد از 1 (یکشنبه) تا 7 (شنبه). در مورد ما، 7 است زیرا 1 اوت 2020 شنبه است. و فرمول ما به:

    44044 - 7 + 1

    44044 کاهش می یابد - 7 برابر با 4403 است که مربوط به شنبه، 25 جولای 2020 است. همانطور که یکشنبه نیاز داریم، تصحیح +1 را اضافه می کنیم.

    به این ترتیب، فرمول ساده‌ای دریافت می‌کنیم که آرایه‌ای از شماره‌های سریال را که با 4404 شروع می‌شود خروجی می‌دهد:

    =SEQUENCE(6, 7, 4404, 1)

    نتایج را به‌عنوان تاریخ قالب‌بندی کنید، و یک تقویم نشان داده شده در اسکرین شات بالا برای مثال، می‌توانید از یکی از قالب‌های تاریخ زیر استفاده کنید:

    • d-mmm-yy برای نمایش تاریخ‌هایی مانند 1-Aug-20
    • mm d برای نمایش ماه و روز مانند 20 اوت
    • d برای نمایش فقط روز

    صبر کنید، اما هدف ما ایجاد یک تقویم ماهانه است. چرا برخی از تاریخ های ماه قبل و بعد ظاهر می شوند؟ برای پنهان کردن آن تاریخ‌های نامربوط، یک قانون قالب‌بندی شرطی با فرمول زیر تنظیم کنید و رنگ قلم سفید را اعمال کنید:

    =MONTH(A5)MONTH(DATEVALUE($B$2 & "1"))

    جایی که A5 سمت چپ ترین سلول است. تقویم شما و B2 هدف استماه.

    برای جزئیات مراحل، لطفاً به نحوه ایجاد یک قانون قالب‌بندی شرطی مبتنی بر فرمول در اکسل مراجعه کنید.

    به این ترتیب می‌توانید یک دنباله ایجاد کنید. تاریخ ها در اکسل از شما سپاسگزارم که خواندید و امیدوارم هفته آینده شما را در وبلاگ خود ببینیم!

    کتاب کار برای دانلود تمرین کنید

    توالی تاریخ در اکسل - نمونه های فرمول (فایل xlsx.)

    پست قبلی صادرات مخاطبین از Outlook به Excel
    پست بعدی چگونه چندین لینک را از کاربرگ های اکسل در یک زمان حذف کنیم؟

    مایکل براون یک علاقه‌مند به فناوری است که علاقه زیادی به ساده‌سازی فرآیندهای پیچیده با استفاده از ابزارهای نرم‌افزاری دارد. او با بیش از یک دهه تجربه در صنعت فناوری، مهارت های خود را در Microsoft Excel و Outlook و همچنین Google Sheets و Docs تقویت کرده است. وبلاگ مایکل اختصاص داده شده است تا دانش و تخصص خود را با دیگران به اشتراک بگذارد و نکات و آموزش هایی را برای بهبود بهره وری و کارایی ارائه دهد. چه یک حرفه ای با تجربه باشید و چه مبتدی، وبلاگ مایکل، بینش های ارزشمند و توصیه های عملی را برای استفاده حداکثری از این ابزارهای نرم افزاری ضروری ارائه می دهد.