Udžbenik pokazuje kako možete iskoristiti novu funkciju SEQUENCE za brzo generiranje popisa datuma u Excelu i koristiti značajku AutoFill za popunjavanje stupca datumima, radnim danima, mjesecima ili godinama.

Donedavno je postojao samo jedan jednostavan način za generiranje datuma u Excelu - značajka AutoFill. Uvođenje nove funkcije SEQUENCE dinamičkog polja također je omogućilo izradu niza datuma s formulom. Ovaj vodič detaljno razmatra obje metode kako biste mogli odabrati onu koja vam najbolje odgovara.

Kako ispuniti niz datuma u programu Excel

Kada morate ispuniti stupac s datumima u Excelu, najbrži način je korištenje značajke AutoFill.

Automatsko popunjavanje serije datuma u Excelu

Punjenje stupca ili retka s datumima koji se povećavaju za jedan dan je vrlo jednostavan:

1. Upišite početni datum u prvu ćeliju.
2. Odaberite ćeliju s početnim datumom i povucite ručicu za popunjavanje (mali zeleni kvadrat na dnu -desni kut) prema dolje ili udesno.

Excel će odmah generirati niz datuma u istom formatu kao i prvi datum koji ste ručno upisali.

Ispunite stupac danima u tjednu, mjesecima ili godinama

Da biste stvorili niz radnih dana, mjeseci ili godina, učinite jedno od sljedećeg:

• Ispunite stupac s uzastopne datume kao što je gore opisano. Nakon toga kliknite gumb Opcije automatskog popunjavanja i odaberiteželjenu opciju, recite Ispunite mjesece :

  

• Ili možete unijeti svoj prvi datum, desnom tipkom miša kliknite ručicu za popunjavanje, držite i povucite kroz onoliko ćelija po potrebi. Kada pustite tipku miša, pojavit će se kontekstni izbornik koji vam omogućuje da odaberete potrebnu opciju, Ispunite godine u našem slučaju:

  

Ispunite niz datuma povećavajući se za N dana

Za automatsko generiranje niza dana, radnih dana, mjeseci ili godina s određenim korakom , ovo je ono što trebate učiniti:

1. Unesite početni datum u prvu ćeliju.
2. Odaberite tu ćeliju, desnom tipkom miša kliknite ručicu za popunjavanje, povucite je kroz onoliko ćelija koliko je potrebno, a zatim otpustite.
3. U skočnom izborniku odaberite Serije (posljednja stavka).
4. U dijaloškom okviru Serije odaberite Datumsku jedinicu od interesa i postavite Vrijednost koraka .
5. Kliknite U redu.

Za više primjera pogledajte Kako umetanje i automatsko popunjavanje datuma u Excelu.

Kako napraviti slijed datuma u Excelu s formulom

U jednom od prethodnih vodiča pogledali smo kako koristiti novu funkciju dinamičkog polja SEQUENCE za generirati niz brojeva. Budući da su interno u Excelu datumi pohranjeni kao serijski brojevi, funkcija može jednostavno proizvesti i niz datuma. Sve što trebate učiniti je ispravno konfigurirati argumente kao što je objašnjeno u sljedećim primjerima.

Napomena. Sve formule o kojima se ovdje raspravlja rade samo unajnovije verzije programa Excel 365 koje podržavaju dinamička polja. U preddinamičkim programima Excel 2019, Excel 2016 i Excel 2013 koristite značajku AutoFill kao što je prikazano u prvom dijelu ovog vodiča.

Stvorite niz datuma u Excelu

Da biste generirali niz datuma u Excelu, postavite sljedeće argumente funkcije SEQUENCE:

• Reci - broj redaka za popunjavanje datumima.
• Stupci - broj stupaca za popunjavanje datumima.
• Početak - početni datum u formatu koji Excel može razumjeti, poput "8/1/2020" ili "1-Aug-2020". Da biste izbjegli pogreške, možete unijeti datum pomoću funkcije DATE kao što je DATE(2020, 8, 1).
• Korak - povećanje za svaki sljedeći datum u nizu.

Na primjer, da biste napravili popis od 10 datuma počevši od 1. kolovoza 2020. i povećavajući se za 1 dan, formula je:

=SEQUENCE(10, 1, "8/1/2020", 1)

ili

=SEQUENCE(10, 1, DATE(2020, 8, 1), 1)

