In dit artikel leert u verschillende manieren om tekstreeksen, getallen en datums in Excel aan elkaar te koppelen met behulp van de functie CONCATENATE en de operator "&". We bespreken ook formules om afzonderlijke cellen, kolommen en bereiken te combineren.

In uw Excel-werkmappen zijn de gegevens niet altijd gestructureerd volgens uw behoeften. Vaak wilt u de inhoud van een cel opsplitsen in afzonderlijke cellen of het tegenovergestelde doen - gegevens uit twee of meer kolommen combineren tot een enkele kolom. Veel voorkomende voorbeelden zijn het samenvoegen van namen en adresdelen, het combineren van tekst met een formulegedreven waarde, het weergeven van datums en tijden in het gewenste formaat, om er een paar te noemen.

In deze zelfstudie gaan we verschillende technieken van Excel-stringaaneenschakeling verkennen, zodat u de methode kunt kiezen die het meest geschikt is voor uw werkbladen.

Wat is "concatenate" in Excel?

In wezen zijn er twee manieren om gegevens in Excel-spreadsheets te combineren:

• Cellen samenvoegen
• Aaneenschakelen van celwaarden

Wanneer je samenvoegen cellen, voegt u twee of meer cellen "fysiek" samen tot een enkele cel. Het resultaat is één grotere cel die over meerdere rijen en/of kolommen wordt weergegeven.

Wanneer je concatenate cellen in Excel, combineert u alleen de inhoud Met andere woorden, aaneenschakelen in Excel is het samenvoegen van twee of meer waarden. Deze methode wordt vaak gebruikt om een paar stukken tekst te combineren die in verschillende cellen staan (technisch gezien heten ze tekststrings of gewoon strings ) of een met een formule berekende waarde midden in de tekst invoegen.

De volgende schermafbeelding toont het verschil tussen deze twee methoden:

Het samenvoegen van cellen in Excel is het onderwerp van een apart artikel, en in deze tutorial bespreken we de twee belangrijkste manieren om strings in Excel aan elkaar te koppelen - met behulp van de functie CONCATENATE en het aaneenschakelingsoperator (&).

Excel CONCATENATE functie

De functie CONCATENATE in Excel wordt gebruikt om verschillende stukken tekst samen te voegen of waarden uit verschillende cellen in één cel te combineren.

De syntaxis van Excel CONCATENATE is als volgt:

Waar tekst is een tekststring, celverwijzing of formulegestuurde waarde.

De functie CONCATENATE wordt ondersteund in alle versies van Excel 365 - 2007.

Om bijvoorbeeld de waarden van B6 en C6 met een komma aan elkaar te rijgen, is de formule:

=CONCATENATE(B6, ",", C6)

Meer voorbeelden staan in de onderstaande afbeelding:

Opmerking. In Excel 365 - Excel 2019 is ook de CONCAT-functie beschikbaar, wat een moderne opvolger is van CONCATENATE met exact dezelfde syntaxis. Hoewel de CONCATENATE-functie wordt behouden voor achterwaartse compatibiliteit, geeft Microsoft geen beloftes dat deze in toekomstige versies van Excel zal worden ondersteund.

CONCATENATE gebruiken in Excel - dingen om te onthouden

Om ervoor te zorgen dat uw CONCATENATE formules altijd de juiste resultaten opleveren, onthoudt u de volgende eenvoudige regels:

• Excel CONCATENATE functie vereist ten minste één "tekst" argument om te werken.
• In één formule kunt u maximaal 255 tekenreeksen aan elkaar rijgen, in totaal 8.192 tekens.
• Het resultaat van de functie CONCATENATE is altijd een tekststring, zelfs wanneer alle bronwaarden getallen zijn.
• In tegenstelling tot de CONCAT-functie, herkent Excel CONCATENATE niet als een matrix. Elke celverwijzing moet afzonderlijk worden vermeld. U moet bijvoorbeeld CONCATENATE(A1, A2, A3) gebruiken en niet CONCATENATE(A1:A3).
• Indien een van de argumenten ongeldig is, geeft de functie CONCATENATE een #VALUE! foutmelding.

