Das Tutorial zeigt, wie Sie IFERROR in Excel verwenden, um Fehler abzufangen und durch eine leere Zelle, einen anderen Wert oder eine benutzerdefinierte Meldung zu ersetzen. Sie lernen, wie Sie die Funktion IFERROR mit Vlookup und Indexabgleich verwenden und wie sie im Vergleich zu IF ISERROR und IFNA funktioniert.

"Gib mir einen Platz zum Stehen, und ich werde die Erde bewegen", sagte Archimedes einmal. "Gib mir eine Formel, und ich werde dafür sorgen, dass sie einen Fehler zurückgibt", würde ein Excel-Benutzer sagen. In diesem Tutorial werden wir uns nicht damit befassen, wie man in Excel Fehler zurückgibt, sondern lernen, wie man sie verhindert, damit Ihre Arbeitsblätter sauber und Ihre Formeln transparent bleiben.

Excel-Funktion IFERROR - Syntax und grundlegende Anwendungen

Die Funktion IFERROR in Excel dient zum Abfangen und Verwalten von Fehlern in Formeln und Berechnungen. Genauer gesagt prüft IFERROR eine Formel und gibt im Falle eines Fehlers einen anderen von Ihnen angegebenen Wert zurück; andernfalls wird das Ergebnis der Formel zurückgegeben.

Die Syntax der Excel-Funktion IFERROR lautet wie folgt:

Wo:

• Wert (erforderlich) - was auf Fehler geprüft werden soll. Es kann eine Formel, ein Ausdruck, ein Wert oder ein Zellbezug sein.
• Wert_wenn_Fehler (erforderlich) - was im Falle eines Fehlers zurückgegeben werden soll, z. B. eine leere Zeichenfolge (leere Zelle), eine Textmeldung, ein numerischer Wert, eine andere Formel oder eine Berechnung.

Wenn Sie z. B. zwei Zahlenspalten dividieren, können Sie eine Reihe verschiedener Fehler erhalten, wenn eine der Spalten leere Zellen, Nullen oder Text enthält.

Um dies zu verhindern, verwenden Sie die Funktion IFERROR, um Fehler abzufangen und zu behandeln, wie Sie es wünschen.

Wenn Fehler, dann leer

