A bemutató bemutatja az XLOOKUP-ot - az új függőleges és vízszintes keresési funkciót az Excelben. A bal oldali keresés, az utolsó egyezés, a Vlookup több kritériummal és még sok más olyan dolog, amelynek elvégzéséhez korábban rakétatudományi végzettségre volt szükség, most olyan egyszerűvé vált, mint az ABC.

Amikor az Excelben keresni kell, melyik függvényt használná? A sarkalatos VLOOKUP-ot vagy annak vízszintes testvérét, a HLOOKUP-ot? Bonyolultabb esetben a kanonikus INDEX MATCH kombinációra támaszkodna, vagy a Power Query-re bízná a feladatot? A jó hír az, hogy többé nem kell választania - mindezek a módszerek helyet adnak egy sokkal erősebb és sokoldalúbb utódnak, az XLOOKUP függvénynek.

Miben jobb az XLOOKUP? Sok szempontból! Függőlegesen és vízszintesen, balra és felülről is tud keresni, több kritériummal keresni, és még egy egész oszlop vagy sor adatot is vissza tud adni, nem csak egy értéket. A Microsoftnak több mint 3 évtizedbe telt, de végre sikerült egy olyan robusztus funkciót tervezniük, amely kiküszöböli a VLOOKUP számos frusztráló hibáját és gyengeségét.

Az XLOOKUP funkció csak az Excel for Microsoft 365, az Excel 2021 és az Excel for the web programokban érhető el.

Excel XLOOKUP funkció - szintaxis és felhasználások

Az Excel XLOOKUP függvénye egy tartományban vagy egy tömbben keres egy megadott értéket, és visszaadja a kapcsolódó értéket egy másik oszlopból. Függőlegesen és vízszintesen is kereshet, és pontos egyezést (alapértelmezett), közelítő (legközelebbi) egyezést vagy helyettesítő (részleges) egyezést végezhet.

Az XLOOKUP függvény szintaxisa a következő:

Az első 3 argumentum kötelező, az utolsó három pedig opcionális.

• Lookup_value - a keresendő érték.
• Lookup_array - a tartomány vagy tömb, ahol keresni kell.
• Return_array - a tartomány vagy tömb, amelyből az értékeket vissza kell adni.
• If_not_found [opcionális] - az érték, amelyet akkor ad vissza, ha nem találunk egyezést. Ha elhagyja, #N/A hibaüzenet érkezik vissza.
• Match_mode [opcionális] - az elvégzendő egyezés típusa:
  • 0 vagy elhagyva (alapértelmezett) - pontos egyezés. Ha nem található, #N/A hibaüzenet érkezik vissza.
  • -1 - pontos egyezés vagy a következő kisebb érték. Ha nem találunk pontos egyezést, a következő kisebb értéket kapjuk vissza.
  • 1 - pontos egyezés vagy a következő nagyobb érték. Ha nem találunk pontos egyezést, a következő nagyobb értéket kapjuk vissza.
  • 2 - helyettesítő karakteres egyezés.
• Keresés_mód [opcionális] - a keresés iránya:
  • 1 vagy elhagyva (alapértelmezett) - az elsőtől az utolsóig történő keresés.
  • -1 - fordított sorrendben, az utolsótól az elsőig történő keresés.
  • 2 - bináris keresés az adatokon növekvő sorrendben.
  • -2 - bináris keresés az adatokon csökkenő sorrendben.

  A Microsoft szerint, bináris keresés egy speciális algoritmus, amely egy rendezett tömbön belül úgy találja meg egy keresési érték pozícióját, hogy összehasonlítja azt a tömb középső elemével. A bináris keresés sokkal gyorsabb, mint a hagyományos keresés, de csak rendezett adatokon működik helyesen.

Alapvető XLOOKUP formula

Hogy jobban megértsük, építsünk egy Xlookup képletet a legegyszerűbb formában, hogy pontos keresést végezzünk. Ehhez csak az első 3 argumentumra lesz szükségünk.