"&" operator om strings aan elkaar te rijgen in Excel

In Microsoft Excel is het ampersand-teken (&) een andere manier om cellen aan elkaar te koppelen. Deze methode is in veel scenario's erg handig omdat het typen van een ampersand veel sneller gaat dan het typen van het woord "aan elkaar koppelen" :)

Om bijvoorbeeld twee celwaarden met een spatie ertussen aan elkaar te rijgen, is de formule:

=A2&" "&B2

Aaneenschakelen in Excel - formulevoorbeelden

Hieronder vindt u enkele voorbeelden van het gebruik van de functie CONCATENATE in Excel.

Twee of meer cellen samenvoegen zonder scheidingsteken

Om de waarden van twee cellen in één, gebruik je de aaneenschakelingsformule in zijn eenvoudigste vorm:

=CONCATENATE(A2, B2)

Of

=A2&B2

Merk op dat de waarden aan elkaar worden gebreid zonder scheidingsteken zoals in onderstaande schermafbeelding.

Aaneenschakelen meerdere cellen moet u elke celverwijzing afzonderlijk opgeven, zelfs als u aaneengesloten cellen combineert. Bijvoorbeeld:

=CONCATENATE(A2, B2, C2)

Of

=A2&B2&C2

De formules werken zowel voor tekst als voor getallen. In het geval van getallen, houd er rekening mee dat het resultaat een tekststring is. Om het om te zetten in een getal, vermenigvuldig de uitvoer van CONCATENATE met 1 of voeg er 0 aan toe. Bijvoorbeeld:

=CONCATENATE(A2, B2)*1

Tip. In Excel 2019 en hoger kunt u de functie CONCAT gebruiken om snel meerdere cellen aan elkaar te koppelen met behulp van een of meer bereikverwijzingen.

Cellen samenvoegen met een spatie, komma of ander scheidingsteken

In uw werkbladen moet u vaak waarden samenvoegen op een manier die komma's, spaties, verschillende leestekens of andere tekens zoals een koppelteken of een schuine streep omvat. Om dit te doen, plaatst u gewoon het gewenste teken in uw aaneenschakelingsformule. Vergeet niet dat teken tussen aanhalingstekens te plaatsen, zoals in de volgende voorbeelden wordt gedemonstreerd.

Twee cellen samenvoegen met een ruimte :

=CONCATENATE(A2, " ", B2)

of

=A2 & " " & B2

Twee cellen samenvoegen met een komma :

=CONCATENATE(A2, ", ", B2)

of

=A2 & ", " & B2

Twee cellen samenvoegen met een koppelteken :

=CONCATENATE(A2, "-", B2)

of

=A2 & "-" & B2

Het volgende screenshot laat zien hoe de resultaten eruit kunnen zien:

Tip. In Excel 2019 en hoger kunt u de functie TEXTJOIN gebruiken om tekenreeksen uit meerdere cellen samen te voegen met elk scheidingsteken dat u opgeeft.

Tekststring en celwaarde samenvoegen

Er is geen reden om de Excel CONCATENATE functie te beperken tot het samenvoegen van de waarden van cellen. U kunt deze ook gebruiken om tekststrings te combineren om het resultaat zinvoller te maken. Bijvoorbeeld:

=CONCATENATE(A2, " ", B2, " voltooid")

De bovenstaande formule informeert de gebruiker dat een bepaald project is voltooid, zoals in rij 2 in de onderstaande schermafbeelding. Merk op dat we een spatie toevoegen vóór het woord "voltooid" om de aaneengeschakelde tekstreeksen te scheiden. Er wordt ook een spatie (" ") ingevoegd tussen de gecombineerde waarden, zodat het resultaat wordt weergegeven als "Project 1" in plaats van "Project1".

Met de aaneenschakelingsoperator kan de formule zo worden geschreven:

=A2 & " " & B2 & " afgerond"

