Tento návod predstavuje XLOOKUP - novú funkciu na vertikálne a horizontálne vyhľadávanie v programe Excel. Ľavé vyhľadávanie, posledná zhoda, Vlookup s viacerými kritériami a mnoho ďalších vecí, ktoré si predtým vyžadovali raketové vedecké vzdelanie, sú teraz také jednoduché ako ABC.

Kedykoľvek potrebujete v Exceli vyhľadávať, ktorú funkciu použijete? Je to základná funkcia VLOOKUP alebo jej horizontálny súrodenec HLOOKUP? V zložitejšom prípade sa spoľahnete na kanonickú kombináciu INDEX MATCH alebo zveríte úlohu Power Query? Dobrou správou je, že si už nemusíte vyberať - všetky tieto metódy uvoľňujú miesto výkonnejšiemu a univerzálnejšiemu nástupcovi, funkcii XLOOKUP.

V čom je XLOOKUP lepší? V mnohých ohľadoch! Dokáže vyhľadávať vertikálne aj horizontálne, vľavo aj hore, vyhľadávať podľa viacerých kritérií a dokonca vrátiť celý stĺpec alebo riadok údajov, nielen jednu hodnotu. Spoločnosti Microsoft to trvalo viac ako tri desaťročia, ale nakoniec sa jej podarilo navrhnúť robustnú funkciu, ktorá prekonáva mnohé frustrujúce chyby a nedostatky VLOOKUP.

Aký je háčik? Bohužiaľ, jeden tu je. Funkcia XLOOKUP je k dispozícii len v aplikáciách Excel pre Microsoft 365, Excel 2021 a Excel pre web.

Funkcia Excel XLOOKUP - syntax a použitie

Funkcia XLOOKUP v programe Excel vyhľadá rozsah alebo pole pre zadanú hodnotu a vráti súvisiacu hodnotu z iného stĺpca. Môže vyhľadávať vertikálne aj horizontálne a vykonať presnú (predvolená), približnú (najbližšiu) alebo zástupnú (čiastočnú) zhodu.

Syntax funkcie XLOOKUP je nasledujúca:

Prvé tri argumenty sú povinné a posledné tri sú nepovinné.

• Lookup_value - hodnota, ktorá sa má vyhľadať.
• Lookup_array - rozsah alebo pole, v ktorom sa má vyhľadávať.
• Return_array - rozsah alebo pole, z ktorého sa majú vrátiť hodnoty.
• If_not_found [voliteľné] - hodnota, ktorá sa vráti, ak sa nenájde žiadna zhoda. Ak sa vynechá, vráti sa chyba #N/A.
• Match_mode [nepovinné] - typ zhody, ktorá sa má vykonať:
  • 0 alebo vynechať (predvolené) - presná zhoda. Ak sa nenájde, vráti sa chyba #N/A.
  • -1 - presná zhoda alebo najbližšia menšia hodnota. Ak sa nenájde presná zhoda, vráti sa najbližšia menšia hodnota.
  • 1 - presná zhoda alebo najbližšia väčšia hodnota. Ak sa nenájde presná zhoda, vráti sa najbližšia väčšia hodnota.
  • 2 - zhoda so zástupným znakom.
• Režim vyhľadávania [nepovinné] - smer vyhľadávania:
  • 1 alebo vynechať (predvolené) - vyhľadávanie od prvého po posledný.
  • -1 - vyhľadávanie v opačnom poradí, od posledného po prvé.
  • 2 - binárne vyhľadávanie v údajoch zoradených vzostupne.
  • -2 - binárne vyhľadávanie v údajoch zoradených zostupne.

  Podľa spoločnosti Microsoft, binárne vyhľadávanie je zahrnutý pre pokročilých používateľov. Je to špeciálny algoritmus, ktorý nájde pozíciu hľadanej hodnoty v rámci zoradeného poľa porovnaním s prostredným prvkom poľa. Binárne vyhľadávanie je oveľa rýchlejšie ako bežné vyhľadávanie, ale správne funguje len na zoradených údajoch.

Základný vzorec XLOOKUP

Aby sme tomu lepšie porozumeli, vytvorme vzorec Xlookup v jeho najjednoduchšej podobe na vykonanie presného vyhľadávania. Na to budeme potrebovať len prvé 3 argumenty.

