ट्यूटोरियल ADDRESS फंक्शन सिंटॅक्सची थोडक्यात ओळख देते आणि ते Excel सेल अॅड्रेस आणि बरेच काही परत करण्यासाठी कसे वापरायचे ते दाखवते.

एक्सेलमध्ये सेल संदर्भ तयार करण्यासाठी, तुम्ही स्तंभ आणि पंक्ती निर्देशांक स्वहस्ते टाइप करू शकतात. वैकल्पिकरित्या, तुम्ही ADDRESS फंक्शनला पुरवलेल्या पंक्ती आणि स्तंभ क्रमांकांमधून एक्सेल सेल पत्ता मिळवू शकता. स्वतःच जवळजवळ निरर्थक, इतर फंक्शन्सच्या संयोजनात जेव्हा सेलचा थेट संदर्भ घेणे शक्य नसते अशा परिस्थितीत हे तंत्र एकमेव उपाय असू शकते.

Excel ADDRESS फंक्शन - वाक्यरचना आणि मुलभूत उपयोग

ADDRESS फंक्शन निर्दिष्ट पंक्ती आणि स्तंभ क्रमांकांवर आधारित Excel मध्ये सेल पत्ता मिळविण्यासाठी डिझाइन केले आहे. सेल पत्ता मजकूर स्ट्रिंग म्हणून परत केला जातो, वास्तविक संदर्भ नाही.

फंक्शन Microsoft 365 - Excel 2007 साठी Excel च्या सर्व आवृत्त्यांमध्ये उपलब्ध आहे.

ADDRESS फंक्शनचे वाक्यरचना आहे खालीलप्रमाणे:

पहिले दोन वितर्क आवश्यक आहेत:

row_num - पंक्ती सेल संदर्भामध्ये वापरण्यासाठी संख्या.

column_num - सेल संदर्भ तयार करण्यासाठी स्तंभ क्रमांक.

शेवटचे तीन वितर्क, जे सेल संदर्भ स्वरूप निर्दिष्ट करतात, आहेत पर्यायी:

abs_num - संदर्भ प्रकार, परिपूर्ण किंवा संबंधित. हे खालीलपैकी कोणतीही संख्या घेऊ शकते; डीफॉल्ट निरपेक्ष आहे.

• 1 किंवा वगळलेले -संपूर्ण सेल संदर्भ जसे की $A$1
• 2 - मिश्र संदर्भ: सापेक्ष स्तंभ आणि A$1
• 3 सारखी परिपूर्ण पंक्ती - मिश्र संदर्भ: परिपूर्ण स्तंभ आणि संबंधित पंक्ती जसे की $A1
• 4 - सापेक्ष सेल संदर्भ जसे की A1

a1 - संदर्भ शैली, A1 किंवा R1C1. वगळल्यास, डीफॉल्ट A1 शैली वापरली जाते.

• 1 किंवा TRUE किंवा वगळलेले - A1 संदर्भ शैलीमध्ये सेल पत्ता देते जेथे स्तंभ अक्षरे असतात आणि पंक्ती संख्या असतात.
• 0 किंवा FALSE - R1C1 संदर्भ शैलीमध्ये सेल पत्ता परत करतो जेथे पंक्ती आणि स्तंभ संख्यांद्वारे दर्शवले जातात.

sheet_text - बाह्य संदर्भामध्ये समाविष्ट करण्यासाठी वर्कशीटचे नाव. पत्रकाचे नाव मजकूर स्ट्रिंग म्हणून दिले जावे आणि अवतरण चिन्हांमध्ये संलग्न केले जावे, उदा. "पत्रक2". वगळल्यास, वर्कशीटचे कोणतेही नाव वापरले जात नाही आणि पत्ता सध्याच्या शीटवर डीफॉल्ट होतो.

उदाहरणार्थ:

=ADDRESS(1,1) - पहिल्या सेलचा पत्ता परत करतो (म्हणजेच सेलच्या छेदनबिंदूवरील सेल पहिली पंक्ती आणि पहिला स्तंभ) निरपेक्ष सेल संदर्भ $A$1 म्हणून.

=ADDRESS(1,1,4) - सापेक्ष सेल संदर्भ A1 म्हणून पहिल्या सेलचा पत्ता मिळवते.

खालील सारणीमध्ये, तुम्हाला आणखी काही संदर्भ प्रकार सापडतील जे ADDRESS सूत्रांद्वारे परत केले जाऊ शकतात.

एक्सेलमध्ये ADDRESS फंक्शन कसे वापरावे - सूत्र उदाहरणे

खालील उदाहरणे अधिक साध्य करण्यासाठी मोठ्या सूत्रांमध्ये ADDRESS फंक्शन कसे वापरायचे ते दर्शविते कठीण कार्ये.