Tegyük fel, hogy van egy összefoglaló táblázata a Föld öt óceánjára vonatkozó információkkal. Egy adott óceán területét szeretné megkapni F1-ben ( lookup_value Az A2:A6-ban szereplő óceánnevekkel ( lookup_array ) és a C2:C6 területek ( return_array ), a képlet a következő:

=XLOOKUP(F1, A2:A6, C2:C6)

Lefordítva egyszerű angolra, azt mondja: keresse meg az F1 értéket az A2:A6-ban és adja vissza az értéket a C2:C6-ban ugyanabban a sorban. Nincs oszlopindex szám, nincs rendezés, nincs más nevetséges furcsasága a Vlookup-nak! Egyszerűen csak működik :)

XLOOKUP vs. VLOOKUP az Excelben

A hagyományos VLOOKUP-hoz képest az XLOOKUP-nak számos előnye van. Miben jobb, mint a VLOOKUP? Íme a 10 legjobb funkció, amelyek az Excel bármely más keresési funkcióját felülmúlják:

1. Függőleges és vízszintes keresés Az XLOOKUP funkció nevét onnan kapta, hogy képes függőlegesen és vízszintesen is felfelé nézni.
2. Nézzen bármelyik irányba: jobbra, balra, alulra vagy felfelé. Míg a VLOOKUP csak a legbaloldali oszlopban, a HLOOKUP pedig a legfelső sorban kereshet, addig az XLOOKUP nem rendelkezik ilyen korlátozásokkal. A hírhedt bal oldali keresés az Excelben többé nem jelent gondot!
3. Alapértelmezés szerint pontos egyezés A legtöbb esetben pontos egyezést keres, és az XLOOKUP alapértelmezés szerint ezt adja vissza (ellentétben a VLOOKUP funkcióval, amely alapértelmezés szerint közelítő egyezést ad vissza). Természetesen az XLOOKUP funkcióval szükség esetén közelítő egyezést is végezhet.
4. Részleges egyezés helyettesítő karakterekkel Ha a keresési értéknek csak egy részét ismeri, de nem az egészet, akkor jól jön a vadkártyás egyezés.
5. Keresés fordított sorrendben Korábban az utolsó előforduláshoz meg kellett fordítania a forrásadatok sorrendjét. Most egyszerűen beállítja a search_mode argumentumot -1-re, hogy az Xlookup-képlet hátulról kezdje a keresést, és az utolsó egyezést adja vissza.
6. Több érték visszaadása . A manipulálással a return_array argumentummal a keresési értékhez kapcsolódó adatok egy teljes sorát vagy oszlopát húzhatja ki.
7. Keresés több kritériummal Az Excel XLOOKUP natívan kezeli a tömböket, ami lehetővé teszi a több kritériummal történő keresést.
8. Ha a hiba funkcionalitás Hagyományosan az IFNA függvényt használjuk a #N/A hibák csapdázására. Az XLOOKUP ezt a funkciót beépíti a if_not_found argumentum, amely lehetővé teszi a saját szöveg kimenetét, ha nem találunk érvényes egyezést.
9. Oszlopok beszúrása/törlése A VLOOKUP egyik legidegesítőbb problémája, hogy az oszlopok hozzáadása vagy eltávolítása megtöri a képletet, mivel a visszatérő oszlopot az indexszáma azonosítja. Az XLOOKUP esetében a visszatérési tartományt adja meg, nem pedig a számot, ami azt jelenti, hogy annyi oszlopot illeszthet be és távolíthat el, amennyit csak akar anélkül, hogy bármit megszakítana.
10. Jobb teljesítmény A VLOOKUP lelassíthatja a munkalapokat, mivel a teljes táblázatot bevonja a számításokba, ami azt eredményezi, hogy sokkal több cellát dolgoz fel, mint amennyire valójában szükség van. Az XLOOKUP csak azokat a keresési és visszatérési tömböket kezeli, amelyektől valóban függ.

Az XLOOKUP használata az Excelben - képletpéldák

A következő példák a leghasznosabb XLOOKUP funkciókat mutatják be működés közben. Ezen kívül felfedezhet néhány nem triviális felhasználási módot, amelyek új szintre emelik az Excel keresési készségeit.

Nézz fel függőlegesen és vízszintesen

A Microsoft Excel korábban két funkcióval rendelkezett a különböző keresési típusokhoz, mindegyiknek saját szintaxisa és használati szabályai voltak: a VLOOKUP függőlegesen egy oszlopban való kereséshez, a HLOOKUP pedig vízszintesen egy sorban való kereséshez.

Az XLOOKUP függvény mindkettőre képes ugyanazzal a szintaxissal. A különbség abban van, hogy mit adunk meg a keresési és visszatérési tömbök számára.

