V tem članku boste spoznali različne načine združevanja besedilnih nizov, številk in datumov v Excelu z uporabo funkcije CONCATENATE in operatorja "&". Obravnavali bomo tudi formule za združevanje posameznih celic, stolpcev in obsegov.

V delovnih zvezkih programa Excel podatki niso vedno strukturirani v skladu z vašimi potrebami. Pogosto želite vsebino ene celice razdeliti na posamezne celice ali storiti nasprotno - združiti podatke iz dveh ali več stolpcev v en sam stolpec. Pogosti primeri so združevanje imen in delov naslovov, združevanje besedila z vrednostjo iz formule, prikaz datumov in časov v želeni obliki in še bi lahko naštevali.

V tem vodniku bomo raziskali različne tehnike povezovanja nizov v Excelu, da boste lahko izbrali metodo, ki je najprimernejša za vaše delovne liste.

Kaj je "concatenate" v programu Excel?

V bistvu obstajata dva načina združevanja podatkov v preglednicah Excel:

• Združevanje celic
• Povezovanje vrednosti celic

Ko združitev fizično združite dve ali več celic v eno samo celico. Tako dobite eno večjo celico, ki je prikazana v več vrsticah in/ali stolpcih.

Ko združiti celic v Excelu, združite samo vsebina Z drugimi besedami, povezovanje v Excelu je postopek združevanja dveh ali več vrednosti. Ta metoda se pogosto uporablja za združevanje nekaj delov besedila, ki se nahajajo v različnih celicah (tehnično se imenujejo besedilni nizi ali preprosto vrstice ) ali vstavite vrednost, izračunano s formulo, na sredino besedila.

Naslednja slika zaslona prikazuje razliko med tema dvema metodama:

Združevanje celic v Excelu je tema posebnega članka, v tem vodniku pa bomo obravnavali dva glavna načina združevanja nizov v Excelu - z uporabo funkcije CONCATENATE in operatorja združevanja (&).

Excelova funkcija CONCATENATE

Funkcija CONCATENATE v Excelu se uporablja za združevanje različnih delov besedila ali združevanje vrednosti iz več celic v eno celico.

Sintaksa programa Excel CONCATENATE je naslednja:

Kje: besedilo je besedilni niz, referenca na celico ali vrednost, ki izhaja iz formule.

Funkcija CONCATENATE je podprta v vseh različicah programa Excel 365 - 2007.

Če želite na primer združiti vrednosti B6 in C6 z vejico, je formula naslednja:

=CONCATENATE(B6, ",", C6)

Več primerov je prikazanih na spodnji sliki:

Opomba: V programih Excel 365 - Excel 2019 je na voljo tudi funkcija CONCAT, ki je sodobna naslednica funkcije CONCATENATE s popolnoma enako sintakso. Čeprav je funkcija CONCATENATE ohranjena zaradi povratne združljivosti, Microsoft ne obljublja, da bo podprta v prihodnjih različicah programa Excel.

Uporaba CONCATENATE v Excelu - stvari, ki si jih morate zapomniti

Če želite zagotoviti, da formule CONCATENATE vedno dajejo pravilne rezultate, si zapomnite naslednja preprosta pravila:

• Excelova funkcija CONCATENATE za delovanje potrebuje vsaj en argument "besedilo".
• V eni formuli lahko združite do 255 nizov, skupaj 8192 znakov.
• Rezultat funkcije CONCATENATE je vedno besedilni niz, tudi če so vse izvorne vrednosti številke.
• Za razliko od funkcije CONCAT Excel CONCATENATE ne prepozna nizov. Vsak sklic na celico je treba navesti ločeno. Uporabiti morate na primer CONCATENATE(A1, A2, A3) in ne CONCATENATE(A1:A3).
• Če je kateri od argumentov neveljaven, funkcija CONCATENATE vrne napako #VALUE!.

Operater "&" za združevanje nizov v Excelu

V programu Microsoft Excel je znak ampersand (&) še en način združevanja celic. Ta metoda je zelo priročna v številnih scenarijih, saj je vnos ampersanda veliko hitrejši od vnosa besede "združi" :)

Če želite na primer združiti dve vrednosti iz celic, med katerima je presledek, je formula naslednja:

=A2&" "&B2

Kako združiti v Excelu - primeri formul

V nadaljevanju je nekaj primerov uporabe funkcije CONCATENATE v Excelu.

Združite dve ali več celic brez ločilnika

Če želite združiti vrednosti dve celici v enega, uporabite formulo za združevanje v njeni najpreprostejši obliki:

=CONCATENATE(A2, B2)

Ali

=A2&B2

Upoštevajte, da bodo vrednosti združene brez ločil, kot je prikazano na spodnji sliki zaslona.