Predpokladajme, že máte súhrnnú tabuľku s informáciami o piatich oceánoch na Zemi. Chcete získať plochu konkrétneho vstupu do oceánu v F1 ( lookup_value ). S názvami oceánov v A2:A6 ( lookup_array ) a plochy v C2:C6 ( return_array ), vzorec je nasledovný:

=XLOOKUP(F1, A2:A6, C2:C6)

Preložené do jednoduchej angličtiny to znamená: vyhľadaj hodnotu F1 v A2:A6 a vráť hodnotu z C2:C6 v tom istom riadku. Žiadne čísla indexov stĺpcov, žiadne triedenie, žiadne iné smiešne vychytávky Vlookup! Jednoducho to funguje :)

XLOOKUP vs. VLOOKUP v programe Excel

V porovnaní s tradičnou funkciou VLOOKUP má XLOOKUP mnoho výhod. V čom je lepšia ako VLOOKUP? Tu je zoznam 10 najlepších funkcií, ktoré vyrážajú dych všetkým ostatným vyhľadávacím funkciám v programe Excel:

1. Vertikálne a horizontálne vyhľadávanie . Funkcia XLOOKUP dostala svoj názov vďaka schopnosti vyhľadávať vertikálne aj horizontálne.
2. Pozrite sa ľubovoľným smerom: doprava, doľava, nadol alebo nahor . Zatiaľ čo VLOOKUP môže vyhľadávať len v ľavom stĺpci a HLOOKUP v najvyššom riadku, XLOOKUP takéto obmedzenia nemá. Notoricky známe vyhľadávanie v ľavom stĺpci v Exceli už nie je trápením!
3. Presná zhoda v predvolenom nastavení Vo väčšine situácií budete hľadať presnú zhodu a funkcia XLOOKUP ju štandardne vracia (na rozdiel od funkcie VLOOKUP, ktorá štandardne používa približnú zhodu). Samozrejme, v prípade potreby môžete funkciu XLOOKUP nastaviť aj na približnú zhodu.
4. Čiastočná zhoda so zástupnými znakmi Ak poznáte len časť hodnoty vyhľadávania, nie celú, hodí sa vám zhoda so zástupným znakom.
5. Vyhľadávanie v opačnom poradí Predtým ste museli obracať poradie zdrojových údajov, aby ste získali posledný výskyt. Teraz stačí nastaviť search_mode na -1, aby ste prinútili vzorec Xlookup vyhľadávať od zadnej strany a vrátiť poslednú zhodu.
6. Vrátenie viacerých hodnôt . Manipuláciou s return_array môžete vytiahnuť celý riadok alebo stĺpec údajov súvisiacich s hodnotou vyhľadávania.
7. Vyhľadávanie pomocou viacerých kritérií . Excel XLOOKUP natívne spracúva polia, čo umožňuje vykonávať vyhľadávanie s viacerými kritériami.
8. Ak je chybová funkcia Tradične používame funkciu IFNA na zachytenie chýb #N/A. XLOOKUP zahŕňa túto funkciu v if_not_found argument, ktorý umožňuje vypisovať vlastný text, ak sa nenájde žiadna platná zhoda.
9. Vkladanie/mazanie stĺpcov . Jedným z najotravnejších problémov pri VLOOKUP je, že pridávanie alebo odstraňovanie stĺpcov narúša vzorec, pretože návratový stĺpec je identifikovaný číslom indexu. Pri XLOOKUP zadávate návratový rozsah, nie číslo, čo znamená, že môžete vkladať a odstraňovať toľko stĺpcov, koľko potrebujete, bez toho, aby ste niečo porušili.
10. Lepší výkon . VLOOKUP by mohol spomaliť vaše pracovné hárky, pretože do výpočtov zahŕňa celú tabuľku, čo vedie k spracovaniu oveľa väčšieho počtu buniek, než je skutočne potrebné. XLOOKUP spracúva iba vyhľadávacie a návratové polia, od ktorých skutočne závisí.

Ako používať XLOOKUP v programe Excel - príklady vzorcov

Nasledujúce príklady demonštrujú najužitočnejšie funkcie XLOOKUP v praxi. Okrem toho objavíte niekoľko netriviálnych spôsobov použitia, ktoré posunú vaše znalosti vyhľadávania v programe Excel na novú úroveň.

Pozrite sa nahor vertikálne a horizontálne

V programe Microsoft Excel sa používali dve funkcie pre rôzne typy vyhľadávania, pričom každá z nich mala vlastnú syntax a pravidlá používania: VLOOKUP na vertikálne vyhľadávanie v stĺpci a HLOOKUP na horizontálne vyhľadávanie v riadku.

