Təlimat Excel-də tarixlərin siyahısını tez yaratmaq üçün yeni SEQUENCE funksiyasından necə istifadə edə biləcəyinizi və sütunu tarixlər, iş günləri, aylar və ya illərlə doldurmaq üçün Avtomatik Doldurma funksiyasından necə istifadə edə biləcəyinizi göstərir.

Son vaxtlara qədər Excel-də tarix yaratmağın yalnız bir asan yolu var idi - Avtomatik Doldurma funksiyası. Yeni dinamik massiv SEQUENCE funksiyasının tətbiqi düsturla da bir sıra tarixlər yaratmağa imkan verdi. Bu dərslik hər iki üsula ətraflı nəzər salır ki, siz özünüz üçün ən uyğun olanı seçə biləsiniz.

Excel-də tarix seriyasını necə doldurmaq olar

Nə vaxt Excel-də bir sütunu tarixlərlə doldurmalısınız, ən sürətli yol Avtomatik Doldur funksiyasından istifadə etməkdir.

Excel-də tarix seriyasını avtomatik doldurmaq

Sütun və ya cərgəni artıran tarixlərlə doldurmaq bir gün çox asandır:

1. İlk xanada ilkin tarixi yazın.
2. İlkin tarixi olan xananı seçin və doldurma sapını (aşağıda kiçik yaşıl kvadrat) dartın -sağ künc) aşağı və ya sağa.

Excel dərhal əl ilə yazdığınız ilk tarixlə eyni formatda bir sıra tarixlər yaradacaq.

Həftənin günləri, ayları və ya illəri ilə sütunu doldurun

Bir sıra iş günləri, aylar və ya illər yaratmaq üçün aşağıdakılardan birini edin:

• Sütunu aşağıdakılarla doldurun yuxarıda göstərildiyi kimi ardıcıl tarixlər. Bundan sonra, Avtomatik Doldurma Seçimləri düyməsinə klikləyin və seçinistədiyiniz seçim üçün Doldurma Ayları deyin:

  

• Və ya ilk tarixinizi daxil edə, doldurma qulpunu sağa klikləyə, basıb saxlayın və çoxlu xanalar arasında sürükləyə bilərsiniz. lazım olduğu kimi. Siçan düyməsini buraxdığınız zaman sizə lazım olan seçimi seçmək imkanı verən kontekst menyusu açılacaq, bizim halda İlləri doldurun :

  

N gün artan bir sıra tarixləri doldurun

xüsusi addım ilə bir sıra günlər, iş günləri, aylar və ya illər seriyasını avtomatik yaratmaq üçün bunu etməlisiniz:

1. İlk xanaya ilkin tarixi daxil edin.
2. Həmin xananı seçin, doldurma sapını sağa klikləyin, onu lazım olan qədər xanalar arasında dartın və sonra buraxın.
3. Açılan menyuda Series (son element) seçin.
4. Series dialoq qutusunda Tarix vahidi<2 seçin> maraqlandırın və Addım dəyərini təyin edin.
5. OK üzərinə klikləyin.

Daha çox nümunə üçün baxın. Excel-də tarixləri daxil edin və avtomatik doldurun.

Düsturla Excel-də tarix ardıcıllığını necə etmək olar

Əvvəlki dərsliklərdən birində biz yeni dinamik massiv SEQUENCE funksiyasından necə istifadə edəcəyimizi nəzərdən keçirdik. ədəd ardıcıllığı yaradın. Excel-də tarixlər daxili olaraq seriya nömrələri kimi saxlandığı üçün funksiya asanlıqla tarix seriyasını da yarada bilər. Sizə lazım olan hər şey aşağıdakı nümunələrdə izah edildiyi kimi arqumentləri düzgün şəkildə konfiqurasiya etməkdir.

Qeyd. Burada müzakirə olunan bütün düsturlar yalnız işləyirdinamik massivləri dəstəkləyən Excel 365-in ən son versiyaları. Pre-dinamik Excel 2019, Excel 2016 və Excel 2013-də, bu təlimatın birinci hissəsində göstərildiyi kimi Avtomatik Doldurma funksiyasından istifadə edin.

