Sisällysluettelo
Ohjeessa esitellään lyhyesti ADDRESS-funktion syntaksi ja näytetään, miten sitä käytetään muun muassa Excel-solun osoitteen palauttamiseen.
Voit luoda soluviittauksen Excelissä kirjoittamalla sarakkeen ja rivin koordinaatit manuaalisesti. Vaihtoehtoisesti voit saada Excel-solun osoitteen ADDRESS-funktiolle annetuista rivin ja sarakkeen numeroista. Tämä tekniikka on yksinään lähes hyödytön, mutta yhdessä muiden toimintojen kanssa se voi olla ainoa ratkaisu tilanteissa, joissa soluun ei ole mahdollista viitata suoraan.
Excelin ADDRESS-toiminto - syntaksi ja peruskäytöt
ADDRESS-funktio on suunniteltu hakemaan Excelin solun osoite määritettyjen rivi- ja sarakenumeroiden perusteella. Solun osoite palautetaan tekstijonona, ei varsinaisena viittauksena.
Toiminto on käytettävissä kaikissa Excel-versioissa Microsoft 365 - Excel 2007.
ADDRESS-funktion syntaksi on seuraava:
ADDRESS(row_num, column_num, [abs_num], [a1], [sheet_text])Kaksi ensimmäistä argumenttia vaaditaan:
row_num - rivin numero, jota käytetään soluviitteessä.
column_num - sarakkeen numero soluviittauksen muodostamiseksi.
Kolme viimeistä argumenttia, jotka määrittävät soluviittauksen muodon, ovat valinnaisia:
abs_num - viittaustyyppi, absoluuttinen tai suhteellinen. Se voi olla mikä tahansa alla olevista numeroista; oletusarvo on absoluuttinen.
- 1 tai jätetään pois - absoluuttinen soluviittaus kuten $A$1
- 2 - sekaviittaus: suhteellinen sarake ja absoluuttinen rivi kuten A$1.
- 3 - sekaviittaus: absoluuttinen sarake ja suhteellinen rivi kuten $A1.
- 4 - suhteellinen soluviittaus, kuten A1
a1 - viitetyyli, A1 tai R1C1. Jos se jätetään pois, käytetään oletustyyliä A1.
- 1 tai TRUE tai jätetään pois - palauttaa solun osoitteen A1-viitetyyliin, jossa sarakkeet ovat kirjaimia ja rivit numeroita.
- 0 tai FALSE - palauttaa solun osoitteen R1C1-viitetyylillä, jossa rivit ja sarakkeet esitetään numeroina.
sheet_text - sen laskentataulukon nimi, joka sisällytetään ulkoiseen viittaukseen. Laskentataulukon nimi on annettava merkkijonona ja lainausmerkeissä, esimerkiksi "Sheet2". Jos se jätetään pois, laskentataulukon nimeä ei käytetä, ja osoitteen oletusarvona on nykyinen laskentataulukko.
Esimerkiksi:
=ADDRESS(1,1) - palauttaa ensimmäisen solun (eli ensimmäisen rivin ja ensimmäisen sarakkeen leikkauspisteessä olevan solun) osoitteen absoluuttisena soluviitteenä $A$1.
=ADDRESS(1,1,4) - palauttaa ensimmäisen solun osoitteen suhteellisena soluviitteenä A1.
Seuraavassa taulukossa on muutamia muita viittaustyyppejä, joita ADDRESS-kaavoilla voidaan palauttaa.
| Kaava | Tulos | Kuvaus |
| =ADDRESS(1,2) | $B$1 | Absoluuttinen soluviittaus |
| =ADDRESS(1,2,4) | B1 | Suhteellinen soluviite |
| =ADDRESS(1,2,2) | B$1 | Suhteellinen sarake ja absoluuttinen rivi |
| =ADDRESS(1,2,3) | $B1 | Absoluuttinen sarake ja suhteellinen rivi |
| =ADDRESS(1,2,1,FALSE) | R1C2 | Absoluuttinen viittaus R1C1-tyyliin |
| =ADDRESS(1,2,4,FALSE) | R[1]C[2] | Suhteellinen viittaus R1C1-tyyliin |
| =ADDRESS(1,2,1,, "Sheet2") | Sheet2!$B$1 | Absoluuttinen viittaus toiseen arkkiin |
| =ADDRESS(1,2,4,, "Sheet2") | Sheet2!B1 | Suhteellinen viittaus toiseen arkkiin |
Kuinka käyttää ADDRESS-funktiota Excelissä - kaavaesimerkkejä
Alla olevat esimerkit osoittavat, miten ADDRESS-funktiota käytetään suurempien kaavojen sisällä vaikeampien tehtävien suorittamiseen.
Palauta solun arvo tietyllä rivillä ja sarakkeessa.
Jos tavoitteena on saada arvo tietystä solusta sen rivin ja sarakkeen numeroiden perusteella, käytä ADDRESS-funktiota yhdessä INDIRECT-toiminnon kanssa:
INDIRECT(ADDRESS(row_num, column_num))ADDRESS-funktio antaa solun osoitteen tekstinä. INDIRECT-funktio muuttaa tekstin tavalliseksi viittaukseksi ja palauttaa vastaavan solun arvon.
Jos haluat esimerkiksi saada solun arvon E1:n rivinumeron ja E2:n sarakkeen numeron perusteella, käytä tätä kaavaa:
=INDIRECT(OSOITE(E1,E2))
Hae sen solun osoite, jonka arvo on suurin tai pienin.
Tässä esimerkissä etsimme ensin alueen B2:B7 suurimman ja pienimmän arvon käyttämällä MAX- ja MIN-funktioita ja tulostamme nämä arvot erityisiin soluihin:
Solu E2: =MAX(B2:B7)
Solu F2: =MIN(B2:B7)
Sitten käytämme ADDRESS- ja MATCH-funktiota solujen osoitteiden saamiseksi.
Solu, jossa on maksimiarvo:
=ADDRESS(MATCH(E2,B:B,0), COLUMN(B2))
Solu, jossa on min-arvo:
=ADDRESS(MATCH(F2,B:B,0), COLUMN(B2))
Jos et halua suurinta ja pienintä arvoa erillisiin soluihin, voit sijoittaa MAX/MIN-funktion MATCHin ensimmäiseen argumenttiin. Esimerkiksi:
Solu, jonka arvo on suurin:
=ADDRESS(MATCH(MAX(B2:B7),B:B,0), COLUMN(B2))
Solu, jonka arvo on alhaisin:
=ADDRESS(MATCH(MIN(B2:B7),B:B,0), COLUMN(B2))
Miten nämä kaavat toimivat
Rivin numeron löytämiseksi käytetään funktiota MATCH(lookup_value, lookup_array, [match_type]), joka palauttaa lookup_valuen suhteellisen sijainnin lookup_array:ssa. Kaavassamme lookup-arvo on MAX- tai MIN-funktion palauttama numero ja lookup-array koko sarake. Näin ollen lookup-arvon suhteellinen sijainti arjessa vastaa tarkalleen rivin numeroa arkilla.
Sarakkeen numeron löydät COLUM-toiminnolla. Mikään ei tietenkään estä sinua kirjoittamasta numeroa suoraan kaavaan, mutta COLUMN säästää manuaalisen laskemisen vaivalta, jos kohdesarake on keskellä arkkia.
Hae sarakkeen kirjain sarakkeen numerosta
Voit muuttaa minkä tahansa numeron sarakkeen kirjaimeksi käyttämällä ADDRESS-toimintoa SUBSTITUTE-toiminnon sisällä:
SUBSTITUTE(OSOITE(1, column_number ,4), "1","")Etsitään esimerkiksi sarakkeen kirjain, joka vastaa numeroa A2:
=SUBSTITUTE(ADDRESS(1,A2,4), "1","")
Kun tarkastellaan alla olevia tuloksia, voidaan todeta, että arkin ensimmäinen sarake on A, mikä on ilmeistä; 10. sarake on J, 50. sarake on AX ja 100. sarake on CV:
Miten tämä kaava toimii
Aluksi määritä ADDRESS-funktio palauttamaan suhteellinen viittaus kohdesarakkeen ensimmäiseen soluun:
- Käytä rivin numerona 1.
- Anna sarakkeen numeroksi viittaus numeron sisältävään soluun, esimerkissämme A2.
- Syötä abs_num-argumentiksi 4.
Tuloksena ADDRESS(1,A2,4) palauttaisi A1:n.
Päästäksesi eroon rivikoordinaatista kääri yllä oleva kaava SUBSTITUTE-funktioon ja korvaa "1" tyhjällä merkkijonolla (""). Valmis!
Hae nimetyn alueen osoite
Jos haluat löytää nimetyn alueen osoitteen Excelissä, sinun on ensin saatava ensimmäisen ja viimeisen soluviittauksen ja yhdistettävä ne sitten toisiinsa. Tämä toimii hieman eri tavalla esidynaamisessa Excelissä (2019 ja vanhemmat) ja dynaamisessa Array Excelissä (Office 365 ja Excel 2021). Alla olevat esimerkit ovat Excel 2019 - Excel 2007 -ohjelmia varten. Excel 365- ja Excel 2021 -ohjelmia koskevat ohjeet ovat täällä.
Miten saada alueen ensimmäisen solun osoite?
Jos haluat palauttaa viittauksen nimetyn alueen ensimmäiseen soluun, käytä tätä yleistä kaavaa:
ADDRESS(ROW( alue ),COLUMN( alue ))Jos oletetaan, että alueen nimi on "Myynti", todellinen kaava on seuraava:
=ADDRESS(ROW(Sales), COLUMN(Sales))
Ja palauttaa alueen vasemman yläpuolisen solun osoitteen:
Tässä kaavassa ROW- ja COLUMN-funktiot palauttavat alueen kaikkien rivien ja sarakkeiden numerot. ADDRESS-funktio muodostaa näiden numeroiden perusteella solujen osoitteiden joukon. Mutta koska kaava on kirjoitettu yhteen soluun, vain joukon ensimmäinen kohde näytetään, joka vastaa alueen ensimmäistä solua.
Miten saada alueen viimeisen solun osoite?
Jos haluat löytää nimetyn alueen viimeisen solun osoitteen, käytä tätä yleistä kaavaa:
ADDRESS(ROW( alue )+ROWS( alue )-1,COLUMN( alue )+COLUMNS( alue )-1)Sovellettuna alueeseen nimeltä "Myynti" kaava on seuraavanlainen:
=ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)
Ja palauttaa viittauksen alueen oikeaan alareunan soluun:
Tällä kertaa tarvitsemme hieman monimutkaisempia laskutoimituksia rivien lukumäärän selvittämiseksi. Kuten edellisessä esimerkissä, ROW-funktio antaa meille matriisin, joka sisältää kaikki rivien numerot alueella, tässä tapauksessa {4;5;6;7}. Meidän on "siirrettävä" näitä numeroita rivien kokonaislukumäärän verran miinus 1, jotta matriisin ensimmäisestä kohdasta tulee viimeinen rivin numero. Rivien kokonaislukumäärän löytämiseksi käytämme ROWS-funktiota ja seuraavia funktioitavähennetään sen tuloksesta 1: (4-1=3). Sitten lisätään 3 jokaiselle alkuperäisen joukon alkioelementille, jotta saadaan aikaan tarvittava siirto: {4;5;6;7} + 3 = {7;8;9;10}.
Sarakkeen numero lasketaan samalla tavalla: {2,3,4}+3-1 = {4,5,6}.
ADDRESS-funktio kokoaa edellä esitetyistä rivien ja sarakkeiden numeromääristä solujen osoitemäärän, mutta palauttaa vain alueen viimeistä solua vastaavan ensimmäisen osoitteen.
Samaan tulokseen päästään myös poimimalla maksimiarvot rivin ja sarakkeen numeroiden riveistä ja sarakkeista. Tämä toimii kuitenkin vain rivitietokaavassa, joka vaatii Ctrl + Shift + Enter -näppäinyhdistelmän painamisen, jotta kaava valmistuu oikein:
=ADDRESS(MAX(ROW(Sales)), MAX(COLUMN(Sales))))
Kuinka saada nimetyn alueen täydellinen osoite
Jos haluat palauttaa nimetyn alueen täydellisen osoitteen, sinun tarvitsee vain yhdistää kaksi edellisissä esimerkeissä käytettyä kaavaa ja lisätä niiden väliin alueoperaattori (:).
ADDRESS(ROW( alue ), COLUMN( alue )) & ":" & ADDRESS(ROW( alue ) + RIVIT( alue )-1, COLUMN( alue ) + COLUMNS( alue )-1)Jotta se toimisi esimerkkitietoaineistossamme, korvataan yleinen "range" oikealla alueen nimellä "Sales":
=ADDRESS(ROW(Sales), COLUMN(Sales)) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)
Ja saat koko alueen osoitteen absoluuttinen viite $B$4:$D$7:
Jos haluat palauttaa alueen osoitteen relative (ilman $-merkkiä, kuten B4:D7), aseta molempien ADDRESS-funktioiden abs_num-argumentiksi 4:
=ADDRESS(ROW(Sales), COLUMN(Sales), 4) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1, 4)
Samat muutokset voidaan luonnollisesti tehdä myös ensimmäisen ja viimeisen solun yksittäisiin kaavoihin, ja tulos näyttää samankaltaiselta kuin tämä:
Kuinka saada nimetyn alueen osoite Excel 365: ssä ja Excel 2021: ssä?
Toisin kuin perinteinen "yksi kaava - yksi solu" -käyttäytyminen vanhemmissa versioissa, uudessa Excelissä kaikki kaavat, jotka voivat palauttaa useita arvoja, tekevät sen automaattisesti. Tällaista käyttäytymistä kutsutaan läikkymiseksi.
Esimerkiksi alla oleva kaava palauttaa ensimmäisen solun osoitteen sijasta jokaisen solun osoitteet nimetyllä alueella:
=ADDRESS(ROW(Sales), COLUMN(Sales))
Saadaksesi osoitteen ensimmäinen solu vain, sinun on otettava käyttöön implisiittinen leikkaus, joka käynnistyy oletusarvoisesti Excel 2019:ssä ja sitä vanhemmissa ohjelmissa. Laita tätä varten @-symboli (implisiittinen leikkausoperaattori) ennen alueiden nimiä:
=ADDRESS(@ROW(Sales), @COLUMN(Sales))
Samalla tavalla voit korjata muitakin kaavoja.
Saadaksesi viimeinen solu alueella:
=ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)
Saadaksesi nimetyn alueen osoite :
=ADDRESS(@ROW(Sales), @COLUMN(Sales)) & ":" & ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)
Alla olevassa kuvakaappauksessa näkyvät tulokset:
Vihje. Kun avaat dynaamisessa Excel-määrityksessä työarkin, jossa on vanhemmassa versiossa luotuja kaavoja, Excel lisää automaattisesti implisiittisen leikkausoperaattorin.
Näin palautat solun osoitteen Excelissä. Jos haluat tutustua tarkemmin kaikkiin tässä opetusohjelmassa käsiteltyihin kaavoihin, voit ladata alla olevan esimerkkityökirjan. Kiitos lukemisesta ja toivottavasti tapaamme blogissamme ensi viikolla!
Käytännön työkirja ladattavissa
Excel ADDRESS-toiminto - kaavaesimerkkejä (.xlsx-tiedosto)
