V tomto článku se seznámíte s různými způsoby spojování textových řetězců, čísel a dat v aplikaci Excel pomocí funkce CONCATENATE a operátoru "&". Probereme také vzorce pro spojování jednotlivých buněk, sloupců a rozsahů.

V sešitech aplikace Excel nejsou data vždy strukturována podle vašich potřeb. Často můžete chtít rozdělit obsah jedné buňky do jednotlivých buněk nebo udělat pravý opak - spojit data ze dvou nebo více sloupců do jednoho sloupce. Častými příklady jsou například spojování částí jmen a adres, spojování textu s hodnotou určenou vzorcem, zobrazování dat a časů v požadovaném formátu a další.

V tomto kurzu se budeme zabývat různými technikami spojování řetězců v aplikaci Excel, abyste si mohli vybrat metodu, která je pro vaše pracovní listy nejvhodnější.

Co je to "concatenate" v aplikaci Excel?

V zásadě existují dva způsoby, jak kombinovat data v tabulkách aplikace Excel:

• Slučování buněk
• Spojování hodnot buněk

Když sloučit buňky "fyzicky" spojíte dvě nebo více buněk do jedné buňky. Výsledkem je jedna větší buňka, která je zobrazena ve více řádcích a/nebo sloupcích.

Když spojit buňky v aplikaci Excel, kombinujete pouze obsah Jinými slovy, spojování v Excelu je proces spojování dvou nebo více hodnot dohromady. Tato metoda se často používá ke spojení několika částí textu, které se nacházejí v různých buňkách (odborně se jim říká textové řetězce nebo jednoduše struny ) nebo vložit hodnotu vypočtenou pomocí vzorce doprostřed textu.

Následující snímek obrazovky ukazuje rozdíl mezi těmito dvěma metodami:

Slučování buněk v aplikaci Excel je předmětem samostatného článku a v tomto tutoriálu probereme dva hlavní způsoby spojování řetězců v aplikaci Excel - pomocí funkce CONCATENATE a operátoru spojování (&).

Funkce CONCATENATE aplikace Excel

Funkce CONCATENATE v aplikaci Excel slouží ke spojení různých částí textu nebo ke spojení hodnot z několika buněk do jedné buňky.

Syntaxe funkce Excel CONCATENATE je následující:

Kde: text je textový řetězec, odkaz na buňku nebo hodnota určená vzorcem.

Funkce CONCATENATE je podporována ve všech verzích aplikace Excel 365 - 2007.

Například pro spojení hodnot B6 a C6 s čárkou je vzorec následující:

=CONCATENATE(B6, ",", C6)

Další příklady jsou uvedeny na obrázku níže:

Poznámka: V aplikaci Excel 365 - Excel 2019 je k dispozici také funkce CONCAT, která je moderním nástupcem funkce CONCATENATE s naprosto stejnou syntaxí. Přestože je funkce CONCATENATE zachována kvůli zpětné kompatibilitě, společnost Microsoft neslibuje, že bude podporována i v dalších verzích aplikace Excel.

Použití funkce CONCATENATE v aplikaci Excel - co je třeba si zapamatovat

Chcete-li zajistit, aby vzorce CONCATENATE vždy poskytovaly správné výsledky, pamatujte na následující jednoduchá pravidla:

• Funkce CONCATENATE aplikace Excel vyžaduje ke své funkci alespoň jeden argument "text".
• V jednom vzorci můžete spojit až 255 řetězců, tedy celkem 8 192 znaků.
• Výsledkem funkce CONCATENATE je vždy textový řetězec, i když jsou všechny zdrojové hodnoty čísla.
• Na rozdíl od funkce CONCAT nerozpozná funkce CONCATENATE aplikace Excel pole. Každý odkaz na buňku musí být uveden samostatně. Například byste měli použít CONCATENATE(A1, A2, A3), nikoli CONCATENATE(A1:A3).
• Pokud je některý z argumentů neplatný, funkce CONCATENATE vrátí chybu #VALUE!.