Alternativno, možete unijeti broj datuma (B1), datum početka (B2) i korak (B3) u unaprijed definirane ćelije i referencirati te ćelije u svojoj formuli. Budući da generiramo popis, broj stupaca (1) je tvrdo kodiran:

=SEQUENCE(B1, 1, B2, B3)

Upišite donju formulu u najvišu ćeliju (A6 u našem slučaju), pritisnite tipku Enter i rezultati će se automatski rasporediti na određeni broj redaka i stupaca.

Napomena. Sa zadanim Općenito formatu, rezultati će se pojaviti kao serijski brojevi. Da bi se ispravno prikazali, svakako primijenite format datuma na sve ćelije u rasponu izlijevanja.

Napravite niz radnih dana u Excelu

Da biste dobili samo niz radnih dana, zamotajte SEQUENCE u funkciju WORKDAY ili WORKDAY.INTL na ovaj način:

Kako funkcija WORKDAY dodaje broj dana navedenih u drugom argumentu početnom datumu, od njega oduzimamo 1 kako bi sam početni datum bio uključen u rezultate.

Na primjer, za generiranje niza radnih dana koji počinju na datum u B2, formula je:

=WORKDAY(B2-1, SEQUENCE(B1))

Gdje je B1 veličina niza.

Savjeti i napomene:

• Ako je datum početka subota ili nedjelja, serija će započeti sljedeći radni dan.
• Funkcija Excel WORKDAY pretpostavlja da su subota i nedjelja vikendi. Da biste konfigurirali prilagođene vikende i praznike, umjesto toga upotrijebite funkciju WORKDAY.INTL.

Generirajte mjesečni niz u programu Excel

Da biste stvorili niz datuma uvećanih za jedan mjesec, možete koristiti ovu generičku formulu:

U ovom slučaju stavljate ciljnu godinu u 1. argument i dan u 3. argument. Za 2. argument, funkcija SEQUENCE vraća uzastopne brojeve od 1 do 12. Na temelju gornjih parametara, funkcija DATE proizvodi nizdatumi kao što je prikazano u lijevom dijelu snimke zaslona u nastavku:

=DATE(2020, SEQUENCE(12), 1)

Za prikaz samo imena mjeseci , postavite jedan od niže prilagođenih formata datuma za raspon izlijevanja :

• mmm - kratki oblik kao siječanj , veljača , ožu itd.
• mmmm - puni obliku poput siječanj , veljača , ožujak itd.

Kao rezultat, samo će se imena mjeseci pojaviti u ćelijama, ali će temeljne vrijednosti i dalje biti puni datumi. U obje serije na snimci zaslona u nastavku primijetite zadano desno poravnanje tipično za brojeve i datume u Excelu:

Za generiranje niza datuma koji se povećava za jedan mjesec i počinje s određenim datumom , koristite funkciju SEQUENCE zajedno s EDATE:

Funkcija EDATE vraća datum koji je navedeni broj mjeseci prije ili poslije datuma početka. A funkcija SEQUENCE proizvodi niz od 12 brojeva (ili onoliko koliko navedete) kako bi prisilila EDATE da se pomakne naprijed u jednomjesečnim koracima. Imajte na umu da je argument start postavljen na 0, tako da je početni datum uključen u rezultate.

S početnim datumom u B1, formula ima ovaj oblik:

=EDATE(B1, SEQUENCE(12, 1, 0))

Napomena. Nakon dovršetka formule, ne zaboravite primijeniti odgovarajući format datuma na rezultate kako bi se ispravno prikazali.

Stvorite slijed godina u Excelu

Za izraduniz datuma uvećanih po godini, koristite ovu generičku formulu:

Gdje je n broj datuma koje želite generirati.

U ovom slučaju, DATUM(godina, mjesec, dan) konstruira datum na ovaj način:

• Godina vraća funkcija SEQUENCE koja je konfigurirana za generiranje n redaka za 1 stupac niz brojeva, počevši od vrijednosti godine od start_date .
• Mjesec i dan vrijednosti povlače se izravno iz početnog datuma.

Na primjer, ako unesete početni datum u B1, sljedeća formula će ispisati niz od 10 datuma u jednogodišnjim koracima:

=DATE(SEQUENCE(10, 1, YEAR(B1)), MONTH(B1), DAY(B1))

Nakon budući da su formatirani kao datumi, rezultati će izgledati ovako:

Generirajte niz vremena u programu Excel

