Pada artikel ini, Anda akan mempelajari berbagai cara untuk menggabungkan string teks, angka, dan tanggal di Excel menggunakan fungsi CONCATENATE dan operator "&". Kami juga akan membahas rumus untuk menggabungkan sel, kolom, dan rentang individu.

Dalam buku kerja Excel Anda, data tidak selalu terstruktur sesuai dengan kebutuhan Anda. Seringkali Anda mungkin ingin membagi konten satu sel ke dalam sel individual atau melakukan yang sebaliknya - menggabungkan data dari dua kolom atau lebih ke dalam satu kolom. Contoh umum adalah menggabungkan nama dan bagian alamat, menggabungkan teks dengan nilai yang digerakkan oleh rumus, menampilkan tanggal dan waktu dalam format yang diinginkan, untuk beberapa nama.

Dalam tutorial ini, kita akan menjelajahi berbagai teknik penggabungan string Excel, sehingga Anda dapat memilih metode yang paling sesuai untuk lembar kerja Anda.

Apa yang dimaksud dengan "concatenate" di Excel?

Pada intinya, ada dua cara untuk menggabungkan data dalam spreadsheet Excel:

• Menggabungkan sel
• Menggabungkan nilai sel

Ketika Anda bergabung Anda secara "fisik" menggabungkan dua sel atau lebih ke dalam satu sel. Hasilnya, Anda memiliki satu sel yang lebih besar yang ditampilkan di beberapa baris dan/atau kolom.

Ketika Anda menggabungkan sel di Excel, Anda hanya menggabungkan isi Dengan kata lain, penggabungan di Excel adalah proses penggabungan dua atau lebih nilai secara bersamaan. Metode ini sering digunakan untuk menggabungkan beberapa bagian teks yang berada di sel yang berbeda (secara teknis, ini disebut string teks atau secara sederhana string ) atau menyisipkan nilai yang dihitung dengan rumus di tengah-tengah teks.

Tangkapan layar berikut ini mendemonstrasikan perbedaan di antara kedua metode ini:

Menggabungkan sel di Excel adalah subjek dari artikel terpisah, dan dalam tutorial ini, kita akan membahas dua cara utama untuk menggabungkan string di Excel - dengan menggunakan fungsi CONCATENATE dan operator penggabungan (&).

Fungsi CONCATENATE Excel

Fungsi CONCATENATE di Excel digunakan untuk menggabungkan potongan teks yang berbeda bersama-sama atau menggabungkan nilai dari beberapa sel menjadi satu sel.

Sintaks Excel CONCATENATE adalah sebagai berikut:

Di mana teks adalah string teks, referensi sel, atau nilai yang digerakkan oleh formula.

Fungsi CONCATENATE didukung di semua versi Excel 365 - 2007.

Misalnya, untuk menggabungkan nilai B6 dan C6 dengan koma, rumusnya adalah:

=CONCATENATE(B6, ",", C6)

Contoh lainnya ditunjukkan dalam gambar di bawah ini:

Catatan. Di Excel 365 - Excel 2019, fungsi CONCAT juga tersedia, yang merupakan penerus modern CONCATENATE dengan sintaksis yang persis sama. Meskipun fungsi CONCATENATE disimpan untuk kompatibilitas ke belakang, Microsoft tidak memberikan janji apa pun bahwa fungsi ini akan didukung di versi Excel yang akan datang.

Menggunakan CONCATENATE di Excel - hal-hal yang perlu diingat

Untuk memastikan bahwa rumus CONCATENATE Anda selalu memberikan hasil yang benar, ingat aturan sederhana berikut:

• Fungsi CONCATENATE Excel membutuhkan setidaknya satu argumen "teks" untuk bekerja.
• Dalam satu formula, Anda bisa menggabungkan hingga 255 string, total 8.192 karakter.
• Hasil dari fungsi CONCATENATE selalu berupa string teks, bahkan ketika semua nilai sumber adalah angka.
• Tidak seperti fungsi CONCAT, Excel CONCATENATE tidak mengenali array. Setiap referensi sel harus dicantumkan secara terpisah. Misalnya, Anda harus menggunakan CONCATENATE (A1, A2, A3) dan bukan CONCATENATE (A1: A3).
• Jika salah satu argumen tidak valid, fungsi CONCATENATE mengembalikan kesalahan #VALUE!