Operátor "&" pro spojování řetězců v aplikaci Excel

V aplikaci Microsoft Excel je dalším způsobem spojování buněk znak ampersand (&). Tento způsob se v mnoha případech velmi hodí, protože zadání ampersandu je mnohem rychlejší než zadání slova "spojit" :)

Například pro spojení dvou hodnot v buňce s mezerou mezi nimi je vzorec následující:

=A2&" "&B2

Jak spojovat v aplikaci Excel - příklady vzorců

Níže najdete několik příkladů použití funkce CONCATENATE v aplikaci Excel.

Spojení dvou nebo více buněk bez oddělovače

Kombinace hodnot dvě buňky do jednoho, použijete konkatenační vzorec v jeho nejjednodušší podobě:

=CONCATENATE(A2, B2)

Nebo

=A2&B2

Všimněte si, že hodnoty budou spojeny dohromady bez jakéhokoli oddělovače jako na obrázku níže.

Zřetězení více buněk , musíte zadat odkaz na každou buňku zvlášť, i když spojujete sousedící buňky. Například:

=CONCATENATE(A2, B2, C2)

Nebo

=A2&B2&C2

Vzorce fungují jak pro text, tak pro čísla. V případě čísel mějte na paměti, že výsledkem je textový řetězec. Chcete-li jej převést na číslo, stačí vynásobit výsledek funkce CONCATENATE číslem 1 nebo k němu přičíst 0. Například:

=CONCATENATE(A2, B2)*1

Tip: V aplikaci Excel 2019 a vyšších verzích můžete použít funkci CONCAT k rychlému spojení více buněk pomocí jednoho nebo více odkazů na rozsah.

Spojování buněk mezerou, čárkou nebo jiným oddělovačem

V pracovních listech můžete často potřebovat spojit hodnoty způsobem, který zahrnuje čárky, mezery, různá interpunkční znaménka nebo jiné znaky, jako je pomlčka nebo lomítko. Chcete-li to provést, jednoduše vložte požadovaný znak do spojovacího vzorce. Nezapomeňte tento znak uzavřít do uvozovek, jak je ukázáno v následujících příkladech.

Spojení dvou buněk pomocí prostor :

=CONCATENATE(A2, " ", B2)

nebo

=A2 & " " & B2

Spojení dvou buněk pomocí čárka :

=CONCATENATE(A2, ", ", B2)

nebo

=A2 & ", " & B2

Spojení dvou buněk pomocí pomlčka :

=CONCATENATE(A2, "-", B2)

nebo

=A2 & "-" & B2

Následující snímek obrazovky ukazuje, jak mohou vypadat výsledky:

Tip: V aplikaci Excel 2019 a vyšších verzích můžete pomocí funkce TEXTJOIN sloučit řetězce z více buněk s libovolným zadaným oddělovačem.

Spojení textového řetězce a hodnoty buňky

Není důvod, aby se funkce CONCATENATE v aplikaci Excel omezovala pouze na spojování hodnot buněk. Můžete ji použít i ke spojování textových řetězců, aby byl výsledek smysluplnější. Např:

=CONCATENATE(A2, " ", B2, " dokončeno")

Výše uvedený vzorec informuje uživatele o tom, že určitý projekt je dokončen, jako v řádku 2 na obrázku níže. Všimněte si, že před slovo " dokončen" přidáváme mezeru, abychom oddělili zřetězené textové řetězce. Mezera (" ") se vkládá také mezi zřetězené hodnoty, takže výsledek se zobrazí jako "Projekt 1", a nikoli jako "Projekt1".

Pomocí operátoru spojování lze vzorec zapsat takto:

=A2 & " " & B2 & " dokončeno"

Stejným způsobem můžete přidat textový řetězec na začátek nebo doprostřed spojovacího vzorce. Například:

=CONCATENATE("Viz ", A2, " ", B2)