Funkcia XLOOKUP dokáže robiť obidve funkcie s rovnakou syntaxou. Rozdiel je v tom, čo poskytujete pre vyhľadávacie a návratové polia.

Pri vyhľadávaní v zadajte stĺpce:

=XLOOKUP(E1, A2:A6, B2:B6)

Pri h-lookup zadávajte namiesto stĺpcov riadky:

=XLOOKUP(I1, B1:F1, B2:F2)

Vyhľadávanie vľavo vykonané natívne

V predchádzajúcich verziách Excelu bol vzorec INDEX MATCH jediným spoľahlivým spôsobom, ako sa pozrieť doľava alebo hore. Teraz už nemusíte kombinovať dve funkcie tam, kde by stačila jedna. Stačí zadať cieľové vyhľadávacie pole a XLOOKUP ho bez problémov spracuje bez ohľadu na jeho umiestnenie.

Ako príklad pridáme Poradie Cieľom je získať poradie oceánskeho vstupu v F1. VLOOKUP by tu narazil, pretože môže vrátiť iba hodnotu zo stĺpca napravo od vyhľadávacieho stĺpca. Vzorec Xlookup si s tým hravo poradí:

=XLOOKUP(F1, B2:B6, A2:A6)

Podobným spôsobom sa môžete pozrieť vyššie pri horizontálnom vyhľadávaní v riadkoch.

XLOOKUP s presnou a približnou zhodou

Správanie sa pri zápase je riadené piatym argumentom s názvom match_mode . V predvolenom nastavení sa vykoná presná zhoda.

Upozorňujeme, že aj keď si vyberiete približnú zhodu ( match_mode nastavená na 1 alebo -1), funkcia bude stále najprv hľadať presnú zhodu. Rozdiel je v tom, čo vráti, ak sa presná hodnota vyhľadávania nenájde.

Argument Match_mode:

• 0 alebo vynechaný - presná zhoda; ak sa nenájde - chyba #N/A.
• -1 - presná zhoda; ak sa nenájde - ďalšia menšia položka.
• 1 - presná zhoda; ak sa nenájde - ďalšia väčšia položka.

Presná zhoda XLOOKUP

Túto možnosť pravdepodobne používate v 99 % prípadov vyhľadávania v programe Excel. Keďže presná zhoda je predvoleným správaním programu XLOOKUP, môžete vynechať match_mode a uveďte len prvé 3 požadované argumenty.

V niektorých situáciách však presná zhoda nebude fungovať. Typickým scenárom je situácia, keď vaša vyhľadávacia tabuľka neobsahuje všetky hodnoty, ale skôr "míľniky" alebo "hranice", ako sú zľavy založené na množstve, provízie založené na predaji atď.

Naša vzorová vyhľadávacia tabuľka zobrazuje koreláciu medzi výsledkami skúšok a známkami. Ako môžete vidieť na snímke obrazovky nižšie, presná zhoda funguje len vtedy, keď sa skóre konkrétneho študenta presne zhoduje s hodnotou vo vyhľadávacej tabuľke (ako Christian v riadku 3). Vo všetkých ostatných prípadoch sa vráti chyba #N/A.

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6)

Ak chceme získať známky namiesto chýb #N/A, musíme hľadať približnú zhodu, ako je uvedené v ďalšom príklade.

Približná zhoda XLOOKUP

Ak chcete vykonať približné vyhľadávanie, nastavte match_mode na -1 alebo 1, v závislosti od toho, ako sú vaše údaje usporiadané.

V našom prípade vyhľadávacia tabuľka uvádza dolné hranice tried. Takže nastavíme match_mode na -1, aby sa hľadala ďalšia menšia hodnota, keď sa nenájde presná zhoda:

=XLOOKUP(F11, $B$11:$B$15, $C$11:$C$15, ,-1)

Napríklad Brian má známku 98 (F2). Vzorec hľadá túto hodnotu v B2:B6, ale nemôže ju nájsť. Potom hľadá ďalšiu menšiu položku a nájde 90, čo zodpovedá známke A:

Ak by naša vyhľadávacia tabuľka obsahovala horné hranice známok, nastavili by sme match_mode na 1, aby sa v prípade neúspešnej presnej zhody vyhľadala ďalšia väčšia položka:

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6, ,1)

