Tabloya naverokê
Dersdar kurtasî danasînek hevoksaziya fonksiyona ADDRESS dide û destnîşan dike ku meriv wê çawa bikar tîne da ku navnîşek hucreyek Excel û hêj bêtir vegerîne.
Ji bo afirandina referansek hucreyê di Excel de, hûn dikare koordînatên stûn û rêzan bi destan binivîse. Wekî din, hûn dikarin navnîşek hucreya Excel-ê ji hejmarên rêz û stûnê yên ku ji fonksiyona ADDRESS re têne peyda kirin bistînin. Bi tena serê xwe hema bêje bêwate ye, digel fonksiyonên din ev teknîk dikare di rewşên ku ne mumkin e ku rasterast bi şaneyek were veguheztin çareserî be.
Fonksiyon ADDRESS Excel - hevoksazî û karanînên bingehîn
Fonksiyon ADDRESS ji bo bidestxistina navnîşana hucreyê li Excel-ê li gorî hejmarên rêz û stûnên diyarkirî hatî çêkirin. Navnîşanek hucreyê wekî rêzika nivîsê tê vegerandin, ne referansek rastîn.
Fonksiyon di hemî guhertoyên Excel-ê de ji bo Microsoft 365 - Excel 2007 heye.
Sîntaksa fonksiyona ADDRESS e bi vî awayî:
ADDRESS(hejmar_rêz, jimar_stûn, [abs_num], [a1], [sheet_text])Du argumanên pêşîn hewce ne:
row_num - rêz hejmara ku di referansa şaneyê de bikar bîne.
column_num - hejmara stûna ku referansa şaneyê ava dike.
Sê argumanên dawîn, ku formata referansa şaneyê diyar dikin, ev in. vebijarkî:
abs_num - cureya referansê, mitleq an têkildar. Ew dikare yek ji hejmarên jêrîn bigire; xwerû mutleq e.
- 1 an jêbirin -referansa hucreya mutleq wek $A$1
- 2 - referansa tevlihev: stûna têkildar û rêza mutleq wek A$1
- 3 - referansa tevlihev: stûna mutleq û rêza têkildar wek $A1
- 4 - referansa hucreya têkildar wek A1
a1 - şêwaza referansê, A1 an R1C1. Ger ji holê rabe, şêwaza A1 ya xwerû tê bikar anîn.
- 1 an RAST an jî jêbirin - navnîşana şaneyê di şêwaza referansa A1 de vedigerîne ku stûn herf in û rêz jî hejmar in.
- 0 an FALSE - navnîşana şaneyê di şêwaza referansa R1C1 de vedigerîne ku rêz û stûn bi hejmaran têne xuyang kirin.
sheet_text - navê pelgeya xebatê ya ku di referansa derve de tê de ye. Navê pelê divê wekî rêzika nivîsê were peyda kirin û di nav lêkeran de were girtin, mînak. "Sheet2". Ger ji holê were rakirin, navê pela xebatê nayê bikar anîn, û navnîşana pelê heyî vedigire.
Mînakî:
=ADDRESS(1,1) - navnîşana şaneya yekem vedigerîne (ango şaneya li xaçerêya rêza yekem û stûna yekem) wekî referansa şaneya mutleq $A$1.
=ADDRESS(1,1,4) - navnîşana şaneya yekem wekî referansa şaneya têkildar A1 vedigerîne.
Di tabloya jêrîn de, hûn ê çend celebên din ên referansê bibînin ku dikarin ji hêla formulên ADDRESS ve werin vegerandin.
| Formula | Encam | Danasîn |
| =ADDRESS(1,2) | $B$1 | Hûna mutleqreferans |
| =ADDRESS(1,2,4) | B1 | Bernava hucreyê ya têkildar |
| =ADDRESS(1,2,2) | B$1 | Stûna têkildar û rêza mutleq |
| =ADDRESS(1,2,3) | $B1 | Stûna mutleq û rêza têkildar |
| =ADDRESS(1,2,1,FALSE) | R1C2 | Di şêwaza R1C1 de referansa bêkêmasî |
| =ADDRESS(1,2,4,FALSE) | R[1]C[2] | Referansa têkildar bi şêwaza R1C1 |
| =ADDRESS(1,2,1,"Sheet2") | Sheet2!$B$1 | Referanseke bêkêmasî ji bo rûpeleke din |
| =ADDRESS(1,2,4,"Sheet2") | Sheet2!B1 | Navnîşana têkildar bernameyek din |
Meriv çawa fonksiyona ADDRESS di Excel-ê de bikar tîne - nimûneyên formula
Mînakên jêrîn destnîşan dikin ka meriv çawa fonksiyona ADDRESS di hundurê formulên mezin de bikar tîne da ku bêtir biser bikeve karên dijwar.
Nirxa şaneyê di rêz û stûneke diyarkirî de vegerîne
Heke mebesta we ew e ku hûn ji şaneyek taybetî nirxek li gorî jimareyên rêz û stûnan bistînin, kêfa ADDRESS bikar bînin. bi INDIRECT re tevdigere:
INDIRECT(ADDRESS(hejmar_rêz, jimar_stûn))Fonksiyon ADDRESS navnîşana şaneyê wekî nivîsê derdixe. Fonksiyona INDIRECT wê nivîsê vedigerîne referansek normal û nirxê ji şaneya peywendîdar vedigerîne.
Mînakî, ji bo ku nirxek şaneyê li gorî jimareya rêzê ya di E1 û jimareya stûnê de di E2 de bigire, vê formulê bikar bîne. :
=INDIRECT(ADDRESS(E1,E2))
Navnîşanê bistîninşaneya bi nirxa herî bilind an kêmtirîn
Di vê nimûneyê de, em ê pêşî bi karanîna fonksiyonên MAX û MIN-ê nirxa herî bilind û nizm di navberê de B2:B7 bibînin û wan nirxan derxin nav şaneyên taybetî:
Hûleya E2: =MAX(B2:B7)
Hûleya F2: =MIN(B2:B7)
Û paşê, em ê ADDRESS bi tevlêbûna fonksiyona MATCH-ê re bikar bînin ku navnîşanên şaneyê bistînin.
Hûleya bi nirxa herî zêde:
=ADDRESS(MATCH(E2,B:B,0), COLUMN(B2))
Hûleya bi nirxa hindik:
=ADDRESS(MATCH(F2,B:B,0), COLUMN(B2))
Heke hûn di şaneyên cuda de nirxa herî bilind û herî nizm nexwazin, hûn dikarin di argumana yekem a MATCH de fonksiyona MAX/MIN hêl bikin. Mînak:
Hûleya bi nirxa herî bilind:
=ADDRESS(MATCH(MAX(B2:B7),B:B,0), COLUMN(B2))
Hûleya bi nirxa herî kêm:
=ADDRESS(MATCH(MIN(B2:B7),B:B,0), COLUMN(B2))
Ev formula çawa kar
Ji bo dîtina jimareya rêzê, hûn fonksiyona MATCH(nirx_lookup, lêgerîn_array, [cure_hevberî]) bikar tînin ku di lêgerîn_array de cîhek têkildar a nirxa lookup_vegerîne. Di formula me de, nirxa lêgerînê hejmar e ku ji hêla fonksiyona MAX an MIN ve hatî vegerandin, û rêzika lêgerînê tevahiya stûnê ye. Ji ber vê yekê, cîhek têkildar a nirxa lêgerînê ya di rêzê de tam bi jimareya rêza li ser pelê re li hev dike.
Ji bo dîtina hejmara stûnê, hûn fonksiyona COLUM bikar tînin. Bê guman, tu tişt nahêle ku hûn hejmarê rasterast di formula de binivîsin, lê COLUMN kêşeya hejmartina bi destan xilas dike ger stûna mebest di nîvê pelê de be.
Herfa stûnê bistîninji jimareke stûnê
Ji bo ku hejmareke diyarkirî bibe tîpeke stûnê, fonksiyona ADDRESS di hundurê SUBSTITUTE de bikar bînin:
SUBSTITUTE(ADDRESS(1, hejmara_stûnê,4),"1 ","")Wek nimûne, em tîpa stûnê ya ku bi hejmara A2 re têkildar e bibînin:
=SUBSTITUTE(ADDRESS(1,A2,4),"1","")
Li encamên jêrîn binêrin, em dikarin bibêjin ku stûna yekem li ser pelê A ye, ku eşkere ye; stûna 10emîn J e, stûna 50emîn AX e û stûna 100emîn CV ye:
Ev formula çawa dixebite
Ji bo destpêkê, saz bikin Fonksiyona ADDRESS-ê ku di stûna armancê de referansek têkildar vedigere şaneya yekem:
- Ji bo jimareya rêzê, 1 bikar bînin.
- Ji bo hejmara stûnê, referansa şaneyê peyda bikin. di mînaka me de jimare, A2 dihewîne.
- Ji bo argumana abs_num, 4 têkevin.
Di encamê de, ADDRESS(1,A2,4) dê A1 vegerîne.
Ji bo ku ji koordînata rêzê xilas bibin, formula jorîn di fonksiyona SUBSTITUTE de bipêçin û "1" bi rêzek vala ("") biguherînin. Qediya!
Navnîşana rêzeka binavkirî bistînin
Ji bo dîtina navnîşana rêzeke bi navkirî di Excel de, hûn ê pêşî hewce bikin ku referansên şaneya yekem û paşîn bistînin û dûv re wan bigihînin hev. . Ev di Excel pêş-dînamîk (2019 û kevntir) û Dynamic Array Excel (Office 365 û Excel 2021) de hinekî cûda dixebite. Nimûneyên jêrîn ji bo Excel 2019 - Excel 2007 ne. Talîmatên ji bo Excel 365 û Excel 2021 inli vir.
Çawa meriv navnîşana şaneya yekem a di nav rêzekê de bistîne
Ji bo vegerandina referansek li şaneya yekem a di rêzek binavkirî de, vê formula giştî bikar bînin:
ADDRESS(ROW( range),COLUMN( range))Bi texmîna ku navber navê "Sales" e, formula rast wiha diçe:
=ADDRESS(ROW(Sales), COLUMN(Sales))
Û navnîşana şaneya çepê ya jorîn a di rêzê de vedigerîne:
Di vê formulê de, fonksiyonên ROW û COLUMN rêzek ji hemî hejmarên rêz û stûnan vedigerînin. range, bi rêzê ve. Li ser bingeha wan hejmaran, fonksiyona ADDRESS komek navnîşanên hucreyê ava dike. Lê ji ber ku formula di şaneyek yekane de tê navnîş kirin, tenê xala yekem a rêzê tê xuyang kirin, ku bi şaneya yekem a rêzê re têkildar e.
Navnîşana şaneya paşîn a rêzek çawa tê wergirtin
Ji bo dîtina navnîşana şaneya paşîn a di nav rêzek bi nav de, vê formula giştî bikar bînin:
ADDRESS(ROW( range)+ROWS( range)-1 ,COLUMN( range)+COLUMNS( range)-1)Ji bo rêza me ya bi navê "Sales" tê sepandin, formula forma jêrîn digire:
=ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)
Û referansê vedigerîne şaneya jêrîn a rastê ya rêzê:
Vê carê, ji bo ku rêzê bixebitin hewceyê hesabên hinekî tevlihevtir in. jimare. Mîna mînaka berê, fonksiyona ROW rêzek ji hemî jimareyên rêzan ên di rêzê de, di rewşa me de {4;5;6;7} dide me. Pêdivî ye ku em van hejmaran bi hejmara rêza giştî kêm 1 "guhezînin", da kudi rêzê de yekem tişt dibe hejmara rêza dawî. Ji bo dîtina jimareya rêzan a giştî, em fonksiyona ROWS bikar tînin û 1 ji encama wê derdixin: (4-1=3). Dûv re, em 3 li her hêmanek rêzika destpêkê zêde dikin da ku veguheztina pêwîst pêk bînin: {4;5;6;7} + 3 = {7;8;9;10}.
Hejmara stûnê ye bi vî rengî tê hesibandin: {2,3,4}+3-1 = {4,5,6}
Ji rêzikên jorîn ên rêz û stûnan, fonksiyona ADDRESS rêzek navnîşanên şaneyê berhev dike. , lê tenê ya yekem li gorî şaneya paşîn a rêzê vedigerîne.
Heman encam dikare bi bijartina nirxên herî zêde ji rêzikên jimareyên rêz û stûnan jî were bidestxistin. Lêbelê, ev tenê di formula array de dixebite, ku pêdivî ye ku pêlkirina Ctrl + Shift + Enter rast were temam kirin:
=ADDRESS(MAX(ROW(Sales)), MAX(COLUMN(Sales)))
Meriv çawa navnîşana tevahî ya navçeyek binavkirî bistîne
Ji bo vegerandina temamê navnîşana rêzek bi navkirî, hûn tenê hewce ne ku hûn du formulan ji mînakên berê bi hev ve girêdin û operatora rêzê (:) têxin navberê.
ADDRESS(ROW( range) , COLUMN( range)) & ":" & amp; ADDRESS(ROW( range) + ROWS( range)-1, COLUMN( range) + COLUMNS( range)-1)Ji bo ku ew ji bo berhevoka daneya nimûneya me bixebite, em "range" ya gelemperî bi navê rêza rastîn "Sales" diguhezînin:
=ADDRESS(ROW(Sales), COLUMN(Sales)) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)
Û navnîşana rêza tevahî wekî navnîşana rêzê werdigirin. absolute referansa $B$4:$D$7:
Ji bo vegerandina rêzênavnîşan wekî referansa girêdayî (bêyî nîşana $, mîna B4:D7), argumana abs_num di her du fonksiyonên ADDRESS de danîne 4:
=ADDRESS(ROW(Sales), COLUMN(Sales), 4) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1, 4)
Bi xwezayî, Di formulên takekesî de ji bo şaneya yekem û paşîn heman guhertin dikarin bêne çêkirin, û encam dê mîna vê xuya bike:
Meriv çawa navnîşana rêzek binavkirî di Excel de digire 365 û Excel 2021
Berevajî tevgera kevneşopî "yek formula - yek hucre" di guhertoyên kevn de, di Excel-a nû de, her formula ku bi potansiyel dikare gelek nirxan vegerîne, vê yekê bixweber dike. Ji vê tevgerê re spilling tê gotin.
Mînakî, li şûna ku navnîşana şaneya yekem vegerîne, formula jêrîn navnîşanên her şaneyek di nav rêzek binavkirî de derdixe:
=ADDRESS(ROW(Sales), COLUMN(Sales))
Ji bo ku hûn navnîşana hucreya yekem tenê bistînin, hûn hewce ne ku hevberdana nepenî çalak bikin, ku ji hêla xwerû ve di Excel 2019 û kevintir de tê destnîşan kirin. Ji bo vê, nîşana @ (operatorê hevberdana nepenî) deynin ber navên rêzê:
=ADDRESS(@ROW(Sales), @COLUMN(Sales))
Bi vî rengî, hûn dikarin formulên din rast bikin.
Ji bo bidestxistina hucreya paşîn di rêzê de:
=ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)
Ji bo bidestxistina navnîşana rêzeka binavkirî :
=ADDRESS(@ROW(Sales), @COLUMN(Sales)) & ":" & ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)
Dîmenê jêrîn encaman nîşan dide:
Serişte. Dema ku pelxebatek bi formulên ku di guhertoyek kevntir de hatine afirandin di rêzika dînamîkî ya Excel-ê de vedikin, operatorek hevberdanê ya nepenî ji hêla Excel ve bixweber tê danîn.
Tu bi vî rengî yenavnîşek hucreyê li Excel vegerîne. Ji bo ku hûn ji nêz ve li hemî formulên ku di vê tutoriyê de hatine nîqaş kirin binêrin, hûn bi xêr hatin ku pirtûka xebata me ya li jêr dakêşin. Ez spasiya te dikim ji bo xwendinê û hêvî dikim ku hefteya pêş me we li ser bloga xwe bibînim!
Ji bo daxistinê pirtûka xebatê pratîk bikin
Fonksiyon ADDRESS Excel - nimûneyên formula (pelê xlsx)