दिलेल्या पंक्ती आणि स्तंभामध्ये सेल मूल्य परत करा

तुमचे ध्येय एखाद्या विशिष्ट सेलमधून त्याच्या पंक्ती आणि स्तंभ संख्यांच्या आधारे मूल्य मिळवण्याचे असेल तर, ADDRESS मजा वापरा ction एकत्र INDIRECT:

ADDRESS फंक्शन सेल अॅड्रेस टेक्स्ट म्हणून आउटपुट करते. INDIRECT फंक्शन त्या मजकुराचे सामान्य संदर्भामध्ये रूपांतर करते आणि संबंधित सेलमधील मूल्य परत करते.

उदाहरणार्थ, E1 मधील पंक्ती क्रमांक आणि E2 मधील स्तंभ क्रमांकावर आधारित सेल मूल्य मिळविण्यासाठी, हे सूत्र वापरा :

=INDIRECT(ADDRESS(E1,E2))

पत्ता मिळवासर्वोच्च किंवा सर्वात कमी मूल्य असलेल्या सेलचे

या उदाहरणात, आम्ही प्रथम श्रेणी B2:B7 मध्ये MAX आणि MIN फंक्शन्स वापरून सर्वोच्च आणि सर्वात कमी मूल्ये शोधू आणि ती मूल्ये विशेष सेलमध्ये आउटपुट करू:

सेल E2: =MAX(B2:B7)

सेल F2: =MIN(B2:B7)

आणि नंतर, आम्ही ADDRESS चा वापर MATCH फंक्शनच्या संयोजनात करू सेल पत्ते मिळवा.

कमाल मूल्यासह सेल:

=ADDRESS(MATCH(E2,B:B,0), COLUMN(B2))

कमी मूल्यासह सेल:

=ADDRESS(MATCH(F2,B:B,0), COLUMN(B2))

तुम्हाला विभक्त सेलमध्ये सर्वोच्च आणि सर्वात कमी मूल्ये नको असल्यास, तुम्ही MATCH च्या पहिल्या युक्तिवादात MAX/MIN फंक्शन नेस्ट करू शकता. उदाहरणार्थ:

सर्वोच्च मूल्य असलेला सेल:

=ADDRESS(MATCH(MAX(B2:B7),B:B,0), COLUMN(B2))

सर्वात कमी मूल्य असलेला सेल:

=ADDRESS(MATCH(MIN(B2:B7),B:B,0), COLUMN(B2))

हे सूत्र कसे कार्य

पंक्ती क्रमांक शोधण्यासाठी, तुम्ही MATCH(lookup_value, lookup_array, [match_type]) फंक्शन वापरता जे lookup_array मध्ये lookup_value चे सापेक्ष स्थान मिळवते. आमच्या सूत्रामध्ये, लुकअप मूल्य हे MAX किंवा MIN फंक्शनद्वारे मिळालेली संख्या आहे आणि लुकअप अॅरे हा संपूर्ण स्तंभ आहे. परिणामी, अॅरेमधील लुकअप मूल्याची सापेक्ष स्थिती शीटवरील पंक्ती क्रमांकाशी तंतोतंत जुळते.

स्तंभ क्रमांक शोधण्यासाठी, तुम्ही COLUM फंक्शन वापरता. अर्थात, फॉर्म्युलामध्ये थेट क्रमांक टाइप करण्यापासून तुम्हाला काहीही प्रतिबंधित करत नाही, परंतु लक्ष्य स्तंभ शीटच्या मध्यभागी असल्यास COLUMN मॅन्युअल मोजणीचा त्रास वाचवते.

स्तंभ पत्र मिळवास्तंभ क्रमांकावरून

कोणत्याही दिलेल्या संख्येला स्तंभ अक्षरात बदलण्यासाठी, SUBSTITUTE च्या आत ADDRESS फंक्शन वापरा:

उदाहरणार्थ, A2 मधील क्रमांकाशी संबंधित स्तंभातील अक्षर शोधूया:

=SUBSTITUTE(ADDRESS(1,A2,4),"1","")

खालील निकाल पाहता, आपण असे म्हणू शकतो की पहिला स्तंभ शीटवर ए आहे, जे स्पष्ट आहे; 10वा स्तंभ J आहे, 50वा स्तंभ AX आहे आणि 100वा स्तंभ CV आहे:

हे सूत्र कसे कार्य करते

स्टार्टर्ससाठी, सेट करा लक्ष्य स्तंभातील पहिल्या सेलचा सापेक्ष संदर्भ परत करण्यासाठी ADDRESS कार्य:

• पंक्ती क्रमांकासाठी, 1 वापरा.
• स्तंभ क्रमांकासाठी, सेलला संदर्भ द्या आमच्या उदाहरणात संख्या, A2 समाविष्टीत आहे.
• abs_num वितर्कासाठी, 4 प्रविष्ट करा.

परिणामी म्हणून, ADDRESS(1,A2,4) A1 मिळवेल.

पंक्ती समन्वयापासून मुक्त होण्यासाठी, उपरोक्त सूत्र SUBSTITUTE फंक्शनमध्ये गुंडाळा आणि "1" ला रिकाम्या स्ट्रिंगने ("") बदला. पूर्ण झाले!

नामांकित श्रेणीचा पत्ता मिळवा

एक्सेलमध्ये नामांकित श्रेणीचा पत्ता शोधण्यासाठी, तुम्हाला प्रथम आणि शेवटचे सेल संदर्भ मिळवावे लागतील आणि नंतर त्यांना एकत्र जोडावे लागेल. . प्री-डायनॅमिक एक्सेल (2019 आणि जुने) आणि डायनॅमिक अॅरे एक्सेल (ऑफिस 365 आणि एक्सेल 2021) मध्ये हे थोडे वेगळे काम करते. खाली दिलेली उदाहरणे Excel 2019 - Excel 2007 साठी आहेत. Excel 365 आणि Excel 2021 साठी सूचना आहेतयेथे.

श्रेणीतील पहिल्या सेलचा पत्ता कसा मिळवायचा

नामांकित श्रेणीतील पहिल्या सेलचा संदर्भ परत करण्यासाठी, हे जेनेरिक सूत्र वापरा:

श्रेणीला "विक्री" नाव दिले आहे असे गृहीत धरून, वास्तविक सूत्र खालीलप्रमाणे आहे:

=ADDRESS(ROW(Sales), COLUMN(Sales))

आणि श्रेणीतील वरच्या डाव्या सेलचा पत्ता मिळवते:

या सूत्रात, ROW आणि COLUMN फंक्शन्स मधील सर्व पंक्ती आणि स्तंभ संख्यांचा अॅरे मिळवतात श्रेणी, अनुक्रमे. त्या संख्यांच्या आधारे, ADDRESS फंक्शन सेल पत्त्यांची अॅरे तयार करते. परंतु सूत्र एका सेलमध्ये एंटर केल्यामुळे, अॅरेचा फक्त पहिला आयटम प्रदर्शित होतो, जो श्रेणीतील पहिल्या सेलशी संबंधित असतो.

श्रेणीतील शेवटच्या सेलचा पत्ता कसा मिळवायचा<27

नामांकित श्रेणीतील शेवटच्या सेलचा पत्ता शोधण्यासाठी, हे जेनेरिक सूत्र वापरा:

ADDRESS(ROW( range )+ROWS( range )-1 ,COLUMN( श्रेणी )+COLUMNS( श्रेणी )-1)

आमच्या "विक्री" नावाच्या श्रेणीवर लागू केलेले, सूत्र खालील आकार घेते:

=ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)

आणि श्रेणीच्या तळाशी उजव्या सेलचा संदर्भ परत करतो:

या वेळी, आम्हाला पंक्ती तयार करण्यासाठी थोडी अधिक जटिल गणना आवश्यक आहे संख्या मागील उदाहरणाप्रमाणे, ROW फंक्शन आपल्याला रेंजमधील सर्व रो क्रमांकांची अॅरे देते, आमच्या बाबतीत {4;5;6;7}. आम्हाला एकूण पंक्ती संख्या वजा १ ने हे आकडे "शिफ्ट" करावे लागतील, जेणेकरूनअॅरेमधील पहिला आयटम शेवटचा पंक्ती क्रमांक बनतो. एकूण पंक्ती संख्या शोधण्यासाठी, आम्ही ROWS फंक्शन वापरतो आणि त्याच्या निकालातून 1 वजा करतो: (4-1=3). त्यानंतर, आवश्यक शिफ्ट करण्यासाठी आम्ही प्रारंभिक अॅरेच्या प्रत्येक घटकामध्ये 3 जोडतो: {4;5;6;7} + 3 = {7;8;9;10}.

स्तंभ क्रमांक आहे अशाच पद्धतीने गणना केली जाते: {2,3,4}+3-1 = {4,5,6}

वरील पंक्ती आणि स्तंभ क्रमांकांच्या अॅरेमधून, ADDRESS फंक्शन सेल अॅड्रेसचे अॅरे एकत्र करते , परंतु श्रेणीतील शेवटच्या सेलशी संबंधित फक्त पहिला मिळवतो.

