Tässä artikkelissa opit erilaisia tapoja yhdistää Excelissä tekstijonoja, numeroita ja päivämääriä käyttämällä CONCATENATE-toimintoa ja "&" -operaattoria. Käsittelemme myös kaavoja, joilla voidaan yhdistää yksittäisiä soluja, sarakkeita ja alueita.

Excel-työkirjoissasi tiedot eivät aina ole rakenteeltaan tarpeittesi mukaisia. Usein saatat haluta jakaa yhden solun sisällön yksittäisiin soluihin tai tehdä päinvastoin - yhdistää tietoja kahdesta tai useammasta sarakkeesta yhdeksi sarakkeeksi. Yleisiä esimerkkejä ovat nimien ja osoiteosien yhdistäminen, tekstin yhdistäminen kaava-arvoon, päivämäärien ja kellonaikojen näyttäminen haluamassasi muodossa, muutamia mainitaksemme.

Tässä opetusohjelmassa tutustumme Excelin merkkijonojen yhdistämisen eri tekniikoihin, jotta voit valita työarkkeihisi parhaiten sopivan menetelmän.

Mikä on "ketjuttaminen" Excelissä?

Excel-taulukoissa on periaatteessa kaksi tapaa yhdistää tietoja:

• Solujen yhdistäminen
• Solujen arvojen yhdistäminen

Kun olet sulauta solujen avulla yhdistät fyysisesti kaksi tai useampia soluja yhdeksi soluksi, jolloin saat yhden suuremman solun, joka näkyy useilla riveillä ja/tai sarakkeilla.

Kun olet concatenate soluja Excelissä, yhdistät vain sisältö Toisin sanoen, ketjuttaminen Excelissä on kahden tai useamman arvon yhdistämistä toisiinsa. Tätä menetelmää käytetään usein yhdistämään muutama tekstikappale, jotka sijaitsevat eri soluissa (teknisesti näitä kutsutaan nimellä tekstijonot tai yksinkertaisesti jouset ) tai lisätä kaavalla lasketun arvon keskelle tekstiä.

Seuraava kuvakaappaus havainnollistaa näiden kahden menetelmän välistä eroa:

Solujen yhdistäminen Excelissä on erillisen artikkelin aihe, ja tässä oppaassa käsittelemme kahta tärkeintä tapaa yhdistää merkkijonoja Excelissä - käyttämällä CONCATENATE-funktiota ja yhdistämisoperaattoria (&).

Excelin CONCATENATE-toiminto

Excelin CONCATENATE-toimintoa käytetään eri tekstikappaleiden yhdistämiseen tai useiden solujen arvojen yhdistämiseen yhteen soluun.

Excelin CONCATENATE-syntaksi on seuraava:

Missä teksti on merkkijono, soluviittaus tai kaavaohjattu arvo.

CONCATENATE-toiminto on tuettu kaikissa Excel 365 - 2007 -versioissa.

Jos esimerkiksi haluat yhdistää arvot B6 ja C6 pilkun kanssa, kaava on seuraava:

=CONCATENATE(B6, ",", C6)

Lisää esimerkkejä on esitetty alla olevassa kuvassa:

Huomautus: Excel 365 - Excel 2019 -versioissa on käytettävissä myös CONCAT-funktio, joka on CONCATENATE-funktion nykyaikainen seuraaja, jolla on täsmälleen sama syntaksi. Vaikka CONCATENATE-funktio säilytetään taaksepäin yhteensopivuuden vuoksi, Microsoft ei lupaa, että sitä tuetaan tulevissa Excel-versioissa.

CONCATENATEn käyttäminen Excelissä - muistettavia asioita

Varmistaaksesi, että CONCATENATE-kaavasi tuottavat aina oikeat tulokset, muista seuraavat yksinkertaiset säännöt:

• Excelin CONCATENATE-toiminto vaatii toimiakseen vähintään yhden "text"-argumentin.
• Yhdessä kaavassa voit yhdistää enintään 255 merkkijonoa, yhteensä 8 192 merkkiä.
• CONCATENATE-funktion tulos on aina merkkijono, vaikka kaikki lähdearvot olisivat numeroita.
• Toisin kuin CONCAT-funktio, Excelin CONCATENATE ei tunnista matriiseja. Jokainen soluviittaus on lueteltava erikseen. Käytä esimerkiksi CONCATENATE(A1, A2, A3) eikä CONCATENATE(A1:A3).
• Jos jokin argumenteista on virheellinen, CONCATENATE-funktio palauttaa #VALUE! -virheen.