Vzorec hľadá hodnotu 98 a opäť ju nenájde. Tentoraz sa pokúsi nájsť ďalšiu väčšiu hodnotu a dostane 100, čo zodpovedá stupňu A:

Tip: Pri kopírovaní vzorca Xlookup do viacerých buniek uzamknite vyhľadávacie alebo návratové rozsahy pomocou absolútnych odkazov na bunky (napríklad $B$2:$B$6), aby ste zabránili ich zmene.

XLOOKUP s čiastočnou zhodou (zástupné znaky)

Ak chcete vykonať vyhľadávanie čiastočnej zhody, nastavte match_mode na hodnotu 2, ktorá funkcii XLOOKUP prikáže spracovať zástupné znaky:

• Hviezdička (*) - predstavuje akúkoľvek postupnosť znakov.
• Otazník (?) - predstavuje akýkoľvek jednotlivý znak.

Aby ste videli, ako to funguje, zvážte nasledujúci príklad. V stĺpci A máte niekoľko modelov smartfónov a v stĺpci B ich kapacitu batérie. Ste zvedaví na batériu určitého smartfónu. Problém je v tom, že si nie ste istí, či môžete zadať názov modelu presne tak, ako je uvedený v stĺpci A. Aby ste to prekonali, zadajte časť, ktorá tam určite je, a nahraďte zvyšokznaky s náhradnými znakmi.

Ak chcete napríklad získať informácie o batérii zariadenia iPhone X, použite tento vzorec:

=XLOOKUP("*iphone X*", A2:A8, B2:B8, ,2)

Alebo zadajte známu časť hodnoty vyhľadávania do niektorej bunky a spojte odkaz na bunku so zástupnými znakmi:

=XLOOKUP("*"&E1& "*", A2:A8, B2:B8, ,2)

XLOOKUP v opačnom poradí na získanie posledného výskytu

V prípade, že vaša tabuľka obsahuje viacero výskytov hodnoty vyhľadávania, môže byť niekedy potrebné vrátiť posledný zápas . Ak to chcete mať hotové, nakonfigurujte vzorec Xlookup tak, aby vyhľadával v opačnom poradí.

Smer vyhľadávania sa riadi 6. argumentom s názvom search_mode :

• 1 alebo vynechať (predvolené) - vyhľadáva od prvej po poslednú hodnotu, t. j. zhora nadol s vertikálnym vyhľadávaním alebo zľava doprava s horizontálnym vyhľadávaním.
• -1 - vyhľadáva v opačnom poradí od poslednej po prvú hodnotu.

Ako príklad uvedieme vrátenie posledného predaja, ktorý uskutočnil konkrétny predajca. Na tento účel sme zostavili prvé tri požadované argumenty (G1 pre lookup_value , B2:B9 pre lookup_array a D2:D9 pre return_array ) a do piateho argumentu vložte -1:

=XLOOKUP(G1, B2:B9, D2:D9, , ,-1)

Jednoduché a ľahké, však?

XLOOKUP na vrátenie viacerých stĺpcov alebo riadkov

Jednou z ďalších úžasných funkcií XLOOKUP je jeho schopnosť vrátiť viac ako jednu hodnotu vzťahujúcu sa na tú istú zhodu. Všetko sa vykonáva pomocou štandardnej syntaxe a bez akýchkoľvek ďalších manipulácií!

Predpokladajme, že z nasledujúcej tabuľky chcete získať všetky údaje týkajúce sa predajcu, ktorý vás zaujíma (F2). Musíte zadať rozsah, nie jeden stĺpec alebo riadok, pre return_array argument:

=XLOOKUP(F2, A2:A7, B2:D7)

Vzorec zadáte do ľavej hornej bunky rozsahu výsledkov a Excel automaticky rozsype výsledky do susedných prázdnych buniek. V našom prípade obsahuje pole návratnosti (B2:D7) 3 stĺpce ( Dátum , Položka a Suma ) a všetky tri hodnoty sa vrátia do rozsahu G2:I2.

Ak chcete výsledky radšej zoradiť vertikálne do stĺpca, vložte funkciu XLOOKUP do funkcie TRANSPOSE, aby sa vrátené pole prevrátilo:

=TRANSPOSE(XLOOKUP(G1, A2:A7, B2:D7))

Podobným spôsobom môžete vrátiť celý stĺpec údajov, napr. Suma Na tento účel použite bunku F1, ktorá obsahuje "Amount" ako lookup_value , rozsah A1:D1 obsahujúci záhlavia stĺpcov ako lookup_array a rozsah A2:D7 obsahujúci všetky údaje ako return_array .

