Mafunzo yanatoa utangulizi mfupi wa sintaksia ya chaguo la kukokotoa ADDRESS na inaonyesha jinsi ya kuitumia kurejesha anwani ya kisanduku cha Excel na zaidi.

Ili kuunda marejeleo ya kisanduku katika Excel, wewe inaweza kuandika safu wima na kuratibu za safu kwa mikono. Vinginevyo, unaweza kupata anwani ya seli ya Excel kutoka kwa safu mlalo na nambari za safu wima zinazotolewa kwa chaguo za kukokotoa ADDRESS. Karibu haina maana yenyewe, pamoja na kazi nyingine mbinu hii inaweza kuwa suluhisho pekee katika hali wakati haiwezekani kurejelea seli moja kwa moja.

Kitendaji cha Excel ADDRESS - sintaksia na matumizi ya msingi

Kitendaji cha ADDRESS kimeundwa ili kupata anwani ya seli katika Excel kulingana na safu mlalo na nambari za safu wima zilizobainishwa. Anwani ya seli inarejeshwa kama mfuatano wa maandishi, si rejeleo halisi.

Kitendaji hiki kinapatikana katika matoleo yote ya Excel kwa Microsoft 365 - Excel 2007.

Sintaksia ya kitendakazi cha ADDRESS ni kama ifuatavyo:

Hoja mbili za kwanza zinahitajika:

nambari_mlalo - safu mlalo nambari ya kutumia katika marejeleo ya seli.

safuwima_num - nambari ya safu wima ya kujenga rejeleo la seli.

Hoja tatu za mwisho, ambazo zinabainisha umbizo la marejeleo ya seli, ni hiari:

abs_num - aina ya marejeleo, kabisa au jamaa. Inaweza kuchukua nambari yoyote kati ya zilizo hapa chini; chaguo-msingi ni kabisa.

• 1 au imeachwa -rejeleo kamili la kisanduku kama $A$1
• 2 - marejeleo mchanganyiko: safu wima ya jamaa na safu mlalo kamili kama A$1
• 3 - marejeleo mchanganyiko: safu wima kamili na safu mlalo kama $A1
• 4 - marejeleo ya kisanduku cha jamaa kama vile A1

a1 - mtindo wa marejeleo, A1 au R1C1. Ikiondolewa, mtindo chaguomsingi wa A1 unatumika.

• 1 au TRUE au imeachwa - hurejesha anwani ya seli katika mtindo wa marejeleo wa A1 ambapo safu wima ni herufi na safu mlalo ni nambari.
• 0 au FALSE - hurejesha anwani ya seli katika mtindo wa marejeleo wa R1C1 ambapo safu mlalo na safu wima zinawakilishwa na nambari.

laha_maandishi - jina la laha ya kazi ili kujumuisha katika marejeleo ya nje. Jina la laha linapaswa kutolewa kama mfuatano wa maandishi na kuambatanishwa katika alama za nukuu, k.m. "Karatasi 2". Ikiwa imeachwa, hakuna jina la laha ya kazi linalotumika, na anwani chaguomsingi ya laha ya sasa.

Kwa mfano:

=ADDRESS(1,1) - hurejesha anwani ya kisanduku cha kwanza (yaani kisanduku kwenye makutano ya kisanduku cha kwanza). safu mlalo ya kwanza na safu wima ya kwanza) kama marejeleo kamili ya kisanduku $A$1.

=ADDRESS(1,1,4) - hurejesha anwani ya kisanduku cha kwanza kama rejeleo la kisanduku A1.

Katika jedwali lifuatalo, utapata aina chache zaidi za marejeleo ambazo zinaweza kurejeshwa kwa fomula za ADDRESS.

Jinsi ya kutumia kitendakazi cha ADDRESS katika Excel - mifano ya fomula

Mifano iliyo hapa chini inaonyesha jinsi ya kutumia kitendakazi cha ADDRESS ndani ya fomula kubwa zaidi ili kutimiza zaidi kazi ngumu.

Rejesha thamani ya seli katika safu mlalo na safu wima fulani

Ikiwa lengo lako ni kupata thamani kutoka kwa kisanduku mahususi kulingana na nambari zake za safu mlalo na safu wima, tumia furaha ya ADDRESS. kitendo pamoja na INDIRECT:

Chaguo za kukokotoa za ADDRESS hutoa anwani ya seli kama maandishi. Chaguo za kukokotoa za INDIRECT hugeuza maandishi hayo kuwa marejeleo ya kawaida na kurudisha thamani kutoka kwa seli inayolingana.

Kwa mfano, ili kupata thamani ya seli kulingana na nambari ya safu mlalo katika E1 na nambari ya safu wima katika E2, tumia fomula hii. :

=INDIRECT(ADDRESS(E1,E2))

Pata anwaniya kisanduku chenye thamani ya juu au ya chini zaidi

Katika mfano huu, kwanza tutapata thamani za juu na za chini kabisa katika masafa B2:B7 kwa kutumia vitendakazi MAX na MIN na kutoa thamani hizo kwenye seli maalum:

Kisanduku E2: =MAX(B2:B7)