A v-kereséshez adjon meg oszlopokat:

=XLOOKUP(E1, A2:A6, B2:B6)

A h-keresésnél oszlopok helyett sorokat adjon meg:

=XLOOKUP(I1, B1:F1, B2:F2)

A bal oldali keresés natívan történik

Az Excel korábbi verzióiban az INDEX MATCH formula volt az egyetlen megbízható módja annak, hogy balra vagy felülre nézzen. Most már nem kell két olyan függvényt kombinálnia, ahol egy is elegendő lenne. Csak adja meg a célkeresési tömböt, és az XLOOKUP gond nélkül kezeli azt, függetlenül annak helyétől.

Példaként adjuk hozzá a Rangsor A cél az, hogy megkapjuk az F1-ben az óceán bemeneti rangját. A VLOOKUP itt megbotlana, mert csak a keresési oszloptól jobbra lévő oszlopból tud értéket visszaadni. Az Xlookup formula könnyedén megbirkózik vele:

=XLOOKUP(F1, B2:B6, A2:A6)

Hasonló módon, a sorokban történő vízszintes keresésnél is fentebb nézhetünk.

XLOOKUP pontos és közelítő egyezéssel

Az egyezés viselkedését az 5. argumentum, az úgynevezett match_mode Alapértelmezés szerint pontos egyezés történik.

Kérjük, figyeljen arra, hogy még akkor is, ha egy hozzávetőleges egyezést választ ( match_mode 1 vagy -1), a függvény továbbra is a pontos egyezést keresi először. A különbség abban van, hogy mit ad vissza, ha nem talál pontos keresési értéket.

Match_mode argumentum:

• 0 vagy elhagyva - pontos egyezés; ha nem található - #N/A hiba.
• -1 - pontos egyezés; ha nem található - a következő kisebb elem.
• 1 - pontos egyezés; ha nem található - következő nagyobb tétel.

Pontos egyezés XLOOKUP

Ezt az opciót valószínűleg az Excelben végzett keresések 99%-ában használja. Mivel a pontos egyezés az XLOOKUP alapértelmezett viselkedése, elhagyhatja a match_mode és csak az első 3 szükséges argumentumot adja meg.

Bizonyos helyzetekben azonban a pontos egyezés nem fog működni. Tipikus forgatókönyv, amikor a keresési táblázat nem tartalmazza az összes értéket, hanem inkább "mérföldköveket" vagy "korlátokat", mint például mennyiségi alapú árengedmények, értékesítés alapú jutalékok stb.

A mintánkban szereplő keresőtáblázat a vizsgaeredmények és az osztályzatok közötti összefüggést mutatja. Amint az alábbi képernyőképen látható, a pontos egyezés csak akkor működik, ha egy adott tanuló pontszáma pontosan megegyezik a keresőtáblában szereplő értékkel (mint Christian a 3. sorban). Minden más esetben #N/A hiba érkezik vissza.

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6)

Ahhoz, hogy az #N/A hibák helyett az osztályzatokat kapjuk, közelítő egyezést kell keresnünk, ahogy a következő példában látható.

Hozzávetőleges egyezés XLOOKUP

A hozzávetőleges keresés elvégzéséhez állítsa be a match_mode argumentum -1 vagy 1, attól függően, hogy az adatok hogyan vannak szervezve.

A mi esetünkben a keresőtáblázat az osztályzatok alsó határait tartalmazza. Tehát a következő értékeket állítjuk be match_mode -1-re, hogy a következő kisebb értéket keresse, ha nem talál pontos egyezést:

=XLOOKUP(F11, $B$11:$B$15, $C$11:$C$15, ,-1)

Például Brian pontszáma 98 (F2). A képlet ezt a keresési értéket keresi a B2:B6 között, de nem találja. Ezután a következő kisebb elemet keresi, és megtalálja a 90-et, ami az A osztályzatnak felel meg:

Ha a keresőtáblánk tartalmazná az osztályzatok felső határértékeit, akkor a következő értéket állítanánk be match_mode 1-re, hogy a következő nagyobb elemet keresse, ha a pontos egyezés nem sikerül:

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6, ,1)

A képlet megkeresi a 98-as értéket, és ismét nem találja meg. Ezúttal a következő nagyobb értéket keresi, és a 100-as értéket kapja, ami az A osztályzatnak felel meg:

Tipp: Amikor egy Xlookup-képletet több cellába másol, rögzítse a keresési vagy visszatérési tartományokat abszolút cellahivatkozásokkal (például $B$2:$B$6), hogy megakadályozza azok változását.

XLOOKUP részleges egyezéssel (jokerek)

A részleges egyezés kereséséhez állítsa be a match_mode argumentumot 2-re, ami utasítja az XLOOKUP függvényt a helyettesítő karakterek feldolgozására:

• A csillag (*) - bármilyen karaktersorozatot jelöl.
• A kérdőjel (?) - bármelyik karaktert jelöli.

Hogy lássa, hogyan működik, tekintse meg a következő példát. Az A oszlopban van néhány okostelefon-modell, a B oszlopban pedig az akkumulátoruk kapacitása. Kíváncsi egy bizonyos okostelefon akkumulátorára. A probléma az, hogy nem biztos benne, hogy pontosan úgy tudja beírni a modell nevét, ahogy az az A oszlopban szerepel. Ennek kiküszöbölésére írja be azt a részt, amelyik biztosan ott van, és helyettesítse a maradékot.karakterek vadkártyákkal.

Ha például az iPhone X akkumulátoráról szeretne információt kapni, használja ezt a képletet:

=XLOOKUP("*iphone X*", A2:A8, B2:B8, ,2)

Vagy írja be a keresési érték ismert részét valamelyik cellába, és kapcsolja össze a cellahivatkozást a helyettesítő karakterekkel:

=XLOOKUP("*"&E1& "*", A2:A8, B2:B8, ,2)

XLOOKUP fordított sorrendben az utolsó előforduláshoz

Abban az esetben, ha a táblázat a keresési érték több előfordulását tartalmazza, néha szükség lehet arra, hogy visszaadja a utolsó mérkőzés Ehhez állítsa be az Xlookup-képletet úgy, hogy fordított sorrendben keressen.

A keresés irányát a 6. argumentum határozza meg. search_mode :

• 1 vagy elhagyva (alapértelmezett) - az elsőtől az utolsó értékig keres, azaz függőleges keresés esetén felülről lefelé, vízszintes keresés esetén balról jobbra.
• -1 - fordított sorrendben keres az utolsó értéktől az első értékig.

Példaként adjuk vissza egy adott értékesítő által végzett utolsó eladást. Ehhez összeállítjuk az első három szükséges argumentumot (G1 a lookup_value , B2:B9 esetében lookup_array , és D2:D9 a return_array ), és az 5. argumentumba -1-et teszünk:

=XLOOKUP(G1, B2:B9, D2:D9, , ,-1)

Egyszerű és könnyű, nem igaz?

XLOOKUP több oszlop vagy sor visszaadásához

Az XLOOKUP még egy lenyűgöző tulajdonsága, hogy képes egynél több értéket is visszaadni ugyanarra a találatra vonatkozóan. Mindezt a szabványos szintaxissal és mindenféle extra manipuláció nélkül!

Tegyük fel, hogy az alábbi táblázatból szeretnénk lekérdezni az összes adatot, amely az adott értékesítőre (F2) vonatkozik. Ehhez egy tartományt kell megadnunk, nem egy oszlopot vagy sort, hanem egy tartományt a return_array érv:

=XLOOKUP(F2, A2:A7, B2:D7)

A képletet az eredménytartomány bal felső cellájába írja be, és az Excel automatikusan kiönti az eredményeket a szomszédos üres cellákba. Esetünkben a visszatérési tömb (B2:D7) 3 oszlopot tartalmaz ( Dátum , Tétel és Összeg ), és mindhárom értéket a G2:I2 tartományban kapjuk vissza.

Ha inkább függőlegesen szeretné elrendezni az eredményeket egy oszlopban, fészkelje be az XLOOKUP-ot a TRANSPOSE függvénybe, hogy megfordítsa a visszaadott tömböt:

=TRANSPOSE(XLOOKUP(G1, A2:A7, B2:D7))

Hasonló módon egy teljes adatoszlopot is visszaadhat, mondjuk a Összeg oszlopot. Ehhez használja az F1-es cellát, amely az "Amount" szót tartalmazza. lookup_value , az A1:D1 tartomány, amely az oszlopfejléceket tartalmazza, mint lookup_array és az A2:D7 tartomány, amely az összes adatot tartalmazza, mint return_array .