Excel-də bir sıra tarixlər yaradın

Varmaq üçün Excel-də tarix ardıcıllığı üçün SEQUENCE funksiyasının aşağıdakı arqumentlərini qurun:

• Sətrlər - tarixlərlə doldurulacaq sətirlərin sayı.
• Sütunlar - tarixlərlə doldurulacaq sütunların sayı.
• Başlanğıc - başlanğıc tarixi "8/1/2020" və ya "1-Avqust-2020" kimi Excel-in başa düşə biləcəyi format. Səhvlərin qarşısını almaq üçün TARİX (2020, 8, 1) kimi TARİX funksiyasından istifadə edərək tarixi təqdim edə bilərsiniz.
• Addım - ardıcıllıqla hər sonrakı tarix üçün artım.

Məsələn, 2020-ci il avqustun 1-dən başlayaraq 1 gün artan 10 tarixdən ibarət siyahı hazırlamaq üçün formula belədir:

=SEQUENCE(10, 1, "8/1/2020", 1)

və ya

=SEQUENCE(10, 1, DATE(2020, 8, 1), 1)

Alternativ olaraq, əvvəlcədən təyin edilmiş xanalara tarixlərin sayını (B1), başlanğıc tarixini (B2) və addımı (B3) daxil edə və formulunuzda həmin xanalara istinad edə bilərsiniz. Siyahı yaratdığımız üçün sütunların nömrəsi (1) sərt kodlaşdırılıb:

=SEQUENCE(B1, 1, B2, B3)

Aşağıdakı düsturu ən yuxarı xanaya yazın (bizim vəziyyətimizdə A6), Enter düyməsini basın və nəticələr avtomatik olaraq göstərilən sıra və sütunların sayına yayılacaq.

Qeyd. Defolt Ümumi iləformatında, nəticələr seriya nömrələri kimi görünəcək. Onların düzgün göstərilməsi üçün tarix formatını dağılma diapazonunun bütün xanalarına tətbiq etməyinizə əmin olun.

Excel-də bir sıra iş günləri yaradın

Yalnız bir sıra iş günləri əldə etmək üçün SEQUENCE-ni WORKDAY və ya WORKDAY.INTL funksiyasına bu şəkildə sarın:

İŞ GÜNÜ funksiyası ikinci arqumentdə göstərilən günlərin sayını başlanğıc tarixinə əlavə etdiyi üçün ondan 1-i çıxarırıq ki, başlanğıc tarixi özü də daxil edilsin. nəticələr.

Məsələn, B2-də tarixdən başlayan iş günləri ardıcıllığını yaratmaq üçün düstur belədir:

=WORKDAY(B2-1, SEQUENCE(B1))

Burada B1 ardıcıllığın ölçüsüdür.

Məsləhətlər və qeydlər:

• Əgər başlanğıc tarixi şənbə və ya bazardırsa, seriya növbəti iş günündə başlayacaq.
• Excel WORKDAY funksiyası şənbə və bazar günlərinin həftə sonları olmasını nəzərdə tutur. Fərdi həftə sonları və bayram günlərini konfiqurasiya etmək üçün əvəzinə WORKDAY.INTL funksiyasından istifadə edin.

Excel-də ay ardıcıllığı yaradın

Bir aya artırılmış bir sıra tarixlər yaratmaq üçün istifadə edə bilərsiniz. bu ümumi düstur:

Bu halda, siz hədəf ili 1-ci arqumentə, günü isə arqumentə qoyursunuz. 3-cü arqument. 2-ci arqument üçün SEQUENCE funksiyası 1-dən 12-yə qədər ardıcıl nömrələri qaytarır. Yuxarıdakı parametrlərə əsasən, TARİX funksiyası bir sıraaşağıdakı ekran görüntüsünün sol hissəsində göstərildiyi kimi tarixlər:

=DATE(2020, SEQUENCE(12), 1)

Yalnız ay adlarını göstərmək üçün dağılma diapazonu üçün aşağıdakı fərdi tarix formatlarından birini təyin edin :

