Ipinapakita ng tutorial kung paano mo magagamit ang bagong SEQUENCE function upang mabilis na makabuo ng listahan ng mga petsa sa Excel at gamitin ang feature na AutoFill upang punan ang isang column ng mga petsa, araw ng trabaho, buwan o taon.

Hanggang kamakailan lamang, mayroon lamang isang madaling paraan upang bumuo ng mga petsa sa Excel - ang tampok na AutoFill. Ang pagpapakilala ng bagong dynamic array SEQUENCE function ay naging posible na gumawa ng isang serye ng mga petsa na may formula din. Ang tutorial na ito ay tumitingin nang malalim sa parehong mga pamamaraan upang mapili mo ang isa na pinakamahusay na gumagana para sa iyo.

Paano punan ang serye ng petsa sa Excel

Kailan kailangan mong punan ang isang column ng mga petsa sa Excel, ang pinakamabilis na paraan ay ang paggamit ng tampok na AutoFill.

Awtomatikong punan ang isang serye ng petsa sa Excel

Pagpupuno sa isang column o row ng mga petsa na tumataas ng napakadali ng isang araw:

1. I-type ang inisyal na petsa sa unang cell.
2. Piliin ang cell na may inisyal na petsa at i-drag ang fill handle (isang maliit na berdeng parisukat sa ibaba -kanang sulok) pababa o sa kanan.

Kaagad na bubuo ng serye ng mga petsa ang Excel sa parehong format tulad ng unang petsa na manu-mano mong na-type.

Punan ang isang column ng mga karaniwang araw, buwan o taon

Upang gumawa ng serye ng mga araw ng trabaho, buwan o taon, gawin ang isa sa mga sumusunod:

• Punan ang isang column ng sunud-sunod na mga petsa tulad ng inilarawan sa itaas. Pagkatapos noon, i-click ang button na AutoFill Options at piliin anggustong opsyon, sabihin ang Fill Months :

  

• O maaari mong ilagay ang iyong unang petsa, i-right-click ang fill handle, hawakan at i-drag sa kasing dami ng mga cell kung kinakailangan. Kapag binitawan mo ang pindutan ng mouse, mag-pop-up ang isang menu ng konteksto na hahayaan kang piliin ang kinakailangang opsyon, Punan ang Mga Taon sa aming kaso:

  

Punan ang isang serye ng mga petsa na tumataas ng N araw

Upang awtomatikong makabuo ng serye ng mga araw, karaniwang araw, buwan o taon na may partikular na hakbang , ito ang kailangan mong gawin:

1. Ilagay ang inisyal na petsa sa unang cell.
2. Piliin ang cell na iyon, i-right-click ang fill handle, i-drag ito sa pinakamaraming cell kung kinakailangan, at pagkatapos ay bitawan.
3. Sa pop-up menu, piliin ang Serye (ang huling item).
4. Sa Series dialog box, piliin ang Date unit ng interes at itakda ang Halaga ng hakbang .
5. I-click ang OK.

Para sa higit pang mga halimbawa, pakitingnan ang Paano magpasok at mag-autofill ng mga petsa sa Excel.

Paano gumawa ng sequence ng petsa sa Excel gamit ang isang formula

Sa isa sa mga nakaraang tutorial, tiningnan namin kung paano gamitin ang bagong dynamic array SEQUENCE function upang bumuo ng pagkakasunod-sunod ng numero. Dahil ang panloob na mga petsa sa Excel ay naka-imbak bilang mga serial number, ang function ay madaling makagawa din ng isang serye ng petsa. Ang kailangan mo lang gawin ay i-configure nang tama ang mga argumento gaya ng ipinaliwanag sa mga sumusunod na halimbawa.

Tandaan. Ang lahat ng mga formula na tinalakay dito ay gumagana lamang sapinakabagong bersyon ng Excel 365 na sumusuporta sa mga dynamic na array. Sa pre-dynamic na Excel 2019, Excel 2016 at Excel 2013, pakigamit ang feature na AutoFill gaya ng ipinapakita sa unang bahagi ng tutorial na ito.

