Õpetuses tutvustatakse lühidalt funktsiooni ADDRESS süntaksit ja näidatakse, kuidas seda kasutada Exceli lahtri aadressi tagastamiseks ja muud.

Exceli lahtrile viitamise loomiseks võite käsitsi sisestada veeru ja rea koordinaadid. Teise võimalusena saate Exceli lahtri aadressi saada funktsioonile ADDRESS esitatud rea ja veeru numbritest. Iseenesest peaaegu mõttetu, kuid koos teiste funktsioonidega võib see tehnika olla ainus lahendus olukordades, kus lahtrile ei ole võimalik otse viidata.

Exceli funktsioon ADDRESS - süntaks ja põhilised kasutusalad

Funktsioon ADDRESS on mõeldud Exceli lahtri aadressi saamiseks määratud rea ja veeru numbrite alusel. Lahtri aadress tagastatakse tekstistringina, mitte tegeliku viitena.

Funktsioon on saadaval kõigis Exceli versioonides Microsoft 365 - Excel 2007.

Funktsiooni ADDRESS süntaks on järgmine:

Esimesed kaks argumenti on vajalikud:

row_num - rea number, mida kasutada lahtri viites.

column_num - veeru number, et luua lahtri viide.

Viimased kolm argumenti, mis määravad lahtri viiteformaadi, on valikulised:

abs_num - viite tüüp, absoluutne või suhteline. See võib võtta ükskõik millise allpool esitatud numbri; vaikimisi on absoluutne.

• 1 või välja jäetud - absoluutne lahtriviide nagu $A$1
• 2 - segaviide: suhteline veerg ja absoluutne rida nagu A$1
• 3 - segaviide: absoluutne veerg ja suhteline rida nagu $A1
• 4 - suhteline lahtriviide, näiteks A1

a1 - viitestiil, A1 või R1C1. Kui see jäetakse välja, kasutatakse vaikimisi stiili A1.

• 1 või TRUE või välja jäetud - tagastab lahtri aadressi A1 viitamisstiilis, kus veerud on tähed ja read on numbrid.
• 0 või FALSE - tagastab lahtri aadressi R1C1 viitamisstiilis, kus read ja veerud on esitatud numbritega.

sheet_text - töölehe nimi, mis lisatakse välisviites. Lehe nimi tuleb esitada tekstisõnana ja sulgeda jutumärkidesse, nt "Sheet2". Kui see jäetakse välja, ei kasutata töölehe nime ja aadressiks võetakse vaikimisi praegune leht.

Näiteks:

=ADDRESS(1,1) - tagastab esimese lahtri (st esimese rea ja esimese veeru ristumiskohas oleva lahtri) aadressi absoluutse lahtriviidetena $A$1.

=AADRESS(1,1,4) - tagastab esimese lahtri aadressi suhtelise lahtriviitena A1.

Järgnevas tabelis on esitatud veel mõned viitetüübid, mida saab ADDRESS-vormeliga tagastada.

Kuidas kasutada funktsiooni ADDRESS Excelis - valemi näited

Allpool toodud näited näitavad, kuidas kasutada funktsiooni ADDRESS suuremate valemite sees, et täita keerulisemaid ülesandeid.

Tagastab lahtri väärtuse antud reas ja veerus

Kui teie eesmärk on saada väärtus konkreetsest lahtrist selle rea ja veeru numbrite põhjal, kasutage funktsiooni ADDRESS koos funktsiooniga INDIRECT:

Funktsioon ADDRESS väljastab lahtri aadressi tekstina. Funktsioon INDIRECT muudab selle teksti tavaliseks viiteks ja tagastab vastava lahtri väärtuse.

Näiteks, et saada lahtri väärtus, mis põhineb rea numbril E1 ja veeru numbril E2, kasutage seda valemit:

=INDIRECT(AADRESS(E1,E2))

Suurima või väikseima väärtusega lahtri aadressi saamine

Selles näites leiame kõigepealt suurima ja väikseima väärtuse vahemikus B2:B7, kasutades funktsioone MAX ja MIN, ning väljastame need väärtused spetsiaalsetesse lahtritesse:

Rakk E2: =MAX(B2:B7)

Lahter F2: =MIN(B2:B7)

