Clàr-innse
Tha an oideachadh a’ toirt seachad ro-ràdh goirid air co-chàradh gnìomh ADDRESS agus a’ sealltainn mar a chleachdas tu e gus seòladh cealla Excel agus barrachd a thilleadh.
Gus iomradh cealla ann an Excel a chruthachadh, bidh thu is urrainn dhaibh na co-chomharran colbh is sreath a thaipeadh le làimh. Air neo, gheibh thu seòladh cealla Excel bhon loidhne agus àireamhan colbh a chaidh a thoirt don ghnìomh ADDRESS. Cha mhòr gun phuing leis fhèin, an co-bhonn ri gnìomhan eile faodaidh an dòigh seo a bhith mar an aon fhuasgladh ann an suidheachaidhean far nach eil e comasach iomradh a thoirt air cealla gu dìreach. cleachdaidhean bunaiteach
Tha an gnìomh ADDRESS air a dhealbhadh gus seòladh cealla fhaighinn ann an Excel stèidhichte air na h-àireamhan sreath is colbhan ainmichte. Tha seòladh cealla air a thilleadh mar shreang teacsa, chan e fìor iomradh.
Tha an gnìomh ri fhaighinn anns a h-uile tionndadh de Excel airson Microsoft 365 - Excel 2007.
Is e co-chòrdadh a’ ghnìomh ADDRESS mar a leanas:
ADDRESS(row_num, column_num, [abs_num], [a1], [sheet_text])Tha a’ chiad dà argamaid a dhìth:
row_num - an loidhne àireamh ri chleachdadh ann an iomradh na cealla.column_num - àireamh a' cholbh airson iomradh na cealla a thogail.
Is iad na trì argamaidean mu dheireadh, a shònraicheas fòrmat iomraidh na cealla, roghainneil:
abs_num - an seòrsa iomraidh, iomlan no càirdeach. Gabhaidh e gin de na h-àireamhan gu h-ìosal; tha am bun-stèidh iomlan.
- 1 no dh'fhàg e -iomraidhean cealla iomlan mar $A$1
- 2 - iomradh measgaichte: colbh dàimheach agus sreath iomlan mar A$1
- 3 - iomradh measgaichte: colbh iomlan agus sreath càirdeach mar $A1
- 4 - iomradh cealla càirdeach leithid A1
a1 - an stoidhle iomraidh, A1 no R1C1. Ma dh'fhàgar air falbh, bithear a' cleachdadh an stoidhle bunaiteach A1.
- 1 no TRUE no air a fàgail a-mach - tillidh an seòladh cealla san stoidhle iomraidh A1 far a bheil colbhan litrichean is sreathan nan àireamhan.
- 0 no FALSE - a' tilleadh an t-seòlaidh cealla san stoidhle iomraidh R1C1 far a bheil sreathan agus colbhan air an riochdachadh le àireamhan. Bu chòir ainm na duilleige a bhith air a thoirt seachad mar shreang teacsa agus air a chuartachadh ann an comharran-luirg, m.e. "Duilleag 2". Ma dh'fhàgar air falbh, chan eil ainm duilleag-obrach air a chleachdadh, agus tha an seòladh a' dol gu duilleag làithreach.
Mar eisimpleir:
=ADDRESS(1,1)- tillidh e seòladh a' chiad chill (i.e. a' chill aig crois-rathaid na a' chiad sreath agus a' chiad cholbh) mar làn-iomradh ceal $A$1.=ADDRESS(1,1,4)- a' tilleadh seòladh na ciad chill mar iomradh cealla càirdeach A1.
Sa chlàr a leanas, lorgaidh tu beagan a bharrachd sheòrsan iomraidh a ghabhas tilleadh le foirmlean ADDRESS.
Formula Toradh Tuairisgeul =ADDRESS(1,2) $B$1 Ceall iomlaniomradh =ADDRESS(1,2,4) B1 Iomradh cealla càirdeach =ADDRESS(1,2,2) B$1 Colbh co-cheangailte agus sreath iomlan =ADDRESS(1,2,3) $B1 Colbh iomlan agus sreath càirdeach =ADDRESS(1,2,1,FALSE) R1C2 Iomradh iomlan ann an stoidhle R1C1 =ADDRESS(1,2,4,FALSE) R[1]C[2] Iomradh coimeasach san stoidhle R1C1 =ADDRESS(1,2,1,,"Sheet2") Duilleag2!$B$1 Iomradh iomlan air duilleag eile =ADDRESS(1,2,4,, "Bileog2") Duilleag2!B1 Iomradh càirdeach gu duilleag eile Mar a chleachdas tu gnìomh ADDRESS ann an Excel - eisimpleirean foirmle
Tha na h-eisimpleirean gu h-ìosal a’ sealltainn mar a chleachdas tu an gnìomh ADDRESS taobh a-staigh foirmlean nas motha gus barrachd a choileanadh gnìomhan duilich.
Till luach cealla ann an sreath agus colbh a chaidh a thoirt seachad
Mas e an t-amas agad luach fhaighinn bho chill shònraichte stèidhichte air àireamhan nan sreath is nan colbhan, cleachd an spòrs ADDRESS gnìomh còmhla ri INDIRECT:
INDIRECT(ADDRESS(row_num, column_num))Bidh an gnìomh ADDRESS a’ toirt a-mach seòladh na cealla mar theacsa. Bidh an gnìomh INDIRECT a’ tionndadh an teacsa sin gu bhith na iomradh àbhaisteach agus a’ tilleadh an luach bhon chill fhreagarrach.
Mar eisimpleir, gus luach cealla fhaighinn stèidhichte air àireamh na loidhne ann an E1 agus àireamh a’ cholbh ann an E2, cleachd am foirmle seo :
=INDIRECT(ADDRESS(E1,E2))
Faigh an seòladhde chill leis an luach as àirde no as ìsle
San eisimpleir seo, lorgaidh sinn an toiseach na luachan as àirde agus as ìsle anns an raon B2: B7 le bhith a’ cleachdadh na gnìomhan MAX agus MIN agus cuir a-mach na luachan sin gu ceallan sònraichte:
Cill E2:
=MAX(B2:B7)Cill F2:
=MIN(B2:B7)
Agus an uairsin, cleachdaidh sinn SEOLADH an co-bhonn ris a’ ghnìomh MATCH gu faigh seòlaidhean na cealla.
Cill leis an luach as motha:
=ADDRESS(MATCH(E2,B:B,0), COLUMN(B2))Cill leis an luach as ìsle:
=ADDRESS(MATCH(F2,B:B,0), COLUMN(B2))
Mura h-eil thu ag iarraidh na luachan as àirde agus as ìsle ann an ceallan fa leth, faodaidh tu an gnìomh MAX/MIN a neadachadh sa chiad argamaid aig MATCH. Mar eisimpleir:
Cill leis an luach as àirde:
=ADDRESS(MATCH(MAX(B2:B7),B:B,0), COLUMN(B2))Cill leis an luach as ìsle:
=ADDRESS(MATCH(MIN(B2:B7),B:B,0), COLUMN(B2))Mar a tha na foirmlean seo obair
Gus àireamh na loidhne a lorg, cleachdaidh tu an gnìomh MATCH(lookup_value, lookup_array, [match_type]) a thilleas suidheachadh coimeasach de lookup_value ann an lookup_array. Anns an fhoirmle againn, is e an luach lorg an àireamh a thill an gnìomh MAX no MIN, agus is e an raon sgrùdaidh an colbh gu lèir. Mar thoradh air an sin, tha suidheachadh coimeasach luach an t-seallaidh san t-sreath a' freagairt gu dìreach ri àireamh na loidhne air an duilleig.
Gus àireamh a' cholbh a lorg, cleachdaidh tu an gnìomh COLUM. Gun teagamh, chan eil dad a' cur bacadh ort bho bhith a' taipeadh an àireamh gu dìreach san fhoirmle, ach sàbhailidh COLUMN trioblaid cunntais làimhe air eagal 's gu bheil an colbh targaid ann am meadhan na duilleige.
Faigh litir colbhbho àireamh colbh
Gus àireamh ainmichte sam bith a thionndadh gu litir colbh, cleachd an gnìomh SEOLADH taobh a-staigh SUBSTITUTE:
SUBSTITUTE(ADDRESS(1, column_number ,4),"1 ","")Mar eisimpleir, lorg sinn an litir colbh a fhreagras ris an àireamh ann an A2:
=SUBSTITUTE(ADDRESS(1,A2,4),"1","")A’ coimhead air na toraidhean gu h-ìosal, is urrainn dhuinn a ràdh gu bheil a’ chiad cholbh air an duilleig tha A, a tha follaiseach; is e J an 10mh colbh, is e AX an 50mh colbh, agus is e CV an 100mh colbh:
Mar a dh’obraicheas am foirmle seo
Airson luchd-tòiseachaidh, cuir air dòigh an Gnìomh ADDRESS gus iomradh càirdeach a thilleadh dhan chiad chill sa cholbh targaid:
- Airson àireamh na loidhne, cleachd 1.
- Airson àireamh a' cholbh, thoir iomradh air a' chill anns a bheil an àireamh, A2 nar n-eisimpleir.
- Airson na h-argamaid abs_num, cuir a-steach 4.
Mar thoradh air an sin, tillidh ADDRESS(1,A2,4) A1.
Gus cuir às don cho-chomharran loidhne, paisg am foirmle gu h-àrd anns a’ ghnìomh SUBSTITUTE agus cuir sreang fhalamh (“”) na àite “1”. Dèanta!
Faigh seòladh raon ainmichte
Gus seòladh raon ainmichte ann an Excel a lorg, feumaidh tu a' chiad agus an t-iomradh cealla mu dheireadh fhaighinn an-toiseach, agus an uair sin a dhol còmhla riutha . Bidh seo ag obair beagan eadar-dhealaichte ann an Excel ro-fiùghantach (2019 agus nas sine) agus Dynamic Array Excel (Oifis 365 agus Excel 2021). Tha na h-eisimpleirean gu h-ìosal airson Excel 2019 - Excel 2007. Tha an stiùireadh airson Excel 365 agus Excel 2021an seo.
Mar a gheibh thu seòladh a' chiad chill ann an raon
Gus iomradh a thilleadh air a' chiad chill ann an raon ainmichte, cleachd am foirmle coitcheann seo:
ADDRESS(ROW( raon ), COLUMN ( raon ))A’ gabhail ris gu bheil an raon air ainmeachadh mar “Reic”, tha am fìor fhoirmle a’ dol mar a leanas:
=ADDRESS(ROW(Sales), COLUMN(Sales))Agus a’ tilleadh seòladh na cealla gu h-àrd air an taobh chlì san raon:
San fhoirmle seo, bidh na gnìomhan ROW agus COLUMN a’ tilleadh sreath de na h-àireamhan sreath is colbhan uile ann an an raon, fa leth. Stèidhichte air na h-àireamhan sin, bidh an gnìomh ADDRESS a’ togail sreath de sheòlaidhean cealla. Ach a chionn 's gu bheil am foirmle air a chur a-steach ann an aon chill, chan eil ach a' chiad nì den raon air a thaisbeanadh, a fhreagras ris a' chiad chill san raon.
Mar a gheibh thu seòladh na cealla mu dheireadh ann an raon<27
Gus seòladh na cealla mu dheireadh ann an raon ainmichte a lorg, cleachd am foirmle coitcheann seo:
ADDRESS(ROW( raon )+ROWS( raon )-1 , COLUMN ( raon ) + COLUMNS ( raon ) -1)An sàs anns an raon againn leis an ainm “Sales”, tha am foirmle a’ gabhail an cumadh a leanas:
=ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)Agus tillidh e an t-iomradh dhan chill gu h-ìosal air an làimh dheis den raon:
An turas seo, feumaidh sinn àireamhachadh beagan nas iom-fhillte gus an loidhne obrachadh a-mach àireamh. Coltach ris an eisimpleir roimhe, tha an gnìomh ROW a’ toirt dhuinn sreath de na h-àireamhan sreath gu lèir san raon, {4; 5; 6; 7} nar cùise. Feumaidh sinn na h-àireamhan sin “gluasad” leis a’ chunnt sreath iomlan às aonais 1, gus am bibidh a’ chiad nì san raon gu bhith na àireamh sreath mu dheireadh. Gus an àireamh sreath iomlan a lorg, bidh sinn a’ cleachdadh gnìomh ROWS agus a’ toirt air falbh 1 bhon toradh aige: (4-1 = 3). An uairsin, cuiridh sinn 3 ris gach eileamaid den t-sreath thùsail gus an gluasad a tha a dhìth a dhèanamh: {4;5; 6; 7} + 3 = {7; 8; 9; 10}.
'S e àireamh a' cholbh air a thomhas san aon dòigh: {2,3,4}+3-1 = {4,5,6}
Bho na h-àireamhan gu h-àrd de shreath is colbhan, tha an gnìomh ADDRESS a’ cruinneachadh sreath de sheòlaidhean cealla , ach cha till e ach a' chiad tè a fhreagras ris a' chill mu dheireadh san raon.
Faodar an aon toradh a choileanadh cuideachd le bhith a' togail nan luachan as àirde bho arrays na loidhne agus àireamhan nan colbhan. Ach, chan obraich seo ach ann am foirmle rèite, a dh’ fheumas putadh air Ctrl + Shift + Enter gus a chrìochnachadh gu ceart:
=ADDRESS(MAX(ROW(Sales)), MAX(COLUMN(Sales)))Mar a gheibh thu làn sheòladh raon ainmichte
Gus seòladh iomlan raon ainmichte a thilleadh, cha leig thu leas ach an dà fhoirmle bho na h-eisimpleirean roimhe a cho-cheangail agus cuir a-steach gnìomhaiche an raoin (:) eadar.
ADDRESS(ROW( raon ) , COLUMN( raon )) & " : " & ADDRESS(ROW( raon ) + ROWS( raon )-1, COLUMN( raon ) + COLUMNS( raon )-1)Gus toirt air obrachadh airson an t-seata dàta sampall againn, bidh sinn a’ cur an fhìor ainm raon “Sales” an àite an “raon” coitcheann:
=ADDRESS(ROW(Sales), COLUMN(Sales)) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)Agus gheibh sinn an seòladh raon iomlan mar iomlan an t-iomradh $B$4:$D$7:
Gus an raon a thilleadhseòladh mar iomradh càirdeas (às aonais an t-soidhne $, mar B4:D7), suidhich an argamaid abs_num anns an dà ghnìomh ADDRESS gu 4:
=ADDRESS(ROW(Sales), COLUMN(Sales), 4) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1, 4)Gu nàdarra, tha an faodar na h-aon atharrachaidhean a dhèanamh ann am foirmlean fa leth airson a’ chiad chill agus an cealla mu dheireadh, agus seallaidh an toradh coltach ri seo:
Mar a gheibh thu seòladh raon ainmichte ann an Excel 365 agus Excel 2021
Eu-coltach ris a’ ghiùlan traidiseanta “aon fhoirmle - aon chealla” ann an dreachan nas sine, ann an Excel ùr, foirmle sam bith a dh’ fhaodadh grunn luachan a thilleadh, nì seo gu fèin-ghluasadach. Canar dòrtadh ris a leithid de ghiùlan.
Mar eisimpleir, an àite seòladh na ciad chill a thilleadh, tha an fhoirmle gu h-ìosal a’ toirt a-mach seòlaidhean gach cealla ann an raon ainmichte:
=ADDRESS(ROW(Sales), COLUMN(Sales))<3
Gus seòladh na chiad chill a-mhàin fhaighinn, feumaidh tu eadar-ghearradh so-thuigsinn a chomasachadh, a tha air a phiobrachadh gu bunaiteach ann an Excel 2019 agus nas sine. Airson seo, cuir an samhla @ (gnìomhaiche eadar-ghearraidh so-thuigsinn) air beulaibh ainmean an raoin:
=ADDRESS(@ROW(Sales), @COLUMN(Sales))San aon dòigh, ’s urrainn dhut foirmlean eile a chàradh.
Gus cealla mu dheireadh san raon:
Faic cuideachd: Gnìomh Excel WEEKNUM - tionndaidh àireamh na seachdain gu ruige seo agus a chaochladh=ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)Gus seòladh raon ainmichte :
0> Tha an dealbh-sgrìn gu h-ìosal a’ sealltainn nan toraidhean:=ADDRESS(@ROW(Sales), @COLUMN(Sales)) & ":" & ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)
Tip. Nuair a dh’ fhosglas tu duilleag-obrach le foirmlean a chaidh a chruthachadh ann an dreach nas sine ann an raon fiùghantach Excel, bidh gnìomhaiche eadar-ghearraidh so-thuigsinn air a chuir a-steach le Excel gu fèin-ghluasadach.
Sin mar a nì thucuir air ais seòladh cealla ann an Excel. Gus sùil nas mionaidiche a thoirt air na foirmlean air an deach beachdachadh san oideachadh seo, tha fàilte oirbh an leabhar-obrach sampall againn gu h-ìosal a luchdachadh sìos. Tha mi a’ toirt taing dhut airson do leughadh agus tha mi an dòchas d’fhaicinn air ar blog an ath sheachdain!
Cleachd leabhar-obrach airson a luchdachadh sìos
Gnìomh SEOLADH Excel - eisimpleirean foirmle (faidhle .xlsx)
