V tomto článku sa dozviete rôzne spôsoby spájania textových reťazcov, čísel a dátumov v programe Excel pomocou funkcie CONCATENATE a operátora "&". Budeme sa venovať aj vzorcom na spájanie jednotlivých buniek, stĺpcov a rozsahov.

V zošitoch programu Excel nie sú údaje vždy štruktúrované podľa vašich potrieb. Často môžete chcieť rozdeliť obsah jednej bunky do jednotlivých buniek alebo urobiť opak - spojiť údaje z dvoch alebo viacerých stĺpcov do jedného stĺpca. Bežnými príkladmi sú napríklad spájanie častí mien a adries, spájanie textu s hodnotou riadenou vzorcom, zobrazovanie dátumov a časov v požadovanom formáte a ďalšie.

V tomto návode sa budeme zaoberať rôznymi technikami spájania reťazcov v programe Excel, aby ste si mohli vybrať metódu, ktorá je najvhodnejšia pre vaše pracovné hárky.

Čo je to "concatenate" v programe Excel?

V podstate existujú dva spôsoby kombinovania údajov v tabuľkách programu Excel:

• Zlučovanie buniek
• Zlučovanie hodnôt buniek

Keď zlúčiť bunky, "fyzicky" spojíte dve alebo viac buniek do jednej bunky. Výsledkom je jedna väčšia bunka, ktorá je zobrazená vo viacerých riadkoch a/alebo stĺpcoch.

Keď spojiť buniek v programe Excel, kombinujete iba obsah Inými slovami, konkatenácia v Exceli je proces spájania dvoch alebo viacerých hodnôt. Táto metóda sa často používa na spojenie niekoľkých častí textu, ktoré sa nachádzajú v rôznych bunkách (odborne sa nazývajú textové reťazce alebo jednoducho reťazce ) alebo vložte hodnotu vypočítanú podľa vzorca doprostred textu.

Nasledujúci obrázok ukazuje rozdiel medzi týmito dvoma metódami:

Zlučovanie buniek v programe Excel je predmetom samostatného článku a v tomto návode sa budeme venovať dvom hlavným spôsobom spájania reťazcov v programe Excel - pomocou funkcie CONCATENATE a operátora spájania (&).

Funkcia CONCATENATE aplikácie Excel

Funkcia CONCATENATE v programe Excel sa používa na spájanie rôznych častí textu alebo na kombinovanie hodnôt z viacerých buniek do jednej bunky.

Syntax programu Excel CONCATENATE je nasledujúca:

Kde text je textový reťazec, odkaz na bunku alebo hodnota riadená vzorcom.

Funkcia CONCATENATE je podporovaná vo všetkých verziách programu Excel 365 - 2007.

Ak chcete napríklad spojiť hodnoty B6 a C6 s čiarkou, vzorec je:

=CONCATENATE(B6, ",", C6)

Ďalšie príklady sú uvedené na obrázku nižšie:

Poznámka: V aplikácii Excel 365 - Excel 2019 je k dispozícii aj funkcia CONCAT, ktorá je moderným nástupcom funkcie CONCATENATE s úplne rovnakou syntaxou. Hoci je funkcia CONCATENATE zachovaná kvôli spätnej kompatibilite, spoločnosť Microsoft nedáva žiadne prísľuby, že bude podporovaná v budúcich verziách aplikácie Excel.

Používanie funkcie CONCATENATE v programe Excel - čo si treba zapamätať

Ak chcete zabezpečiť, aby vaše vzorce CONCATENATE vždy poskytovali správne výsledky, pamätajte na nasledujúce jednoduché pravidlá:

• Funkcia CONCATENATE programu Excel vyžaduje pre svoju činnosť aspoň jeden argument "text".
• V jednom vzorci môžete spojiť až 255 reťazcov, čo je spolu 8 192 znakov.
• Výsledkom funkcie CONCATENATE je vždy textový reťazec, aj keď sú všetky zdrojové hodnoty čísla.
• Na rozdiel od funkcie CONCAT, Excel CONCATENATE nerozoznáva polia. Každý odkaz na bunku musí byť uvedený samostatne. Napríklad by ste mali použiť CONCATENATE(A1, A2, A3) a nie CONCATENATE(A1:A3).
• Ak je niektorý z argumentov neplatný, funkcia CONCATENATE vráti chybu #VALUE!.

