В этой статье вы узнаете о различных способах объединения текстовых строк, чисел и дат в Excel с помощью функции CONCATENATE и оператора "&". Мы также обсудим формулы для объединения отдельных ячеек, столбцов и диапазонов.

В рабочих книгах Excel данные не всегда структурированы в соответствии с вашими потребностями. Часто вам может понадобиться разделить содержимое одной ячейки на отдельные ячейки или сделать обратное - объединить данные из двух или более столбцов в один столбец. Обычные примеры - объединение имен и частей адреса, объединение текста со значением, заданным формулой, отображение дат и времени в нужном формате и т.п.

В этом учебнике мы рассмотрим различные методы конкатенации строк Excel, чтобы вы могли выбрать метод, наиболее подходящий для ваших рабочих листов.

Что такое "конкатенат" в Excel?

По сути, существует два способа объединения данных в электронных таблицах Excel:

• Объединение ячеек
• Конкатенация значений ячеек

Когда ты объединить ячейки, вы "физически" объединяете две или более ячеек в одну ячейку. В результате вы получаете одну большую ячейку, которая отображается в нескольких строках и/или столбцах.

Когда ты конкатенат ячейки в Excel, вы объединяете только содержание Другими словами, конкатенация в Excel - это процесс соединения двух или более значений вместе. Этот метод часто используется для объединения нескольких фрагментов текста, которые находятся в разных ячейках (технически они называются текстовые строки или просто строки ) или вставить рассчитанное по формуле значение в середину текста.

Следующий снимок экрана демонстрирует разницу между этими двумя методами:

Объединение ячеек в Excel является темой отдельной статьи, а в этом руководстве мы рассмотрим два основных способа объединения строк в Excel - с помощью функции CONCATENATE и оператора конкатенации (&).

Функция Excel CONCATENATE

Функция CONCATENATE в Excel используется для объединения различных фрагментов текста или объединения значений из нескольких ячеек в одну ячейку.

Синтаксис Excel CONCATENATE выглядит следующим образом:

Где текст это текстовая строка, ссылка на ячейку или значение, управляемое формулой.

Функция CONCATENATE поддерживается во всех версиях Excel 365 - 2007.

Например, чтобы объединить значения B6 и C6 через запятую, используется следующая формула:

=CONCATENATE(B6, ",", C6)

Другие примеры показаны на рисунке ниже:

Примечание. В Excel 365 - Excel 2019 также доступна функция CONCAT, которая является современным преемником CONCATENATE с точно таким же синтаксисом. Хотя функция CONCATENATE сохранена для обратной совместимости, Microsoft не дает никаких обещаний, что она будет поддерживаться в будущих версиях Excel.

Использование CONCATENATE в Excel - что нужно помнить

Чтобы ваши формулы CONCATENATE всегда давали правильные результаты, запомните следующие простые правила:

• Для работы функции Excel CONCATENATE требуется хотя бы один аргумент "текст".
• В одной формуле можно объединить до 255 строк, всего 8 192 символа.
• Результатом функции CONCATENATE всегда является текстовая строка, даже если все исходные значения являются числами.
• В отличие от функции CONCAT, Excel CONCATENATE не распознает массивы. Каждая ссылка на ячейку должна быть указана отдельно. Например, следует использовать CONCATENATE(A1, A2, A3), а не CONCATENATE(A1:A3).
• Если какой-либо из аргументов недействителен, функция CONCATENATE возвращает ошибку #VALUE!

Оператор "&" для конкатенации строк в Excel

В Microsoft Excel знак амперсанда (&) - это еще один способ объединения ячеек. Этот метод очень удобен во многих сценариях, поскольку набрать амперсанд гораздо быстрее, чем слово "объединить" :)

Например, чтобы объединить два значения ячеек с пробелом между ними, используется следующая формула:

=A2&" "&B2

Как выполнить конкатенацию в Excel - примеры формул

Ниже приведено несколько примеров использования функции CONCATENATE в Excel.

Объединение двух или более ячеек без разделителя

Чтобы объединить значения две ячейки в один, вы используете формулу конкатенации в ее простейшей форме:

=CONCATENATE(A2, B2)

Или

=A2&B2

Обратите внимание, что значения будут сшиты вместе без разделителей, как на скриншоте ниже.

Для конкатенации многочисленные клетки Вы должны указать ссылку на каждую ячейку отдельно, даже если вы объединяете смежные ячейки. Например:

=CONCATENATE(A2, B2, C2)

Или

=A2&B2&C2

Формулы работают как для текста, так и для чисел. В случае с числами, пожалуйста, помните, что результат - это текстовая строка. Чтобы преобразовать ее в число, просто умножьте результат CONCATENATE на 1 или добавьте к нему 0. Например:

=CONCATENATE(A2, B2)*1

Совет. В Excel 2019 и выше можно использовать функцию CONCAT для быстрого объединения нескольких ячеек с помощью одной или нескольких ссылок на диапазон.

Конкатенировать ячейки с пробелом, запятой или другим разделителем

В рабочих листах часто возникает необходимость соединить значения, включающие запятые, пробелы, различные знаки препинания или другие символы, такие как дефис или косая черта. Для этого просто поместите нужный символ в формулу конкатенации. Не забудьте заключить этот символ в кавычки, как показано в следующих примерах.

Конкатенация двух ячеек с помощью пространство :

=CONCATENATE(A2, " ", B2)

или

=A2 & " " & B2

Конкатенация двух ячеек с помощью запятая :

=CONCATENATE(A2, ", ", B2)

или

=A2 & ", " & B2

Конкатенация двух ячеек с помощью дефис :

=CONCATENATE(A2, "-", B2)

или

=A2 & "-" & B2

На следующем снимке экрана показано, как могут выглядеть результаты:

Совет. В Excel 2019 и выше можно использовать функцию TEXTJOIN для объединения строк из нескольких ячеек с любым указанным разделителем.

Конкатенация текстовой строки и значения ячейки

Нет причин ограничивать функцию Excel CONCATENATE только объединением значений ячеек. Вы также можете использовать ее для объединения текстовых строк, чтобы сделать результат более осмысленным. Например:

=CONCATENATE(A2, " ", B2, "завершено")

Приведенная выше формула сообщает пользователю, что определенный проект завершен, как в строке 2 на скриншоте ниже. Обратите внимание, что мы добавляем пробел перед словом "завершен", чтобы разделить объединенные текстовые строки. Пробел (" ") также вставляется между объединенными значениями, чтобы результат отображался как "Проект 1", а не "Проект1".

С помощью оператора конкатенации формулу можно записать так:

=A2 & " " & B2 & " завершено"

Таким же образом можно добавить текстовую строку в начало или в середину формулы конкатенации. Например:

=CONCATENATE("См. ", A2, " ", B2)

= "См. " & A2 & " " & B2

Объединение текстовой строки и другой формулы

Чтобы сделать результат, возвращаемый какой-либо формулой, более понятным для пользователей, вы можете объединить его с текстовой строкой, которая объясняет, что на самом деле представляет собой значение.

Например, вы можете использовать следующую формулу, чтобы вернуть текущую дату в нужном формате и указать, что это за дата:

=CONCATENATE("Сегодня ",TEXT(TODAY(), "mmmm d, yyyy"))

= "Сегодня " & TEXT(TODAY(), "dd-mmm-yy")

Совет. Если вы хотите удалить исходные данные, не затрагивая результирующие текстовые строки, используйте опцию "Paste special - values only" для преобразования формул в их значения.

Конкатенация текстовых строк с переводом строки

Чаще всего результирующие текстовые строки разделяются знаками препинания и пробелами, как показано в предыдущем примере. В некоторых случаях, однако, может возникнуть необходимость разделить значения с помощью перевода строки или возврата каретки. Распространенным примером является объединение почтовых адресов из данных в отдельных колонках.

Проблема заключается в том, что вы не можете просто ввести в формулу перенос строки, как обычный символ. Вместо этого вы используете функцию CHAR, чтобы ввести соответствующий код ASCII в формулу конкатенации:

• В Windows используйте CHAR(10), где 10 - код символа для Подача линии .
• На Mac используйте CHAR(13), где 13 - код символа для Возврат каретки .

В этом примере у нас есть части адреса в столбцах с A по F, и мы объединяем их в столбце G с помощью оператора конкатенации "&". Объединенные значения разделяются запятой (", "), пробелом (" ") и переводом строки CHAR(10):

=A2 & " " & B2 & CHAR(10) & C2 & CHAR(10) & D2 & ", " & E2 & " " & F2

Функция CONCATENATE будет иметь такую форму:

=CONCATENATE(A2, " ", B2, CHAR(10), C2, CHAR(10), D2, ", ", E2, " ", F2)

В любом случае результатом будет 3-строчная текстовая строка: Примечание. При использовании переноса строки для разделения комбинированных значений, чтобы результат отображался корректно, необходимо включить функцию Обернуть текст. Для этого нажмите Ctrl + 1, чтобы открыть окно Форматирование ячеек диалоговое окно, переключитесь на Выравнивание и проверьте Обернуть текст коробка.

Таким же образом можно разделять конечные строки другими символами, например:

• Двойные кавычки ("") - CHAR(34)
• Прямая косая черта (/) - CHAR(47)
• Звездочка (*) - CHAR (42)
• Полный список ASCII-коды можно найти здесь.

Как объединить столбцы в Excel

Чтобы объединить два или более столбцов, просто введите формулу конкатенации в первую ячейку, а затем скопируйте ее в другие ячейки, перетащив ручку заполнения (маленький квадратик, который появляется в правом нижнем углу выделенной ячейки).

Например, чтобы объединить два столбца (столбцы A и B), разделив значения пробелом, скопируйте формулу в C2:

=CONCATENATE(A2, " ", B2)

Или

= A2 & " " & B2 Совет. Быстрый способ скопировать формулу в столбец - выделить ячейку с формулой и дважды щелкнуть по ручке заливки.

Для получения дополнительной информации см. раздел Как объединить два столбца в Excel без потери данных.

Объединяйте текст и числа, сохраняя форматирование

При конкатенации текстовой строки с числом, процентами или датой вы можете захотеть сохранить исходное форматирование числового значения или отобразить его по-другому. Это можно сделать, предоставив код формата внутри функции TEXT, который вы вставляете в формулу конкатенации.

В начале этого учебника мы уже обсуждали формулу, которая конкатенирует текст и дату.

А вот еще несколько примеров формул, в которых сочетаются текст и номер :

Число с 2 десятичными знаками и знаком $:

=A2 & " " & TEXT(B2, "$#,#0.00")

Число без незначащих нулей и знака $:

=A2 & " " & TEXT(B2, "0.#")

Дробное число:

=A2 & " " & TEXT(B2, "# ?/???")

Для конкатенации текст и процент , формулы таковы:

Процент с двумя десятичными знаками:

=A12 & " " & TEXT(B12, "0.00%")

Округленные целые проценты:

=A12 & " " & TEXT(B12, "0%")

Как объединить диапазон ячеек в Excel

Объединение значений из нескольких ячеек может потребовать некоторых усилий, поскольку функция Excel CONCATENATE не принимает массивы.

Чтобы объединить несколько ячеек, например, с A1 по A4, необходимо использовать одну из следующих формул:

=CONCATENATE(A1, A2, A3, A4)

или

=A1 & A2 & A3 & A4

При объединении довольно небольшой группы ячеек нет необходимости вводить все ссылки. Большой диапазон было бы утомительно снабжать, вводя каждую отдельную ссылку вручную. Ниже приведены 3 метода быстрого объединения диапазонов в Excel.

Способ 1. Нажмите CTRL, чтобы выделить несколько ячеек

Чтобы быстро выделить несколько ячеек, можно нажать и удерживать клавишу Ctrl, одновременно щелкая по каждой ячейке, которую вы хотите включить в формулу. Ниже приведены подробные шаги:

1. Выберите ячейку, в которую нужно ввести формулу.
2. Введите =CONCATENATE( в этой ячейке или в строке формул.
3. Нажмите и удерживайте Ctrl и щелкните по каждой ячейке, которую вы хотите объединить.
4. Отпустите кнопку Ctrl, введите закрывающую скобку и нажмите Enter .

Метод 2. Используйте функцию TRANSPOSE для получения значений всех ячеек

Если диапазон состоит из десятков или сотен ячеек, предыдущий метод может оказаться недостаточно быстрым, поскольку требует щелчка на каждой ячейке. В этом случае можно использовать функцию TRANSPOSE, чтобы вернуть массив значений, а затем объединить их одним махом.

1. В ячейке, где вы хотите, чтобы появился результат, введите формулу ТРАНСПОЗИЦИЯ, например:

   =TRANSPOSE(A1:A10)

2. В строке формул нажмите F9, чтобы заменить формулу вычисляемыми значениями. В результате у вас появится массив значений, которые нужно конкатенировать.
3. Удалите фигурные скобки, окружающие массив.
4. Введите =CONCATENATE( перед первым значением, затем введите закрывающую скобку после последнего значения и нажмите Enter .

Примечание. Результатом этой формулы является статический так как он объединяет значения, а не ссылки на ячейки. Если исходные данные изменятся, вам придется повторить процесс.

Метод 3. Использование функции CONCAT

В Excel 365 и Excel 2021 эта простая формула конкатенирует диапазон ячеек в мгновение ока:

=CONCAT(A1:A10)

Метод 4. Используйте надстройку "Объединить ячейки

Быстрый и свободный от формул способ объединить любой диапазон в Excel - это использовать надстройку Merge Cells с параметром " Объедините все области в выделении " выключена, как показано в разделе Объединение значений нескольких ячеек в одну ячейку.

Оператор Excel "&" в сравнении с функцией CONCATENATE

Многие пользователи задаются вопросом, что является более эффективным способом объединения строк в Excel - функция CONCATENATE или оператор "&".

Единственное реальное отличие - это ограничение в 255 строк при использовании функции CONCATENATE и отсутствие такого ограничения при использовании амперсанда. В остальном, между этими двумя методами нет никакой разницы, как нет и разницы в скорости между формулами CONCATENATE и "&".

Поскольку 255 - это очень большое число, и в реальной работе вам вряд ли когда-нибудь понадобится объединять такое количество строк, разница сводится к удобству и простоте использования. Некоторые пользователи находят формулы CONCATENATE более удобными для чтения, я лично предпочитаю использовать метод "&". Поэтому просто придерживайтесь той техники, с которой вам удобнее работать.

Противоположность CONCATENATE в Excel (разделение ячеек)

Противоположностью конкатенации в Excel является разбиение содержимого одной ячейки на несколько ячеек. Это можно сделать несколькими различными способами:

• Функция "Текст в столбцы
• Опция Flash Fill в Excel 2013 и выше
• Функция TEXTSPLIT в Excel 365
• Пользовательские формулы для разделения ячеек (MID, RIGHT, LEFT и т.д.)

Вы также можете найти полезную информацию в этой статье: Как разделить ячейки в Excel.

Конкатенация в Excel с помощью надстройки Merge Cells

С помощью надстройки Merge Cells, входящей в состав Ultimate Suite for Excel, можно эффективно делать и то, и другое:

• Объединить несколько ячеек в одну без потери данных.
• Конкатенат значения нескольких ячеек в одну ячейку и разделите их любым разделителем по вашему выбору.

Инструмент Merge Cells работает со всеми версиями Excel от 2016 до 365 и может объединять все типы данных, включая текстовые строки, числа, даты и специальные символы. Два его ключевых преимущества - простота и скорость - любая конкатенация выполняется в пару кликов.

Объедините значения нескольких ячеек в одну ячейку

Чтобы объединить содержимое нескольких ячеек, выберите диапазон для объединения и настройте следующие параметры:

• Под Что объединить , выберите Клетки в одну .
• Под Соединить с введите разделитель (в нашем случае запятая и пробел).
• Выберите, где вы хотите разместить результат.
• Самое главное, снимите флажок Объединить все области в выделении Именно этот параметр определяет, будут ли ячейки объединены или их значения скомпонованы.

Объединить столбцы ряд за рядом

Чтобы объединить два или более столбцов, вы настраиваете параметры "Объединить ячейки" аналогичным образом, но выбираете объединение колонки в одну и поместите результаты в левую колонку.

Присоединяйте строки по столбцам

Для объединения данных в каждой отдельной строке, столбец за столбцом, вы выбираете:

• Объединить ряды в один .
• Используйте перенос строки для разделителя.
• Поместите результаты в верхний ряд .

Результат может выглядеть примерно так:

Чтобы проверить, как надстройка Merge Cells справится с вашими наборами данных, вы можете загрузить полнофункциональную пробную версию нашего пакета Ultimate Suite для Excel.

Вот как выполнять конкатенацию в Excel. Я благодарю вас за чтение и надеюсь увидеть вас в нашем блоге на следующей неделе!

Доступные загрузки

Примеры формул конкатенации (файл.xlsx)

Ultimate Suite 14-дневная пробная версия (файл .exe)