=XLOOKUP(F1, A1:D1, A2:D7)

Megjegyzés: Mivel több értéket tölt ki a szomszédos cellákba, győződjön meg róla, hogy van-e elég üres cella jobbra vagy lefelé. Ha az Excel nem talál elég üres cellát, #SPILL! hiba lép fel.

Tipp. Az XLOOKUP nemcsak több bejegyzést adhat vissza, hanem azokat más, Ön által megadott értékekkel is helyettesítheti. Egy példa az ilyen tömeges helyettesítésre itt található: Hogyan keressünk és helyettesítsünk több értéket az XLOOKUP segítségével.

XLOOKUP több kritériummal

Az XLOOKUP másik nagy előnye, hogy natívan kezeli a tömböket. Ennek a képességnek köszönhetően több kritériumot is kiértékelhet közvetlenül a lookup_array érv:

Hogyan működik ez a képlet : Az egyes kritériumtesztek eredménye egy TRUE és FALSE értékekből álló tömb. A tömbök szorzása a TRUE és FALSE értékeket 1-re, illetve 0-ra alakítja, és így kapjuk meg a végső keresési tömböt. Mint tudjuk, a 0-val való szorzás mindig nullát ad, így a keresési tömbben csak azok az elemek jelennek meg 1-gyel, amelyek megfelelnek az összes kritériumnak. És mivel a keresési értékünk "1", az Excel az első "1"-t veszi a lookup_array (első találat) és visszaadja a return_array ugyanabban a helyzetben.

Hogy lássuk a képletet működés közben, húzzunk ki egy összeget a D2:D10-ből ( return_array ) a következő feltételekkel:

• Kritériumok1 (dátum) = G1
• Criteria2 (értékesítő) = G2
• Kritériumok3 (tétel) = G3

A2:A10-es dátumokkal ( criteria_range1 ), az eladók nevei a B2:B10-ben ( criteria_range2 ) és a C2:C10-es tételek ( criteria_range3 ), a képlet a következő formát ölti:

=XLOOKUP(1, (B2:B10=G1) * (A2:A10=G2) * (C2:C10=G3), D2:D10)

Bár az Excel XLOOKUP függvénye tömböket dolgoz fel, szabályos képletként működik, és a szokásos Enter billentyűleütéssel fejeződik be.

A több kritériumot tartalmazó XLOOKUP formula nem korlátozódik az "egyenlő" feltételekre. Szabadon használhat más logikai operátorokat is. Például, ha a G1 vagy korábbi időpontban leadott megrendeléseket szeretné szűrni, az első kritériumba írja be az "<=G1" szót:

=XLOOKUP(1, (A2:A10<=G1) * (B2:B10=G2) * (C2:C10=G3), D2:D10)

Dupla XLOOKUP

Ha egy adott sor és oszlop metszéspontjában lévő értéket szeretnénk megtalálni, akkor végezzük el az ún. kettős keresés vagy mátrix keresés Igen, az Excel XLOOKUP is képes erre! Egyszerűen csak beágyazza az egyik függvényt a másikba:

Hogyan működik ez a képlet : A képlet az XLOOKUP azon képességén alapul, hogy egy teljes sort vagy oszlopot tud visszaadni. A belső függvény megkeresi a keresési értékét, és visszaadja a kapcsolódó adatok egy oszlopát vagy sorát. Ez a tömb a külső függvényhez kerül, mint a(z) return_array .

Ebben a példában egy adott értékesítő által egy adott negyedévben végzett eladásokat fogunk megtalálni. Ehhez a H1 (értékesítő neve) és a H2 (negyedév) értékeket adjuk meg, és kétirányú Xlookupot végzünk a következő képlettel:

=XLOOKUP(H1, A2:A6, XLOOKUP(H2, B1:E1, B2:E6))

Vagy fordítva:

=XLOOKUP(H2, B1:E1, XLOOKUP(H1, A2:A6, B2:E6))

Ahol A2:A6 az eladók neve, B1:E1 a negyedévek (oszlopcímek), B2:E6 pedig az adatértékek.

A kétirányú keresés INDEX Match formulával és néhány más módon is elvégezhető. További információért lásd: Kétirányú keresés az Excelben.