Gumawa ng serye ng mga petsa sa Excel

Upang bumuo ng pagkakasunud-sunod ng mga petsa sa Excel, i-set up ang mga sumusunod na argumento ng SEQUENCE function:

• Rows - ang bilang ng mga row na pupunuan ng mga petsa.
• Mga Column - ang bilang ng mga column na pupunuan ng mga petsa.
• Start - ang petsa ng pagsisimula sa format na mauunawaan ng Excel, tulad ng "8/1/2020" o "1-Aug-2020". Upang maiwasan ang mga pagkakamali, maaari mong ibigay ang petsa sa pamamagitan ng paggamit ng DATE function gaya ng DATE(2020, 8, 1).
• Hakbang - ang pagdaragdag para sa bawat kasunod na petsa sa isang sequence.

Halimbawa, para gumawa ng listahan ng 10 petsa simula sa Agosto 1, 2020 at tumaas ng 1 araw, ang formula ay:

=SEQUENCE(10, 1, "8/1/2020", 1)

o

=SEQUENCE(10, 1, DATE(2020, 8, 1), 1)

Bilang kahalili, maaari mong ipasok ang bilang ng mga petsa (B1), petsa ng pagsisimula (B2) at hakbang (B3) sa mga paunang natukoy na mga cell at i-reference ang mga cell na iyon sa iyong formula. Dahil kami ay bumubuo ng isang listahan, ang mga column na numero (1) ay naka-hardcode:

=SEQUENCE(B1, 1, B2, B3)

I-type ang formula sa ibaba sa pinakatuktok na cell (A6 sa aming kaso), pindutin ang Enter key, at awtomatikong dadaloy ang mga resulta sa tinukoy na bilang ng mga row at column.

Tandaan. Gamit ang default na General format, lalabas ang mga resulta bilang mga serial number. Upang maipakita nang tama ang mga ito, tiyaking ilapat ang format ng Petsa sa lahat ng mga cell sa hanay ng spill.

Gumawa ng serye ng mga araw ng trabaho sa Excel

Upang makakuha ng serye ng mga araw ng trabaho lamang, i-wrap ang SEQUENCE sa WORKDAY o WORKDAY.INTL function sa ganitong paraan:

Habang idinaragdag ng WORKDAY function ang bilang ng mga araw na tinukoy sa pangalawang argumento sa petsa ng pagsisimula, binabawasan namin ang 1 mula dito upang maisama ang mismong petsa ng pagsisimula sa mga resulta.

Halimbawa, para makabuo ng sequence ng mga araw ng trabaho simula sa petsa sa B2, ang formula ay:

=WORKDAY(B2-1, SEQUENCE(B1))

Kung saan ang B1 ay ang sequence size.

Mga tip at paalala:

• Kung Sabado o Linggo ang petsa ng pagsisimula, magsisimula ang serye sa susunod na araw ng trabaho.
• Ipinapalagay ng Excel WORKDAY function na ang Sabado at Linggo ay weekend. Upang i-configure ang mga custom na weekend at holiday, gamitin na lang ang WORKDAY.INTL function.

Bumuo ng isang buwan na pagkakasunud-sunod sa Excel

Upang lumikha ng isang serye ng mga petsa na dinagdagan ng isang buwan, maaari mong gamitin ang generic na formula na ito:

Sa kasong ito, inilalagay mo ang target na taon sa 1st argument at araw sa ika-3 argumento. Para sa 2nd argument, ang SEQUENCE function ay nagbabalik ng mga sequential number mula 1 hanggang 12. Batay sa mga parameter sa itaas, ang DATE function ay gumagawa ng isang serye ngmga petsa tulad ng ipinapakita sa kaliwang bahagi ng screenshot sa ibaba:

=DATE(2020, SEQUENCE(12), 1)

Upang ipakita lamang ang mga pangalan ng buwan , itakda ang isa sa mga custom na format ng petsa sa ibaba para sa saklaw ng spill :