Kisanduku F2: =MIN(B2:B7)

Na kisha, tutatumia ADDRESS pamoja na kitendakazi cha MATCH ili pata anwani za seli.

Kisanduku chenye thamani ya juu zaidi:

=ADDRESS(MATCH(E2,B:B,0), COLUMN(B2))

Kisanduku chenye thamani ndogo:

=ADDRESS(MATCH(F2,B:B,0), COLUMN(B2))

Iwapo hutaki thamani za juu na za chini zaidi katika seli tofauti, unaweza kuweka chaguo za kukokotoa MAX/MIN katika hoja ya kwanza ya MATCH. Kwa mfano:

Kisanduku chenye thamani ya juu zaidi:

=ADDRESS(MATCH(MAX(B2:B7),B:B,0), COLUMN(B2))

Kisanduku chenye thamani ya chini kabisa:

=ADDRESS(MATCH(MIN(B2:B7),B:B,0), COLUMN(B2))

Jinsi fomula hizi work

Ili kupata nambari ya safu mlalo, unatumia chaguo la kukokotoa MATCH(lookup_value, lookup_array, [match_type]) ambayo inarejesha nafasi ya jamaa ya lookup_value katika lookup_array. Katika fomula yetu, thamani ya kuangalia ni nambari iliyorejeshwa na kazi ya MAX au MIN, na safu ya utafutaji ni safu nzima. Kwa hivyo, nafasi ya jamaa ya thamani ya kuangalia katika safu inalingana kabisa na nambari ya safu mlalo kwenye laha.

Ili kupata nambari ya safu wima, unatumia chaguo la kukokotoa la COLUM. Bila shaka, hakuna kinachokuzuia kuandika nambari moja kwa moja kwenye fomula, lakini COLUMN huokoa shida ya kuhesabu kwa mikono ikiwa safu wima lengwa iko katikati ya laha.

Pata herufi ya safu wima.kutoka kwa nambari ya safu wima

Ili kugeuza nambari yoyote uliyopewa kuwa herufi ya safu wima, tumia kitendakazi cha ANWANI ndani ya SUBSTITUTE:

Kwa mfano, hebu tutafute herufi ya safu wima inayolingana na nambari katika A2:

=SUBSTITUTE(ADDRESS(1,A2,4),"1","")

Tukiangalia matokeo hapa chini, tunaweza kusema kwamba safu wima ya kwanza. kwenye karatasi ni A, ambayo ni dhahiri; safu ya 10 ni J, safu ya 50 ni AX, na safu wima ya 100 ni CV:

Jinsi fomula hii inavyofanya kazi

Kwa wanaoanza, sanidi Chaguo za kukokotoa za ADDRESS ili kurejesha rejeleo husika kwa kisanduku cha kwanza katika safu wima lengwa:

• Kwa nambari ya safu mlalo, tumia 1.
• Kwa nambari ya safu wima, toa rejeleo kwenye kisanduku. iliyo na nambari, A2 katika mfano wetu.
• Kwa hoja ya abs_num, weka 4.

Kwa matokeo, ADDRESS(1,A2,4) itarudisha A1.

Ili kuondoa uratibu wa safu mlalo, funga fomula iliyo hapo juu katika chaguo za kukokotoa SUBSTITUTE na ubadilishe "1" kwa mfuatano tupu (""). Umemaliza!

Pata anwani ya safu iliyotajwa

Ili kupata anwani ya safu iliyotajwa katika Excel, utahitaji kwanza kupata marejeleo ya kisanduku cha kwanza na cha mwisho, na kisha uziunganishe pamoja. . Hii inafanya kazi kwa njia tofauti kidogo katika Excel-dynamic ya awali (2019 na zaidi) na Dynamic Array Excel (Ofisi 365 na Excel 2021). Mifano iliyo hapa chini ni ya Excel 2019 - Excel 2007. Maagizo ya Excel 365 na Excel 2021 nihapa.

Jinsi ya kupata anwani ya kisanduku cha kwanza katika safu

Ili kurudisha rejeleo kwa kisanduku cha kwanza katika safu iliyotajwa, tumia fomula hii ya jumla:

Tukichukulia kuwa masafa yameitwa "Mauzo", fomula halisi huenda kama ifuatavyo:

=ADDRESS(ROW(Sales), COLUMN(Sales))

Na hurejesha anwani ya kisanduku cha juu kushoto katika safu:

Katika fomula hii, vitendaji vya ROW na COLUMN vinarejesha safu ya nambari zote za safu mlalo na safu wima katika. mbalimbali, kwa mtiririko huo. Kulingana na nambari hizo, chaguo za kukokotoa ADDRESS huunda safu ya anwani za seli. Lakini kwa sababu fomula imeingizwa katika kisanduku kimoja, ni kipengee cha kwanza pekee cha safu kinachoonyeshwa, ambacho kinalingana na kisanduku cha kwanza katika safu.

Jinsi ya kupata anwani ya kisanduku cha mwisho katika safu

Ili kupata anwani ya kisanduku cha mwisho katika safu iliyotajwa, tumia fomula hii ya jumla:

Imetumika kwa safu yetu iitwayo "Mauzo", fomula inachukua sura ifuatayo:

=ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)

Na kurejesha rejeleo kwenye seli ya chini kulia ya safu:

Wakati huu, tunahitaji hesabu changamano zaidi ili kuhesabu safu mlalo. nambari. Kama ilivyo katika mfano uliopita, chaguo za kukokotoa za ROW hutupa safu ya nambari zote za safu mlalo katika safu, {4;5;6;7} kwa upande wetu. Tunahitaji "kuhamisha" nambari hizi kwa jumla ya hesabu ya safu mlalo kutoa 1, ilikipengee cha kwanza katika safu inakuwa nambari ya safu ya mwisho. Ili kupata hesabu ya jumla ya safu mlalo, tunatumia kitendakazi cha ROWS na kutoa 1 kutoka kwa matokeo yake: (4-1=3). Kisha, tunaongeza 3 kwa kila kipengele cha safu ya awali ili kufanya mabadiliko yanayohitajika: {4;5;6;7} + 3 = {7;8;9;10}.

Nambari ya safu wima ni imekokotolewa kwa njia sawa: {2,3,4}+3-1 = {4,5,6}

Kutoka kwa safu zilizo hapo juu za nambari za safu mlalo na safu wima, chaguo la kukokotoa la ADDRESS hukusanya safu ya anwani za seli. , lakini hurejesha tu ya kwanza inayolingana na kisanduku cha mwisho katika safu.

Tokeo sawa pia linaweza kupatikana kwa kuchagua thamani za juu zaidi kutoka kwa safu mlalo na nambari za safu wima. Walakini, hii inafanya kazi tu katika fomula ya safu, ambayo inahitaji kubonyeza Ctrl + Shift + Enter ili kukamilishwa ipasavyo:

=ADDRESS(MAX(ROW(Sales)), MAX(COLUMN(Sales)))

Jinsi ya kupata anwani kamili ya safu iliyotajwa

Ili kurudisha anwani kamili ya safu iliyotajwa, unahitaji tu kuambatanisha fomula mbili kutoka kwa mifano iliyotangulia na uweke kiendesha masafa (:) katikati.

Ili kuifanya ifanye kazi kwa sampuli ya seti yetu ya data, tunabadilisha "safa" ya jumla na jina halisi la masafa "Mauzo":

=ADDRESS(ROW(Sales), COLUMN(Sales)) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)

Na kupata anwani kamili ya masafa kama absolute rejelea $B$4:$D$7:

Ili kurudisha masafaanwani kama rejeleo jamaa (bila ishara ya $, kama B4:D7), weka hoja ya abs_num katika vitendaji vyote viwili ADDRESS kuwa 4:

=ADDRESS(ROW(Sales), COLUMN(Sales), 4) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1, 4)

Kwa kawaida, mabadiliko sawa yanaweza kufanywa katika fomula za kibinafsi za seli ya kwanza na ya mwisho, na matokeo yataonekana sawa na haya:

Jinsi ya kupata anwani ya safu iliyotajwa katika Excel. 365 na Excel 2021

Tofauti na tabia ya kitamaduni ya "fomula moja - seli moja" katika matoleo ya awali, katika Excel mpya, fomula yoyote ambayo inaweza kurejesha thamani nyingi, hufanya hili kiotomatiki. Tabia kama hiyo inaitwa kumwagika.

Kwa mfano, badala ya kurudisha anwani ya kisanduku cha kwanza, fomula iliyo hapa chini hutoa anwani za kila seli katika safu iliyotajwa:

=ADDRESS(ROW(Sales), COLUMN(Sales))

Ili kupata anwani ya kisanduku cha kwanza pekee, unahitaji kuwezesha makutano yasiyo dhahiri, ambayo yanaanzishwa kwa chaguomsingi katika Excel 2019 na zaidi. Kwa hili, weka alama ya @ (mendeshaji wa makutano dhahiri) kabla ya majina ya safu:

=ADDRESS(@ROW(Sales), @COLUMN(Sales))

Kwa njia sawa, unaweza kurekebisha fomula zingine.

Ili kupata kisanduku cha mwisho katika masafa:

=ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)

Ili kupata anwani ya safu iliyotajwa :

=ADDRESS(@ROW(Sales), @COLUMN(Sales)) & ":" & ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)

Kidokezo. Wakati wa kufungua laha ya kazi iliyo na fomula zilizoundwa katika toleo la zamani katika safu inayobadilika ya Excel, opereta ya makutano isiyo wazi inaingizwa na Excel kiotomatiki.

Hivyo ndivyo unavyofanya.rudisha anwani ya seli katika Excel. Ili kuangalia kwa karibu fomula zote zilizojadiliwa katika somo hili, unakaribishwa kupakua sampuli yetu ya kitabu cha kazi hapa chini. Ninakushukuru kwa kusoma na natumai kukuona kwenye blogu yetu wiki ijayo!

Fanya mazoezi ya kupakuliwa kwa kitabu cha kazi

Kitendaji cha Excel ADDRESS - mifano ya fomula (.xlsx file)