"&" -operaattori merkkijonojen yhdistämiseen Excelissä

Microsoft Excelissä amppelimerkki (&) on toinen tapa liittää soluja yhteen. Tämä menetelmä on erittäin kätevä monissa tilanteissa, koska amppelimerkin kirjoittaminen on paljon nopeampaa kuin sanan "liittää" kirjoittaminen :)

Esimerkiksi kahden solun arvojen ketjuttaminen välilyönnillä on seuraavanlainen kaava:

=A2&" "&B2

Miten ketjutetaan Excelissä - kaavaesimerkkejä

Alla on muutamia esimerkkejä CONCATENATE-funktion käytöstä Excelissä.

Kahden tai useamman solun yhdistäminen ilman erotinta

Yhdistääksesi arvot kaksi solua yhdeksi, käytät ketjutuskaavaa sen yksinkertaisimmassa muodossa:

=CONCATENATE(A2, B2)

Tai

=A2&B2

Huomaa, että arvot liitetään yhteen ilman erottimia, kuten alla olevassa kuvassa.

Yhdistäminen useita soluja , sinun on annettava jokainen soluviittaus erikseen, vaikka yhdistät vierekkäisiä soluja. Esimerkiksi:

=CONCATENATE(A2, B2, C2)

Tai

=A2&B2&C2

Kaavat toimivat sekä tekstille että numeroille. Kun kyseessä ovat numerot, pidä mielessä, että tulos on tekstijono. Jos haluat muuntaa sen numeroksi, kerro CONCATENATEn tulos 1:llä tai lisää siihen 0. Esimerkiksi:

=CONCATENATE(A2, B2)*1

Vihje. Excel 2019:ssä ja uudemmissa versioissa voit käyttää CONCAT-toimintoa useiden solujen nopeaan yhdistämiseen yhden tai useamman alueviittauksen avulla.

Solujen yhdistäminen välilyönnillä, pilkulla tai muulla erottimella

Voit usein joutua yhdistämään arvoja laskentataulukoissasi tavalla, joka sisältää pilkkuja, välilyöntejä, erilaisia välimerkkejä tai muita merkkejä, kuten väliviivan tai vinoviivan. Voit tehdä tämän yksinkertaisesti lisäämällä halutun merkin ketjutuskaavaan. Muista sulkea kyseinen merkki lainausmerkkeihin, kuten seuraavissa esimerkeissä on esitetty.

Kahden solun liittäminen yhteen avaruus :

=CONCATENATE(A2, " ", B2)

tai

=A2 & " " & B2

Kahden solun liittäminen yhteen pilkku :

=CONCATENATE(A2, ", ", B2)

tai

=A2 & ", " & B2

Kahden solun liittäminen yhteen yhdysmerkki :

=CONCATENATE(A2, "-", B2)

tai

=A2 & "-" & B2

Seuraava kuvakaappaus osoittaa, miltä tulokset voivat näyttää:

Vihje. Excel 2019:ssä ja uudemmissa versioissa voit käyttää TEXTJOIN-toimintoa yhdistämään merkkijonoja useista soluista millä tahansa määrittelemälläsi erottimella.

Tekstijonon ja solun arvon yhdistäminen

Excelin CONCATENATE-toiminnon ei tarvitse rajoittua vain solujen arvojen yhdistämiseen. Voit käyttää sitä myös tekstijonojen yhdistämiseen, jotta tuloksesta tulee mielekkäämpi. Esim:

=CONCATENATE(A2, " ", B2, " completed")

Yllä oleva kaava ilmoittaa käyttäjälle, että tietty projekti on valmistunut, kuten alla olevan kuvakaappauksen rivillä 2. Huomaa, että lisäämme välilyönnin ennen sanaa " valmistunut", jotta yhdistetyt tekstijonot saadaan erotettua toisistaan. Välilyönti (" ") lisätään myös yhdistettyjen arvojen väliin, jotta tuloksena näytetään "Projekti 1" eikä "Projekti1".

Ketjutusoperaattorin avulla kaava voidaan kirjoittaa näin:

=A2 & " " & B2 & " valmis"

Samalla tavalla voit lisätä tekstijonon ketjutuskaavan alkuun tai keskelle. Esimerkiksi:

=CONCATENATE("Katso ", A2, " ", B2)

="Katso " & A2 & " " & B2".

Liitä tekstijono ja toinen kaava

