Како да бројам ќелии со текст во Excel? Постојат неколку различни формули за броење ќелии кои содржат каков било текст, специфични знаци или само филтрирани ќелии. Сите формули работат во Excel 365, 2021, 2019, 2016, 2013 и 2010 година.

Првично, табелите на Excel беа дизајнирани да работат со броеви. Но, овие денови често ги користиме и за складирање и манипулирање со текст. Сакате да знаете колку ќелии со текст има во вашиот работен лист? Microsoft Excel има неколку функции за ова. Кој треба да го користите? Па, зависи од ситуацијата. Во ова упатство, ќе најдете различни формули и кога секоја формула е најдобро да се користи.

Како да се брои бројот на ќелии со текст во Excel

Таму се две основни формули за да откриете колку ќелии во даден опсег содржат текстуална низа или знак.

COUNTIF формула за броење на сите ќелии со текст

Кога сакате да го пронајдете бројот на ќелии со текст во Excel, функцијата COUNTIF со ѕвездичка во аргументот критериуми е најдоброто и најлесното решение:

Бидејќи ѕвездичката (*) е џокер што се совпаѓа со која било низа од знаци, формулата ги брои сите ќелии што содржат каков било текст.

SUMPRODUCT формула за броење ќелии со кој било текст

Друг начин да се добие бројот на ќелиите што содржат текст треба да ги комбинираат функциите SUMPRODUCT и ISTEXT:

Или

Функцијата ISTEXT проверува дали секоја ќелија во наведената опсегот содржи какви било текстуални знаци и враќа низа од TRUE (ќелии со текст) и FALSE (други ќелии). Двојната унарна (--) или операцијата за множење ги принудува TRUE и FALSE во 1 и 0, соодветно, создавајќи низа од единици и нули. Функцијата SUMPRODUCT ги сумира сите елементи на низата и го враќа бројот на 1, што е бројот на ќелии што содржат текст.

За да добиете повеќе разбирање за тоа како функционираат овие формули, ве молиме погледнете кои вредности се бројат и кои не се:

На пример, за броење ќелии со текст во опсегот A2:A10, со исклучок на броеви, датуми, логички вредности, грешки и празни ќелии, користете една од овие формули:

=COUNTIF(A2:A10, "*")

=SUMPRODUCT(--ISTEXT(A2:A10))

=SUMPRODUCT(ISTEXT(A2:A10)*1)

На сликата подолу е прикажан резултатот:

Броење ќелии со текст без празни места и празни низи

Формулите дискутирани погоре броисите ќелии кои имаат текстуални знаци во нив. Меѓутоа, во некои ситуации тоа може да биде збунувачки бидејќи одредени ќелии може да изгледаат само празни, но всушност содржат знаци невидливи за човечкото око како празни жици, апострофи, празни места, прекини на линии итн. Како резултат на тоа, визуелно празно ќелијата се брои со формулата што предизвикува корисникот да ја вади косата обидувајќи се да открие зошто :)

За да ги исклучите „лажно позитивните“ празни ќелии од броењето, користете ја функцијата COUNTIFS со знакот „исклучен“ во вториот критериум.

На пример, за броење ќелии со текст во опсегот A2:A7 игнорирајќи ги оние што содржат празен знак , користете ја оваа формула:

=COUNTIFS(A2:A7,"*", A2:A7, " ")

Ако вашиот целен опсег содржи податоци засновани на формула, некои од формулите може да резултираат со празна низа („“). За да ги игнорирате и ќелиите со празни низи , заменете го „*“ со „*?*“ во аргументот criteria1 :

=COUNTIFS(A2:A9,"*?*", A2:A9, " ")

