В тази статия ще научите различни начини за обединяване на текстови низове, числа и дати в Excel с помощта на функцията CONCATENATE и оператора "&". Ще обсъдим и формули за обединяване на отделни клетки, колони и диапазони.

В работните книги на Excel данните невинаги са структурирани според нуждите ви. Често може да искате да разделите съдържанието на една клетка на отделни клетки или да направите обратното - да обедините данни от две или повече колони в една колона. Често срещани примери са обединяване на имена и части от адреси, комбиниране на текст със стойност, зададена с формула, показване на дати и часове в желания формат и др.

В този урок ще разгледаме различни техники за свързване на низове в Excel, за да можете да изберете най-подходящия метод за вашите работни листове.

Какво е "concatenate" в Excel?

По същество има два начина за комбиниране на данни в електронни таблици на Excel:

• Сливане на клетки
• Конкатениране на стойностите на клетките

Когато сливане В резултат на това получавате една по-голяма клетка, която се изобразява в няколко реда и/или колони.

Когато конкатенация клетки в Excel, комбинирате само съдържание С други думи, конкатенацията в Excel е процес на обединяване на две или повече стойности. Този метод често се използва за комбиниране на няколко части от текст, които се намират в различни клетки (технически те се наричат текстови низове или просто низове ) или да вмъкнете стойност, изчислена по формула, в средата на текст.

Следващата снимка на екрана показва разликата между тези два метода:

Обединяването на клетки в Excel е предмет на отделна статия, а в този урок ще разгледаме двата основни начина за обединяване на низове в Excel - чрез функцията CONCATENATE и оператора за обединяване (&).

Функция CONCATENATE на Excel

Функцията CONCATENATE в Excel се използва за обединяване на различни части от текста или за комбиниране на стойности от няколко клетки в една клетка.

Синтаксисът на Excel CONCATENATE е следният:

Къде: текст е текстов низ, препратка към клетка или стойност, зададена по формула.

Функцията CONCATENATE се поддържа във всички версии на Excel 365 - 2007.

Например за конкатенация на стойностите B6 и C6 със запетая формулата е:

=CONCATENATE(B6, ",", C6)

Повече примери са показани на изображението по-долу:

Забележка: В Excel 365 - Excel 2019 е налична и функцията CONCAT, която е съвременен наследник на CONCATENATE с абсолютно същия синтаксис. Въпреки че функцията CONCATENATE е запазена за обратна съвместимост, Microsoft не дава никакви обещания, че тя ще се поддържа в бъдещите версии на Excel.

Използване на CONCATENATE в Excel - неща, които трябва да запомните

За да сте сигурни, че формулите CONCATENATE винаги дават правилните резултати, запомнете следните прости правила:

• Функцията CONCATENATE на Excel изисква поне един аргумент "текст", за да работи.
• В една формула можете да обедините до 255 символни низа с общо 8192 символа.
• Резултатът от функцията CONCATENATE винаги е текстов низ, дори когато всички изходни стойности са числа.
• За разлика от функцията CONCAT, Excel CONCATENATE не разпознава масиви. Всяка препратка към клетка трябва да бъде посочена отделно. Например трябва да използвате CONCATENATE(A1, A2, A3), а не CONCATENATE(A1:A3).
• Ако някой от аргументите е невалиден, функцията CONCATENATE връща грешка #VALUE!.

Оператор "&" за конкатениране на низове в Excel

В Microsoft Excel знакът амперсанд (&) е друг начин за конкатенация на клетки. Този метод е много удобен в много случаи, тъй като въвеждането на амперсанд е много по-бързо от въвеждането на думата "конкатенация" :)

Например за конкатенация на две стойности от клетки с интервал между тях формулата е:

=A2&" "&B2

Как да конкатенирате в Excel - примери за формули

По-долу ще намерите няколко примера за използване на функцията CONCATENATE в Excel.

Конкатениране на две или повече клетки без разделител

За да комбинирате стойностите на две клетки в едно, се използва формулата за конкатенация в нейната най-проста форма:

=CONCATENATE(A2, B2)

Или

=A2&B2

Обърнете внимание, че стойностите ще бъдат обединени без разделител, както е показано на снимката по-долу.

Конкатенация множество клетки , трябва да предоставите поотделно препратка към всяка клетка, дори ако комбинирате съседни клетки. Например:

=CONCATENATE(A2, B2, C2)

Или

=A2&B2&C2

Формулите работят както за текст, така и за числа. В случай на числа, моля, имайте предвид, че резултатът е текстов низ. За да го превърнете в число, просто умножете резултата на CONCATENATE по 1 или добавете 0 към него. Например:

=CONCATENATE(A2, B2)*1

Съвет. В Excel 2019 и по-нови версии можете да използвате функцията CONCAT за бързо обединяване на няколко клетки, като използвате една или повече препратки към диапазона.

Конкатениране на клетки с интервал, запетая или друг разделител

В работните си листове често се налага да обединявате стойности по начин, който включва запетаи, интервали, различни препинателни знаци или други символи, като например тире или наклонена черта. За да направите това, просто поставете желания символ във формулата за обединяване. Не забравяйте да оградите този символ в кавички, както е показано в следните примери.

Конкатениране на две клетки с пространство :

=CONCATENATE(A2, " ", B2)

или

=A2 & " " & B2

Конкатениране на две клетки с запетая :

=CONCATENATE(A2, ", ", B2)

или

=A2 & ", " & B2

Конкатениране на две клетки с Дефис :

=CONCATENATE(A2, "-", B2)

или

=A2 & "-" & B2

Следната снимка показва как могат да изглеждат резултатите:

Съвет: В Excel 2019 и по-нови версии можете да използвате функцията TEXTJOIN, за да обединявате низове от няколко клетки с всеки зададен от вас разделител.

Конкатениране на текстов низ и стойност на клетка

Няма причина функцията CONCATENATE на Excel да се ограничава само до обединяване на стойностите на клетките. Можете да я използвате и за обединяване на текстови низове, за да направите резултата по-смислен. Например:

=CONCATENATE(A2, " ", B2, " завършен")

Горната формула информира потребителя, че определен проект е завършен, както е показано на ред 2 в снимката по-долу. Моля, обърнете внимание, че добавяме интервал преди думата " completed" (завършен), за да отделим обединените текстови низове. Между обединените стойности също се добавя интервал (" "), така че резултатът да се показва като "Project 1", а не като "Project1".

С помощта на оператора за конкатенация формулата може да се запише по следния начин:

=A2 & " " & B2 & " завършен"

По същия начин можете да добавите текстов низ в началото или в средата на формулата за конкатенация. Например:

=CONCATENATE("Вижте ", A2, " ", B2)

="Вижте " & A2 & " " & B2

Присъединяване на текстов низ и друга формула

За да направите резултата, върнат от някоя формула, по-разбираем за потребителите, можете да го свържете с текстов низ, който обяснява каква всъщност е стойността.

Например можете да използвате следната формула, за да върнете текущата дата в желания формат и да посочите какъв вид дата е това:

=CONCATENATE("Днес е ",TEXT(TODAY(), "mmmm d, yyyy"))

="Днес е " & TEXT(TODAY(), "dd-mmm-yy")

Съвет: Ако искате да изтриете изходните данни, без това да се отрази на получените текстови низове, използвайте опцията "Paste special - values only" (Вмъкни специално - само стойности), за да преобразувате формулите в техните стойности.

Конкатениране на текстови низове с прекъсвания на редовете

Най-често ще разделяте получените текстови низове с препинателни знаци и интервали, както е показано в предишния пример. В някои случаи обаче може да се наложи да разделите стойностите с прекъсване на реда или връщане на карета. Често срещан пример е обединяването на пощенски адреси от данни в отделни колони.

Проблемът е, че не можете просто да въведете прекъсване на реда във формулата като обикновен символ. Вместо това трябва да използвате функцията CHAR, за да предоставите съответния ASCII код на формулата за конкатенация:

• В Windows използвайте CHAR(10), където 10 е кодът на символите за Подаване на линията .
• В Mac използвайте CHAR(13), където 13 е кодът на символа за Връщане на карета .

В този пример имаме частите на адресите в колони от A до F и ги обединяваме в колона G, като използваме оператора за конкатенация "&". Обединените стойности са разделени със запетая (", "), интервал (" ") и прекъсване на реда CHAR(10):

=A2 & " " & B2 & CHAR(10) & C2 & CHAR(10) & D2 & ", " & E2 & " " & F2