Seejärel kasutame lahtri aadresside saamiseks funktsiooni ADDRESS koos funktsiooniga MATCH.

Lahter maksimaalse väärtusega:

=ADDRESS(MATCH(E2,B:B,0), COLUMN(B2))

Lahter min väärtusega:

=ADDRESS(MATCH(F2,B:B,0), COLUMN(B2))

Kui te ei soovi, et suurim ja väikseim väärtus oleksid eraldi lahtrites, võite funktsiooni MAX/MIN lisada MATCH esimesele argumendile. Näiteks:

Suurima väärtusega lahter:

=ADDRESS(MATCH(MAX(B2:B7),B:B,0), COLUMN(B2))

Madalaima väärtusega lahter:

=ADDRESS(MATCH(MIN(B2:B7),B:B,0), COLUMN(B2))

Kuidas need valemid toimivad

Rea numbri leidmiseks kasutate funktsiooni MATCH(lookup_value, lookup_array, [match_type]), mis tagastab lookup_value suhtelise positsiooni lookup_array's. Meie valemis on lookup value funktsiooniga MAX või MIN tagastatud number ja lookup array on kogu veerg. Järelikult vastab lookup value'i suhteline positsioon massiivis täpselt rea numbrile lehel.

Veergude numbri leidmiseks kasutate funktsiooni COLUMN. Muidugi ei takista miski teil numbri otse valemisse sisestamist, kuid COLUMN säästab käsitsi lugemise vaeva juhul, kui sihtveerg asub lehe keskel.

Saada veeru number veeru tähega veeru numbrist

Selleks, et muuta ükskõik milline number veerus olevaks täheks, kasutage funktsiooni ADDRESS funktsiooni SUBSTITUTE sees:

Leiame näiteks veeru tähe, mis vastab numbrile A2:

=SUBSTITUTE(ADDRESS(1,A2,4), "1","")

Vaadates allpool esitatud tulemusi, võime öelda, et lehe esimene veerg on A, mis on ilmselge; 10. veerg on J, 50. veerg on AX ja 100. veerg on CV:

Kuidas see valem töötab

Alustuseks seadistage funktsioon ADDRESS nii, et see tagastab suhtelise viite sihtveergu esimesse lahtrisse:

• Rea numbriks kasutage 1.
• Andke veeru numbri jaoks viide lahtrisse, mis sisaldab numbrit, meie näites A2.
• Argumendiks abs_num sisestage 4.

Tulemusena annaks ADDRESS(1,A2,4) tagasi A1.

Selleks, et vabaneda rea koordinaadist, mähkige ülaltoodud valem funktsiooniga SUBSTITUTE ja asendage "1" tühja stringiga (""). Valmis!

Nimetatud vahemiku aadressi saamine

Nimelise vahemiku aadressi leidmiseks Excelis peate kõigepealt saama esimese ja viimase lahtri viite ning seejärel ühendama need omavahel. See toimib pisut erinevalt dünaamilise Exceli eelse (2019 ja vanemad) ja dünaamilise vahemiku Excelis (Office 365 ja Excel 2021). Allpool toodud näited on Excel 2019 - Excel 2007. Excel 365 ja Excel 2021 juhised on siin.

Kuidas saada vahemiku esimese lahtri aadressi

Et tagastada viide nimivahemiku esimesele lahtrile, kasutage seda üldist valemit:

Eeldades, et vahemiku nimi on "Müük", on tegelik valem järgmine:

=ADDRESS(ROW(Sales), COLUMN(Sales))

Ja tagastab vahemiku vasakpoolse ülemise lahtri aadressi:

Selles valemis annavad funktsioonid ROW ja COLUMN tagasi massiivi, mis sisaldab vastavalt kõiki rea ja veeru numbreid vahemikus. Nende numbrite põhjal koostab funktsioon ADDRESS lahtrite aadresside massiivi. Kuid kuna valem on sisestatud ühte lahtrisse, kuvatakse ainult massiivi esimene element, mis vastab vahemiku esimesele lahtrile.

Kuidas saada vahemiku viimase lahtri aadressi

Nimelise vahemiku viimase lahtri aadressi leidmiseks kasutage seda üldist valemit:

Rakendatuna meie vahemikule nimega "Müük", võtab valem järgmise kuju:

=ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)

Ja tagastab viite vahemiku parempoolse alumise lahtrile:

Seekord on meil vaja veidi keerulisemaid arvutusi, et leida rea number. Nagu eelmises näites, annab funktsioon ROW meile massiivi kõigist rea numbritest vahemikus, meie puhul {4;5;6;7}. Me peame neid numbreid "nihutama" kogu rea arvu võrra miinus 1, nii et massiivi esimesest elemendist saaks viimane rea number. Rea kogu arvu leidmiseks kasutame funktsiooni ROWS ja järgmist funktsioonilahutame selle tulemusest 1: (4-1=3). Seejärel lisame 3 algse massiivi igale elemendile, et teha vajalik nihke: {4;5;6;7} + 3 = {7;8;9;10}.

Veergude arv arvutatakse sarnaselt: {2,3,4}+3-1 = {4,5,6}.

Ülaltoodud ridade ja veergude numbrite massiividest koostab funktsioon ADDRESS lahtrite aadresside massiivi, kuid tagastab ainult esimese, mis vastab vahemiku viimasele lahtrile.

Sama tulemuse saab saavutada ka ridade ja veergude numbrite massiividest maksimaalsete väärtuste valimisega. See toimib aga ainult massiivi valemis, mille korrektseks täitmiseks on vaja vajutada Ctrl + Shift + Enter:

=ADDRESS(MAX(ROW(Sales)), MAX(COLUMN(Sales)))

Kuidas saada täisaadressi nimega vahemik

Nimelise vahemiku täieliku aadressi tagastamiseks peate lihtsalt ühendama kaks eelmiste näidete valemit ja sisestama nende vahele vahemikuoperaatori (:).

Selleks, et see meie näidisandmestiku puhul toimiks, asendame üldise "range" tegeliku vahemiku nimega "Sales":

=ADDRESS(ROW(Sales), COLUMN(Sales)) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)

Ja saada täielik vahemiku aadress kui absoluutne viide $B$4:$D$7:

Et tagastada vahemiku aadressi kui suhteline viide (ilma $-märgita, nagu B4:D7), siis seadke mõlemas ADDRESS-funktsioonis abs_num argumendiks 4:

=ADDRESS(ROW(Sales), COLUMN(Sales), 4) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1, 4)

Loomulikult saab samu muudatusi teha ka esimese ja viimase lahtri üksikutes valemites ning tulemus näeb välja sarnane:

Kuidas saada Excel 365 ja Excel 2021 nimelise vahemiku aadressi.

Erinevalt traditsioonilisest "üks valem - üks lahter" käitumisest vanemates versioonides, teeb uues Excelis iga valem, mis võib potentsiaalselt tagastada mitu väärtust, seda automaatselt. Sellist käitumist nimetatakse ülekandmiseks.

Näiteks annab alljärgnev valem esimese lahtri aadressi asemel välja iga nimelise vahemiku iga lahtri aadressid:

=ADDRESS(ROW(Sales), COLUMN(Sales))

Et saada aadressi esimene lahter ainult, tuleb teil lubada kaudne lõikamine, mis käivitub Excel 2019 ja vanemates programmides vaikimisi. Selleks pange vahemiku nimede ette sümbol @ (kaudse lõikamise operaator):

=ADDRESS(@ROW(Sales), @COLUMN(Sales))

Samamoodi saate parandada ka teisi valemeid.

Et saada viimane lahter vahemikus:

=ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)

Et saada nimega vahemiku aadress :

=ADDRESS(@ROW(Sales), @COLUMN(Sales)) & ":" & ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)

Tulemused on esitatud allpool oleval ekraanipildil:

Näpunäide. Kui avate töölehe, mille valemid on loodud vanemas versioonis Excelis dünaamilise massiivi abil, lisab Excel automaatselt kaudse ristamisoperaatori.

Nii tagastate lahtri aadressi Excelis. Et lähemalt tutvuda kõigi selles õpetuses käsitletud valemitega, olete teretulnud alljärgnevalt alla laadima meie näidistööraamatu. Tänan teid lugemise eest ja loodan, et näeme teid järgmisel nädalal meie blogis!

Praktiline töövihik allalaadimiseks

Exceli funktsioon ADRESS - valemi näited (.xlsx fail)