• mmmm - qısa forma Yanvar , Fevral , Mar və s.
• mmmm - tam Yanvar , Fevral , Mart və s. kimi forma.

Nəticədə xanalarda yalnız ay adları görünəcək, lakin əsas dəyərlər hələ də tam tarixlər olacaq. Aşağıdakı skrinşotdakı hər iki seriyada Excel-də nömrələr və tarixlər üçün xarakterik olan defolt sağ düzülməyə diqqət yetirin:

Bir ay və <17 artan tarix ardıcıllığı yaratmaq üçün>müəyyən bir tarixlə başlayır , EDATE ilə birlikdə SEQUENCE funksiyasından istifadə edin:

EDATE funksiyası tarixi qaytarır başlama tarixindən əvvəl və ya sonrakı ayların müəyyən edilmiş sayıdır. Və SEQUENCE funksiyası EDATE-i bir aylıq artımlarla irəliləməyə məcbur etmək üçün 12 ədəddən (və ya sizin təyin etdiyiniz qədər) bir sıra yaradır. Diqqət yetirin ki, start arqumenti 0-a təyin edilib, beləliklə, başlanğıc tarixi nəticələrə daxil edilsin.

B1-də başlanğıc tarixi ilə düstur bu formanı alır:

=EDATE(B1, SEQUENCE(12, 1, 0))

Qeyd. Düsturu tamamladıqdan sonra nəticələrin düzgün göstərilməsi üçün müvafiq tarix formatını tətbiq etməyi unutmayın.

Excel-də il ardıcıllığı yaradın

Etmək üçünillə artırılan bir sıra tarixlər üçün bu ümumi düsturdan istifadə edin:

Burada n yaratmaq istədiyiniz tarixlərin sayıdır.

Bu halda, TARİX(il, ay, gün) funksiyası bu şəkildə tarixi qurur:

• İl 1-ə qədər n sətir yaratmaq üçün konfiqurasiya edilmiş SEQUENCE funksiyası ilə qaytarılır. başlanğıc_tarixi -dən etibarən il dəyərindən başlayaraq rəqəmlərin sütun massivi.
• Ay və gün dəyərləri birbaşa başlanğıc tarixindən götürülür.

Məsələn, B1-də başlanğıc tarixini daxil etsəniz, aşağıdakı düstur bir illik artımlarla 10 tarix seriyasını verəcəkdir:

=DATE(SEQUENCE(10, 1, YEAR(B1)), MONTH(B1), DAY(B1))

Sonra tarixlər kimi formatlaşdırıldıqda, nəticələr aşağıdakı kimi görünəcək:

Excel-də vaxt ardıcıllığı yaradın

Çünki vaxtlar Excel-də bir rəqəmi təmsil edən onluq ədədlər kimi saxlanılır. günün bir hissəsi, SEQUENCE funksiyası birbaşa zamanla işləyə bilər.

A başlama vaxtının B1-də olduğunu fərz etsək, 10 dəfə seriya yaratmaq üçün aşağıdakı düsturlardan birini istifadə edə bilərsiniz. Fərq yalnız addım arqumentindədir. Gündə 24 saat olduğundan, bir saat artırmaq üçün 1/24, 30 dəqiqə artırmaq üçün 1/48 və s. istifadə edin.

30 dəqiqə ara ilə:

=SEQUENCE(10, 1, B1, 1/48)

1 saat fərq:

=SEQUENCE(10, 1, B1, 1/24)

2 saat fərq:

=SEQUENCE(10, 1, B1, 1/12)

Aşağıdakı ekran görüntüsünəticələr:

Addımı əl ilə hesablamaqla narahat olmaq istəmirsinizsə, TIME funksiyasından istifadə edərək onu müəyyən edə bilərsiniz:

Bu misal üçün bütün dəyişənləri aşağıdakı ekran görüntüsündə göstərildiyi kimi ayrı-ayrı xanalara daxil edəcəyik . Və sonra, E2 (saat), E3 (dəqiqə) və E4 (saniyə) xanalarında göstərdiyiniz istənilən artım addım ölçüsü ilə zaman seriyası yaratmaq üçün aşağıdakı düsturdan istifadə edə bilərsiniz:

=SEQUENCE(B2, B3, B4, TIME(E2, E3, E4))

Excel-də aylıq təqvimi necə yaratmaq olar

Bu son nümunədə biz yenilənəcək aylıq təqvim yaratmaq üçün DATEVALUE və WEEKDAY ilə birlikdə SEQUENCE funksiyasından istifadə edəcəyik. avtomatik olaraq qeyd etdiyiniz il və aya əsaslanır.

A5-də düstur aşağıdakı kimidir:

=SEQUENCE(6, 7, DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1, 1)

Bu düstur necə işləyir:

Siz 6 cərgə (bir ayda mümkün həftələrin maksimum sayı) 7 sütun (həftədə günlərin sayı) tarix massivi yaratmaq üçün SEQUENCE funksiyasından istifadə edirsiniz 1 gün artırılır. Beləliklə, sətir , sütun və addım arqumentləri heç bir sual doğurmur.

start arqumentində ən çətin hissə . Həftənin hansı günü olduğunu bilmədiyimiz üçün təqvimimizi hədəf ayın 1-ci günü ilə başlaya bilmirik. Beləliklə, göstərilən ayın 1-ci günündən əvvəl ilk bazar gününü tapmaq üçün aşağıdakı düsturdan istifadə edirik vəil:

DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

İlk TARİXVALUE funksiyası daxili Excel sistemində B2-də ayın 1-ci gününü və B1-də ili təmsil edən seriya nömrəsini qaytarır. Bizim vəziyyətimizdə bu, 1 avqust 2020-ci il tarixinə uyğun gələn 44044-dür. Bu nöqtədə bizdə var:

44044 - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

WEEKDAY funksiyası hədəfin 1-ci gününə uyğun gələn həftənin gününü qaytarır. ay 1-dən (bazar) 7-yə (şənbə) qədər rəqəm kimi. Bizim vəziyyətimizdə 7-dir, çünki 1 avqust 2020-ci il şənbə günüdür. Düsturumuz isə azalır:

44044 - 7 + 1

44044 - 7 4403-dür, bu, 25 iyul 2020-ci il şənbə gününə uyğundur. Bazar gününə ehtiyacımız olduğu üçün +1 düzəlişini əlavə edirik.

Bu yolla, 4404 ilə başlayan seriya nömrələri massivini çıxaran sadə düstur əldə edirik:

=SEQUENCE(6, 7, 4404, 1)

Nəticələri tarix kimi formatlayın və siz aşağıda göstərilən təqvimi əldə edəcəksiniz yuxarıdakı ekran görüntüsü. Məsələn, aşağıdakı tarix formatlarından birini istifadə edə bilərsiniz:

• d-aaa-yy 1-Avqust-20 <12 kimi tarixləri göstərmək üçün>
• mmm d yalnız günü göstərmək üçün 20 avqust
• d kimi ay və günü göstərmək üçün

Gözləyin, lakin biz aylıq təqvim yaratmağı planlaşdırırıq. Niyə əvvəlki və gələn ayın bəzi tarixləri görünür? Bu uyğunsuz tarixləri gizlətmək üçün aşağıdakı düsturla şərti formatlaşdırma qaydası qurun və ağ şrift rəngini tətbiq edin:

=MONTH(A5)MONTH(DATEVALUE($B$2 & "1"))

A5 ən sol xanadır. təqviminiz və B2 hədəfdiray.

Ətraflı addımlar üçün Excel-də düstura əsaslanan şərti formatlaşdırma qaydasını necə yaratmaq olar bölməsinə baxın.

Ardıcıllığı belə yarada bilərsiniz. Excel-də tarixlər. Oxuduğunuz üçün sizə təşəkkür edirəm və sizi gələn həftə bloqumuzda görməyə ümid edirəm!

Endirmək üçün məşq kitabı

Excel-də tarix ardıcıllığı - düstur nümunələri (.xlsx faylı)