• mmm - maikling anyo tulad ng Ene , Peb , Mar , atbp.
• mmmm - puno form tulad ng Enero , Pebrero , Marso , atbp.

Bilang resulta, ang mga pangalan ng buwan lang ang lalabas sa mga cell, ngunit ang mga pinagbabatayan na halaga ay magiging buong petsa pa rin. Sa parehong serye sa screenshot sa ibaba, pakipansin ang default na right alignment na tipikal para sa mga numero at petsa sa Excel:

Upang bumuo ng sequence ng petsa na tumataas ng isang buwan at nagsisimula sa isang partikular na petsa , gamitin ang SEQUENCE function kasama ng EDATE:

Ang EDATE function ay nagbabalik ng petsa na ay ang tinukoy na bilang ng mga buwan bago o pagkatapos ng petsa ng pagsisimula. At ang SEQUENCE function ay gumagawa ng hanay ng 12 numero (o kasing dami ng iyong tinukoy) upang pilitin ang EDATE na sumulong sa isang buwang pagdaragdag. Pakipansin na ang argumentong start ay nakatakda sa 0, upang ang petsa ng pagsisimula ay maisama sa mga resulta.

Gamit ang petsa ng pagsisimula sa B1, ganito ang hugis ng formula:

=EDATE(B1, SEQUENCE(12, 1, 0))

Tandaan. Pagkatapos makumpleto ang isang formula, mangyaring tandaan na maglapat ng naaangkop na format ng petsa sa mga resulta upang maipakita ng mga ito nang tama.

Gumawa ng sequence ng taon sa Excel

Para gawinisang serye ng mga petsa na dinaragdagan ayon sa taon, gamitin ang generic na formula na ito:

Kung saan ang n ay ang bilang ng mga petsang gusto mong buuin.

Sa kasong ito, ang DATE(taon, buwan, araw) na function ay gumagawa ng petsa sa ganitong paraan:

• Taon ay ibinabalik ng SEQUENCE function na naka-configure upang bumuo ng n na mga hilera ng 1 hanay ng hanay ng mga numero, simula sa halaga ng taon mula sa start_date .
• Buwan at araw ay direktang kinukuha mula sa petsa ng pagsisimula.

Halimbawa, kung ilalagay mo ang petsa ng pagsisimula sa B1, ang sumusunod na formula ay maglalabas ng serye ng 10 petsa sa isang taon na pagdaragdag:

=DATE(SEQUENCE(10, 1, YEAR(B1)), MONTH(B1), DAY(B1))

Pagkatapos na naka-format bilang mga petsa, ang mga resulta ay magiging ganito ang hitsura:

Bumuo ng pagkakasunod-sunod ng mga beses sa Excel

Dahil ang mga oras ay naka-imbak sa Excel bilang mga decimal na numero na kumakatawan sa isang fraction ng araw, ang SEQUENCE function ay maaaring gumana nang direkta sa mga oras.

A sa pag-aakalang ang oras ng pagsisimula ay nasa B1, maaari mong gamitin ang isa sa mga sumusunod na formula upang makagawa ng serye ng 10 beses. Ang pagkakaiba ay nasa step argument lamang. Dahil may 24 na oras sa isang araw, gamitin ang 1/24 para dagdagan ng isang oras, 1/48 para dagdagan ng 30 minuto, at iba pa.

30 minuto ang pagitan:

=SEQUENCE(10, 1, B1, 1/48)

1 oras ang pagitan:

=SEQUENCE(10, 1, B1, 1/24)

2 oras ang pagitan:

=SEQUENCE(10, 1, B1, 1/12)

Ang screenshot sa ibaba ay nagpapakita ngmga resulta:

Kung ayaw mong mag-abala sa pagkalkula ng hakbang nang manu-mano, maaari mo itong tukuyin sa pamamagitan ng paggamit ng TIME function:

Para sa halimbawang ito, ilalagay namin ang lahat ng mga variable sa magkakahiwalay na mga cell tulad ng ipinapakita sa screenshot sa ibaba . At pagkatapos, maaari mong gamitin ang formula sa ibaba upang bumuo ng isang serye ng oras na may anumang pagtaas ng laki ng hakbang na iyong tinukoy sa mga cell E2 (oras), E3 (minuto) at E4 (segundo):