Прашање ознаката опкружена со ѕвездички покажува дека треба да има барем еден текстуален знак во ќелијата. Бидејќи празна низа нема знаци во неа, таа не ги исполнува критериумите и не се брои. Не се бројат ниту празните ќелии кои започнуваат со апостроф (').

На сликата од екранот подолу, има празно место во А7, апостроф во А8 и празна низа (="") во А9. Нашата формула ги изоставува сите тие ќелии и враќа број на текстуални ќелии3:

Како да ги броите ќелиите со одреден текст во Excel

За да го добиете бројот на ќелии што содржат одреден текст или знак, едноставно го снабдувате тој текст во аргументот критериуми на функцијата COUNTIF. Примерите подолу ги објаснуваат нијансите.

За да се совпадне со примерокот на текстот точно , внесете го целиот текст затворен во наводници:

За броење ќелии со делумно совпаѓање , ставете го текстот помеѓу две ѕвездички, кои претставуваат кој било број знаци пред и по текстот:

На пример, за да откриете колку ќелии во опсегот A2:A7 го содржат точно зборот „банани“, користете оваа формула:

=COUNTIF(A2:A7, "bananas")

За да ги броите сите ќелии што содржат „банани“ како дел од нивната содржина во која било позиција, користете ја оваа:

=COUNTIF(A2:A7, "*bananas*")

За да ја направите формулата попријатна за корисникот, можете да ги поставите критериумите во претходно дефинирана ќелија, да речеме D2, и да ја ставите референцата на ќелијата во вториот аргумент:

=COUNTIF(A2:A7, D2)

Во зависност од влезот во D2, формулата може целосно или делумно да одговара на текстот на примерокот:

• За целосно совпаѓање, напишете го целиот збор или фраза како што се појавува во изворната табела, на пр. Банани .
• За делумно совпаѓање, напишете го примерокот на текст опкружен со знаците со џокер, како *Банани* .

Како што формулата е неосетлива на букви , можеби нема да се замарате за буквите,што значи дека и *бананите* исто така.

Алтернативно, за броење ќелии со делумно совпаѓање , спојте ја референцата на ќелијата и знаци како што се:

=COUNTIF(A2:A7, "*"&D2&"*")

За повеќе информации, погледнете Како да се бројат ќелиите со специфичен текст во Excel.

Како за броење филтрирани ќелии со текст во Excel

Кога користите Excel филтер за прикажување само на податоците релевантни во даден момент, понекогаш можеби ќе треба да броите видливи ќелии со текст . За жал, не постои решение со еден клик за оваа задача, но примерот подолу удобно ќе ве води низ чекорите.

Да се ​​претпостави дека имате табела како што е прикажана на сликата подолу. Некои записи беа повлечени од поголема база на податоци користејќи формули, а на патот се појавија разни грешки. Барате да го пронајдете вкупниот број на ставки во колоната А. Со видливи сите редови, формулата COUNTIF што ја користевме за броење ќелии со текст работи добро:

=COUNTIF(A2:A10, "*")

И сега, ја стеснуваш листата по некои критериуми, да речеме, филтрирај ги артиклите со количина поголема од 10. Прашањето е - колку ставки останале?

Да се ​​избројат филтрирани ќелии со текст , еве што треба да направите:

1. Во вашата изворна табела, направете ги сите редови видливи. За ова, исчистете ги сите филтри и откријте ги скриените редови.
2. Додајте помошна колона со формулата SUBTOTAL која покажува дали редот ефилтрирани или не.

   За ракување со филтрирани ќелии , користете 3 за аргументот function_num :

   =SUBTOTAL(3, A2)

   За да ги идентификувате сите скриени ќелии , филтрирани и скриени рачно, ставете 103 во function_num :

   =SUBTOTAL(103, A2)

   Во овој пример, сакаме да броиме само видливи ќелии со текст без оглед на тоа како се скриени другите ќелии, затоа ја внесуваме втората формула во А2 и ја копираме на А10.

   За видливи ќелии, формулата враќа 1. Штом ќе филтрирате или рачно сокријте некои редови, формулата ќе врати 0 за нив. (Нема да ги видите тие нули затоа што се вратени за скриени редови. За да бидете сигурни дека тоа функционира на овој начин, само копирајте ја содржината на скриената ќелија со формулата Subtotal на која било видлива, да речеме =D2, под претпоставка дека редот 2 е скриен .)

   

3. Користете ја функцијата COUNTIFS со два различни опсег_критериуми / критериуми парови за броење видливи ќелии со текст:
   • Criteria1 - пребарува ќелии со кој било текст („*“) во опсегот A2:A10.
   • Criteria2 - бара 1 во опсегот D2:D10 за да открие видливи ќелии.

   =COUNTIFS(A2:A10, "*", D2:D10, 1)

Сега, можете да ги филтрирате податоците како што сакате, а формулата ќе ви каже колку филтрирани ќелии во колоната А содржат текст (3 во нашиот случај):

Ако не сакате да вметнете дополнителна колона во вашиот работен лист, тогаш ќе ви треба подолга формула за да ја исполните задачата. Само изберете го оној што виеми се допаѓа подобро:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISTEXT(A2:A10)))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), -- (ISTEXT(A2:A10)))

Ќе работи и операторот за множење:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))) * (ISTEXT(A2:A10)))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10)-MIN(ROW(A2:A10)),,1)) * (ISTEXT(A2:A10)))

Која формула да се користи е прашање на ваш личен избор - резултатот ќе биде ист во секој случај:

Како функционираат овие формули

Првата формулата ја користи функцијата INDIRECT за да ги „нахрани“ поединечните референци на сите ќелии во наведениот опсег до SUBTOTAL. Втората формула користи комбинација од функциите OFFSET, ROW и MIN за истата цел.

Функцијата SUBTOTAL враќа низа од 1 и 0 каде што едниот претставуваат видливи ќелии, а нулите се совпаѓаат со скриените ќелии (како помошната колона погоре).

Функцијата ISTEXT ја проверува секоја ќелија во A2:A10 и враќа TRUE ако ќелијата содржи текст, во спротивно FALSE. Двојниот унарен оператор (--) ги принудува вредностите TRUE и FALSE во 1 и 0. Во овој момент, формулата изгледа вака:

=SUMPRODUCT({0;1;1;1;0;1;1;0;0}, {1;1;1;0;1;1;0;1;1})

Функцијата SUMPRODUCT прво ги множи елементите на двете низи на исти позиции, а потоа ја сумира добиената низа.

Бидејќи множењето со нула дава нула, само ќелиите претставени со 1 во двете низи имаат 1 во последната низа.

=SUMPRODUCT({0;1;1;0;0;1;0;0;0})

А бројот на 1 во горната низа е бројот на видливи ќелии што содржат текст.

Така се брои ќелиите со текст во Excel. Ви благодарам што прочитавте и се надевам дека ќе се видиме на нашиот блог следната недела!

Достапнопреземања

Формули на Excel за броење ќелии со текст