Budući da su vremena pohranjena u programu Excel kao decimalni brojevi koji predstavljaju dio dana, funkcija SEQUENCE može izravno raditi s vremenima.

A pod pretpostavkom da je vrijeme početka u B1, možete upotrijebiti jednu od sljedećih formula za izradu serije od 10 puta. Razlika je samo u argumentu korak . Budući da dan ima 24 sata, upotrijebite 1/24 za povećanje za sat, 1/48 za povećanje za 30 minuta i tako dalje.

Razmak od 30 minuta:

=SEQUENCE(10, 1, B1, 1/48)

Razmak od 1 sata:

=SEQUENCE(10, 1, B1, 1/24)

Razmak od 2 sata:

=SEQUENCE(10, 1, B1, 1/12)

Snimak zaslona u nastavku prikazujerezultati:

Ako se ne želite zamarati ručnim izračunavanjem koraka, možete ga definirati pomoću funkcije VRIJEME:

Za ovaj primjer, unijet ćemo sve varijable u zasebne ćelije kao što je prikazano na slici ispod . Zatim možete koristiti donju formulu za generiranje vremenske serije s bilo kojom veličinom koraka povećanja koju navedete u ćelijama E2 (sati), E3 (minute) i E4 (sekunde):

=SEQUENCE(B2, B3, B4, TIME(E2, E3, E4))

Kako izraditi mjesečni kalendar u programu Excel

U ovom posljednjem primjeru koristit ćemo funkciju SEQUENCE zajedno s DATEVALUE i WEEKDAY za izradu mjesečnog kalendara koji će se ažurirati automatski na temelju godine i mjeseca koje navedete.

Formula u A5 je sljedeća:

=SEQUENCE(6, 7, DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1, 1)

Kako funkcionira ova formula:

Koristite funkciju SEQUENCE za generiranje niza datuma od 6 redaka (najveći mogući broj tjedana u mjesecu) sa 7 stupaca (broj dana u tjednu). povećan za 1 dan. Dakle, argumenti redovi , stupci i korak ne postavljaju pitanja.

Najteži dio u argumentu početak . Naš kalendar ne možemo započeti s 1. danom ciljanog mjeseca jer ne znamo koji je dan u tjednu. Dakle, koristimo sljedeću formulu da pronađemo prvu nedjelju prije 1. dana navedenog mjeseca igodina:

DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

Prva funkcija DATEVALUE vraća serijski broj koji u internom Excel sustavu predstavlja 1. dan u mjesecu u B2 i godinu u B1. U našem slučaju, to je 44044 što odgovara 1. kolovozu 2020. U ovom trenutku imamo:

44044 - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

Funkcija WEEKDAY vraća dan u tjednu koji odgovara 1. danu cilja mjesec kao broj od 1 (nedjelja) do 7 (subota). U našem slučaju to je 7 jer je 1. kolovoza 2020. subota. A naša formula se smanjuje na:

44044 - 7 + 1

44044 - 7 je 4403, što odgovara suboti, 25. srpnja 2020. Kako nam treba nedjelja, dodajemo +1 ispravak.

Na ovaj način dobivamo jednostavnu formulu koja daje niz serijskih brojeva koji počinju s 4404:

=SEQUENCE(6, 7, 4404, 1)

Formatirajte rezultate kao datume i dobit ćete kalendar prikazan u snimak zaslona iznad. Na primjer, možete koristiti jedan od sljedećih formata datuma:

• d-mmm-gg za prikaz datuma poput 1-Aug-20
• mmm d za prikaz mjeseca i dana poput 20. kolovoza
• d za prikaz samo dana

Čekaj, ali cilj nam je stvoriti mjesečni kalendar. Zašto se prikazuju neki datumi prethodnog i sljedećeg mjeseca? Kako biste sakrili te nevažne datume, postavite pravilo uvjetnog oblikovanja s donjom formulom i primijenite bijelu boju fonta :

=MONTH(A5)MONTH(DATEVALUE($B$2 & "1"))

Gdje je A5 krajnja lijeva ćelija od vaš kalendar i B2 je ciljmjesec.

Za detaljne korake pogledajte Kako stvoriti pravilo uvjetnog oblikovanja temeljeno na formuli u programu Excel.

Tako možete generirati niz datuma u Excelu. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeći tjedan!

Radna bilježnica za vježbe za preuzimanje

Slijed datuma u Excelu - primjeri formula (.xlsx datoteka)