Povezovanje več celic , morate navesti vsak sklic na celico posebej, tudi če združujete sosednje celice. Na primer:

=CONCATENATE(A2, B2, C2)

Ali

=A2&B2&C2

Formule delujejo za besedilo in številke. Pri številkah upoštevajte, da je rezultat besedilni niz. Če ga želite pretvoriti v številko, pomnožite rezultat CONCATENATE z 1 ali mu dodajte 0. Na primer:

=CONCATENATE(A2, B2)*1

Nasvet. V Excelu 2019 in novejših različicah lahko s funkcijo CONCAT hitro združite več celic z enim ali več referenčnimi območji.

združite celice s presledkom, vejico ali drugim ločilom

V svojih delovnih listih boste morda pogosto morali združiti vrednosti na način, ki vključuje vejice, presledke, različna ločila ali druge znake, kot sta pomišljaj ali poševnica. To storite tako, da v formulo za združevanje vstavite želeni znak. Ne pozabite tega znaka zapreti v narekovaje, kot je prikazano v naslednjih primerih.

Povezovanje dveh celic z prostor :

=CONCATENATE(A2, " ", B2)

ali

=A2 & " " & B2

Povezovanje dveh celic z vejica :

=CONCATENATE(A2, ", ", B2)

ali

=A2 & ", " & B2

Povezovanje dveh celic z pomišljaj :

=CONCATENATE(A2, "-", B2)

ali

=A2 & "-" & B2

Naslednja zaslonska slika prikazuje, kako so lahko videti rezultati:

Nasvet. V Excelu 2019 in novejših različicah lahko s funkcijo TEXTJOIN združite nize iz več celic s katerim koli ločilom, ki ga določite.

Povezovanje besedilnega niza in vrednosti celice

Ni razloga, da bi bila funkcija Excel CONCATENATE omejena samo na združevanje vrednosti celic. Uporabite jo lahko tudi za združevanje besedilnih nizov, da bo rezultat bolj smiseln. Na primer:

=CONCATENATE(A2, " ", B2, " končano")

Zgornja formula obvesti uporabnika, da je določen projekt končan, kot v vrstici 2 na spodnji sliki zaslona. Opazite, da pred besedo " končan" dodamo presledek, da ločimo združene besedilne nize. Presledek (" ") je vstavljen tudi med združene vrednosti, tako da je rezultat prikazan kot "Projekt 1" in ne "Projekt1".

Z operatorjem za združevanje lahko formulo zapišemo na naslednji način:

=A2 & " " & B2 & " končano"

Na enak način lahko besedilni niz dodate na začetek ali na sredino formule za združevanje. Na primer:

=CONCATENATE("Glej ", A2, " ", B2)

="Glej " & A2 & " " & B2

Združite besedilni niz in drugo formulo

Če želite, da je rezultat, ki ga vrne določena formula, uporabnikom bolj razumljiv, ga lahko povežete z besedilnim nizom, ki pojasnjuje, kakšna je dejanska vrednost.

Z naslednjo formulo lahko na primer vrnete trenutni datum v želeni obliki in določite, za kakšen datum gre:

=CONCATENATE("Danes je ",TEXT(TODAY(), "mmmm d, yyyy"))

="Danes je " & TEXT(TODAY(), "dd-mmm-yy")

Nasvet. Če želite izbrisati izvorne podatke, ne da bi to vplivalo na dobljene besedilne nize, uporabite možnost "Paste special - values only" (Prilepi posebno - samo vrednosti), da pretvorite formule v njihove vrednosti.

Povezovanje besedilnih nizov s prelomi vrstic

Najpogosteje boste dobljene besedilne nize ločili z ločili in presledki, kot je prikazano v prejšnjem primeru. V nekaterih primerih pa bo morda treba vrednosti ločiti s prekinitvijo vrstice ali povratkom. Pogost primer je združevanje poštnih naslovov iz podatkov v ločenih stolpcih.

Težava je v tem, da v formulo ne morete preprosto vnesti preloma vrstice kot običajen znak. Namesto tega uporabite funkcijo CHAR, da formuli za združevanje posredujete ustrezno kodo ASCII:

• V operacijskem sistemu Windows uporabite CHAR(10), kjer je 10 znakovna koda za Podajanje vrstice .
• V računalnikih Mac uporabite CHAR(13), kjer je 13 koda znakov za Vračanje vozička .

V tem primeru imamo dele naslovov v stolpcih od A do F in jih združimo v stolpcu G z uporabo operatorja za združevanje "&". Združene vrednosti so ločene z vejico (", "), presledkom (" ") in prekinitvijo vrstice CHAR(10):

=A2 & " " & B2 & CHAR(10) & C2 & CHAR(10) & D2 & ", " & E2 & " " & F2