=XLOOKUP(F1, A1:D1, A2:D7)

Poznámka: Keďže sa do susedných buniek vyplnia viaceré hodnoty, uistite sa, že máte dostatok prázdnych buniek vpravo alebo dole. Ak Excel nenájde dostatok prázdnych buniek, vyskytne sa chyba #SPILL!

Tip. XLOOKUP dokáže nielen vrátiť viacero položiek, ale ich aj nahradiť inými hodnotami, ktoré zadáte. Príklad takéhoto hromadného nahradenia nájdete tu: Ako vyhľadať a nahradiť viacero hodnôt pomocou XLOOKUP.

XLOOKUP s viacerými kritériami

Ďalšou veľkou výhodou funkcie XLOOKUP je, že natívne pracuje s poliami. Vďaka tejto schopnosti môžete vyhodnotiť viacero kritérií priamo v lookup_array argument:

Ako tento vzorec funguje : Výsledkom každého testu kritérií je pole hodnôt TRUE a FALSE. Vynásobením polí sa hodnoty TRUE a FALSE premenia na 1, resp. 0 a vytvorí sa konečné vyhľadávacie pole. Ako viete, vynásobením 0 sa vždy získa nula, takže vo vyhľadávacom poli sú len položky, ktoré spĺňajú všetky kritériá, reprezentované hodnotou 1. A keďže naša vyhľadávacia hodnota je "1", Excel vezme prvú "1" v lookup_array (prvá zhoda) a vráti hodnotu z return_array v rovnakej polohe.

Ak chcete vidieť vzorec v akcii, vytiahnime sumu z D2:D10 ( return_array ) s týmito podmienkami:

• Kritérium1 (dátum) = G1
• Kritérium2 (predajca) = G2
• Kritérium3 (položka) = G3

S dátumami v A2:A10 ( kritérium_rozsah1 ), mená predajcov v B2:B10 ( kritérium_rozsah2 ) a položky v C2:C10 ( kritériá_rozsahu3 ), vzorec má tento tvar:

=XLOOKUP(1, (B2:B10=G1) * (A2:A10=G2) * (C2:C10=G3), D2:D10)

Hoci funkcia XLOOKUP programu Excel spracováva polia, funguje ako bežný vzorec a dokončí sa bežným stlačením klávesu Enter.

Vzorec XLOOKUP s viacerými kritériami nie je obmedzený na podmienky "rovná sa". Môžete použiť aj iné logické operátory. Ak chcete napríklad filtrovať objednávky uskutočnené v deň G1 alebo skôr, vložte do prvého kritéria "<=G1":

=XLOOKUP(1, (A2:A10<=G1) * (B2:B10=G2) * (C2:C10=G3), D2:D10)

Dvojitý XLOOKUP

Ak chcete nájsť hodnotu v priesečníku určitého riadku a stĺpca, vykonajte tzv. dvojité vyhľadávanie alebo vyhľadávanie matíc Áno, aj to dokáže Excel XLOOKUP! Jednoducho vnoríte jednu funkciu do druhej:

Ako tento vzorec funguje : Vzorec je založený na schopnosti funkcie XLOOKUP vrátiť celý riadok alebo stĺpec. Vnútorná funkcia vyhľadá svoju vyhľadávaciu hodnotu a vráti stĺpec alebo riadok súvisiacich údajov. Toto pole sa prenesie do vonkajšej funkcie ako return_array .

V tomto príklade budeme zisťovať tržby, ktoré dosiahol konkrétny predajca v rámci určitého štvrťroka. Na tento účel zadáme hodnoty vyhľadávania do H1 (meno predajcu) a H2 (štvrťrok) a vykonáme obojsmerný Xlookup s nasledujúcim vzorcom:

=XLOOKUP(H1, A2:A6, XLOOKUP(H2, B1:E1, B2:E6))

Alebo naopak:

=XLOOKUP(H2, B1:E1, XLOOKUP(H1, A2:A6, B2:E6))

Kde A2:A6 sú mená predajcov, B1:E1 sú štvrtiny (hlavičky stĺpcov) a B2:E6 sú hodnoty údajov.

Obojsmerné vyhľadávanie možno vykonať aj pomocou vzorca INDEX Match a niekoľkými ďalšími spôsobmi. Viac informácií nájdete v časti Obojsmerné vyhľadávanie v programe Excel.

