Σε αυτό το άρθρο, θα μάθετε διάφορους τρόπους για τη συνένωση συμβολοσειρών κειμένου, αριθμών και ημερομηνιών στο Excel χρησιμοποιώντας τη συνάρτηση CONCATENATE και τον τελεστή "&". Θα συζητήσουμε επίσης τύπους για τη συνένωση μεμονωμένων κελιών, στηλών και περιοχών.

Στα βιβλία εργασίας σας στο Excel, τα δεδομένα δεν είναι πάντα δομημένα σύμφωνα με τις ανάγκες σας. Συχνά μπορεί να θέλετε να χωρίσετε το περιεχόμενο ενός κελιού σε μεμονωμένα κελιά ή να κάνετε το αντίθετο - να συνδυάσετε δεδομένα από δύο ή περισσότερες στήλες σε μία μόνο στήλη. Συνήθη παραδείγματα είναι η ένωση ονομάτων και τμημάτων διευθύνσεων, ο συνδυασμός κειμένου με μια τιμή βάσει τύπου, η εμφάνιση ημερομηνιών και ωρών στην επιθυμητή μορφή, για να αναφέρουμε μερικά από αυτά.

Σε αυτό το σεμινάριο, θα εξερευνήσουμε διάφορες τεχνικές συνένωσης συμβολοσειρών του Excel, ώστε να μπορείτε να επιλέξετε τη μέθοδο που ταιριάζει καλύτερα στα φύλλα εργασίας σας.

Τι είναι η "συνένωση" στο Excel;

Στην ουσία, υπάρχουν δύο τρόποι για να συνδυάσετε δεδομένα σε υπολογιστικά φύλλα του Excel:

• Συγχώνευση κελιών
• Συνένωση τιμών κελιών

Όταν merge κελιά, ενώνετε "φυσικά" δύο ή περισσότερα κελιά σε ένα ενιαίο κελί. Ως αποτέλεσμα, έχετε ένα μεγαλύτερο κελί που εμφανίζεται σε πολλές γραμμές ή/και στήλες.

Όταν concatenate κελιά στο Excel, συνδυάζετε μόνο τα περιεχόμενα Με άλλα λόγια, η συνένωση στο Excel είναι η διαδικασία ένωσης δύο ή περισσότερων τιμών μαζί. Αυτή η μέθοδος χρησιμοποιείται συχνά για να συνδυάσει μερικά κομμάτια κειμένου που βρίσκονται σε διαφορετικά κελιά (τεχνικά, αυτά ονομάζονται συμβολοσειρές κειμένου ή απλά χορδές ) ή να εισαγάγετε μια υπολογισμένη από τον τύπο τιμή στη μέση κάποιου κειμένου.

Το ακόλουθο στιγμιότυπο οθόνης δείχνει τη διαφορά μεταξύ αυτών των δύο μεθόδων:

Η συγχώνευση κελιών στο Excel είναι το θέμα ενός ξεχωριστού άρθρου και σε αυτό το σεμινάριο θα συζητήσουμε τους δύο κύριους τρόπους για τη συνένωση συμβολοσειρών στο Excel - με τη χρήση της συνάρτησης CONCATENATE και του τελεστή συνένωσης (&).

Συνάρτηση CONCATENATE του Excel

Η συνάρτηση CONCATENATE στο Excel χρησιμοποιείται για να ενώσετε διαφορετικά κομμάτια κειμένου ή να συνδυάσετε τιμές από διάφορα κελιά σε ένα κελί.

Η σύνταξη του Excel CONCATENATE έχει ως εξής:

Πού κείμενο είναι μια συμβολοσειρά κειμένου, μια αναφορά κελιού ή μια τιμή βάσει τύπου.

Η συνάρτηση CONCATENATE υποστηρίζεται σε όλες τις εκδόσεις του Excel 365 - 2007.

Για παράδειγμα, για να συνδέσετε τις τιμές των B6 και C6 με ένα κόμμα, ο τύπος είναι ο εξής:

=CONCATENATE(B6, ",", C6)

Περισσότερα παραδείγματα παρουσιάζονται στην παρακάτω εικόνα:

Σημείωση. Στο Excel 365 - Excel 2019, είναι επίσης διαθέσιμη η συνάρτηση CONCAT, η οποία είναι ένας σύγχρονος διάδοχος της CONCATENATE με την ίδια ακριβώς σύνταξη. Παρόλο που η συνάρτηση CONCATENATE διατηρείται για λόγους συμβατότητας προς τα πίσω, η Microsoft δεν δίνει καμία υπόσχεση ότι θα υποστηρίζεται σε μελλοντικές εκδόσεις του Excel.

Χρήση της CONCATENATE στο Excel - πράγματα που πρέπει να θυμάστε

Για να διασφαλίσετε ότι οι τύποι CONCATENATE σας παρέχουν πάντα τα σωστά αποτελέσματα, να θυμάστε τους ακόλουθους απλούς κανόνες:

• Η συνάρτηση CONCATENATE του Excel απαιτεί τουλάχιστον ένα όρισμα "text" για να λειτουργήσει.
• Σε έναν τύπο, μπορείτε να συνδέσετε έως και 255 συμβολοσειρές, συνολικά 8.192 χαρακτήρες.
• Το αποτέλεσμα της συνάρτησης CONCATENATE είναι πάντα μια συμβολοσειρά κειμένου, ακόμη και όταν όλες οι τιμές προέλευσης είναι αριθμοί.
• Σε αντίθεση με τη συνάρτηση CONCAT, η συνάρτηση CONCATENATE του Excel δεν αναγνωρίζει τους πίνακες. Κάθε αναφορά κελιού πρέπει να παρατίθεται ξεχωριστά. Για παράδειγμα, θα πρέπει να χρησιμοποιήσετε τη συνάρτηση CONCATENATE(A1, A2, A3) και όχι τη συνάρτηση CONCATENATE(A1:A3).
• Εάν κάποιο από τα ορίσματα είναι άκυρο, η συνάρτηση CONCATENATE επιστρέφει ένα σφάλμα #VALUE!

Ο τελεστής "&" για τη συνένωση συμβολοσειρών στο Excel

Στο Microsoft Excel, το σύμβολο της άνω τελείας (&) είναι ένας άλλος τρόπος για τη συνένωση κελιών. Αυτή η μέθοδος είναι πολύ χρήσιμη σε πολλά σενάρια, καθώς η πληκτρολόγηση μιας άνω τελείας είναι πολύ πιο γρήγορη από την πληκτρολόγηση της λέξης "συνένωση" :)

Για παράδειγμα, για να συνδέσετε δύο τιμές κελιών με ένα κενό ανάμεσά τους, ο τύπος είναι:

=A2&" "&B2

Πώς να συνδέσετε στο Excel - παραδείγματα τύπων

Παρακάτω θα βρείτε μερικά παραδείγματα χρήσης της συνάρτησης CONCATENATE στο Excel.

Συνδέστε δύο ή περισσότερα κελιά χωρίς διαχωριστικό

Για να συνδυάσετε τις τιμές των δύο κύτταρα σε ένα, χρησιμοποιείτε τον τύπο της συνένωσης στην απλούστερη μορφή του:

=CONCATENATE(A2, B2)

Ή

=A2&B2

Σημειώστε ότι οι τιμές θα είναι ενωμένες χωρίς κανένα διαχωριστικό, όπως στο παρακάτω στιγμιότυπο.

Για να συνδέσετε πολλαπλά κύτταρα , πρέπει να παρέχετε κάθε αναφορά κελιού ξεχωριστά, ακόμη και αν συνδυάζετε συνεχόμενα κελιά. Για παράδειγμα:

=CONCATENATE(A2, B2, C2)

Ή

=A2&B2&C2

Οι τύποι λειτουργούν τόσο για κείμενο όσο και για αριθμούς. Στην περίπτωση των αριθμών, λάβετε υπόψη σας ότι το αποτέλεσμα είναι μια συμβολοσειρά κειμένου. Για να το μετατρέψετε σε αριθμό, απλά πολλαπλασιάστε την έξοδο του CONCATENATE με 1 ή προσθέστε 0. Για παράδειγμα:

=CONCATENATE(A2, B2)*1

Συμβουλή. Στο Excel 2019 και νεότερες εκδόσεις, μπορείτε να χρησιμοποιήσετε τη συνάρτηση CONCAT για να συνδέσετε γρήγορα πολλαπλά κελιά χρησιμοποιώντας μία ή περισσότερες αναφορές περιοχής.