समान परिणाम पंक्ती आणि स्तंभ क्रमांकांच्या अॅरेमधून जास्तीत जास्त मूल्ये निवडून देखील मिळवता येतो. तथापि, हे केवळ अॅरे फॉर्म्युलामध्ये कार्य करते, ज्यासाठी Ctrl + Shift + Enter दाबून योग्यरित्या पूर्ण करणे आवश्यक आहे:

=ADDRESS(MAX(ROW(Sales)), MAX(COLUMN(Sales)))

नामांकित श्रेणीचा पूर्ण पत्ता कसा मिळवायचा

नामांकित श्रेणीचा संपूर्ण पत्ता परत करण्यासाठी, तुम्हाला फक्त मागील उदाहरणांमधून दोन सूत्रे एकत्र करणे आवश्यक आहे आणि त्यामध्ये श्रेणी ऑपरेटर (:) समाविष्ट करणे आवश्यक आहे.

आमच्या नमुना डेटा सेटसाठी ते कार्य करण्यासाठी, आम्ही जेनेरिक "श्रेणी" ला वास्तविक श्रेणी नाव "विक्री" ने बदलतो:

=ADDRESS(ROW(Sales), COLUMN(Sales)) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)

आणि संपूर्ण श्रेणी पत्ता म्हणून मिळवा संपूर्ण संदर्भ $B$4:$D$7:

श्रेणी परत करण्यासाठी सापेक्ष संदर्भ म्हणून पत्ता ($ चिन्हाशिवाय, जसे की B4:D7), दोन्ही ADDRESS फंक्शन्समधील abs_num वितर्क 4:

=ADDRESS(ROW(Sales), COLUMN(Sales), 4) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1, 4)

साहजिकच, पहिल्या आणि शेवटच्या सेलसाठी वैयक्तिक सूत्रांमध्ये समान बदल केले जाऊ शकतात आणि परिणाम यासारखे दिसेल:

एक्सेलमध्ये नामांकित श्रेणीचा पत्ता कसा मिळवायचा 365 आणि Excel 2021

जुन्या आवृत्त्यांमधील पारंपारिक "एक फॉर्म्युला - एक सेल" वर्तनाच्या विपरीत, नवीन एक्सेलमध्ये, संभाव्यत: एकाधिक मूल्ये परत करू शकणारे कोणतेही सूत्र हे स्वयंचलितपणे करते. अशा वर्तनाला स्पिलिंग म्हणतात.

उदाहरणार्थ, पहिल्या सेलचा पत्ता परत करण्याऐवजी, खालील सूत्र नामांकित श्रेणीतील प्रत्येक सेलचे पत्ते आउटपुट करते:

=ADDRESS(ROW(Sales), COLUMN(Sales)) <3

फक्त पहिल्या सेल चा पत्ता मिळवण्यासाठी, तुम्हाला अंतर्निहित छेदनबिंदू सक्षम करणे आवश्यक आहे, जे एक्सेल 2019 आणि जुन्यामध्ये डीफॉल्टनुसार ट्रिगर केले जाते. यासाठी, रेंजच्या नावांपूर्वी @ चिन्ह (अव्यक्त छेदनबिंदू ऑपरेटर) ठेवा:

=ADDRESS(@ROW(Sales), @COLUMN(Sales))

अशाच प्रकारे, तुम्ही इतर सूत्रे निश्चित करू शकता.

मिळवण्यासाठी <श्रेणीतील 8>अंतिम सेल :

=ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)

नामांकित श्रेणीचा पत्ता मिळवण्यासाठी :

=ADDRESS(@ROW(Sales), @COLUMN(Sales)) & ":" & ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)

खालील स्क्रीनशॉट परिणाम दर्शवितो:

टीप. डायनॅमिक अॅरे Excel मध्ये जुन्या आवृत्तीमध्ये तयार केलेल्या सूत्रांसह वर्कशीट उघडताना, Excel द्वारे आपोआप अंतर्निहित इंटरसेक्शन ऑपरेटर घातला जातो.

असेच तुम्हीExcel मध्ये सेल पत्ता परत करा. या ट्युटोरियलमध्ये चर्चा केलेली सर्व सूत्रे जवळून पाहण्यासाठी, आमचे खालील नमुना वर्कबुक डाउनलोड करण्यासाठी तुमचे स्वागत आहे. वाचल्याबद्दल मी तुमचा आभारी आहे आणि पुढच्या आठवड्यात तुम्हाला आमच्या ब्लॉगवर भेटण्याची आशा आहे!

डाउनलोड करण्यासाठी सराव वर्कबुक

एक्सेल ADDRESS फंक्शन - सूत्र उदाहरणे (.xlsx फाइल)