Функцията CONCATENATE ще има следната форма:

=CONCATENATE(A2, " ", B2, CHAR(10), C2, CHAR(10), D2, ", ", E2, " ", F2)

И в двата случая резултатът е 3-редов текстов низ: Забележка: Когато използвате прекъсвания на редовете за разделяне на комбинираните стойности, трябва да активирате функцията Wrap text, за да се покаже резултатът правилно. За да направите това, натиснете Ctrl + 1, за да отворите Форматиране на клетките диалогов прозорец, преминете към Изравняване и проверете Обвиване на текста кутия.

По същия начин можете да отделяте крайните низове с други знаци, като например:

• Двойни кавички (") - CHAR(34)
• Предна наклонена черта (/) - CHAR(47)
• Звездичка (*) - CHAR (42)
• Пълният списък на ASCII кодове е достъпен тук.

Как да конкатенирате колони в Excel

За да обедините две или повече колони, просто въведете формулата за обединяване в първата клетка и след това я копирайте в други клетки, като плъзнете дръжката за запълване (малкия квадрат, който се появява в долния десен ъгъл на избраната клетка).

Например, за да комбинирате две колони (колона А и В), като разделите стойностите с интервал, формулата в C2, копирана надолу, е:

=CONCATENATE(A2, " ", B2)

Или

= A2 & " " & B2 Съвет: Бърз начин за копиране на формулата надолу по колоната е да изберете клетката с формулата и да щракнете два пъти върху дръжката за запълване.

За повече информация вижте Как да обединим две колони в Excel, без да губим данни.

Комбиниране на текст и цифри, като запазвате форматирането

Когато конкатенирате текстов низ с число, процент или дата, може да искате да запазите оригиналното форматиране на цифровата стойност или да я покажете по различен начин. Това може да стане, като въведете код за форматиране във функцията TEXT, която вграждате във формулата за конкатениране.

В началото на този урок вече разгледахме формула, която обединява текст и дата.

А ето и още няколко примера за комбинирани формули текст и номер :

Число с 2 знака след десетичната запетая и знака $:

=A2 & " " & TEXT(B2, "$#,#0.00")

Число без незначителни нули и знака $:

=A2 & " " & TEXT(B2, "0.#")

Дробно число:

=A2 & " " & TEXT(B2, "# ?/???")

Конкатенация текст и процент , формулите са:

Процент с два знака след десетичната запетая:

=A12 & " " & TEXT(B12, "0.00%")

Закръглени цели проценти:

=A12 & " " & TEXT(B12, "0%")

Как да конкатенирате диапазон от клетки в Excel

Комбинирането на стойности от няколко клетки може да отнеме известно усилие, тъй като функцията CONCATENATE на Excel не приема масиви.

За да обедините няколко клетки, например от A1 до A4, трябва да използвате една от следните формули:

=CONCATENATE(A1, A2, A3, A4)

или

=A1 & A2 & A3 & A4

Когато комбинирате сравнително малка група клетки, не е проблем да въведете всички препратки. Голям диапазон би бил досаден за предоставяне, като се въвежда ръчно всяка отделна препратка. По-долу ще намерите 3 метода за бързо обединяване на диапазони в Excel.

Метод 1. Натиснете CTRL, за да изберете няколко клетки

За да изберете бързо няколко клетки, можете да натиснете и задържите клавиша Ctrl, като щракнете върху всяка клетка, която искате да включите във формулата. Ето и подробните стъпки:

1. Изберете клетка, в която искате да въведете формулата.
2. Въведете =CONCATENATE( в тази клетка или в лентата с формули.
3. Натиснете и задръжте Ctrl и щракнете върху всяка клетка, която искате да обедините.
4. Отпуснете бутона Ctrl, въведете затварящата скоба и натиснете Enter .

Метод 2: Използвайте функцията TRANSPOSE, за да получите всички стойности на клетките

Когато диапазонът се състои от десетки или стотици клетки, предишният метод може да не е достатъчно бърз, тъй като изисква щракване върху всяка клетка. В този случай можете да използвате функцията TRANSPOSE, за да върнете масив от стойности и след това да ги обедините с един замах.

1. В клетката, в която искате да се появи резултатът, въведете формулата TRANSPOSE, например:

   =TRANSPOSE(A1:A10)

2. В лентата на формулите натиснете F9, за да замените формулата с изчислени стойности. В резултат на това ще получите масив от стойности, които трябва да бъдат конкатенирани.
3. Изтрийте къдравите скоби около масива.
4. Въведете =CONCATENATE( преди първата стойност, след това въведете затварящата скоба след последната стойност и натиснете Enter .

Забележка. Резултатът от тази формула е статичен Ако изходните данни се променят, ще трябва да повторите процеса.

Метод 3. Използване на функцията CONCAT

В Excel 365 и Excel 2021 тази проста формула ще свърже диапазон от клетки за миг:

=CONCAT(A1:A10)

Метод 4. Използване на добавката Merge Cells

Бърз начин без формули за обединяване на всеки диапазон в Excel е да използвате добавката Merge Cells с " Сливане на всички области в избора " е изключена, както е показано в Комбиниране на стойности от няколко клетки в една клетка.

Оператор "&" в Excel срещу функцията CONCATENATE

Много потребители се чудят кой е по-ефективният начин за обединяване на низове в Excel - функцията CONCATENATE или операторът "&".

Единствената реална разлика е ограничението от 255 низа на функцията CONCATENATE и липсата на такова ограничение при използването на амперсанд. Освен това няма разлика между тези два метода, нито пък има разлика в скоростта между формулите CONCATENATE и "&".

И тъй като 255 е наистина голямо число и едва ли някога ще ви се наложи да комбинирате толкова много низове в реалната работа, разликата се свежда до удобство и лекота на използване. Някои потребители намират формулите CONCATENATE за по-лесни за четене, аз лично предпочитам да използвам метода "&". Така че просто се придържайте към техниката, която ви е по-удобна.

Противоположност на CONCATENATE в Excel (разделяне на клетки)

Противоположното на конкатенацията в Excel е разделянето на съдържанието на една клетка в няколко клетки. Това може да се направи по няколко различни начина:

• Функция "Текст към колони
• Опция Flash Fill в Excel 2013 и по-нови версии
• Функция TEXTSPLIT в Excel 365
• Персонализирани формули за разделяне на клетки (MID, RIGHT, LEFT и др.)

Можете също така да намерите полезна информация в тази статия: Как да разедините клетки в Excel.

Конкатенация в Excel с добавката Merge Cells

С приставката Merge Cells, включена в Ultimate Suite for Excel, можете ефективно да правите и двете:

• Обединяване на няколко клетки в една без загуба на данни.
• Конкатенация стойностите на няколко клетки в една клетка и ги отделете с произволен разделител по ваш избор.

Инструментът Merge Cells работи с всички версии на Excel от 2016 до 365 и може да обединява всички типове данни, включително текстови низове, числа, дати и специални символи. Двете му основни предимства са простота и бързина - всяко обединяване се извършва с няколко кликвания.

Комбиниране на стойности от няколко клетки в една клетка

За да комбинирате съдържанието на няколко клетки, избирате диапазона за обединяване и конфигурирате следните настройки:

• Под Какво да слеете , изберете Клетки в една .
• Под Комбинирайте с , въведете разделител (запетая и интервал в нашия случай).
• Изберете къде да поставите резултата.
• Най-важното е да премахнете отметката от Сливане на всички области в селекцията Тази опция контролира дали клетките се обединяват или стойностите им се конкатенират.

Комбиниране на колони ред по ред

За да обедините две или повече колони, конфигурирате настройките на "Обединяване на клетки" по подобен начин, но избирате да обедините колони в една и поставете резултатите в лявата колона.

Присъединяване на редове колона по колона

За да комбинирате данните във всеки отделен ред, колона по колона, можете да изберете:

• Обединяване на редове в един .
• Използвайте прекъсване на реда за разделител.
• Поставете резултатите в горен ред .

Резултатът може да изглежда по следния начин:

За да проверите как добавката Merge Cells ще се справи с вашите набори от данни, можете да изтеглите напълно функционална пробна версия на нашия Ultimate Suite за Excel по-долу.

Това е начинът за конкатенация в Excel. Благодаря ви, че прочетохте, и се надявам да се видим в нашия блог следващата седмица!

Налични изтегляния

Примери за формула за конкатенация (.xlsx файл)

14-дневна пробна версия на Ultimate Suite (.exe файл)