=SEQUENCE(B2, B3, B4, TIME(E2, E3, E4))

Paano gumawa ng buwanang kalendaryo sa Excel

Sa huling halimbawang ito, gagamitin namin ang SEQUENCE function kasama ng DATEVALUE at WEEKDAY para gumawa ng buwanang kalendaryo na mag-a-update awtomatikong batay sa taon at buwan na iyong tinukoy.

Ang formula sa A5 ay ang sumusunod:

=SEQUENCE(6, 7, DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1, 1)

Paano gumagana ang formula na ito:

Ginagamit mo ang SEQUENCE function para bumuo ng 6 na row (ang max na posibleng bilang ng linggo sa isang buwan) sa pamamagitan ng 7 column (ang bilang ng mga araw sa isang linggo) na hanay ng mga petsa nadagdagan ng 1 araw. Kaya naman, ang rows , column at step na argumento ay walang itinaas na tanong.

Ang pinakamahirap na bahagi sa start argument . Hindi namin maaaring simulan ang aming kalendaryo sa unang araw ng target na buwan dahil hindi namin alam kung aling araw ng linggo ito. Kaya, ginagamit namin ang sumusunod na formula upang mahanap ang unang Linggo bago ang unang araw ng tinukoy na buwan attaon:

DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

Ang unang DATEVALUE function ay nagbabalik ng serial number na, sa internal na Excel system, ay kumakatawan sa unang araw ng buwan sa B2 at ang taon sa B1. Sa aming kaso, ito ay 44044 na tumutugma sa Agosto 1, 2020. Sa puntong ito, mayroon kaming:

44044 - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

Ibinabalik ng WEEKDAY function ang araw ng linggo na tumutugma sa unang araw ng target buwan bilang numero mula 1 (Linggo) hanggang 7 (Sabado). Sa aming kaso, ito ay 7 dahil Agosto 1, 2020 ay Sabado. At ang aming formula ay bumaba sa:

44044 - 7 + 1

44044 - 7 ay 4403, na tumutugma sa Sabado, Hulyo 25, 2020. Kung kailangan namin ng Linggo, idinaragdag namin ang +1 na pagwawasto.

Sa ganitong paraan, nakakakuha kami ng simpleng formula na naglalabas ng hanay ng mga serial number na nagsisimula sa 4404:

=SEQUENCE(6, 7, 4404, 1)

I-format ang mga resulta bilang mga petsa, at makakakuha ka ng kalendaryong ipinapakita sa ang screenshot sa itaas. Halimbawa, maaari mong gamitin ang isa sa mga sumusunod na format ng petsa:

• d-mmm-yy upang ipakita ang mga petsa tulad ng 1-Ago-20
• mmm d upang ipakita ang buwan at araw tulad ng Ago 20
• d upang ipakita lamang ang araw

Maghintay, ngunit nilalayon naming lumikha ng buwanang kalendaryo. Bakit lumalabas ang ilang petsa ng nakaraan at susunod na buwan? Para itago ang mga hindi nauugnay na petsang iyon, mag-set up ng conditional formatting rule na may formula sa ibaba at ilapat ang white font na kulay:

=MONTH(A5)MONTH(DATEVALUE($B$2 & "1"))

Kung saan ang A5 ang pinakakaliwang cell ng iyong kalendaryo at B2 ang targetbuwan.

Para sa mga detalyadong hakbang, pakitingnan ang Paano gumawa ng nakabatay sa formula na tuntunin sa pag-format ng kondisyon sa Excel.

Iyan ay kung paano ka makakabuo ng isang sequence ng mga petsa sa Excel. Salamat sa pagbabasa at umaasa akong makita ka sa aming blog sa susunod na linggo!

Magsanay ng workbook para sa pag-download

Pagkakasunod-sunod ng petsa sa Excel - mga halimbawa ng formula (.xlsx file)