Op dezelfde manier kunt u een tekststring toevoegen aan het begin of in het midden van uw aaneenschakelingsformule. Bijvoorbeeld:

=CONCATENATE("Zie", A2, " ", B2)

="Zie " & A2 & " & B2

Voeg tekststring en een andere formule samen

Om het resultaat van een formule begrijpelijker te maken voor uw gebruikers, kunt u een tekststring toevoegen die uitlegt wat de waarde is.

U kunt bijvoorbeeld de volgende formule gebruiken om de huidige datum in het gewenste formaat terug te geven en aangeven wat voor soort datum dat is:

=CONCATENATE("Vandaag is ",TEXT(TODAY(), "mmmm d, yyyy"))

="Vandaag is het " & TEXT(TODAY(), "dd-mmm-yy")

Tip. Als u de brongegevens wilt verwijderen zonder de resulterende tekstreeksen te beïnvloeden, gebruik dan de optie "Plakken speciaal - alleen waarden" om formules om te zetten in hun waarden.

Tekstreeksen met regeleinden samenvoegen

Meestal scheidt u de resulterende tekstreeksen met leestekens en spaties, zoals in het vorige voorbeeld. In sommige gevallen kan het echter nodig zijn de waarden te scheiden met een regeleinde of een carriage return. Een veel voorkomend voorbeeld is het samenvoegen van postadressen uit gegevens in afzonderlijke kolommen.

Een probleem is dat u niet gewoon een regeleinde in de formule kunt typen zoals een gewoon teken. In plaats daarvan gebruikt u de CHAR-functie om de overeenkomstige ASCII-code aan de aaneenschakelingsformule toe te voegen:

• In Windows gebruikt u CHAR(10) waarbij 10 de tekencode is voor Lijn feed .
• Op Mac gebruikt u CHAR(13) waarbij 13 de tekencode is voor Carriage return .

In dit voorbeeld hebben we de adresstukken in de kolommen A tot en met F, en we voegen ze samen in kolom G door gebruik te maken van de aaneenschakelingsoperator "&". De samengevoegde waarden worden gescheiden door een komma (", "), spatie (" ") en een regeleinde CHAR(10):

=A2 & " " & B2 & CHAR(10) & C2 & CHAR(10) & D2 & ", " & E2 & " " & F2

De CONCATENATE functie zou deze vorm aannemen:

=CONCATENATE(A2, " ", B2, CHAR(10), C2, CHAR(10), D2, ", ", E2, " ", F2)

Hoe dan ook, het resultaat is een tekststring van 3 regels: Opmerking: wanneer u regeleinden gebruikt om de gecombineerde waarden te scheiden, moet u Wrap tekst aanzetten om het resultaat correct weer te geven. Druk hiervoor op Ctrl + 1 om het menu Cellen opmaken dialoog, schakel over naar de Uitlijning tabblad en controleer de Tekst inpakken doos.

Op dezelfde manier kunt u eindreeksen scheiden met andere tekens zoals:

• Dubbele aanhalingstekens (") - CHAR(34)
• Voorwaartse schuine streep (/) - CHAR(47)
• Asterisk (*) - CHAR (42)
• De volledige lijst van ASCII-codes is hier beschikbaar.

Kolommen samenvoegen in Excel

Om twee of meer kolommen samen te voegen, voert u uw aaneenschakelingsformule in de eerste cel in, en kopieert u deze vervolgens naar andere cellen door de vulgreep (het kleine vierkantje dat rechtsonder in de geselecteerde cel verschijnt) te verslepen.

Om bijvoorbeeld twee kolommen (kolom A en B) te combineren en de waarden te begrenzen met een spatie, is de formule in C2 gekopieerd:

=CONCATENATE(A2, " ", B2)

Of

= A2 & " " & B2 Tip. Een snelle manier om de formule naar beneden te kopiëren is door de cel met de formule te selecteren en te dubbelklikken op de vulgreep.

Zie voor meer informatie Hoe twee kolommen in Excel samen te voegen zonder gegevens te verliezen.

Tekst en getallen combineren met behoud van opmaak

Wanneer u een tekststring samenvoegt met een getal, percentage of datum, wilt u misschien de oorspronkelijke opmaak van een numerieke waarde behouden of deze op een andere manier weergeven. Dit kunt u doen door de opmaakcode mee te geven in de TEXT-functie, die u insluit in een aaneenschakelingsformule.

In het begin van deze tutorial hebben we al een formule besproken die tekst en datum aan elkaar rijgt.

En hier zijn nog een paar formulevoorbeelden die combineren tekst en nummer :

Getal met 2 decimalen en het $-teken:

=A2 & " " & TEXT(B2, "$#,#0.00")

Getal zonder onbelangrijke nullen en het $-teken:

=A2 & " " & TEXT(B2, "0.#")

Fractioneel getal:

=A2 & " " & TEXT(B2, "# ?/???")

Aaneenschakelen tekst en percentage zijn de formules:

Percentage met twee decimalen:

=A12 & " " & TEXT(B12, "0.00%")

Afgeronde hele procenten:

=A12 & " " & TEXT(B12, "0%")

Hoe een bereik van cellen in Excel aan elkaar te koppelen

Het combineren van waarden uit meerdere cellen kan enige moeite kosten omdat de Excel CONCATENATE functie geen matrices accepteert.

Om verschillende cellen, bijvoorbeeld A1 tot A4, samen te voegen, moet u een van de volgende formules gebruiken:

=CONCATENATE(A1, A2, A3, A4)

of

=A1 & A2 & A3 & A4

Wanneer u een vrij kleine groep cellen samenvoegt, is het niet erg om alle verwijzingen over te typen. Een groot bereik zou vervelend zijn om aan te leveren, door elke individuele verwijzing handmatig in te typen. Hieronder vindt u 3 methoden om snel bereiken samen te voegen in Excel.

Methode 1. Druk op CTRL om meerdere cellen te selecteren

Om snel meerdere cellen te selecteren, kunt u de Ctrl-toets ingedrukt houden terwijl u klikt op elke cel die u in de formule wilt opnemen. Hier zijn de gedetailleerde stappen:

1. Selecteer een cel waar u de formule wilt invoeren.
2. Typ =CONCATENATE( in die cel of in de formulebalk.
3. Houd Ctrl ingedrukt en klik op elke cel die u wilt samenvoegen.
4. Laat de Ctrl-toets los, typ het afsluitende haakje en druk op Enter .

Methode 2. Gebruik de functie TRANSPOSE om alle celwaarden te verkrijgen

Wanneer een bereik uit tientallen of honderden cellen bestaat, is de vorige methode misschien niet snel genoeg, omdat u dan op elke cel moet klikken. In dat geval kunt u de functie TRANSPOSE gebruiken om een array van waarden terug te geven, en die dan in één keer samenvoegen.

1. Voer in de cel waar u het resultaat wilt zien de formule TRANSPOSE in, bijvoorbeeld:

   =TRANSPOSE(A1:A10)

2. Druk in de formulebalk op F9 om de formule te vervangen door berekende waarden. Het resultaat is een array van aan elkaar te rijgen waarden.
3. Verwijder de accolades rond de matrix.
4. Typ =CONCATENATE( voor de eerste waarde, typ dan het haakje achter de laatste waarde en druk op Enter .

Opmerking. Het resultaat van deze formule is statisch Als de brongegevens veranderen, moet u het proces herhalen.

Methode 3. Gebruik de functie CONCAT

In Excel 365 en Excel 2021 zal deze eenvoudige formule in een oogwenk een reeks cellen aan elkaar rijgen:

=CONCAT(A1:A10)

Methode 4. Gebruik de invoegtoepassing Cellen samenvoegen

Een snelle en formulevrije manier om elk bereik in Excel samen te voegen is door gebruik te maken van de invoegtoepassing Cellen samenvoegen met de " Alle gebieden in de selectie samenvoegen " optie uitgeschakeld, zoals aangetoond in Waarden van verschillende cellen combineren in één cel.

Excel "&" operator vs. CONCATENATE functie

Veel gebruikers vragen zich af wat een efficiëntere manier is om strings in Excel samen te voegen - CONCATENATE functie of "&" operator.

Het enige echte verschil is de limiet van 255 strings van de CONCATENATE functie en geen dergelijke beperking bij gebruik van de ampersand. Buiten dat is er geen verschil tussen deze twee methoden, noch is er een verschil in snelheid tussen de CONCATENATE en "&" formules.

En aangezien 255 een heel groot getal is en je in het echte werk bijna nooit zoveel strings hoeft te combineren, komt het verschil neer op comfort en gebruiksgemak. Sommige gebruikers vinden CONCATENATE formules gemakkelijker te lezen, ik persoonlijk gebruik liever de "&" methode. Blijf dus gewoon bij de techniek waar je je prettiger bij voelt.

Tegenovergestelde van CONCATENATE in Excel (cellen splitsen)

Het tegenovergestelde van concatenate in Excel is het splitsen van de inhoud van een cel in meerdere cellen. Dit kan op een paar verschillende manieren:

• Functie Tekst naar kolommen
• Flash Fill optie in Excel 2013 en hoger
• TEXTSPLIT functie in Excel 365
• Aangepaste formules om cellen te splitsen (MIDDEN, RECHTS, LINKS, enz.)

U kunt ook nuttige informatie vinden in dit artikel: Hoe cellen ontmengen in Excel.

Samenvoegen in Excel met invoegtoepassing Cellen samenvoegen

Met de invoegtoepassing Cellen samenvoegen in Ultimate Suite voor Excel kunt u beide efficiënt doen:

• Samenvoegen verschillende cellen samenvoegen zonder gegevens te verliezen.
• Aaneenschakelen de waarden van verschillende cellen in één cel en scheidt ze met een scheidingsteken naar keuze.

De tool Cellen samenvoegen werkt met alle Excel-versies van 2016 tot 365 en kan alle soorten gegevens combineren, waaronder tekstreeksen, getallen, datums en speciale symbolen. De twee belangrijkste voordelen zijn eenvoud en snelheid - elke aaneenschakeling is in een paar klikken gebeurd.

Waarden van verschillende cellen combineren in één cel

Om de inhoud van verschillende cellen te combineren, selecteert u het bereik dat u wilt samenvoegen en configureert u de volgende instellingen:

• Onder Wat samenvoegen kies Cellen in een .
• Onder Combineer met , typ de scheidingsteken (een komma en een spatie in ons geval).
• Kies waar u het resultaat wilt plaatsen.
• Het belangrijkste is dat u de Alle gebieden in de selectie samenvoegen Deze optie bepaalt of de cellen worden samengevoegd of dat hun waarden worden samengevoegd.

Kolommen rij per rij combineren

Om twee of meer kolommen samen te voegen, configureert u de instellingen voor Cellen samenvoegen op een vergelijkbare manier, maar kiest u voor samenvoegen kolommen in een en plaats de resultaten in de linkerkolom.

Voeg rijen kolom per kolom samen

Om gegevens in elke afzonderlijke rij, kolom per kolom, te combineren, kiest u:

• Samenvoegen rijen in een .
• Gebruik een regeleinde voor het scheidingsteken.
• Plaats de resultaten in de bovenste rij .

Het resultaat kan er ongeveer zo uitzien:

Om te controleren hoe de invoegtoepassing Samenvoegen van cellen met uw gegevenssets omgaat, kunt u hieronder een volledig functionele proefversie van onze Ultimate Suite voor Excel downloaden.

Ik dank u voor het lezen en hoop u volgende week op onze blog te zien!

Beschikbare downloads

Voorbeelden van aaneenschakelingsformules (.xlsx-bestand)

Ultimate Suite 14-daagse proefversie (.exe bestand)