Geben Sie eine leere Zeichenkette (") an die wert_wenn_fehler Argument, um eine leere Zelle zurückzugeben, wenn ein Fehler gefunden wird:

=IFERROR(A2/B2, "")

Wenn Fehler, dann eine Meldung anzeigen

Sie können auch Ihre eigene Meldung anstelle der Excel-Standardfehlernotation anzeigen:

=IFERROR(A2/B2, "Fehler bei der Berechnung")

5 Dinge, die Sie über die Excel-Funktion IFERROR wissen sollten

1. Die Funktion IFERROR in Excel behandelt alle Fehlertypen einschließlich #DIV/0!, #N/A, #NAME?, #NULL!, #NUM!, #REF! und #VALUE!.
2. Je nach dem Inhalt der Datei wert_wenn_fehler kann IFERROR Fehler durch Ihre eigene Textmeldung, eine Zahl, ein Datum oder einen logischen Wert, das Ergebnis einer anderen Formel oder eine leere Zeichenfolge (leere Zelle) ersetzen.
3. Wenn die Wert Argument eine leere Zelle ist, wird es als leere Zeichenfolge (''') behandelt, aber nicht als Fehler.
4. IFERROR wurde in Excel 2007 eingeführt und ist in allen nachfolgenden Versionen von Excel 2010, Excel 2013, Excel 2016, Excel 2019, Excel 2021 und Excel 365 verfügbar.
5. Um Fehler in Excel 2003 und früheren Versionen abzufangen, verwenden Sie die Funktion ISERROR in Kombination mit IF, wie in diesem Beispiel gezeigt.

Beispiele für IFERROR-Formeln

Die folgenden Beispiele zeigen, wie Sie IFERROR in Excel in Kombination mit anderen Funktionen verwenden können, um komplexere Aufgaben zu bewältigen.

Excel IFERROR mit Vlookup

Eine der häufigsten Verwendungen der Funktion IFERROR besteht darin, den Benutzern mitzuteilen, dass der gesuchte Wert im Datensatz nicht vorhanden ist. Zu diesem Zweck wird eine VLOOKUP-Formel wie folgt in IFERROR eingeschlossen:

Wenn der Nachschlagewert nicht in der Tabelle enthalten ist, in der Sie suchen, würde eine normale Vlookup-Formel den Fehler #N/A zurückgeben:

Um Ihre Benutzer zu beruhigen, sollten Sie VLOOKUP in IFERROR verpacken und eine informativere und benutzerfreundlichere Meldung anzeigen:

=IFERROR(VLOOKUP(A2, 'Nachschlagetabelle'!$A$2:$B$4, 2,FALSE), "Nicht gefunden")

Der folgende Screenshot zeigt diese Iferror-Formel in Excel:

Wenn Sie nur #N/A-Fehler, aber nicht alle Fehler abfangen möchten, verwenden Sie die Funktion IFNA anstelle von IFERROR.

Weitere Beispiele für Excel IFERROR VLOOKUP-Formeln finden Sie in diesen Tutorials:

• Iferror mit Vlookup zum Abfangen und Behandeln von Fehlern
• Wie erhalte ich das N-te Vorkommen eines Nachschlagewertes?
• Wie erhalte ich alle Vorkommen eines Nachschlagewertes?

Verschachtelte IFERROR-Funktionen zur Durchführung von sequentiellen Vlookups in Excel

In Situationen, in denen Sie mehrere Vlookups durchführen müssen, je nachdem, ob das vorherige Vlookup erfolgreich war oder nicht, können Sie zwei oder mehr IFERROR-Funktionen ineinander verschachteln.

Angenommen, Sie haben eine Reihe von Verkaufsberichten von regionalen Niederlassungen Ihres Unternehmens und möchten einen Betrag für eine bestimmte Auftragsnummer ermitteln. Mit A2 als Referenzwert im aktuellen Blatt und A2:B5 als Referenzbereich in drei Referenzblättern (Bericht 1, Bericht 2 und Bericht 3) sieht die Formel wie folgt aus:

=IFERROR(VLOOKUP(A2,'Bericht 1'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Bericht 2'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Bericht 3'!A2:B5,2,0), "nicht gefunden")))

Das Ergebnis wird in etwa so aussehen:

Eine ausführliche Erklärung der Logik der Formel finden Sie unter Wie man sequenzielle Vlookups in Excel durchführt.

IFERROR in Array-Formeln

Wie Sie wahrscheinlich wissen, sind Array-Formeln in Excel dazu gedacht, mehrere Berechnungen innerhalb einer einzigen Formel durchzuführen. Wenn Sie eine Array-Formel oder einen Ausdruck eingeben, der zu einem Array in der Wert Argument der Funktion IFERROR ein Array von Werten für jede Zelle im angegebenen Bereich zurück. Das folgende Beispiel zeigt die Details.

Nehmen wir an, Sie haben Insgesamt in Spalte B und Preis in Spalte C, und Sie wollen berechnen Gesamtmenge Dies kann wie folgt geschehen Array-Formel, die jede Zelle des Bereichs B2:B4 durch die entsprechende Zelle des Bereichs C2:C4 dividiert und dann die Ergebnisse addiert:

=SUM($B$2:$B$4/$C$2:$C$4)

Die Formel funktioniert gut, solange der Divisorbereich keine Nullen oder leeren Zellen enthält. Wenn es mindestens einen 0-Wert oder eine leere Zelle gibt, wird der Fehler #DIV/0! zurückgegeben:

Um diesen Fehler zu beheben, führen Sie einfach die Division innerhalb der Funktion IFERROR durch:

=SUM(IFERROR($B$2:$B$4/$C$2:$C$4,0))

Die Formel teilt in jeder Zeile (100/2, 200/5 und 0/0) einen Wert in Spalte B durch einen Wert in Spalte C und gibt das Ergebnisfeld {50; 40; #DIV/0!} zurück. Die Funktion IFERROR fängt alle #DIV/0!-Fehler ab und ersetzt sie durch Nullen. Dann addiert die Funktion SUMME die Werte im Ergebnisfeld {50; 40; 0} und gibt das Endergebnis aus (50+40=90).

Hinweis: Bitte denken Sie daran, dass Array-Formeln durch Drücken der Tastenkombination Strg + Umschalt + Eingabe abgeschlossen werden sollten.

IFERROR vs. IF ISERROR

Jetzt, da Sie wissen, wie einfach die Funktion IFERROR in Excel zu verwenden ist, fragen Sie sich vielleicht, warum manche Leute immer noch die Kombination IF ISERROR verwenden. Hat sie irgendwelche Vorteile gegenüber IFERROR? Keine. In den schlechten alten Tagen von Excel 2003 und niedriger, als es IFERROR noch nicht gab, war IF ISERROR die einzige Möglichkeit, Fehler abzufangen. In Excel 2007 und später ist es nur eine etwas komplexere Methode, umdas gleiche Ergebnis erzielen.

Um zum Beispiel Vlookup-Fehler abzufangen, können Sie eine der folgenden Formeln verwenden.

In Excel 2007 - Excel 2016:

In allen Excel-Versionen:

Beachten Sie, dass Sie in der Formel IF ISERROR VLOOKUP zweimal Vlookup durchführen müssen. Im Klartext kann die Formel wie folgt gelesen werden: Wenn Vlookup zu einem Fehler führt, geben Sie "Nicht gefunden" zurück, andernfalls geben Sie das Vlookup-Ergebnis aus.

Und hier ist ein praktisches Beispiel für eine Excel If Iserror Vlookup-Formel:

=IF(ISERROR(VLOOKUP(D2, A2:B5,2,FALSE)), "Nicht gefunden", VLOOKUP(D2, A2:B5,2,FALSE ))

Weitere Informationen finden Sie unter Verwendung der Funktion ISERROR in Excel.

IFERROR vs. IFNA

IFNA wurde mit Excel 2013 eingeführt und ist eine weitere Funktion zur Überprüfung einer Formel auf Fehler. Die Syntax ist ähnlich wie bei IFERROR:

Inwiefern unterscheidet sich IFNA von IFERROR? Die Funktion IFNA fängt nur #N/A-Fehler während IFERROR alle Fehlertypen behandelt.

In welchen Situationen sollten Sie IFNA verwenden? Wenn es unklug ist, alle Fehler zu verschleiern. Wenn Sie beispielsweise mit wichtigen oder sensiblen Daten arbeiten, möchten Sie vielleicht auf mögliche Fehler in Ihrem Datensatz aufmerksam gemacht werden, und die Standard-Excel-Fehlermeldungen mit dem "#"-Symbol könnten anschauliche visuelle Indikatoren sein.

Sehen wir uns an, wie Sie eine Formel erstellen können, die die Meldung "Nicht gefunden" anstelle des N/A-Fehlers anzeigt, der erscheint, wenn der Nachschlagewert nicht im Datensatz vorhanden ist, aber andere Excel-Fehler anzeigt.

Angenommen, Sie möchten die Menge aus der Nachschlagetabelle in die Übersichtstabelle ziehen, wie in der nachstehenden Abbildung gezeigt. Die Verwendung der Excel-Formel Iferror Vlookup würde ein ästhetisch ansprechendes Ergebnis liefern, das technisch nicht korrekt ist, weil Zitronen in der Lookup-Tabelle vorhanden sind:

Um #N/A zu erfassen, aber den Fehler #DIV/0 anzuzeigen, verwenden Sie die Funktion IFNA in Excel 2013 und Excel 2016:

=IFNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE), "Nicht gefunden")

Oder die Kombination IF ISNA in Excel 2010 und früheren Versionen:

=IF(ISNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE)), "Nicht gefunden", VLOOKUP(F3,$A$3:$D$6,4,FALSE))

Die Syntax der IFNA VLOOKUP- und IF ISNA VLOOKUP-Formeln ist ähnlich wie die von IFERROR VLOOKUP und IF ISERROR VLOOKUP.

Wie in der folgenden Abbildung zu sehen ist, gibt die Ifna-Vlookup-Formel "Nicht gefunden" nur für das Element zurück, das nicht in der Lookup-Tabelle vorhanden ist ( Pfirsiche ), denn Zitronen wird #DIV/0! angezeigt, was bedeutet, dass unsere Nachschlagetabelle einen Fehler bei der Teilung durch Null enthält:

Weitere Einzelheiten finden Sie unter Verwendung der Funktion IFNA in Excel.

Bewährte Verfahren für die Verwendung von IFERROR in Excel

Inzwischen wissen Sie bereits, dass die Funktion IFERROR die einfachste Möglichkeit ist, Fehler in Excel abzufangen und mit leeren Zellen, Nullwerten oder eigenen Meldungen zu maskieren. Das bedeutet jedoch nicht, dass Sie jede einzelne Formel mit einer Fehlerbehandlung ausstatten sollten. Die folgenden einfachen Empfehlungen können Ihnen helfen, die Balance zu halten.

1. Fangen Sie Fehler nicht ohne Grund ein.
2. Den kleinstmöglichen Teil einer Formel in IFERROR verpacken.
3. Um nur bestimmte Fehler zu behandeln, verwenden Sie eine Fehlerbehandlungsfunktion mit kleinerem Umfang:
   • IFNA oder IF ISNA, um nur #N/A-Fehler zu erfassen.
   • ISERR, um alle Fehler außer #N/A abzufangen.

So verwenden Sie die Funktion IFERROR in Excel, um Fehler abzufangen und zu behandeln. Wenn Sie sich die in diesem Tutorial besprochenen Formeln genauer ansehen möchten, können Sie gerne unsere Excel-Musterarbeitsmappe IFERROR herunterladen. Ich danke Ihnen für die Lektüre und hoffe, Sie nächste Woche in unserem Blog wiederzusehen.