Operátor "&" na spájanie reťazcov v programe Excel

V programe Microsoft Excel je ďalším spôsobom spájania buniek znak ampersand (&). Táto metóda je veľmi užitočná v mnohých scenároch, pretože písanie ampersandu je oveľa rýchlejšie ako písanie slova "spojiť" :)

Napríklad na spojenie dvoch hodnôt buniek s medzerou medzi nimi je vzorec nasledovný:

=A2&" "&B2

Ako spájať v programe Excel - príklady vzorcov

Nižšie nájdete niekoľko príkladov použitia funkcie CONCATENATE v programe Excel.

Spojenie dvoch alebo viacerých buniek bez oddeľovača

Kombinácia hodnôt dve bunky do jedného, použijete konkatenačný vzorec v jeho najjednoduchšej podobe:

=CONCATENATE(A2, B2)

Alebo

=A2&B2

Všimnite si, že hodnoty sa budú spájať bez oddeľovača, ako je to na obrázku nižšie.

Zlučovanie viacero buniek , musíte uviesť odkaz na každú bunku samostatne, aj keď kombinujete susediace bunky. Napríklad:

=CONCATENATE(A2, B2, C2)

Alebo

=A2&B2&C2

Vzorce fungujú pre text aj čísla. V prípade čísel majte na pamäti, že výsledok je textový reťazec. Ak ho chcete previesť na číslo, stačí výstup CONCATENATE vynásobiť 1 alebo k nemu pripočítať 0. Napríklad:

=CONCATENATE(A2, B2)*1

Tip. V aplikácii Excel 2019 a vyšších môžete použiť funkciu CONCAT na rýchle spojenie viacerých buniek pomocou jedného alebo viacerých odkazov na rozsah.

Zlučovanie buniek pomocou medzery, čiarky alebo iného oddeľovača

V pracovných hárkoch môžete často potrebovať spojiť hodnoty spôsobom, ktorý obsahuje čiarky, medzery, rôzne interpunkčné znamienka alebo iné znaky, ako je napríklad spojovník alebo lomka. Ak to chcete urobiť, jednoducho vložte požadovaný znak do spojovacieho vzorca. Nezabudnite tento znak uzavrieť do úvodzoviek, ako je uvedené v nasledujúcich príkladoch.

Spojenie dvoch buniek so znakom priestor :

=CONCATENATE(A2, " ", B2)

alebo

=A2 & " " & B2

Spojenie dvoch buniek so znakom čiarka :

=CONCATENATE(A2, ", ", B2)

alebo

=A2 & ", " & B2

Spojenie dvoch buniek so znakom pomlčka :

=CONCATENATE(A2, "-", B2)

alebo

=A2 & "-" & B2

Nasledujúci obrázok ukazuje, ako môžu vyzerať výsledky:

Tip. V aplikácii Excel 2019 a vyšších môžete použiť funkciu TEXTJOIN na zlúčenie reťazcov z viacerých buniek s ľubovoľným oddeľovačom, ktorý zadáte.

Zlučovanie textového reťazca a hodnoty bunky

Nie je dôvod, aby sa funkcia CONCATENATE v programe Excel obmedzovala len na spájanie hodnôt buniek. Môžete ju použiť aj na spájanie textových reťazcov, aby bol výsledok zmysluplnejší. Napríklad

=CONCATENATE(A2, " ", B2, " dokončené")

Vyššie uvedený vzorec informuje používateľa o tom, že určitý projekt je dokončený, ako v riadku 2 na snímke nižšie. Všimnite si, že pred slovo " dokončený" pridávame medzeru, aby sme oddelili spojený textový reťazec. Medzera (" ") sa vkladá aj medzi spojené hodnoty, aby sa výsledok zobrazil ako "Projekt 1" a nie ako "Projekt1".

Pomocou operátora zlučovania možno vzorec zapísať takto:

=A2 & " " & B2 & " dokončené"

Rovnakým spôsobom môžete pridať textový reťazec na začiatok alebo do stredu konkatenačného vzorca. Napríklad:

=CONCATENATE("Pozri ", A2, " ", B2)

="Pozri " & A2 & " " & B2

Spojenie textového reťazca a iného vzorca