Funkcija CONCATENATE bi imela naslednjo obliko:

=CONCATENATE(A2, " ", B2, CHAR(10), C2, CHAR(10), D2, ", ", E2, " ", F2)

V vsakem primeru je rezultat trivrstični besedilni niz: Opomba: Pri uporabi prelomov vrstic za ločevanje kombiniranih vrednosti morate omogočiti objavo besedila, da bo rezultat pravilno prikazan. To storite tako, da pritisnete kombinacijo tipk Ctrl + 1, da odprete okno Oblikovanje celic preklopite na pogovorno okno Uskladitev in preverite zavihek Ovijanje besedila škatla.

Na enak način lahko končne nize ločite z drugimi znaki, kot so:

• Dvojni narekovaji (") - CHAR(34)
• Poševnica naprej (/) - CHAR(47)
• Zvezdica (*) - CHAR (42)
• Celoten seznam Kode ASCII je na voljo tukaj.

Kako združiti stolpce v Excelu

Če želite združiti dva ali več stolpcev, v prvo celico vnesite formulo za združevanje, nato pa jo kopirajte v druge celice tako, da povlečete ročico za zapolnitev (majhen kvadrat, ki se prikaže v spodnjem desnem kotu izbrane celice).

Če želite na primer združiti dva stolpca (stolpca A in B) in vrednosti ločiti s presledkom, je formula v C2 kopirana navzdol naslednja:

=CONCATENATE(A2, " ", B2)

Ali

= A2 & " " & B2 Nasvet: Hitro lahko kopirate formulo po stolpcu navzdol tako, da izberete celico s formulo in dvakrat kliknete ročico za zapolnitev.

Za več informacij glejte Kako združiti dva stolpca v Excelu brez izgube podatkov.

združevanje besedila in številk z ohranjanjem oblikovanja

Pri povezovanju besedilnega niza s številko, odstotkom ali datumom boste morda želeli ohraniti prvotno oblikovanje številčne vrednosti ali jo prikazati na drugačen način. To lahko storite tako, da znotraj funkcije TEXT podate kodo za oblikovanje, ki jo vstavite v formulo za povezovanje.

Na začetku tega učbenika smo že obravnavali formulo, ki združuje besedilo in datum.

Tukaj je še nekaj primerov formul, ki združujejo besedilo in številka :

Število z dvema decimalnima mestoma in znakom $:

=A2 & " " & TEXT(B2, "$#,#0.00")

Število brez nepomembnih ničel in znaka $:

=A2 & " " & TEXT(B2, "0.#")

Drobno število:

=A2 & " " & TEXT(B2, "# ?/???")

Povezovanje besedilo in odstotek , so formule naslednje:

Odstotek z dvema decimalnima mestoma:

=A12 & " " & TEXT(B12, "0,00%")

Zaokroženi celi odstotki:

=A12 & " " & TEXT(B12, "0%")

Kako združiti obseg celic v Excelu

Združevanje vrednosti iz več celic lahko zahteva nekaj truda, saj Excelova funkcija CONCATENATE ne sprejema nizov.

Če želite združiti več celic, na primer od A1 do A4, morate uporabiti eno od naslednjih formul:

=CONCATENATE(A1, A2, A3, A4)

ali

=A1 & A2 & A3 & A4

Pri združevanju dokaj majhne skupine celic ni velik problem vnesti vse sklice. Velik obseg bi bil zamuden, če bi ročno vnesli vsako posamezno sklicevanje. V nadaljevanju najdete 3 metode hitrega združevanja obsegov v Excelu.

Metoda 1. Pritisnite CTRL, da izberete več celic

Če želite hitro izbrati več celic, lahko pritisnete in držite tipko Ctrl, medtem ko kliknete vsako celico, ki jo želite vključiti v formulo. Tukaj so podrobni koraki:

1. Izberite celico, v katero želite vnesti formulo.
2. V to celico ali v vrstico formul vnesite =CONCATENATE(.
3. Pritisnite in pridržite tipko Ctrl ter kliknite vsako celico, ki jo želite združiti.
4. Spustite tipko Ctrl, vnesite zaključni oklepaj in pritisnite Enter .

Metoda 2. Uporabite funkcijo TRANSPOSE za pridobitev vseh vrednosti celic

Če je območje sestavljeno iz deset ali sto celic, prejšnja metoda morda ne bo dovolj hitra, saj zahteva klik na vsako celico. V tem primeru lahko uporabite funkcijo TRANSPOSE, ki vrne polje vrednosti, nato pa jih združite z enim samim zamahom.

1. V celico, v kateri želite prikazati rezultat, vnesite formulo TRANSPOSE, na primer:

   =TRANSPOZICIJA(A1:A10)

2. V vrstici formul pritisnite F9, da formulo nadomestite z izračunanimi vrednostmi. Tako boste dobili polje vrednosti, ki jih je treba združiti.
3. Izbrišite oglate oklepaje, ki obkrožajo polje.
4. Pred prvo vrednostjo vnesite =CONCATENATE(, nato za zadnjo vrednostjo vnesite zaključni oklepaj in pritisnite Enter .

Opomba: Rezultat te formule je statični saj združuje vrednosti in ne referenc celic. Če se izvorni podatki spremenijo, boste morali postopek ponoviti.

Metoda 3. Uporaba funkcije CONCAT

V Excelu 365 in Excelu 2021 bo ta preprosta formula v trenutku združila niz celic:

=CONCAT(A1:A10)

Metoda 4. Uporaba dodatka Merge Cells

Hitro in brez formule združite poljubno območje v Excelu tako, da uporabite dodatek Merge Cells z " Združitev vseh območij v izboru " izklopljena, kot je prikazano v poglavju Združevanje vrednosti več celic v eno celico.

Excelov operator "&" v primerjavi s funkcijo CONCATENATE

Številni uporabniki se sprašujejo, kateri način združevanja nizov v Excelu je učinkovitejši - funkcija CONCATENATE ali operator "&".

Edina resnična razlika je omejitev funkcije CONCATENATE na 255 nizov, pri uporabi ampersanda pa te omejitve ni. Razen tega med tema dvema metodama ni nobene razlike, prav tako ni razlike v hitrosti med formulama CONCATENATE in "&".

Ker je 255 res veliko število in pri resničnem delu skoraj nikoli ne boste morali združiti toliko nizov, je razlika v udobju in enostavnosti uporabe. Nekaterim uporabnikom se zdijo formule CONCATENATE lažje berljive, sam pa raje uporabljam metodo "&". Zato se preprosto držite tehnike, ki vam bolj ustreza.

Nasprotje CONCATENATE v Excelu (razdelitev celic)

Nasprotje konkatenaciji v Excelu je razdelitev vsebine ene celice na več celic. To lahko storite na več različnih načinov:

• Funkcija Besedilo v stolpce
• Možnost Flash Fill v Excelu 2013 in novejših različicah
• Funkcija TEXTSPLIT v Excelu 365
• Prilagojene formule za razdelitev celic (MID, RIGHT, LEFT itd.)

Koristne informacije lahko najdete tudi v tem članku: Kako sprostiti združene celice v Excelu.

Povezovanje v Excelu z dodatkom Merge Cells

Z dodatkom Merge Cells, ki je vključen v paket Ultimate Suite za Excel, lahko učinkovito opravite oboje:

• Združitev več celic v eno brez izgube podatkov.
• Konkatenirati vrednosti več celic v eno samo celico in jih ločite s poljubnim razmejitvenim znakom po lastni izbiri.

Orodje Merge Cells deluje v vseh različicah programa Excel od 2016 do 365 in lahko združuje vse vrste podatkov, vključno z besedilnimi nizi, številkami, datumi in posebnimi simboli. Njegovi ključni prednosti sta preprostost in hitrost - vsako združevanje opravite z nekaj kliki.

Združite vrednosti več celic v eno celico

Če želite združiti vsebino več celic, izberite območje za združevanje in konfigurirajte naslednje nastavitve:

• Pod naslovom Kaj združiti , izberite celice v eno .
• Pod naslovom Združite z , vnesite razmejitev (v našem primeru z vejico in presledkom).
• Izberite, kam želite umestiti rezultat.
• Najpomembneje je, da odkljukate polje Združite vsa območja v izboru Ta možnost določa, ali se celice združijo ali se njihove vrednosti združijo.

Združevanje stolpcev po vrsticah

Če želite združiti dva ali več stolpcev, konfigurirate nastavitve Merge Cells na podoben način, vendar izberete združitev stolpcev v enega in rezultate postavite v levi stolpec.

Združevanje vrstic po stolpcih

Če želite združiti podatke v vsaki posamezni vrstici po posameznih stolpcih, lahko izberete:

• Združitev vrstic v eno .
• Uporabite Prekinitev vrstice za ločilo.
• Rezultate vstavite v zgornja vrstica .

Rezultat je lahko podoben temu:

Če želite preveriti, kako se bo dodatek Merge Cells spopadel z vašimi podatkovnimi nizi, lahko spodaj prenesete popolnoma funkcionalno preskusno različico našega paketa Ultimate Suite za Excel.

To je način za povezovanje v Excelu. Zahvaljujem se vam za branje in upam, da se naslednji teden vidimo na našem blogu!

Razpoložljivi prenosi

Primeri formul za združevanje (.xlsx datoteka)

14-dnevna poskusna različica paketa Ultimate Suite (.exe datoteka)