="Viz " & A2 & " " & B2

Spojení textového řetězce a jiného vzorce

Chcete-li, aby byl výsledek vrácený nějakým vzorcem pro uživatele srozumitelnější, můžete jej spojit s textovým řetězcem, který vysvětluje, jaká je vlastně hodnota.

Například můžete použít následující vzorec pro vrácení aktuálního data v požadovaném formátu a zadat, o jaký druh data se jedná:

=CONCATENATE("Dnes je ",TEXT(TODAY(), "mmmm d, rrrr"))

="Dnes je " & TEXT(TODAY(), "dd-mmm-yy")

Tip: Pokud chcete odstranit zdrojová data, aniž byste ovlivnili výsledné textové řetězce, použijte možnost "Vložit speciální - pouze hodnoty" a převeďte vzorce na jejich hodnoty.

Spojování textových řetězců se zalomením řádků

Nejčastěji byste výsledné textové řetězce oddělili interpunkčními znaménky a mezerami, jak je uvedeno v předchozím příkladu. V některých případech však může být potřeba oddělit hodnoty zalomením řádku nebo návratem vozíku. Častým příkladem je sloučení poštovních adres z dat v samostatných sloupcích.

Problémem je, že do vzorce nelze jednoduše zadat zalomení řádku jako běžný znak. Místo toho je třeba použít funkci CHAR, která do vzorce pro spojování zadá odpovídající kód ASCII:

• V systému Windows použijte CHAR(10), kde 10 je kód znaku pro Podávání řádků .
• V systému Mac použijte CHAR(13), kde 13 je kód znaku pro Vrácení vozu .

V tomto příkladu máme části adres ve sloupcích A až F a spojujeme je ve sloupci G pomocí operátoru spojování "&". Sloučené hodnoty jsou odděleny čárkou (", "), mezerou (" ") a zalomením řádku CHAR(10):

=A2 & " " & B2 & CHAR(10) & C2 & CHAR(10) & D2 & ", " & E2 & " " & F2

Funkce CONCATENATE by měla tento tvar:

=CONCATENATE(A2, " ", B2, CHAR(10), C2, CHAR(10), D2, ", ", E2, " ", F2)

V každém případě je výsledkem třířádkový textový řetězec: Poznámka: Při použití oddělovačů řádků pro oddělení kombinovaných hodnot je nutné mít povoleno obtékání textu, aby se výsledek zobrazil správně. To provedete stisknutím klávesové zkratky Ctrl + 1, čímž otevřete okno Formátování buněk přepněte na dialogové okno Zarovnání a zaškrtněte políčko Obalení textu box.

Stejným způsobem můžete oddělovat koncové řetězce dalšími znaky, např.:

• Dvojité uvozovky (") - CHAR(34)
• Přední lomítko (/) - CHAR(47)
• Hvězdička (*) - CHAR (42)
• Úplný seznam Kódy ASCII je k dispozici zde.

Jak spojit sloupce v aplikaci Excel

Chcete-li spojit dva nebo více sloupců, stačí zadat spojovací vzorec do první buňky a poté jej zkopírovat do dalších buněk přetažením úchytu výplně (malý čtvereček, který se zobrazí v pravém dolním rohu vybrané buňky).

Například pro spojení dvou sloupců (sloupec A a B), které jsou ohraničeny mezerou, je vzorec v C2 zkopírován takto:

=CONCATENATE(A2, " ", B2)

Nebo

= A2 & " " & B2 Tip: Rychlý způsob, jak zkopírovat vzorec dolů do sloupce, je vybrat buňku se vzorcem a dvakrát kliknout na úchyt výplně.

Další informace naleznete v části Jak sloučit dva sloupce v aplikaci Excel bez ztráty dat.

Kombinace textu a čísel při zachování formátování

Při spojování textového řetězce s číslem, procentem nebo datem můžete chtít zachovat původní formátování číselné hodnoty nebo ji zobrazit jiným způsobem. To lze provést zadáním formátovacího kódu uvnitř funkce TEXT, který vložíte do spojovacího vzorce.

Na začátku tohoto kurzu jsme již probrali vzorec, který spojuje text a datum.

A zde je několik dalších příkladů vzorců, které kombinují text a číslo :

Číslo se dvěma desetinnými místy a znakem $:

=A2 & " " & TEXT(B2, "$#,#0.00")

Číslo bez nevýznamných nul a znaku $:

=A2 & " " & TEXT(B2, "0.#")

Zlomkové číslo:

=A2 & " " & TEXT(B2, "# ?/???")

Zřetězení text a procenta , vzorce jsou následující:

Procenta se dvěma desetinnými místy:

=A12 & " " & TEXT(B12, "0.00%")

Zaokrouhlené celé procento:

=A12 & " " & TEXT(B12, "0%")

Jak spojit rozsah buněk v aplikaci Excel

Kombinování hodnot z více buněk může vyžadovat určité úsilí, protože funkce CONCATENATE aplikace Excel neakceptuje pole.

Chcete-li spojit několik buněk, například A1 až A4, musíte použít jeden z následujících vzorců:

=CONCATENATE(A1, A2, A3, A4)

nebo

=A1 & A2 & A3 & A4

Při spojování poměrně malé skupiny buněk není velký problém zadat všechny odkazy. Velký rozsah by bylo zdlouhavé dodávat a zadávat každý jednotlivý odkaz ručně. Níže najdete 3 metody rychlého spojování rozsahů v aplikaci Excel.

Metoda 1. Stisknutím klávesy CTRL vyberte více buněk

Chcete-li rychle vybrat několik buněk, můžete stisknout a podržet klávesu Ctrl a zároveň kliknout na každou buňku, kterou chcete zahrnout do vzorce. Zde je uveden podrobný postup:

1. Vyberte buňku, do které chcete vzorec zadat.
2. Do této buňky nebo do panelu vzorců zadejte =CONCATENATE(.
3. Stiskněte a podržte klávesu Ctrl a klikněte na každou buňku, kterou chcete spojit.
4. Uvolněte tlačítko Ctrl, zadejte uzavírací závorku a stiskněte klávesu Enter .

Metoda 2. Pomocí funkce TRANSPOSE získáte všechny hodnoty buněk

Pokud se rozsah skládá z desítek nebo stovek buněk, nemusí být předchozí metoda dostatečně rychlá, protože vyžaduje kliknutí na každou buňku. V takovém případě můžete použít funkci TRANSPOSE, která vrátí pole hodnot, a pak je jedním tahem sloučit.

1. Do buňky, ve které chcete zobrazit výsledek, zadejte vzorec TRANSPOSE, například:

   =TRANSPOSE(A1:A10)

2. V panelu vzorců stiskněte klávesu F9, čímž nahradíte vzorec vypočtenými hodnotami. Výsledkem bude pole hodnot, které se má spojit.
3. Odstraňte kudrnaté závorky kolem pole.
4. Před první hodnotu zadejte =CONCATENATE(, za poslední hodnotu zadejte uzavírací závorku a stiskněte klávesu Enter .

Poznámka: Výsledek tohoto vzorce je statické protože spojuje hodnoty, nikoli odkazy na buňky. Pokud se zdrojová data změní, budete muset proces opakovat.

Metoda 3. Použití funkce CONCAT

V aplikacích Excel 365 a Excel 2021 tento jednoduchý vzorec v mžiku spojí řadu buněk:

=CONCAT(A1:A10)

Metoda 4. Použití doplňku Sloučit buňky

Rychlým způsobem, jak bez použití vzorců spojit libovolný rozsah v aplikaci Excel, je použití doplňku Sloučit buňky s " Sloučení všech oblastí ve výběru " vypnuta, jak je ukázáno v části Spojení hodnot několika buněk do jedné buňky.

Operátor "&" aplikace Excel vs. funkce CONCATENATE

Mnoho uživatelů se ptá, který způsob spojování řetězců v aplikaci Excel je efektivnější - funkce CONCATENATE nebo operátor "&".

Jediným skutečným rozdílem je omezení na 255 řetězců u funkce CONCATENATE a žádné takové omezení při použití ampersandu. Kromě toho není mezi těmito dvěma metodami žádný rozdíl, stejně jako není žádný rozdíl v rychlosti mezi vzorci CONCATENATE a "&".

A protože 255 je opravdu velké číslo a v reálné práci sotva budete potřebovat kombinovat tolik řetězců, rozdíl se omezuje na pohodlí a snadnost použití. Někteří uživatelé považují vzorce CONCATENATE za přehlednější, já osobně dávám přednost použití metody "&". Takže se jednoduše držte techniky, která je vám příjemnější.

Opak funkce CONCATENATE v aplikaci Excel (rozdělení buněk)

Opakem spojování v aplikaci Excel je rozdělení obsahu jedné buňky do více buněk. To lze provést několika různými způsoby:

• Funkce Text do sloupců
• Možnost Flash Fill v aplikaci Excel 2013 a novějších
• Funkce TEXTSPLIT v aplikaci Excel 365
• Vlastní vzorce pro rozdělení buněk (MID, RIGHT, LEFT atd.)

Užitečné informace najdete také v tomto článku: Jak zrušit sloučení buněk v aplikaci Excel.

Spojování v aplikaci Excel pomocí doplňku Sloučit buňky

Pomocí doplňku Sloučit buňky, který je součástí sady Ultimate Suite pro aplikaci Excel, můžete efektivně provádět obojí:

• Sloučení několik buněk do jedné, aniž by došlo ke ztrátě dat.
• Konkatenace hodnoty několika buněk do jedné buňky a oddělte je libovolným oddělovačem.

Nástroj Sloučit buňky funguje se všemi verzemi aplikace Excel od verze 2016 do 365 a dokáže kombinovat všechny typy dat včetně textových řetězců, čísel, dat a speciálních symbolů. Jeho dvěma hlavními výhodami jsou jednoduchost a rychlost - jakékoli sloučení provedete na několik kliknutí.

Spojení hodnot několika buněk do jedné buňky

Chcete-li spojit obsah několika buněk, vyberte rozsah, který chcete spojit, a nakonfigurujte následující nastavení:

• Pod Co sloučit , vyberte Buňky do jedné .
• Pod Kombinujte s , zadejte oddělovač (v našem případě čárka a mezera).
• Vyberte, kam chcete výsledek umístit.
• Především zrušte zaškrtnutí políčka Sloučení všech oblastí ve výběru Tato volba určuje, zda se buňky sloučí, nebo se jejich hodnoty spojí.

Kombinování sloupců po řádcích

Chcete-li sloučit dva nebo více sloupců, nakonfigurujte nastavení funkce Sloučit buňky podobným způsobem, ale vyberte si, zda chcete sloučit. sloupců do jednoho a výsledky umístěte do levého sloupce.

Spojení řádků po sloupcích

Chcete-li kombinovat data v jednotlivých řádcích po sloupcích, zvolte:

• Sloučení řádků do jednoho .
• Použijte přerušení řádku pro oddělovač.
• Umístěte výsledky do horní řada .

Výsledek může vypadat podobně:

Chcete-li si ověřit, jak si doplněk Merge Cells poradí s vašimi datovými sadami, můžete si stáhnout plně funkční zkušební verzi naší sady Ultimate Suite pro Excel níže.

To je postup, jak v Excelu spojovat. Děkuji vám za přečtení a doufám, že se příští týden uvidíme na našem blogu!

Dostupné soubory ke stažení

Příklady konkatenačních vzorců (.xlsx soubor)

14denní zkušební verze sady Ultimate Suite (.exe soubor)