Jos haluat tehdä jonkin kaavan palauttaman tuloksen ymmärrettävämmäksi käyttäjille, voit liittää siihen merkkijonon, joka selittää, mikä arvo oikeastaan on.

Voit esimerkiksi palauttaa nykyisen päivämäärän halutussa muodossa seuraavan kaavan avulla ja määrittää, millainen päivämäärä on kyseessä:

=CONCATENATE("Tänään on ",TEXT(TODAY(), "mmmm d, yyyy"))

="Tänään on " & TEXT(TODAY(), "dd-mmm-yy")

Vihje. Jos haluat poistaa lähdetiedot vaikuttamatta tuloksena oleviin merkkijonoihin, käytä "Liitä erikois - vain arvot" -vaihtoehtoa, kun haluat muuntaa kaavat niiden arvoiksi.

Tekstijonojen ketjuttaminen rivinvaihdoilla

Useimmiten erotat tuloksena syntyvät tekstijonot välimerkeillä ja välilyönneillä, kuten edellisessä esimerkissä on esitetty. Joissakin tapauksissa voi kuitenkin olla tarpeen erottaa arvot rivinvaihdolla tai rivinvaihdolla. Yleinen esimerkki on postitusosoitteiden yhdistäminen erillisissä sarakkeissa olevista tiedoista.

Ongelmana on se, että et voi yksinkertaisesti kirjoittaa rivinvaihtoa kaavaan tavallisen merkin tavoin. Sen sijaan käytät CHAR-funktiota, jolla annat vastaavaa ASCII-koodia ketjutuskaavaan:

• Käytä Windowsissa CHAR(10) -merkkiä, jossa 10 on merkkikoodi seuraavalle merkille Rivinsyöttö .
• Mac-tietokoneessa käytä CHAR(13), jossa 13 on merkkikoodi seuraavalle merkille Kuljetuksen palautus .

Tässä esimerkissä meillä on osoitekappaleet sarakkeissa A-F, ja yhdistämme ne sarakkeeseen G käyttämällä ketjutusoperaattoria "&". Yhdistetyt arvot erotetaan toisistaan pilkulla (", "), välilyönnillä (" ") ja rivinvaihdolla CHAR(10):

=A2 & " " & B2 & CHAR(10) & C2 & CHAR(10) & D2 & ", " & E2 & " " & F2

CONCATENATE-funktio olisi seuraavanlainen:

=CONCATENATE(A2, " ", B2, CHAR(10), C2, CHAR(10), D2, ", ", ", E2, " ", F2)

Tuloksena on joka tapauksessa 3-rivinen merkkijono: Huomautus: Kun käytät rivinvaihtoa yhdistettyjen arvojen erottamiseen, sinun on otettava tekstin kääriminen käyttöön, jotta tulos näkyy oikein. Voit tehdä tämän painamalla Ctrl + 1 avataksesi ikkunan Solujen muotoilu valintaikkunassa, vaihda Kohdistus välilehti ja tarkista Kääri teksti laatikko.

Samalla tavalla voit erottaa lopulliset merkkijonot toisistaan muilla merkeillä, kuten:

• Kaksoislainausmerkit (") - CHAR(34)
• Viivoitusviiva (/) - CHAR(47)
• Tähti (*) - CHAR (42)
• Täydellinen luettelo ASCII-koodit on saatavilla täällä.

Kuinka yhdistää sarakkeita Excelissä

Jos haluat yhdistää kaksi tai useampia sarakkeita, kirjoita yhdistämiskaava ensimmäiseen soluun ja kopioi se sitten muihin soluihin vetämällä täyttökahvaa (pieni neliö, joka näkyy valitun solun oikeassa alakulmassa).

Jos esimerkiksi haluat yhdistää kaksi saraketta (sarakkeet A ja B) ja rajata arvot välilyönnillä, C2:ssa oleva kaava kopioidaan alaspäin seuraavasti:

=CONCATENATE(A2, " ", B2)

Tai

= A2 & " " & B2 Vihje. Nopea tapa kopioida kaava saraketta alaspäin on valita solu, jossa kaava on, ja kaksoisnapsauttaa täyttökahvaa.

Lisätietoja on kohdassa Miten yhdistää kaksi saraketta Excelissä menettämättä tietoja.

Tekstin ja numeroiden yhdistäminen muotoilun avulla

Kun yhdistät tekstijonoa numeron, prosenttiluvun tai päivämäärän kanssa, voit haluta säilyttää numeroarvon alkuperäisen muotoilun tai näyttää sen eri tavalla. Tämä voidaan tehdä antamalla muotoilukoodi TEXT-funktion sisällä, jonka upotat yhdistämiskaavaan.

Tämän ohjeen alussa keskustelimme jo kaavasta, joka yhdistää tekstin ja päivämäärän.

Ja tässä on vielä muutama kaavaesimerkki, jotka yhdistävät teksti ja numero :

Luku, jossa on 2 desimaalia ja $-merkki:

=A2 & " " & TEXT(B2, "$#,#0.00")

Luku ilman merkityksettömiä nollia ja $-merkkiä:

=A2 & " " & TEXT(B2, "0.#")

Murtoluku:

=A2 & " " & TEXT(B2, "# ?/?????")

Yhdistäminen teksti ja prosenttiosuus , kaavat ovat:

Prosentti kahdella desimaalilla:

=A12 & " " & TEXT(B12, "0.00%")

Pyöristetty kokonainen prosentti:

=A12 & " " & TEXT(B12, "0%")

Kuinka ketjuttaa solualue Excelissä?

Useiden solujen arvojen yhdistäminen saattaa vaatia jonkin verran vaivaa, koska Excelin CONCATENATE-toiminto ei hyväksy matriiseja.

Jos haluat yhdistää useita soluja, esimerkiksi A1-A4, sinun on käytettävä jotakin seuraavista kaavoista:

=CONCATENATE(A1, A2, A3, A4)

tai

=A1 & A2 & A3 & A4

Kun yhdistät melko pienen soluryhmän, ei ole iso juttu kirjoittaa kaikki viittaukset. Suuren alueen toimittaminen olisi työlästä, kun kirjoitat jokaisen yksittäisen viittauksen manuaalisesti. Alla on 3 menetelmää Excelin nopeaan alueen yhdistämiseen.

Menetelmä 1. Valitse useita soluja painamalla CTRL-näppäintä.

Jos haluat valita nopeasti useita soluja, voit pitää Ctrl-näppäintä painettuna ja napsauttaa samalla jokaista solua, jonka haluat sisällyttää kaavaan. Seuraavassa on yksityiskohtaiset vaiheet:

1. Valitse solu, johon haluat syöttää kaavan.
2. Kirjoita =CONCATENATE( kyseiseen soluun tai kaavapalkkiin.
3. Pidä Ctrl-näppäintä painettuna ja napsauta jokaista solua, jonka haluat yhdistää.
4. Vapauta Ctrl-painike, kirjoita sulkeva sulku ja paina Enter .

Menetelmä 2. Käytä TRANSPOSE-toimintoa kaikkien solujen arvojen saamiseksi.

Kun alue koostuu kymmenistä tai sadoista soluista, edellinen menetelmä ei ehkä ole tarpeeksi nopea, koska se vaatii jokaisen solun napsauttamista. Tässä tapauksessa voit käyttää TRANSPOSE-funktiota palauttamaan arvojen joukon ja yhdistää ne sitten yhdellä kertaa.

1. Kirjoita siihen soluun, jossa haluat tuloksen näkyvän, kaava TRANSPOSE, esimerkiksi:

   =TRANSPOSE(A1:A10)

2. Korvaa kaava lasketuilla arvoilla painamalla F9-kaavapalkissa. Tuloksena on joukko yhdistettäviä arvoja.
3. Poista joukkoa ympäröivät suljetut sulut.
4. Kirjoita =CONCATENATE( ennen ensimmäistä arvoa, kirjoita sitten sulkeutuva sulku viimeisen arvon jälkeen ja paina Enter .

Huom. Tämän kaavan tulos on static koska se yhdistää arvot, ei soluviittauksia. Jos lähdetiedot muuttuvat, prosessi on toistettava.

Menetelmä 3. Käytä CONCAT-funktiota

Excel 365:ssä ja Excel 2021:ssä tämä yksinkertainen kaava yhdistää solualueen silmänräpäyksessä:

=CONCAT(A1:A10)

Menetelmä 4. Käytä Merge Cells -lisäosaa

Nopea ja kaavaton tapa ketjuttaa mikä tahansa alue Excelissä on käyttää Merge Cells -lisäosaa, jossa on " Yhdistä kaikki alueet valinnassa " -vaihtoehto pois päältä, kuten on esitetty kohdassa Useiden solujen arvojen yhdistäminen yhdeksi soluksi.

Excelin "&" -operaattori vs. CONCATENATE-funktio

Monet käyttäjät ihmettelevät, kumpi on tehokkaampi tapa yhdistää merkkijonoja Excelissä - CONCATENATE-funktio vai "&" -operaattori.

Ainoa todellinen ero on CONCATENATE-funktion 255 merkkijonon rajoitus ja se, ettei tätä rajoitusta ole, kun käytetään amperandia. Muuten näiden kahden menetelmän välillä ei ole eroa, eikä CONCATENATE- ja "&"-kaavojen välillä ole nopeuseroa.

Ja koska 255 on todella suuri luku ja koska sinun tuskin koskaan tarvitsee yhdistää niin monta merkkijonoa todellisessa työssä, ero kiteytyy mukavuuteen ja helppokäyttöisyyteen. Joidenkin käyttäjien mielestä CONCATENATE-kaavat ovat helpommin luettavissa, mutta itse käytän mieluummin "&"-menetelmää. Joten pysyttele siinä tekniikassa, joka tuntuu mukavammalta.

CONCATENATE:n vastakohta Excelissä (solujen jakaminen).

Yhdistämisen vastakohta Excelissä on yhden solun sisällön jakaminen useampaan soluun. Tämä voidaan tehdä muutamalla eri tavalla:

• Tekstiä sarakkeisiin -ominaisuus
• Flash Fill -vaihtoehto Excel 2013:ssa ja uudemmissa versioissa
• TEXTSPLIT-toiminto Excel 365:ssä
• Mukautetut kaavat solujen jakamiseen (MID, RIGHT, LEFT jne.).

Löydät hyödyllistä tietoa myös tästä artikkelista: Solujen yhdistämisen poistaminen Excelissä.

Yhdistä Excelissä Solujen yhdistäminen -lisäosan avulla

Ultimate Suite for Exceliin sisältyvän Solujen yhdistäminen -lisäosan avulla voit tehdä tehokkaasti molemmat:

• Yhdistä useita soluja yhdeksi soluksi menettämättä tietoja.
• Ketjuttaminen useiden solujen arvot yhteen soluun ja erottaa ne haluamallasi erotinmerkillä.

Solujen yhdistäminen -työkalu toimii kaikissa Excel-versioissa vuodesta 2016 vuoteen 365, ja sillä voidaan yhdistää kaikkia tietotyyppejä, kuten tekstijonoja, numeroita, päivämääriä ja erikoissymboleja. Sen kaksi tärkeintä etua ovat yksinkertaisuus ja nopeus - kaikki yhdistämiset tehdään muutamalla napsautuksella.

Yhdistä useiden solujen arvot yhteen soluun

Jos haluat yhdistää useiden solujen sisällön, valitse yhdistettävä alue ja määritä seuraavat asetukset:

• osoitteessa Mitä yhdistää , valitse Solut yhdeksi .
• osoitteessa Yhdistä , kirjoita delimiter (meidän tapauksessamme pilkku ja välilyönti).
• Valitse, mihin haluat sijoittaa tuloksen.
• Tärkeintä on poistaa valintaruutu Yhdistä kaikki valinnan alueet Tällä valinnalla säädetään, yhdistetäänkö solut vai yhdistetäänkö niiden arvot.

Yhdistä sarakkeet rivi riviltä

Kahden tai useamman sarakkeen yhdistämistä varten määrität Solujen yhdistäminen -asetukset samalla tavalla, mutta valitset yhdistämisen seuraavasti sarakkeet yhdeksi ja sijoita tulokset vasempaan sarakkeeseen.

Liity riveihin sarake sarakkeelta

Voit yhdistää tiedot kullakin rivillä sarakekohtaisesti valitsemalla:

• Yhdistä rivit yhdeksi .
• Käytä rivinvaihto erotinmerkiksi.
• Sijoita tulokset ylärivi .

Tulos voi näyttää samankaltaiselta kuin tämä:

Jos haluat tarkistaa, miten Merge Cells -lisäosa selviytyy tietokokonaisuuksistasi, voit ladata alla olevan Ultimate Suite for Excel -ohjelman täysin toimivan kokeiluversion.

Näin ketjutat Excelissä. Kiitos lukemisesta ja toivottavasti tapaamme blogissamme ensi viikolla!

Saatavilla olevat lataukset

Esimerkkejä ketjutuskaavoista (.xlsx-tiedosto)

Ultimate Suite 14 päivän kokeiluversio (.exe-tiedosto)