Tutorial masihan bubuka ringkes kana sintaksis pungsi ADDRESS sareng nunjukkeun cara ngagunakeunana pikeun mulangkeun alamat sél Excel sareng seueur deui.

Pikeun nyieun rujukan sél dina Excel, anjeun tiasa ngetik koordinat kolom sareng baris sacara manual. Alternatipna, anjeun tiasa kéngingkeun alamat sél Excel tina nomer baris sareng kolom anu disayogikeun kana fungsi ADDRESS. Ampir teu aya gunana sorangan, dina kombinasi sareng fungsi anu sanés, téknik ieu tiasa janten hiji-hijina solusi dina kaayaan nalika henteu tiasa ngarujuk kana sél langsung.

Fungsi ALAMAT Excel - sintaksis sareng kagunaan dasar

Pungsi ADDRESS dirancang pikeun meunangkeun alamat sél dina Excel dumasar kana nomer baris jeung kolom nu ditangtukeun. Alamat sél dipulangkeun salaku string téks, lain référénsi sabenerna.

Pungsi éta sadia dina sakabéh vérsi Excel pikeun Microsoft 365 - Excel 2007.

Sintaksis pungsi ADDRESS nyaéta kieu:

Dua argumen kahiji diperlukeun:

num_baris - baris angka nu dipaké dina rujukan sél.

column_num - nomer kolom pikeun ngawangun rujukan sél.

Tilu argumen pamungkas, nu nangtukeun format rujukan sél, nyaéta pilihan:

abs_num - tipe rujukan, mutlak atawa relatif. Éta tiasa nyandak salah sahiji nomer di handap ieu; standarna mutlak.

• 1 atawa dileungitkeun -rujukan sél mutlak kawas $A$1
• 2 - rujukan campuran: kolom relatif jeung baris mutlak kawas A$1
• 3 - rujukan campuran: kolom mutlak jeung baris relatif kawas $A1
• 4 - rujukan sél relatif kayaning A1

a1 - gaya rujukan, A1 atawa R1C1. Upami dileungitkeun, gaya standar A1 dianggo.

• 1 atanapi BENER atanapi dileungitkeun - mulihkeun alamat sél dina gaya rujukan A1 dimana kolom mangrupikeun hurup sareng baris mangrupikeun angka.
• 0 atawa FALSE - mulangkeun alamat sél dina gaya rujukan R1C1 dimana baris jeung kolom digambarkeun ku angka.

sheet_text - ngaran lembar kerja pikeun kaasup kana rujukan éksternal. Ngaran lambar kudu disadiakeun salaku string téks na enclosed dina tanda petik, misalna. "Lembar 2". Upami dileungitkeun, teu aya nami lembar kerja anu dianggo, sareng alamatna janten standar kana lambaran ayeuna.

Contona:

=ADDRESS(1,1) - mulihkeun alamat sél anu munggaran (nyaéta sél anu aya di simpang tina baris kahiji jeung kolom kahiji) salaku rujukan sél mutlak $A$1.

=ADDRESS(1,1,4) - mulangkeun alamat sél kahiji salaku rujukan sél relatif A1.

Dina tabel di handap ieu, anjeun bakal mendakan sababaraha jinis rujukan deui anu tiasa dipulangkeun ku rumus ADDRESS.

Kumaha ngagunakeun fungsi ADDRESS dina Excel - conto rumus

Conto di handap ieu nunjukkeun kumaha ngagunakeun fungsi ADDRESS di jero rumus anu langkung ageung pikeun ngalengkepan langkung seueur tugas anu hese.

Mulangkeun nilai sél dina baris sareng kolom anu ditangtukeun

Upami tujuan anjeun kéngingkeun nilai tina sél khusus dumasar kana nomer baris sareng kolomna, paké hiburan ADDRESS ction bareng jeung INDIRECT:

Pungsi ADDRESS outputs alamat sél salaku téks. Pungsi INDIRECT ngarobah éta téks jadi rujukan normal jeung mulangkeun nilai tina sél nu pakait.

Contona, pikeun meunangkeun nilai sél dumasar kana nomer baris dina E1 jeung nomer kolom dina E2, make rumus ieu. :

=INDIRECT(ADDRESS(E1,E2))

Kéngingkeun alamatnatina sél nu boga nilai pangluhurna atawa panghandapna

Dina conto ieu, urang mimiti manggihan nilai pangluhurna jeung panghandapna dina rentang B2:B7 ku ngagunakeun fungsi MAX jeung MIN tur kaluaran nilai-nilai kana sél husus:

Cell E2: =MAX(B2:B7)

Cell F2: =MIN(B2:B7)