Ak chcete, aby bol výsledok vrátený určitým vzorcom pre používateľov zrozumiteľnejší, môžete ho spojiť s textovým reťazcom, ktorý vysvetľuje, čo je vlastne hodnota.

Na vrátenie aktuálneho dátumu v požadovanom formáte a určenie, o aký druh dátumu ide, môžete použiť napríklad nasledujúci vzorec:

=CONCATENATE("Dnes je ",TEXT(TODAY(), "mmmm d, rrrr")

="Dnes je " & TEXT(TODAY(), "dd-mmm-yy")

Tip. Ak chcete odstrániť zdrojové údaje bez toho, aby ste ovplyvnili výsledné textové reťazce, použite možnosť "Vložiť špeciálne - len hodnoty" na prevod vzorcov na ich hodnoty.

Spájanie textových reťazcov s oddeľovaním riadkov

Najčastejšie by ste výsledné textové reťazce oddelili interpunkčnými znamienkami a medzerami, ako je uvedené v predchádzajúcom príklade. V niektorých prípadoch však môže byť potrebné oddeliť hodnoty zalomením riadku alebo návratom vozíka. Bežným príkladom je zlúčenie poštových adries z údajov v samostatných stĺpcoch.

Problémom je, že do vzorca nemôžete jednoducho zadať zalomenie riadku ako bežný znak. Namiesto toho musíte použiť funkciu CHAR, ktorá do vzorca na zlučovanie dodá príslušný kód ASCII:

• V systéme Windows použite CHAR(10), kde 10 je kód znaku pre Podávanie riadkov .
• V systéme Mac použite CHAR(13), kde 13 je kód znaku pre Vrátenie vozňa .

V tomto príklade máme časti adries v stĺpcoch A až F a spájame ich do stĺpca G pomocou operátora spájania "&". Zlúčené hodnoty sú oddelené čiarkou (", "), medzerou (" ") a zalomením riadku CHAR(10):

=A2 & " " & B2 & CHAR(10) & C2 & CHAR(10) & D2 & ", " & E2 & " " & F2

Funkcia CONCATENATE by mala tento tvar:

=CONCATENATE(A2, " ", B2, CHAR(10), C2, CHAR(10), D2, ", ", E2, " ", F2)

V každom prípade je výsledkom trojriadkový textový reťazec: Poznámka: Pri použití zalomenia riadkov na oddelenie kombinovaných hodnôt musíte mať povolené obtekanie textu, aby sa výsledok zobrazil správne. Ak to chcete urobiť, stlačte klávesovú skratku Ctrl + 1, aby ste otvorili Formátovanie buniek prepnite na dialógové okno Zarovnanie a začiarknite kartu Obalenie textu box.

Rovnakým spôsobom môžete oddeliť koncové reťazce inými znakmi, ako napr:

• Dvojité úvodzovky (") - CHAR(34)
• Lomítko vpred (/) - CHAR(47)
• Hviezdička (*) - CHAR (42)
• Úplný zoznam Kódy ASCII je k dispozícii tu.

Ako spojiť stĺpce v programe Excel

Ak chcete spojiť dva alebo viac stĺpcov, stačí do prvej bunky zadať spojovací vzorec a potom ho skopírovať do ďalších buniek potiahnutím úchytu výplne (malý štvorček, ktorý sa zobrazí v pravom dolnom rohu vybranej bunky).

Ak chcete napríklad spojiť dva stĺpce (stĺpec A a B) a ohraničiť hodnoty medzerou, vzorec v C2 skopírovaný dole je:

=CONCATENATE(A2, " ", B2)

Alebo

= A2 & " " & B2 Tip: Rýchly spôsob, ako skopírovať vzorec do stĺpca, je vybrať bunku so vzorcom a dvakrát kliknúť na úchyt výplne.

Ďalšie informácie nájdete v časti Ako zlúčiť dva stĺpce v programe Excel bez straty údajov.

Kombinácia textu a čísel so zachovaním formátovania

Pri spájaní textového reťazca s číslom, percentom alebo dátumom môžete chcieť zachovať pôvodné formátovanie číselnej hodnoty alebo ju zobraziť iným spôsobom. To môžete urobiť zadaním formátovacieho kódu vo vnútri funkcie TEXT, ktorý vložíte do vzorca spájania.

Na začiatku tohto návodu sme už hovorili o vzorci, ktorý spája text a dátum.

A tu je niekoľko ďalších príkladov vzorcov, ktoré kombinujú text a číslo :

Číslo s 2 desatinnými miestami a znakom $:

=A2 & " " & TEXT(B2, "$#,#0.00")

Číslo bez bezvýznamových núl a znaku $:

=A2 & " " & TEXT(B2, "0.#")

Zlomkové číslo:

=A2 & " " & TEXT(B2, "# ?/???")

Zlučovanie text a percentá , vzorce sú:

Percentá s dvoma desatinnými miestami:

=A12 & " " & TEXT(B12, "0,00%")

Zaokrúhlené celé percento:

=A12 & " " & TEXT(B12, "0%")

Ako spojiť rozsah buniek v programe Excel

Kombinovanie hodnôt z viacerých buniek môže vyžadovať určité úsilie, pretože funkcia CONCATENATE aplikácie Excel neakceptuje polia.

Ak chcete spojiť niekoľko buniek, napríklad A1 až A4, musíte použiť jeden z nasledujúcich vzorcov:

=CONCATENATE(A1, A2, A3, A4)

alebo

=A1 & A2 & A3 & A4

Pri spájaní pomerne malej skupiny buniek nie je veľký problém zadať všetky odkazy. Veľký rozsah by bolo zdĺhavé dodávať a zadávať každý jednotlivý odkaz ručne. Nižšie nájdete 3 spôsoby rýchleho spájania rozsahov v programe Excel.

Metóda 1. Stlačením klávesu CTRL vyberte viac buniek

Ak chcete rýchlo vybrať niekoľko buniek, môžete stlačiť a podržať kláves Ctrl a zároveň kliknúť na každú bunku, ktorú chcete zahrnúť do vzorca. Tu sú uvedené podrobné kroky:

1. Vyberte bunku, do ktorej chcete zadať vzorec.
2. Do tejto bunky alebo do panela vzorcov zadajte =CONCATENATE(.
3. Stlačte a podržte kláves Ctrl a kliknite na každú bunku, ktorú chcete spojiť.
4. Uvoľnite tlačidlo Ctrl, zadajte uzatváraciu zátvorku a stlačte kláves Enter .

Metóda 2. Na získanie všetkých hodnôt buniek použite funkciu TRANSPOSE

Ak rozsah pozostáva z desiatok alebo stoviek buniek, predchádzajúca metóda nemusí byť dostatočne rýchla, pretože vyžaduje kliknutie na každú bunku. V takom prípade môžete použiť funkciu TRANSPOSE, ktorá vráti pole hodnôt a potom ich jedným ťahom zlúči.

1. Do bunky, v ktorej chcete zobraziť výsledok, zadajte vzorec TRANSPOSE, napríklad:

   =TRANSPOSE(A1:A10)

2. V paneli vzorcov stlačte kláves F9, čím nahradíte vzorec vypočítanými hodnotami. Výsledkom bude pole hodnôt, ktoré sa majú spojiť.
3. Odstráňte kučeravé zátvorky okolo poľa.
4. Zadajte =CONCATENATE( pred prvú hodnotu, potom zadajte uzatváraciu zátvorku za poslednú hodnotu a stlačte kláves Enter .

Poznámka: Výsledok tohto vzorca je statické pretože spája hodnoty, nie odkazy na bunky. Ak sa zdrojové údaje zmenia, budete musieť tento proces zopakovať.

Metóda 3. Použitie funkcie CONCAT

V aplikáciách Excel 365 a Excel 2021 tento jednoduchý vzorec v okamihu spojí rozsah buniek:

=CONCAT(A1:A10)

Metóda 4. Použitie doplnku Merge Cells

Rýchlym spôsobom bez použitia vzorcov na spojenie ľubovoľného rozsahu v programe Excel je použitie doplnku Merge Cells s príkazom " Zlúčiť všetky oblasti vo výbere " vypnutá, ako je uvedené v časti Kombinovanie hodnôt viacerých buniek do jednej bunky.

Operátor "&" programu Excel vs. funkcia CONCATENATE

Mnohí používatelia sa pýtajú, ktorý spôsob spájania reťazcov v programe Excel je efektívnejší - funkcia CONCATENATE alebo operátor "&".

Jediným skutočným rozdielom je obmedzenie počtu reťazcov na 255 pri funkcii CONCATENATE a žiadne takéto obmedzenie pri použití ampersandu. Okrem toho nie je medzi týmito dvoma metódami žiadny rozdiel a nie je ani žiadny rozdiel v rýchlosti medzi vzorcami CONCATENATE a "&".

A keďže 255 je naozaj veľké číslo a v reálnej práci sotva budete potrebovať kombinovať toľko reťazcov, rozdiel sa obmedzuje na pohodlie a jednoduchosť používania. Niektorí používatelia považujú vzorce CONCATENATE za ľahšie čitateľné, ja osobne uprednostňujem používanie metódy "&". Takže jednoducho zostaňte pri technike, ktorá je vám pohodlnejšia.

Opak funkcie CONCATENATE v programe Excel (rozdelenie buniek)

Opakom funkcie concatenate v programe Excel je rozdelenie obsahu jednej bunky do viacerých buniek. To možno vykonať niekoľkými rôznymi spôsobmi:

• Funkcia Text do stĺpcov
• Možnosť Flash Fill v programe Excel 2013 a vyšších verziách
• Funkcia TEXTSPLIT v programe Excel 365
• Vlastné vzorce na rozdelenie buniek (MID, RIGHT, LEFT atď.)

Užitočné informácie nájdete aj v tomto článku: Ako zrušiť spájanie buniek v programe Excel.

Zlučovanie v aplikácii Excel pomocou doplnku Merge Cells

Pomocou doplnku Merge Cells, ktorý je súčasťou balíka Ultimate Suite for Excel, môžete efektívne vykonávať obe činnosti:

• Zlúčenie niekoľko buniek do jednej bez straty údajov.
• Konkatenácia hodnoty viacerých buniek do jednej bunky a oddeľte ich ľubovoľným oddeľovačom podľa vlastného výberu.

Nástroj Zlúčiť bunky funguje so všetkými verziami aplikácie Excel od 2016 po 365 a dokáže spájať všetky typy údajov vrátane textových reťazcov, čísel, dátumov a špeciálnych symbolov. Jeho dve hlavné výhody sú jednoduchosť a rýchlosť - akékoľvek spájanie sa vykoná na niekoľko kliknutí.

Spojenie hodnôt viacerých buniek do jednej bunky

Ak chcete spojiť obsah niekoľkých buniek, vyberte rozsah, ktorý chcete spojiť, a nakonfigurujte nasledujúce nastavenia:

• Pod Čo zlúčiť , vyberte Bunky do jednej .
• Pod Kombinujte s , zadajte oddeľovač (v našom prípade čiarka a medzera).
• Vyberte, kam chcete umiestniť výsledok.
• Najdôležitejšie je zrušiť začiarknutie políčka Zlúčiť všetky oblasti vo výbere Práve táto možnosť určuje, či sa bunky zlúčia alebo sa ich hodnoty spoja.

Kombinácia stĺpcov po riadkoch

Ak chcete spojiť dva alebo viac stĺpcov, nakonfigurujte nastavenia funkcie Zlúčiť bunky podobným spôsobom, ale vyberte možnosť zlúčiť stĺpcov do jedného a umiestnite výsledky do ľavého stĺpca.

Pripojenie riadkov po stĺpcoch

Ak chcete skombinovať údaje v jednotlivých riadkoch, stĺpec po stĺpci, vyberte:

• Zlúčenie riadkov do jedného .
• Použite prerušenie riadku pre oddeľovač.
• Výsledky umiestnite do horný riadok .

Výsledok môže vyzerať podobne:

Ak si chcete overiť, ako si doplnok Merge Cells poradí s vašimi súbormi údajov, môžete si stiahnuť plne funkčnú skúšobnú verziu nášho balíka Ultimate Suite pre Excel.

To je spôsob, ako v programe Excel spájať. Ďakujem vám za prečítanie a dúfam, že sa uvidíme na našom blogu budúci týždeň!

Dostupné súbory na stiahnutie

Príklady konkatenačných vzorcov (.xlsx súbor)

14-dňová skúšobná verzia balíka Ultimate Suite (.exe súbor)