Operator "&" untuk menggabungkan string di Excel

Di Microsoft Excel, tanda ampersand (&) adalah cara lain untuk menggabungkan sel. Metode ini sangat berguna dalam banyak skenario karena mengetik ampersand jauh lebih cepat daripada mengetik kata "concatenate" :)

Misalnya, untuk menggabungkan dua nilai sel dengan spasi di antaranya, rumusnya adalah:

=A2&" "&B2

Cara menggabungkan di Excel - contoh rumus

Di bawah ini Anda akan menemukan beberapa contoh penggunaan fungsi CONCATENATE di Excel.

Gabungkan dua sel atau lebih tanpa pemisah

Untuk menggabungkan nilai-nilai dua sel menjadi satu, Anda menggunakan rumus penggabungan dalam bentuknya yang paling sederhana:

=CONCATENATE(A2, B2)

Atau

= A2 & amp; B2

Harap dicatat bahwa nilai akan disatukan tanpa pembatas seperti pada gambar di bawah ini.

Untuk menggabungkan banyak sel Anda harus menyediakan setiap referensi sel satu per satu, bahkan jika Anda menggabungkan sel yang bersebelahan:

=CONCATENATE(A2, B2, C2)

Atau

= A2 & amp; B2 & amp; C2

Rumus ini bekerja untuk teks dan angka. Untuk angka, harap diingat bahwa hasilnya adalah string teks. Untuk mengubahnya menjadi angka, cukup kalikan output CONCATENATE dengan 1 atau tambahkan 0 ke dalamnya. Misalnya:

=CONCATENATE(A2, B2)*1

jenis. Di Excel 2019 dan yang lebih tinggi, Anda dapat menggunakan fungsi CONCAT untuk menggabungkan beberapa sel dengan cepat menggunakan satu atau lebih referensi rentang.

Gabungkan sel dengan spasi, koma, atau pembatas lainnya

Dalam lembar kerja Anda, Anda mungkin sering perlu menggabungkan nilai dengan cara yang menyertakan koma, spasi, berbagai tanda baca, atau karakter lain seperti tanda hubung atau garis miring. Untuk melakukan ini, cukup letakkan karakter yang diinginkan dalam rumus penggabungan Anda. Ingatlah untuk menyertakan karakter itu dalam tanda kutip, seperti yang ditunjukkan dalam contoh berikut.

Menggabungkan dua sel dengan ruang :

=CONCATENATE(A2, " ", B2)

atau

=A2 & " " & B2

Menggabungkan dua sel dengan koma :

=CONCATENATE(A2, ", ", B2)

atau

=A2 & "," & B2

Menggabungkan dua sel dengan tanda hubung :

=CONCATENATE(A2, "-", B2)

atau

=A2 & "-" & B2

Tangkapan layar berikut ini mendemonstrasikan bagaimana hasilnya terlihat:

jenis. Di Excel 2019 dan yang lebih tinggi, Anda dapat menggunakan fungsi TEXTJOIN untuk menggabungkan string dari beberapa sel dengan pembatas apa pun yang Anda tentukan.

Menggabungkan string teks dan nilai sel

Tidak ada alasan bagi fungsi CONCATENATE Excel untuk dibatasi hanya untuk menggabungkan nilai sel. Anda juga dapat menggunakannya untuk menggabungkan string teks untuk membuat hasilnya lebih bermakna. Misalnya:

=CONCATENATE(A2, " ", B2, " selesai")

Rumus di atas menginformasikan pengguna bahwa proyek tertentu telah selesai, seperti pada baris 2 pada gambar di bawah ini. Harap perhatikan bahwa kami menambahkan spasi sebelum kata "selesai" untuk memisahkan string teks gabungan. Spasi (" ") juga disisipkan di antara nilai gabungan, sehingga hasilnya ditampilkan sebagai "Proyek 1" daripada "Proyek1".

Dengan operator penggabungan, rumusnya bisa dituliskan seperti ini:

=A2 & " " & B2 & " selesai"

Dengan cara yang sama, kamu bisa menambahkan string teks di awal atau di tengah-tengah rumus penggabunganmu. Sebagai contoh:

=CONCATENATE("Lihat ", A2, " ", B2)

="Lihat " & A2 & " " & B2

Gabungkan string teks dan rumus lain

Untuk membuat hasil yang dikembalikan oleh beberapa rumus lebih mudah dipahami oleh pengguna Anda, Anda dapat menggabungkannya dengan string teks yang menjelaskan apa sebenarnya nilai tersebut.

Misalnya, Anda dapat menggunakan rumus berikut untuk mengembalikan tanggal saat ini dalam format yang diinginkan dan menentukan jenis tanggal itu:

=CONCATENATE("Hari ini adalah ",TEXT(TODAY(), "mmmm d, yyyy"))

="Hari ini adalah " & TEXT(TODAY(), "dd-mmm-yy")

Tip. Jika Anda ingin menghapus data sumber tanpa memengaruhi string teks yang dihasilkan, gunakan opsi "Tempel khusus - hanya nilai" untuk mengonversi rumus ke nilainya.

Menggabungkan string teks dengan jeda baris

Paling sering, Anda akan memisahkan string teks yang dihasilkan dengan tanda baca dan spasi, seperti yang ditunjukkan dalam contoh sebelumnya. Namun demikian, dalam beberapa kasus, mungkin ada kebutuhan untuk memisahkan nilai dengan jeda baris, atau carriage return. Contoh yang umum adalah penggabungan alamat surat dari data dalam kolom terpisah.

Masalahnya adalah Anda tidak bisa begitu saja mengetikkan jeda baris dalam rumus seperti karakter biasa. Sebagai gantinya, Anda menggunakan fungsi CHAR untuk memasok kode ASCII yang sesuai ke rumus penggabungan:

• Pada Windows, gunakan CHAR(10) di mana 10 adalah kode karakter untuk Umpan garis .
• Pada Mac, gunakan CHAR(13) di mana 13 adalah kode karakter untuk Pengembalian kereta .

Dalam contoh ini, kita memiliki potongan-potongan alamat dalam kolom A sampai F, dan kita menggabungkannya dalam kolom G dengan menggunakan operator penggabungan "&". Nilai-nilai yang digabungkan dipisahkan dengan koma (", "), spasi (" ") dan jeda baris CHAR(10):

=A2 & " " & B2 & CHAR(10) & C2 & CHAR(10) & D2 & ", " & E2 & " " & F2

Fungsi CONCATENATE akan mengambil bentuk ini:

=CONCATENATE(A2, " ", B2, CHAR(10), C2, CHAR(10), D2, ", ", ", E2, " ", F2)

Apa pun itu, hasilnya adalah string teks 3 baris: Catatan. Ketika menggunakan jeda baris untuk memisahkan nilai gabungan, Anda harus mengaktifkan Wrap text (teks Bungkus) agar hasilnya ditampilkan dengan benar. Untuk melakukan ini, tekan Ctrl + 1 untuk membuka menu Format Sel dialog, beralih ke Keselarasan dan periksa tab Bungkus teks kotak.

Dengan cara yang sama, Anda bisa memisahkan string akhir dengan karakter lain, seperti:

• Tanda kutip ganda (") - CHAR(34)
• Garis miring ke depan (/) - CHAR(47)
• Tanda bintang (*) - CHAR (42)
• Daftar lengkap Kode ASCII tersedia di sini.

Cara menggabungkan kolom di Excel

Untuk menggabungkan dua kolom atau lebih, cukup masukkan rumus penggabungan Anda di sel pertama, lalu salin ke sel lain dengan menyeret gagang isian (kotak kecil yang muncul di sudut kanan bawah sel yang dipilih).

Misalnya, untuk menggabungkan dua kolom (kolom A dan B) yang membatasi nilai dengan spasi, rumus dalam C2 yang disalin ke bawah adalah:

=CONCATENATE(A2, " ", B2)

Atau

= A2 & " " & B2 Tip. Cara cepat untuk menyalin rumus ke bawah kolom adalah dengan memilih sel dengan rumus dan klik dua kali gagang isian.

Untuk informasi lebih lanjut, silakan lihat Cara menggabungkan dua kolom di Excel tanpa kehilangan data.

Menggabungkan teks dan angka dengan tetap memformat

Saat menggabungkan string teks dengan angka, persentase, atau tanggal, Anda mungkin ingin mempertahankan pemformatan asli dari nilai numerik atau menampilkannya dengan cara yang berbeda. Ini dapat dilakukan dengan memberikan kode format di dalam fungsi TEXT, yang Anda sematkan dalam rumus penggabungan.

Di awal tutorial ini, kita sudah membahas rumus yang menggabungkan teks dan tanggal.

Dan berikut ini ada beberapa contoh formula lagi yang menggabungkan teks dan nomor :

Angka dengan 2 tempat desimal dan tanda $:

=A2 & " " & TEXT(B2, "$#,#0.00")

Angka tanpa angka nol yang tidak signifikan dan tanda $:

=A2 & " " & TEXT(B2, "0.#")

Bilangan pecahan:

=A2 & " " & TEXT(B2, "# ?/?????")

Untuk menggabungkan teks dan persentase , rumus-rumusnya adalah:

Persen dengan dua tempat desimal:

=A12 & " " & TEXT(B12, "0.00%")

Dibulatkan seluruh persen:

=A12 & " " & TEXT(B12, "0%")

Cara menggabungkan rentang sel di Excel

Menggabungkan nilai dari beberapa sel mungkin membutuhkan usaha karena fungsi CONCATENATE Excel tidak menerima array.

Untuk menggabungkan beberapa sel, katakanlah A1 hingga A4, Anda perlu menggunakan salah satu rumus berikut:

=CONCATENATE(A1, A2, A3, A4)

atau

=A1 &; A2 &; A3 &; A4

Saat menggabungkan sekelompok kecil sel, bukan masalah besar untuk mengetik semua referensi. Rentang yang besar akan membosankan untuk disediakan, mengetik setiap referensi individu secara manual. Di bawah ini Anda akan menemukan 3 metode penggabungan rentang cepat di Excel.

Metode 1. Tekan CTRL untuk memilih beberapa sel

Untuk memilih beberapa sel dengan cepat, Anda dapat menekan dan menahan Ctrl kunci sambil mengklik setiap sel yang ingin Anda sertakan dalam rumus. Berikut adalah langkah-langkah detailnya:

1. Pilih sel tempat Anda ingin memasukkan formula.
2. Ketik =CONCATENATE( di sel tersebut atau di formula bar.
3. Tekan dan tahan Ctrl dan klik pada setiap sel yang ingin Anda gabungkan.
4. Lepaskan tombol Ctrl, ketik tanda kurung penutup, dan tekan Enter .

Metode 2. Gunakan fungsi TRANSPOSE untuk mendapatkan semua nilai sel

Jika rentang terdiri dari puluhan atau ratusan sel, metode sebelumnya mungkin tidak cukup cepat karena memerlukan klik pada setiap sel. Dalam kasus ini, Anda dapat menggunakan fungsi TRANSPOSE untuk mengembalikan larik nilai, lalu menggabungkannya bersama-sama dalam satu gerakan.

1. Di sel tempat Anda ingin hasilnya muncul, masukkan rumus TRANSPOSE, misalnya:

   =TRANSPOSE(A1:A10)

2. Pada formula bar, tekan F9 untuk mengganti formula dengan nilai terhitung. Hasilnya, Anda akan memiliki larik nilai untuk digabungkan.
3. Hapus tanda kurung kurawal yang mengelilingi larik.
4. Ketik =CONCATENATE( sebelum nilai pertama, kemudian ketik tanda kurung penutup setelah nilai terakhir, dan tekan Enter .

Catatan. Hasil dari rumus ini adalah statis karena menggabungkan nilai, bukan referensi sel. Jika data sumber berubah, Anda harus mengulangi prosesnya.

Metode 3. Gunakan fungsi CONCAT

Di Excel 365 dan Excel 2021, rumus sederhana ini akan menggabungkan berbagai sel dalam sekejap:

=CONCAT(A1:A10)

Metode 4. Gunakan add-in Gabungkan Sel

Cara cepat dan bebas rumus untuk menggabungkan rentang apa pun di Excel adalah dengan menggunakan add-in Merge Cells dengan " Gabungkan semua area dalam pemilihan " dimatikan, seperti yang didemonstrasikan dalam Menggabungkan nilai dari beberapa sel ke dalam satu sel.

Operator "&" Excel vs fungsi CONCATENATE

Banyak pengguna bertanya-tanya cara mana yang lebih efisien untuk menggabungkan string di Excel - fungsi CONCATENATE atau operator "&".

Satu-satunya perbedaan nyata adalah batas 255 string dari fungsi CONCATENATE dan tidak ada batasan seperti itu saat menggunakan ampersand. Selain itu, tidak ada perbedaan antara kedua metode ini, juga tidak ada perbedaan kecepatan antara rumus CONCATENATE dan "&".

Dan karena 255 adalah angka yang sangat besar dan anda hampir tidak akan pernah perlu menggabungkan string sebanyak itu dalam pekerjaan nyata, perbedaannya bermuara pada kenyamanan dan kemudahan penggunaan. Beberapa pengguna merasa rumus CONCATENATE lebih mudah dibaca, saya pribadi lebih suka menggunakan metode "&". Jadi, tetaplah menggunakan teknik yang anda rasa lebih nyaman.

Kebalikan dari CONCATENATE di Excel (memisahkan sel)

Kebalikan dari concatenate di Excel adalah membagi konten satu sel menjadi beberapa sel. Ini dapat dilakukan dengan beberapa cara berbeda:

• Fitur Teks ke Kolom
• Opsi Isi Flash di Excel 2013 dan yang lebih tinggi
• Fungsi TEXTSPLIT di Excel 365
• Rumus khusus untuk membagi sel (MID, RIGHT, LEFT, dll.)

Anda juga dapat menemukan informasi berguna dalam artikel ini: Cara membatalkan penggabungan sel di Excel.

Gabungkan di Excel dengan add-in Gabungkan Sel

Dengan add-in Gabung Sel yang disertakan dalam Ultimate Suite untuk Excel, Anda dapat melakukan keduanya secara efisien:

• Gabung beberapa sel menjadi satu tanpa kehilangan data.
• Menggabungkan nilai dari beberapa sel ke dalam satu sel dan pisahkan dengan pembatas yang Anda pilih.

Alat Gabung Sel berfungsi dengan semua versi Excel dari 2016 hingga 365 dan dapat menggabungkan semua tipe data termasuk string teks, angka, tanggal, dan simbol khusus. Dua keunggulan utamanya adalah kesederhanaan dan kecepatan - penggabungan apa pun dilakukan dalam beberapa klik.

Menggabungkan nilai dari beberapa sel ke dalam satu sel

Untuk menggabungkan konten beberapa sel, Anda memilih rentang untuk menggabungkan dan mengonfigurasi pengaturan berikut:

• Di bawah Apa yang harus digabungkan , pilih Sel menjadi satu .
• Di bawah Kombinasikan dengan , ketik pembatas (koma dan spasi dalam kasus kami).
• Pilih di mana Anda ingin menempatkan hasilnya.
• Yang paling penting, hapus centang pada Gabungkan semua area dalam pemilihan Opsi inilah yang mengontrol apakah sel digabungkan atau nilainya digabungkan.

Gabungkan kolom baris demi baris

Untuk menggabungkan dua kolom atau lebih, Anda mengonfigurasi pengaturan Merge Cells (Gabungkan Sel) dengan cara yang sama, tetapi memilih untuk menggabungkan kolom menjadi satu dan menempatkan hasilnya di kolom kiri.

Bergabung dengan baris kolom demi kolom

Untuk menggabungkan data dalam setiap baris individual, kolom demi kolom, Anda memilih:

• Gabung baris menjadi satu .
• Gunakan jeda baris untuk pembatas.
• Tempatkan hasilnya di dalam baris atas .

Hasilnya mungkin terlihat mirip dengan ini:

Untuk memeriksa bagaimana add-in Merge Cells akan mengatasi kumpulan data Anda, Anda dipersilakan untuk mengunduh versi uji coba yang berfungsi penuh dari Ultimate Suite untuk Excel kami di bawah ini.

Itulah cara menggabungkan di Excel. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!

Unduhan yang tersedia

Contoh rumus penggabungan (file .xlsx)

Suite Ultimate versi uji coba 14 hari (file .exe)