Terus, urang bakal make ADDRESS dina kombinasi jeung fungsi MATCH pikeun kéngingkeun alamat sél.

Sél anu gaduh nilai maksimal:

=ADDRESS(MATCH(E2,B:B,0), COLUMN(B2))

Sél kalayan nilai mnt:

=ADDRESS(MATCH(F2,B:B,0), COLUMN(B2))

Upami anjeun henteu hoyong nilai pangluhurna sareng panghandapna dina sél anu misah, anjeun tiasa nyarang fungsi MAX/MIN dina argumen MATCH munggaran. Contona:

Sél kalawan nilai pangluhurna:

=ADDRESS(MATCH(MAX(B2:B7),B:B,0), COLUMN(B2))

Sél kalawan nilai panghandapna:

=ADDRESS(MATCH(MIN(B2:B7),B:B,0), COLUMN(B2))

Kumaha rumus ieu karya

Pikeun manggihan jumlah baris, Anjeun nganggo MATCH(lookup_value, lookup_array, [match_type]) fungsi nu mulih posisi relatif lookup_value dina lookup_array. Dina rumus kami, nilai lookup nyaéta jumlah anu dipulangkeun ku fungsi MAX atanapi MIN, sareng array lookup nyaéta sakabéh kolom. Akibatna, posisi relatif tina nilai lookup dina array persis cocog jeung nomer baris dina lambar.

Pikeun manggihan nomer kolom, Anjeun nganggo fungsi COLUM. Tangtosna, teu aya anu ngahalangan anjeun ngetik nomer langsung dina rumus, tapi COLUMN ngahemat masalah ngitung manual upami kolom target aya di tengah lambar.

Kéngingkeun hurup kolom.tina nomer kolom

Pikeun ngarobah nomer anu dipasihkeun kana hurup kolom, paké fungsi ADDRESS di jero SUBSTITUTE:

Salaku conto, hayu urang manggihan hurup kolom nu pakait jeung angka di A2:

=SUBSTITUTE(ADDRESS(1,A2,4),"1","")

Ningali hasil di handap, urang bisa nyebutkeun yén kolom kahiji. dina lambaran aya A, anu atra; kolom ka-10 nyaéta J, kolom ka-50 nyaéta AX, sareng kolom ka-100 nyaéta CV:

Kumaha rumus ieu dianggo

Pikeun ngamimitian, nyetél Pungsi ADDRESS pikeun mulangkeun référénsi rélatif ka sél munggaran dina kolom udagan:

• Pikeun nomer baris, paké 1.
• Pikeun nomer kolom, asupkeun rujukan ka sél ngandung angka, A2 dina conto urang.
• Pikeun argumen abs_num, lebetkeun 4.

Hasilna, ALAMAT(1,A2,4) bakal mulangkeun A1.

Pikeun ngaleungitkeun koordinat baris, bungkus rumus di luhur dina fungsi SUBSTITUTE sareng gentos "1" ku string kosong (""). Réngsé!

Kéngingkeun alamat rentang anu dingaranan

Pikeun milarian alamat rentang anu dingaranan dina Excel, anjeun kedah kéngingkeun rujukan sél anu munggaran sareng panungtung, teras gabungkeunana. . Ieu jalanna rada béda dina Excel pra-dinamis (2019 sareng langkung lami) sareng Dynamic Array Excel (Office 365 sareng Excel 2021). Conto di handap ieu kanggo Excel 2019 - Excel 2007. Parentah pikeun Excel 365 sareng Excel 2021 nyaétadi dieu.

Kumaha carana meunangkeun alamat sél munggaran dina rentang

Pikeun mulangkeun rujukan ka sél munggaran dina rentang ngaranna, make rumus generik ieu:

Anggap rentang kasebut dingaranan "Penjualan", rumus nyatana kieu:

=ADDRESS(ROW(Sales), COLUMN(Sales))

Jeung mulangkeun alamat sél kénca luhur dina rentang:

Dina rumus ieu, fungsi ROW jeung COLUMN ngabalikeun susunan sakabéh nomer baris jeung kolom dina rentang, masing-masing. Dumasar kana angka-angka éta, fungsi ADDRESS ngawangun sakumpulan alamat sél. Tapi ku sabab rumusna diasupkeun kana sél tunggal, ngan ukur item kahiji tina array anu dipintonkeun, nu pakait jeung sél munggaran dina rentang.

Kumaha carana meunangkeun alamat sél panungtungan dina rentang

Pikeun manggihan alamat sél panungtungan dina rentang ngaranna, make rumus generik ieu:

Diterapkeun kana rentang kami anu ngaranna "Penjualan", rumusna jadi kieu:

=ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)

Jeung mulangkeun rujukan ka sél katuhu handap rentang:

Waktos ieu, urang peryogi itungan anu rada rumit pikeun ngerjakeun barisan. angka. Sapertos dina conto sateuacana, fungsi ROW masihan kami susunan sadaya nomer baris dina rentang, {4;5;6;7} dina kasus urang. Urang kudu "shift" angka ieu ku total baris count dikurangan 1, ku kitunaitem kahiji dina Asép Sunandar Sunarya jadi angka baris panungtungan. Pikeun manggihan jumlah baris cacah, urang ngagunakeun fungsi ROWS sarta ngurangan 1 hasilna: (4-1 = 3). Lajeng, urang tambahkeun 3 ka unggal unsur tina Asép Sunandar Sunarya awal pikeun ngalakukeun shift diperlukeun: {4;5;6;7} + 3 = {7;8;9;10}.

Jumlah kolom nyaeta diitung ku cara nu sarupa: {2,3,4}+3-1 = {4,5,6}

Tina susunan nomer baris jeung kolom di luhur, fungsi ADDRESS ngumpulkeun susunan alamat sél , tapi ngan ukur mulangkeun anu pangheulana pakait sareng sél terakhir dina rentang.

Hasil anu sami ogé tiasa dihontal ku cara milih nilai maksimal tina susunan nomer baris sareng kolom. Nanging, ieu ngan ukur tiasa dianggo dina rumus array, anu peryogi mencét Ctrl + Shift + Enter pikeun réngsé leres:

=ADDRESS(MAX(ROW(Sales)), MAX(COLUMN(Sales)))

Kumaha carana kéngingkeun alamat lengkep tina rentang anu namina

Pikeun mulangkeun alamat lengkep tina rentang ngaranna, anjeun ngan perlu concatenate dua rumus ti conto saméméhna tur selapkeun operator rentang (:) di-antara.

Supaya tiasa dianggo pikeun sampel set data urang, urang ngaganti generik "rentang" kalawan ngaran rentang nyata "Penjualan":

=ADDRESS(ROW(Sales), COLUMN(Sales)) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)

Jeung meunang alamat rentang lengkep salaku absolut rujukan $B$4:$D$7:

Pikeun mulangkeun rentangalamat salaku rujukan relatif (tanpa tanda $, sapertos B4:D7), setel argumen abs_num dina duanana fungsi ADDRESS ka 4:

=ADDRESS(ROW(Sales), COLUMN(Sales), 4) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1, 4)

Sacara alami, Parobahan anu sami tiasa dilakukeun dina rumus individu pikeun sél kahiji sareng panungtung, sareng hasilna bakal katingali sapertos kieu:

Kumaha cara kéngingkeun alamat rentang anu namina dina Excel 365 jeung Excel 2021

Beda jeung kabiasaan tradisional "hiji rumus - hiji sél" dina versi heubeul, dina Excel anyar, sagala rumus nu berpotensi bisa balik sababaraha nilai, ngalakukeun ieu otomatis. Kalakuan kitu disebut spilling.

Misalna, tinimbang mulangkeun alamat sél munggaran, rumus di handap ieu kaluaran alamat unggal sél dina rentang ngaranna:

=ADDRESS(ROW(Sales), COLUMN(Sales))

Pikeun meunangkeun alamat sél kahiji ngan, Anjeun kudu ngaktipkeun intersection implisit, nu dipicu sacara standar dina Excel 2019 jeung nu leuwih heubeul. Jang ngalampahkeun ieu, nempatkeun simbol @ (operator simpang implisit) saméméh ngaran rentang:

=ADDRESS(@ROW(Sales), @COLUMN(Sales))

Ku cara nu sarua, anjeun bisa ngalereskeun rumus séjén.

Pikeun meunangkeun sél panungtungan dina rentang:

=ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)

Pikeun meunangkeun alamat rentang ngaranna :

=ADDRESS(@ROW(Sales), @COLUMN(Sales)) & ":" & ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)

Potret layar di handap nembongkeun hasil:

Tip. Nalika muka lembar kerja kalayan rumus anu didamel dina vérsi anu langkung lami dina larik dinamis Excel, operator simpang implisit diselapkeun ku Excel sacara otomatis.

Kitu kumaha anjeunmulangkeun alamat sél dina Excel. Pikeun langkung caket kana sadaya rumus anu dibahas dina tutorial ieu, anjeun wilujeng sumping pikeun ngaunduh buku kerja conto kami di handap. Hatur nuhun pikeun maca sareng ngarepkeun anjeun tiasa ningali anjeun dina blog kami minggu payun!

Buku kerja latihan pikeun diunduh

Fungsi ALAMAT Excel - conto rumus (file .xlsx)