Ak chyba XLOOKUP

Ak sa hodnota vyhľadávania nenájde, Excel XLOOKUP vráti chybu #N/A. Pre skúsených používateľov je to pomerne známe a zrozumiteľné, pre začiatočníkov to môže byť dosť mätúce. Ak chcete nahradiť štandardný zápis chyby používateľsky prívetivou správou, zadajte vlastný text do 4. argumentu s názvom if_not_found .

Vráťme sa k prvému príkladu, o ktorom sme hovorili v tomto návode. Ak niekto zadá do E1 neplatný názov oceánu, nasledujúci vzorec mu explicitne oznámi, že "Nenašla sa žiadna zhoda":

=XLOOKUP(E1, A2:A6, B2:B6, "Žiadna zhoda nebola nájdená")

Poznámky:

• Stránka if_not_found argument zachytáva iba chyby #N/A, nie všetky chyby.
• Chyby #N/A sa dajú riešiť aj pomocou IFNA a VLOOKUP, ale syntax je trochu zložitejšia a vzorec je dlhší.

XLOOKUP s citlivosťou na veľkosť písmen

V predvolenom nastavení funkcia XLOOKUP považuje malé a veľké písmená za rovnaké znaky. Ak chcete, aby rozlišovala veľké a malé písmená, použite funkciu EXACT pre lookup_array argument:

Ako tento vzorec funguje : Funkcia EXACT porovnáva vyhľadávanú hodnotu s každou hodnotou v poli vyhľadávania a vracia TRUE, ak sú presne rovnaké vrátane veľkosti písmen, inak FALSE. Toto pole logických hodnôt ide do lookup_array Výsledkom je, že XLOOKUP hľadá hodnotu TRUE vo vyššie uvedenom poli a vracia zhodu z návratového poľa.

Napríklad na získanie ceny z B2:B7 ( return_array ) pre položku v E1 ( lookup_value) , vzorec v E2 je:

=XLOOKUP(TRUE, EXACT(E1, A2:A7), B2:B7, "Nenájdené")

Poznámka: Ak sa v poli vyhľadávania nachádzajú dve alebo viac presne rovnakých hodnôt (vrátane veľkosti písmen), vráti sa prvá nájdená zhoda.

Excel XLOOKUP nefunguje

Ak váš vzorec nefunguje správne alebo je chybný, je to pravdepodobne z nasledujúcich dôvodov:

XLOOKUP nie je k dispozícii v mojom programe Excel

Funkcia XLOOKUP nie je spätne kompatibilná. Je k dispozícii len v aplikácii Excel pre Microsoft 365 a Excel 2021 a v predchádzajúcich verziách sa neobjaví.

XLOOKUP vráti nesprávny výsledok

Ak váš zjavne správny vzorec Xlookup vráti nesprávnu hodnotu, je pravdepodobné, že sa vyhľadávací alebo návratový rozsah "posunul", keď bol vzorec skopírovaný nadol alebo naprieč. Aby ste tomu zabránili, nezabudnite vždy uzamknúť oba rozsahy pomocou absolútnych odkazov na bunky (napríklad $A$2:$A$10).

XLOOKUP vráti chybu #N/A

Chyba #N/A znamená len to, že hodnota vyhľadávania nebola nájdená. Ak to chcete opraviť, skúste vyhľadať približnú zhodu alebo informujte používateľov, že sa nenašla žiadna zhoda.

XLOOKUP vráti chybu #VALUE

Chyba #VALUE! nastane, ak vyhľadávacie a návratové polia majú nekompatibilné rozmery. Napríklad nie je možné vyhľadávať v horizontálnom poli a vracať hodnoty z vertikálneho poľa.

XLOOKUP vráti chybu #REF

Pri vyhľadávaní medzi dvoma rôznymi zošitmi, z ktorých jeden je zatvorený, sa vyhodí chyba #REF! Ak chcete chybu odstrániť, jednoducho otvorte oba súbory.

Ako ste práve videli, XLOOKUP má mnoho úžasných funkcií, ktoré z neho robia funkciu pre takmer akékoľvek vyhľadávanie v programe Excel. Ďakujem vám za prečítanie a dúfam, že sa uvidíme na našom blogu budúci týždeň!

Cvičebnica na stiahnutie

Príklady vzorcov Excel XLOOKUP (.xlsx súbor)