Συνδέστε κελιά με κενό, κόμμα ή άλλο διαχωριστικό

Στα φύλλα εργασίας σας, μπορεί συχνά να χρειαστεί να ενώσετε τιμές με τρόπο που να περιλαμβάνει κόμματα, κενά, διάφορα σημεία στίξης ή άλλους χαρακτήρες, όπως παύλα ή κάθετο. Για να το κάνετε αυτό, απλά βάλτε τον επιθυμητό χαρακτήρα στον τύπο συνένωσης. Θυμηθείτε να περικλείσετε τον χαρακτήρα αυτό σε εισαγωγικά, όπως φαίνεται στα παρακάτω παραδείγματα.

Συνδέοντας δύο κελιά με ένα χώρος :

=CONCATENATE(A2, " ", B2)

ή

=A2 & " " & B2

Συνδέοντας δύο κελιά με ένα κόμμα :

=CONCATENATE(A2, ", ", B2)

ή

=A2 & ", " & B2

Συνδέοντας δύο κελιά με ένα παύλα :

=CONCATENATE(A2, "-", B2)

ή

=A2 & "-" & B2

Το ακόλουθο στιγμιότυπο οθόνης δείχνει πώς μπορεί να φαίνονται τα αποτελέσματα:

Συμβουλή. Στο Excel 2019 και νεότερες εκδόσεις, μπορείτε να χρησιμοποιήσετε τη συνάρτηση TEXTJOIN για να συγχωνεύσετε συμβολοσειρές από πολλαπλά κελιά με οποιοδήποτε διαχωριστικό που έχετε καθορίσει.

Συνένωση συμβολοσειράς κειμένου και τιμής κελιού

Δεν υπάρχει κανένας λόγος η συνάρτηση CONCATENATE του Excel να περιορίζεται μόνο στην ένωση των τιμών των κελιών. Μπορείτε επίσης να τη χρησιμοποιήσετε για να συνδυάσετε συμβολοσειρές κειμένου για να κάνετε το αποτέλεσμα πιο ουσιαστικό. Για παράδειγμα:

=CONCATENATE(A2, " ", B2, " completed")

Ο παραπάνω τύπος ενημερώνει τον χρήστη ότι ένα συγκεκριμένο έργο έχει ολοκληρωθεί, όπως στη γραμμή 2 στο παρακάτω στιγμιότυπο οθόνης. Παρατηρήστε ότι προσθέτουμε ένα κενό πριν από τη λέξη " completed" για να διαχωρίσουμε τις συνδεδεμένες συμβολοσειρές κειμένου. Ένα κενό (" ") παρεμβάλλεται επίσης μεταξύ των συνδυασμένων τιμών, έτσι ώστε το αποτέλεσμα να εμφανίζεται ως "Project 1" και όχι ως "Project1".

Με τον τελεστή συνένωσης, ο τύπος μπορεί να γραφτεί ως εξής:

=A2 & " " & B2 & " completed"

Με τον ίδιο τρόπο, μπορείτε να προσθέσετε μια συμβολοσειρά κειμένου στην αρχή ή στη μέση του τύπου συνένωσης. Για παράδειγμα:

=CONCATENATE("Βλέπε ", A2, " ", B2)

="Βλέπε " & A2 & " " & B2

Συνδέστε μια συμβολοσειρά κειμένου και έναν άλλο τύπο

Για να κάνετε το αποτέλεσμα που επιστρέφεται από κάποιον τύπο πιο κατανοητό για τους χρήστες σας, μπορείτε να το συνδέσετε με μια συμβολοσειρά κειμένου που εξηγεί ποια είναι στην πραγματικότητα η τιμή.

Για παράδειγμα, μπορείτε να χρησιμοποιήσετε τον ακόλουθο τύπο για να επιστρέψετε την τρέχουσα ημερομηνία στην επιθυμητή μορφή και να καθορίσετε το είδος της ημερομηνίας:

=CONCATENATE("Σήμερα είναι ",TEXT(TODAY(), "mmmm d, yyyy"))

="Σήμερα είναι " & TEXT(TODAY(), "dd-mmm-yy")