Ha Hiba XLOOKUP

Ha a keresési érték nem található, az Excel XLOOKUP egy #N/A hibaüzenetet ad vissza. Ez a szakértő felhasználók számára meglehetősen ismerős és érthető, a kezdők számára azonban meglehetősen zavaró lehet. Ha a szabványos hibaüzenetet felhasználóbarát üzenettel szeretné helyettesíteni, írja be saját szövegét a 4. argumentumba, amelynek neve if_not_found .

Visszatérve a legelső példához, amelyet ebben az oktatóanyagban tárgyaltunk. Ha valaki egy érvénytelen óceánnevet ír be az E1-be, a következő képlet kifejezetten azt mondja neki, hogy "Nem találtunk egyezést":

=XLOOKUP(E1, A2:A6, B2:B6, "Nincs találat")

Megjegyzések:

• A if_not_found argumentum csak az #N/A hibákat csapdázza, nem az összes hibát.
• Az #N/A hibák IFNA és VLOOKUP segítségével is kezelhetők, de a szintaxis kicsit bonyolultabb és a képlet hosszabb.

Nagy- és kisbetű-érzékeny XLOOKUP

Alapértelmezés szerint az XLOOKUP függvény a kis- és nagybetűket azonos karaktereknek tekinti. Ha a kis- és nagybetűket is figyelembe akarja venni, használja az EXACT függvényt a lookup_array érv:

Hogyan működik ez a képlet : Az EXACT függvény összehasonlítja a keresési értéket a keresési tömb minden egyes értékével, és TRUE-t ad vissza, ha pontosan megegyeznek, beleértve a betűket is, ellenkező esetben FALSE-t. Ez a logikai értékek tömbje megy a lookup_array Az XLOOKUP az XLOOKUP argumentuma. Az XLOOKUP a fenti tömbben a TRUE értéket keresi, és a visszatérő tömbben visszaadja az egyezést.

Például, a B2:B7 árat ( return_array ) az E1-ben szereplő tételre ( lookup_value) az E2-ben szereplő képlet a következő:

=XLOOKUP(TRUE, EXACT(E1, A2:A7), B2:B7, "Nem található")

Megjegyzés: Ha a keresési tömbben két vagy több pontosan azonos érték van (beleértve a betűket is), akkor az első talált egyezést adja vissza.

Excel XLOOKUP nem működik

Ha a képlet nem működik megfelelően, vagy hibát eredményez, annak valószínűleg a következő okai vannak:

Az XLOOKUP nem áll rendelkezésre az Excelben

Az XLOOKUP funkció nem visszafelé kompatibilis. Csak az Excel for Microsoft 365 és az Excel 2021 programban érhető el, a korábbi verziókban nem jelenik meg.

Az XLOOKUP rossz eredményt ad vissza

Ha a nyilvánvalóan helyes Xlookup-képlet rossz értéket ad vissza, akkor nagy az esélye, hogy a keresési vagy visszatérési tartomány "eltolódott", amikor a képletet lefelé vagy átmásolták. Hogy ez ne történhessen meg, mindig rögzítse mindkét tartományt abszolút cellahivatkozásokkal (például $A$2:$A$10).

XLOOKUP visszatér #N/A hiba

Az #N/A hiba csak azt jelenti, hogy a keresési érték nem található. A hiba kijavításához próbáljon meg közelítő egyezést keresni, vagy tájékoztassa a felhasználókat, hogy nem találtak egyezést.

XLOOKUP visszatér #VALUE hiba

#VALUE! hiba lép fel, ha a keresési és a visszatérési tömbök nem kompatibilis méretűek. Például nem lehetséges egy vízszintes tömbben keresni és egy függőleges tömbből értékeket visszaadni.

XLOOKUP visszatér #REF hiba

Két különböző munkafüzet közötti kereséskor, amelyek közül az egyik le van zárva, #REF! hiba lép fel. A hiba kijavításához egyszerűen nyissa meg mindkét fájlt.

Mint most láthattad, az XLOOKUP-nak számos fantasztikus funkciója van, amelyek az Excel szinte bármilyen keresési funkciójává teszik. Köszönöm, hogy elolvastad, és remélem, hogy jövő héten találkozunk a blogunkon!

Gyakorlati munkafüzet letölthető

Excel XLOOKUP képlet példák (.xlsx fájl)