Συμβουλή. Αν θέλετε να διαγράψετε τα δεδομένα της πηγής χωρίς να επηρεάσετε τις συμβολοσειρές κειμένου που προκύπτουν, χρησιμοποιήστε την επιλογή "Ειδική επικόλληση - μόνο τιμές" για να μετατρέψετε τους τύπους στις τιμές τους.

Συνδέστε συμβολοσειρές κειμένου με διαλείμματα γραμμής

Τις περισσότερες φορές, θα διαχωρίζατε τις σειρές κειμένου που προκύπτουν με σημεία στίξης και κενά, όπως φαίνεται στο προηγούμενο παράδειγμα. Σε ορισμένες περιπτώσεις, ωστόσο, μπορεί να υπάρχει ανάγκη διαχωρισμού των τιμών με αλλαγή γραμμής, ή επιστροφή μεταφοράς. Ένα συνηθισμένο παράδειγμα είναι η συγχώνευση ταχυδρομικών διευθύνσεων από δεδομένα σε ξεχωριστές στήλες.

Ένα πρόβλημα είναι ότι δεν μπορείτε απλώς να πληκτρολογήσετε μια αλλαγή γραμμής στον τύπο όπως έναν συνηθισμένο χαρακτήρα. Αντ' αυτού, χρησιμοποιείτε τη συνάρτηση CHAR για να παρέχετε τον αντίστοιχο κωδικό ASCII στον τύπο της συνένωσης:

• Στα Windows, χρησιμοποιήστε CHAR(10), όπου 10 είναι ο κωδικός χαρακτήρων για Τροφοδοσία γραμμής .
• Σε Mac, χρησιμοποιήστε CHAR(13) όπου 13 είναι ο κωδικός χαρακτήρων για Επιστροφή μεταφοράς .

Σε αυτό το παράδειγμα, έχουμε τα κομμάτια διευθύνσεων στις στήλες A έως F και τα ενώνουμε στη στήλη G χρησιμοποιώντας τον τελεστή συνένωσης "&". Οι τιμές που συνενώνονται διαχωρίζονται με κόμμα (", "), κενό (" ") και αλλαγή γραμμής CHAR(10):

=A2 &? " " & B2 & CHAR(10) &- C2 &- CHAR(10) &- D2 &- ", " &- E2 &- " " &- F2

Η συνάρτηση CONCATENATE θα είχε την εξής μορφή:

=CONCATENATE(A2, " ", B2, CHAR(10), C2, CHAR(10), D2, ", ", ", E2, " ", F2)

Όπως και να έχει, το αποτέλεσμα είναι μια συμβολοσειρά κειμένου 3 γραμμών: Σημείωση. Όταν χρησιμοποιείτε τα διαλείμματα γραμμής για να διαχωρίσετε τις συνδυασμένες τιμές, πρέπει να έχετε ενεργοποιήσει την επιλογή Wrap text (Αναδίπλωση κειμένου) για να εμφανιστεί σωστά το αποτέλεσμα. Για να το κάνετε αυτό, πατήστε Ctrl + 1 για να ανοίξετε το παράθυρο Κελιά μορφοποίησης διαλόγου, μεταβείτε στο Ευθυγράμμιση και ελέγξτε την καρτέλα Αναδίπλωση κειμένου κουτί.

Με τον ίδιο τρόπο, μπορείτε να διαχωρίσετε τις τελικές συμβολοσειρές με άλλους χαρακτήρες, όπως:

• Διπλά εισαγωγικά (") - CHAR(34)
• Κάθετος προς τα εμπρός (/) - CHAR(47)
• Αστερίσκος (*) - CHAR (42)
• Ο πλήρης κατάλογος των Κώδικες ASCII είναι διαθέσιμο εδώ.

Πώς να συνδέσετε στήλες στο Excel

Για να ενώσετε δύο ή περισσότερες στήλες, απλώς εισαγάγετε τον τύπο συνένωσης στο πρώτο κελί και, στη συνέχεια, αντιγράψτε τον σε άλλα κελιά σύροντας τη λαβή γεμίσματος (το μικρό τετράγωνο που εμφανίζεται στην κάτω δεξιά γωνία του επιλεγμένου κελιού).

Για παράδειγμα, για να συνδυάσετε δύο στήλες (στήλη Α και Β) οριοθετώντας τις τιμές με ένα κενό, ο τύπος στο C2 που αντιγράφεται είναι:

=CONCATENATE(A2, " ", B2)

Ή

= A2 & " " & B2 Συμβουλή. Ένας γρήγορος τρόπος για να αντιγράψετε τον τύπο προς τα κάτω στη στήλη είναι να επιλέξετε το κελί με τον τύπο και να κάνετε διπλό κλικ στη λαβή γεμίσματος.

Για περισσότερες πληροφορίες, ανατρέξτε στην ενότητα Πώς να συγχωνεύσετε δύο στήλες στο Excel χωρίς να χάσετε δεδομένα.

Συνδυάστε κείμενο και αριθμούς διατηρώντας τη μορφοποίηση

Κατά τη συνένωση μιας συμβολοσειράς κειμένου με έναν αριθμό, ένα ποσοστό ή μια ημερομηνία, μπορεί να θέλετε να διατηρήσετε την αρχική μορφοποίηση μιας αριθμητικής τιμής ή να την εμφανίσετε με διαφορετικό τρόπο. Αυτό μπορεί να γίνει παρέχοντας τον κωδικό μορφοποίησης μέσα στη συνάρτηση TEXT, τον οποίο ενσωματώνετε σε έναν τύπο συνένωσης.

Στην αρχή αυτού του σεμιναρίου, έχουμε ήδη συζητήσει έναν τύπο που συνδέει κείμενο και ημερομηνία.

Και εδώ είναι μερικά ακόμη παραδείγματα τύπων που συνδυάζουν κείμενο και αριθμός :

Αριθμός με 2 δεκαδικά ψηφία και το σύμβολο $:

=A2 & " " & TEXT(B2, "$#,#0.00")

Αριθμός χωρίς ασήμαντα μηδενικά και το σύμβολο $:

=A2 & " " & TEXT(B2, "0.#")

Κλασματικός αριθμός:

=A2 & " " & TEXT(B2, "# ?/;;;;")

Για να συνδέσετε κείμενο και ποσοστό , οι τύποι είναι:

Ποσοστό με δύο δεκαδικά ψηφία:

=A12 & " " & TEXT(B12, "0.00%")

Στρογγυλοποιημένο ακέραιο ποσοστό:

=A12 & " " & TEXT(B12, "0%")

Πώς να συνδέσετε μια σειρά κελιών στο Excel

Ο συνδυασμός τιμών από πολλαπλά κελιά μπορεί να απαιτήσει κάποια προσπάθεια, επειδή η συνάρτηση CONCATENATE του Excel δεν δέχεται πίνακες.

Για να συνδέσετε πολλά κελιά, π.χ. από το Α1 έως το Α4, πρέπει να χρησιμοποιήσετε έναν από τους ακόλουθους τύπους:

=CONCATENATE(A1, A2, A3, A4)

ή

=A1 & A2 & A3 & A4

Όταν συνδυάζετε μια αρκετά μικρή ομάδα κελιών, δεν είναι μεγάλη υπόθεση να πληκτρολογήσετε όλες τις αναφορές. Μια μεγάλη σειρά θα ήταν κουραστική για την παροχή, πληκτρολογώντας κάθε μεμονωμένη αναφορά με το χέρι. Παρακάτω θα βρείτε 3 μεθόδους γρήγορης συνένωσης σειράς στο Excel.

Μέθοδος 1. Πατήστε CTRL για να επιλέξετε πολλαπλά κελιά

Για να επιλέξετε γρήγορα πολλά κελιά, μπορείτε να πατήσετε και να κρατήσετε πατημένο το πλήκτρο Ctrl ενώ κάνετε κλικ σε κάθε κελί που θέλετε να συμπεριλάβετε στον τύπο. Ακολουθούν τα αναλυτικά βήματα:

1. Επιλέξτε ένα κελί στο οποίο θέλετε να εισαγάγετε τον τύπο.
2. Πληκτρολογήστε =CONCATENATE( σε αυτό το κελί ή στη γραμμή τύπων.
3. Κρατήστε πατημένο το Ctrl και κάντε κλικ σε κάθε κελί που θέλετε να συνδέσετε.
4. Αφήστε το πλήκτρο Ctrl, πληκτρολογήστε την κλειστή παρένθεση και πατήστε Enter .

Μέθοδος 2. Χρησιμοποιήστε τη συνάρτηση TRANSPOSE για να λάβετε όλες τις τιμές των κελιών

Όταν μια περιοχή αποτελείται από δεκάδες ή εκατοντάδες κελιά, η προηγούμενη μέθοδος μπορεί να μην είναι αρκετά γρήγορη, καθώς απαιτεί κλικ σε κάθε κελί. Σε αυτή την περίπτωση, μπορείτε να χρησιμοποιήσετε τη συνάρτηση TRANSPOSE για να επιστρέψετε έναν πίνακα τιμών και στη συνέχεια να τις συγχωνεύσετε με μια κίνηση.

1. Στο κελί όπου θέλετε να εμφανίζεται το αποτέλεσμα, πληκτρολογήστε τον τύπο TRANSPOSE, για παράδειγμα:

   =TRANSPOSE(A1:A10)

2. Στη γραμμή τύπων, πατήστε F9 για να αντικαταστήσετε τον τύπο με υπολογιζόμενες τιμές. Ως αποτέλεσμα, θα έχετε έναν πίνακα τιμών προς σύνδεση.
3. Διαγράψτε τις καμπύλες αγκύλες που περιβάλλουν τον πίνακα.
4. Πληκτρολογήστε =CONCATENATE( πριν από την πρώτη τιμή, στη συνέχεια πληκτρολογήστε την κλειστή παρένθεση μετά την τελευταία τιμή και πατήστε Enter .

Σημείωση. Το αποτέλεσμα αυτού του τύπου είναι static Αν τα δεδομένα προέλευσης αλλάξουν, θα πρέπει να επαναλάβετε τη διαδικασία.

Μέθοδος 3. Χρήση της συνάρτησης CONCAT

Στο Excel 365 και στο Excel 2021, αυτός ο απλός τύπος θα συνδέσει μια σειρά κελιών σε ένα λεπτό:

=CONCAT(A1:A10)

Μέθοδος 4. Χρησιμοποιήστε το πρόσθετο Merge Cells (Συγχώνευση κελιών)

Ένας γρήγορος και χωρίς τύπους τρόπος για τη συνένωση οποιασδήποτε περιοχής στο Excel είναι να χρησιμοποιήσετε το πρόσθετο Merge Cells (Συγχώνευση κελιών) με το " Συγχώνευση όλων των περιοχών στην επιλογή " απενεργοποιημένη, όπως φαίνεται στην ενότητα Συνδυασμός τιμών πολλών κελιών σε ένα κελί.

Ο τελεστής "&" του Excel έναντι της συνάρτησης CONCATENATE

Πολλοί χρήστες αναρωτιούνται ποιος είναι πιο αποτελεσματικός τρόπος για να ενώσετε συμβολοσειρές στο Excel - η συνάρτηση CONCATENATE ή ο τελεστής "&".

Η μόνη πραγματική διαφορά είναι το όριο των 255 συμβολοσειρών της συνάρτησης CONCATENATE και η απουσία τέτοιου περιορισμού όταν χρησιμοποιείται η άνω τελεία. Εκτός από αυτό, δεν υπάρχει καμία διαφορά μεταξύ αυτών των δύο μεθόδων, ούτε υπάρχει διαφορά ταχύτητας μεταξύ των τύπων CONCATENATE και "&".

Και δεδομένου ότι το 255 είναι ένας πραγματικά μεγάλος αριθμός και δύσκολα θα χρειαστεί να συνδυάσετε τόσες πολλές συμβολοσειρές στην πραγματική εργασία, η διαφορά καταλήγει στην άνεση και την ευκολία χρήσης. Ορισμένοι χρήστες βρίσκουν τους τύπους CONCATENATE πιο ευανάγνωστους, εγώ προσωπικά προτιμώ να χρησιμοποιώ τη μέθοδο "&". Έτσι, απλά μείνετε με την τεχνική με την οποία αισθάνεστε πιο άνετα.

Το αντίθετο της CONCATENATE στο Excel (διαχωρισμός κελιών)

Το αντίθετο της συνένωσης στο Excel είναι η διάσπαση του περιεχομένου ενός κελιού σε πολλαπλά κελιά. Αυτό μπορεί να γίνει με μερικούς διαφορετικούς τρόπους:

• Λειτουργία "Κείμενο σε στήλες
• Επιλογή Flash Fill στο Excel 2013 και νεότερες εκδόσεις
• Συνάρτηση TEXTSPLIT στο Excel 365
• Προσαρμοσμένοι τύποι διαχωρισμού κελιών (MID, RIGHT, LEFT, κ.λπ.)

Μπορείτε επίσης να βρείτε χρήσιμες πληροφορίες σε αυτό το άρθρο: Πώς να καταργήσετε τη συγχώνευση κελιών στο Excel.

Συνδέστε στο Excel με το πρόσθετο Merge Cells (Συγχώνευση κελιών)

Με το πρόσθετο Merge Cells που περιλαμβάνεται στο Ultimate Suite for Excel, μπορείτε να κάνετε αποτελεσματικά και τα δύο:

• Συγχώνευση πολλά κελιά σε ένα χωρίς να χάνονται δεδομένα.
• Συνδυασμός τις τιμές πολλών κελιών σε ένα μόνο κελί και να τις διαχωρίσετε με οποιοδήποτε διαχωριστικό της επιλογής σας.

Το εργαλείο Merge Cells λειτουργεί με όλες τις εκδόσεις του Excel από το 2016 έως το 365 και μπορεί να συνδυάσει όλους τους τύπους δεδομένων, συμπεριλαμβανομένων των συμβολοσειρών κειμένου, των αριθμών, των ημερομηνιών και των ειδικών συμβόλων. Τα δύο βασικά πλεονεκτήματά του είναι η απλότητα και η ταχύτητα - οποιαδήποτε συνένωση γίνεται με μερικά κλικ.

Συνδυασμός τιμών πολλών κελιών σε ένα κελί

Για να συνδυάσετε τα περιεχόμενα πολλών κελιών, επιλέγετε την περιοχή προς συνένωση και διαμορφώνετε τις ακόλουθες ρυθμίσεις:

• Κάτω από το Τι να συγχωνεύσετε , επιλέξτε Κύτταρα σε ένα .
• Κάτω από το Συνδυάστε με , πληκτρολογήστε το διαχωριστικό (ένα κόμμα και ένα κενό στην περίπτωσή μας).
• Επιλέξτε πού θέλετε να τοποθετήσετε το αποτέλεσμα.
• Το πιο σημαντικό, καταργήστε την επιλογή Συγχώνευση όλων των περιοχών της επιλογής Αυτή η επιλογή ελέγχει αν τα κελιά συγχωνεύονται ή αν οι τιμές τους συνενώνονται.

Συνδυασμός στηλών γραμμή-γραμμή

Για τη συνένωση δύο ή περισσότερων στηλών, ρυθμίζετε τις παραμέτρους των ρυθμίσεων Συγχώνευση κελιών με παρόμοιο τρόπο, αλλά επιλέγετε να συγχωνεύσετε στήλες σε μία και τοποθετήστε τα αποτελέσματα στην αριστερή στήλη.

Συνδέστε τις γραμμές στήλη προς στήλη

Για να συνδυάσετε τα δεδομένα σε κάθε μεμονωμένη γραμμή, στήλη προς στήλη, επιλέγετε:

• Συγχώνευση γραμμές σε μία .
• Χρησιμοποιήστε ένα διακοπή γραμμής για το διαχωριστικό.
• Τοποθετήστε τα αποτελέσματα στο πάνω σειρά .

Το αποτέλεσμα μπορεί να μοιάζει με αυτό:

Για να ελέγξετε πώς το πρόσθετο Merge Cells θα αντιμετωπίσει τα σύνολα δεδομένων σας, μπορείτε να κατεβάσετε μια πλήρως λειτουργική δοκιμαστική έκδοση του Ultimate Suite for Excel παρακάτω.

Αυτός είναι ο τρόπος σύνδεσης στο Excel. Σας ευχαριστώ που διαβάσατε και ελπίζω να σας δω στο blog μας την επόμενη εβδομάδα!

Διαθέσιμες λήψεις

Παραδείγματα τύπων συνένωσης (.xlsx αρχείο)

Δοκιμαστική έκδοση Ultimate Suite 14 ημερών (.exe αρχείο)