Das Tutorial stellt XLOOKUP vor - die neue Funktion für vertikale und horizontale Suche in Excel. Linke Suche, letzte Übereinstimmung, Vlookup mit mehreren Kriterien und viele andere Dinge, für die man früher einen Abschluss in Raketenwissenschaft brauchte, sind jetzt so einfach wie das ABC.

Wenn Sie in Excel nachschlagen müssen, welche Funktion verwenden Sie dann? Ist es der Eckpfeiler VLOOKUP oder sein horizontales Geschwisterchen HLOOKUP? Verlassen Sie sich in einem komplexeren Fall auf die kanonische INDEX MATCH-Kombination oder übergeben Sie die Aufgabe an Power Query? Die gute Nachricht ist, dass Sie sich nicht mehr entscheiden müssen - all diese Methoden machen einem leistungsfähigeren und vielseitigeren Nachfolger Platz, der XLOOKUP-Funktion.

Inwiefern ist XLOOKUP besser? In vielerlei Hinsicht! Es kann vertikal und horizontal, nach links und oben schauen, mit mehreren Kriterien suchen und sogar eine ganze Spalte oder Zeile von Daten zurückgeben, nicht nur einen Wert. Microsoft hat mehr als drei Jahrzehnte gebraucht, aber endlich ist es ihnen gelungen, eine robuste Funktion zu entwickeln, die viele frustrierende Fehler und Schwächen von VLOOKUP überwindet.

Leider gibt es einen Haken: Die Funktion XLOOKUP ist nur in Excel für Microsoft 365, Excel 2021 und Excel für das Web verfügbar.

Excel XLOOKUP-Funktion - Syntax und Verwendung

Die Funktion XLOOKUP in Excel durchsucht einen Bereich oder ein Feld nach einem bestimmten Wert und gibt den zugehörigen Wert aus einer anderen Spalte zurück. Sie kann sowohl vertikal als auch horizontal nachschlagen und eine exakte Übereinstimmung (Standard), eine ungefähre Übereinstimmung (engste Übereinstimmung) oder einen Platzhalter (teilweise Übereinstimmung) durchführen.

Die Syntax der XLOOKUP-Funktion lautet wie folgt:

Die ersten 3 Argumente sind erforderlich, die letzten drei sind optional.

• Nachschlagen_Wert - der Wert, nach dem gesucht werden soll.
• Nachschlagen_Array - den Bereich oder das Feld, in dem gesucht werden soll.
• Rückgabe_Array - den Bereich oder das Array, aus dem Werte zurückgegeben werden sollen.
• Wenn_nicht_gefunden [optional] - der Wert, der zurückgegeben werden soll, wenn keine Übereinstimmung gefunden wird. Wird er weggelassen, wird ein #N/A-Fehler zurückgegeben.
• Spiel_Modus [optional] - die Art der Übereinstimmung, die durchgeführt werden soll:
  • 0 oder weggelassen (Voreinstellung) - exakte Übereinstimmung; wenn nicht gefunden, wird ein #N/A-Fehler zurückgegeben.
  • -1 - exakte Übereinstimmung oder nächst kleinerer Wert; wird keine exakte Übereinstimmung gefunden, wird der nächst kleinere Wert zurückgegeben.
  • 1 - exakte Übereinstimmung oder nächstgrößerer Wert; wird keine exakte Übereinstimmung gefunden, wird der nächstgrößere Wert zurückgegeben.
  • 2 - Übereinstimmung mit Platzhalterzeichen.
• Suche_Modus [optional] - die Richtung der Suche:
  • 1 oder weggelassen (Standard) - Suche vom ersten bis zum letzten Eintrag.
  • -1 - um in umgekehrter Reihenfolge zu suchen, vom letzten zum ersten.
  • 2 - Binäre Suche nach aufsteigend sortierten Daten.
  • -2 - Binäre Suche auf absteigend sortierten Daten.

  Nach Angaben von Microsoft, binäre Suche ist ein spezieller Algorithmus, der die Position eines Nachschlagewertes innerhalb eines sortierten Arrays findet, indem er ihn mit dem mittleren Element des Arrays vergleicht. Eine binäre Suche ist viel schneller als eine normale Suche, funktioniert aber nur bei sortierten Daten korrekt.

Grundlegende XLOOKUP-Formel

Um ein besseres Verständnis zu erlangen, wollen wir eine Xlookup-Formel in ihrer einfachsten Form erstellen, um eine exakte Suche durchzuführen. Dazu benötigen wir nur die ersten 3 Argumente.

Angenommen, Sie haben eine Übersichtstabelle mit Informationen über die fünf Ozeane der Erde. Sie möchten die Fläche eines bestimmten Ozeans in F1 eingeben ( lookup_value Mit den Ozeannamen in A2:A6 ( lookup_array ) und Flächen in C2:C6 ( return_array ), lautet die Formel wie folgt:

=XLOOKUP(F1, A2:A6, C2:C6)

Übersetzt in einfaches Englisch heißt das: Suche nach dem Wert F1 in A2:A6 und gib einen Wert aus C2:C6 in derselben Zeile zurück. Keine Spaltenindexnummern, keine Sortierung, keine anderen lächerlichen Eigenheiten von Vlookup! Es funktioniert einfach :)

XLOOKUP vs. VLOOKUP in Excel

Im Vergleich zum traditionellen VLOOKUP hat XLOOKUP viele Vorteile. Inwiefern ist es besser als VLOOKUP? Hier finden Sie eine Liste der 10 besten Funktionen, die jede andere Lookup-Funktion in Excel in den Schatten stellen:

1. Vertikales und horizontales Nachschlagen Die Funktion XLOOKUP erhielt ihren Namen aufgrund ihrer Fähigkeit, sowohl vertikal als auch horizontal nachzuschlagen.
2. Blick in jede Richtung: rechts, links, unten oder oben Während VLOOKUP nur in der Spalte ganz links und HLOOKUP nur in der obersten Zeile suchen kann, gibt es bei XLOOKUP keine derartigen Einschränkungen. Das berüchtigte Nachschlagen auf der linken Seite in Excel ist nicht mehr lästig!
3. Exakte Übereinstimmung als Standard In den meisten Fällen werden Sie nach einer exakten Übereinstimmung suchen, und XLOOKUP gibt diese standardmäßig zurück (im Gegensatz zur Funktion VLOOKUP, die standardmäßig eine ungefähre Übereinstimmung liefert). Natürlich können Sie XLOOKUP dazu bringen, bei Bedarf auch eine ungefähre Übereinstimmung durchzuführen.
4. Teilweise Übereinstimmung mit Wildcards Wenn Sie nur einen Teil des Suchwerts kennen, aber nicht den gesamten Wert, ist ein Wildcard-Match sehr nützlich.
5. Suche in umgekehrter Reihenfolge Früher mussten Sie die Reihenfolge der Quelldaten umkehren, um das letzte Vorkommen zu erhalten. Jetzt setzen Sie einfach die Suchmodus auf -1 setzen, um Ihre Xlookup-Formel zu zwingen, von hinten zu suchen und den letzten Treffer zurückzugeben.
6. Mehrere Werte zurückgeben Durch Manipulation mit dem return_array können Sie eine ganze Zeile oder Spalte von Daten abrufen, die sich auf Ihren Nachschlagewert beziehen.
7. Suche mit mehreren Kriterien Excel XLOOKUP kann von Haus aus mit Arrays umgehen, so dass es möglich ist, eine Suche mit mehreren Kriterien durchzuführen.
8. Wenn Fehlerfunktionalität Traditionell verwenden wir die IFNA-Funktion, um #N/A-Fehler abzufangen. XLOOKUP integriert diese Funktionalität in die if_not_found Argument, mit dem Sie Ihren eigenen Text ausgeben können, wenn keine gültige Übereinstimmung gefunden wird.
9. Einfügen/Löschen von Spalten Eines der ärgerlichsten Probleme mit VLOOKUP ist, dass das Hinzufügen oder Entfernen von Spalten eine Formel unterbricht, da die Rückgabespalte durch ihre Indexnummer identifiziert wird. Bei XLOOKUP geben Sie den Rückgabebereich an, nicht die Nummer, d. h. Sie können so viele Spalten einfügen und entfernen, wie Sie benötigen, ohne dass etwas unterbrochen wird.
10. Bessere Leistung VLOOKUP kann Ihre Arbeitsblätter verlangsamen, weil es die gesamte Tabelle in die Berechnungen einbezieht, was dazu führt, dass viel mehr Zellen verarbeitet werden, als tatsächlich benötigt werden. XLOOKUP behandelt nur die Such- und Rückgabefelder, auf die es wirklich angewiesen ist.

Verwendung von XLOOKUP in Excel - Formelbeispiele

Die folgenden Beispiele demonstrieren die nützlichsten XLOOKUP-Funktionen in der Praxis. Darüber hinaus werden Sie einige nicht-triviale Anwendungen entdecken, die Ihre Excel-Lookup-Kenntnisse auf ein neues Niveau heben werden.

Vertikaler und horizontaler Blick nach oben

In Microsoft Excel gab es früher zwei Funktionen für verschiedene Nachschlagetypen, die jeweils eine eigene Syntax und eigene Verwendungsregeln hatten: VLOOKUP für die vertikale Suche in einer Spalte und HLOOKUP für die horizontale Suche in einer Zeile.

Die XLOOKUP-Funktion kann beides mit der gleichen Syntax tun. Der Unterschied liegt darin, was Sie für die Lookup- und Return-Arrays bereitstellen.

Für v-lookup sind Spalten anzugeben:

=XLOOKUP(E1, A2:A6, B2:B6)

Für h-lookup geben Sie Zeilen statt Spalten ein:

=XLOOKUP(I1, B1:F1, B2:F2)

Linke Suche wird nativ durchgeführt

In früheren Excel-Versionen war die INDEX MATCH-Formel die einzige zuverlässige Methode, um nach links oder oben zu suchen. Jetzt müssen Sie nicht mehr zwei Funktionen kombinieren, wo eine ausreichen würde. Geben Sie einfach das Ziel-Lookup-Array an, und XLOOKUP wird es problemlos verarbeiten, unabhängig von seiner Position.

Als Beispiel fügen wir die Rang Das Ziel ist es, den Rang des eingegebenen Ozeans in F1 zu erhalten. VLOOKUP würde hier straucheln, weil es nur einen Wert aus einer Spalte rechts von der Lookup-Spalte zurückgeben kann. Eine Xlookup-Formel bewältigt dies mit Leichtigkeit:

=XLOOKUP(F1, B2:B6, A2:A6)

In ähnlicher Weise können Sie bei der horizontalen Suche in Zeilen nach oben schauen.

XLOOKUP mit genauer und ungefährer Übereinstimmung

Das Spielverhalten wird durch das 5. Argument namens match_mode Standardmäßig wird eine exakte Übereinstimmung durchgeführt.

Bitte beachten Sie, dass selbst wenn Sie eine ungefähre Übereinstimmung wählen ( match_mode auf 1 oder -1 gesetzt), sucht die Funktion immer noch zuerst nach einer exakten Übereinstimmung. Der Unterschied besteht darin, was sie zurückgibt, wenn kein exakter Nachschlagewert gefunden wird.

Argument Match_mode:

• 0 oder weggelassen - exakte Übereinstimmung; wenn nicht gefunden - #N/A Fehler.
• -1 - genaue Übereinstimmung; wenn nicht gefunden - nächstkleinere Position.
• 1 - exakte Übereinstimmung; wenn nicht gefunden - nächstgrößere Position.

Genaue Übereinstimmung XLOOKUP

Diese Option verwenden Sie wahrscheinlich in 99% der Fälle, in denen Sie eine Suche in Excel durchführen. Da XLOOKUP standardmäßig eine exakte Übereinstimmung anstrebt, können Sie die Option match_mode und geben Sie nur die ersten 3 erforderlichen Argumente an.

Ein typisches Szenario ist, dass Ihre Nachschlagetabelle nicht alle Werte enthält, sondern eher "Meilensteine" oder "Grenzen" wie mengenabhängige Rabatte, umsatzabhängige Provisionen usw.

Unsere Beispielnachschlagetabelle zeigt die Korrelation zwischen Prüfungsergebnissen und Noten. Wie Sie in der Abbildung unten sehen können, funktioniert eine exakte Übereinstimmung nur, wenn das Ergebnis eines bestimmten Schülers genau mit dem Wert in der Nachschlagetabelle übereinstimmt (wie Christian in Zeile 3). In allen anderen Fällen wird ein #N/A-Fehler zurückgegeben.

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6)

Um die Noten anstelle von #N/A-Fehlern zu erhalten, müssen wir nach einer ungefähren Übereinstimmung suchen, wie im nächsten Beispiel gezeigt.

Ungefähre Übereinstimmung XLOOKUP

Um eine ungefähre Suche durchzuführen, setzen Sie den match_mode entweder auf -1 oder 1, je nachdem, wie Ihre Daten organisiert sind.

In unserem Fall listet die Lookup-Tabelle die Untergrenzen der Noten auf. Wir setzen also match_mode auf -1, um nach dem nächstkleineren Wert zu suchen, wenn keine exakte Übereinstimmung gefunden wird:

=XLOOKUP(F11, $B$11:$B$15, $C$11:$C$15, ,-1)

Beispiel: Brian hat die Note 98 (F2). Die Formel sucht diesen Wert in B2:B6, findet ihn aber nicht. Dann sucht sie nach dem nächstkleineren Element und findet 90, was der Note A entspricht:

Wenn unsere Nachschlagetabelle die Obergrenzen der Noten enthielte, würden wir match_mode auf 1 setzen, um nach dem nächstgrößeren Element zu suchen, wenn eine exakte Übereinstimmung nicht möglich ist:

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6, ,1)

Die Formel sucht nach 98 und findet es wieder nicht. Diesmal versucht sie, den nächstgrößeren Wert zu finden und erhält 100, was der Note A entspricht:

Tipp: Wenn Sie eine Xlookup-Formel in mehrere Zellen kopieren, sperren Sie die Lookup- oder Rückgabebereiche mit absoluten Zellreferenzen (z. B. $B$2:$B$6), damit sie sich nicht ändern.

XLOOKUP mit teilweiser Übereinstimmung (Wildcards)

Um eine partielle Suche nach Übereinstimmungen durchzuführen, setzen Sie die match_mode Argument auf 2, was die XLOOKUP-Funktion anweist, die Platzhalterzeichen zu verarbeiten:

• Ein Sternchen (*) - steht für eine beliebige Folge von Zeichen.
• Ein Fragezeichen (?) - steht für ein beliebiges einzelnes Zeichen.

Um zu sehen, wie es funktioniert, betrachten Sie bitte das folgende Beispiel: In Spalte A haben Sie einige Smartphone-Modelle und in Spalte B deren Akkukapazität. Sie sind neugierig auf den Akku eines bestimmten Smartphones. Das Problem ist, dass Sie nicht sicher sind, ob Sie den Modellnamen genau so eingeben können, wie er in Spalte A erscheint. Um dieses Problem zu lösen, geben Sie den Teil ein, der auf jeden Fall vorhanden ist, und ersetzen den RestZeichen mit Platzhaltern.

Um zum Beispiel Informationen über den Akku des iPhone X zu erhalten, verwenden Sie diese Formel:

=XLOOKUP("*iphone X*", A2:A8, B2:B8, ,2)

Oder Sie geben den bekannten Teil des Suchwerts in eine Zelle ein und verketten den Zellverweis mit den Platzhalterzeichen:

=XLOOKUP("*"&E1& "*", A2:A8, B2:B8, ,2)

XLOOKUP in umgekehrter Reihenfolge, um das letzte Vorkommen zu ermitteln

Falls Ihre Tabelle mehrere Vorkommen des Nachschlagewerts enthält, müssen Sie manchmal die letztes Spiel Konfigurieren Sie dazu Ihre Xlookup-Formel so, dass sie in umgekehrter Reihenfolge sucht.

Die Suchrichtung wird durch das 6. Argument namens Suchmodus :

• 1 oder weggelassen (Standard) - sucht vom ersten bis zum letzten Wert, d. h. von oben nach unten bei vertikaler Suche oder von links nach rechts bei horizontaler Suche.
• -1 - sucht in umgekehrter Reihenfolge vom letzten zum ersten Wert.

Als Beispiel wollen wir den letzten Verkauf eines bestimmten Verkäufers zurückgeben. Dazu stellen wir die ersten drei erforderlichen Argumente zusammen (G1 für lookup_value , B2:B9 für lookup_array und D2:D9 für return_array ) und setzen Sie -1 in das 5. Argument:

=XLOOKUP(G1, B2:B9, D2:D9, , ,-1)

Unkompliziert und einfach, nicht wahr?

XLOOKUP, um mehrere Spalten oder Zeilen zurückzugeben

Eine weitere erstaunliche Eigenschaft von XLOOKUP ist die Möglichkeit, mehr als einen Wert für dieselbe Übereinstimmung zurückzugeben, und zwar mit der Standardsyntax und ohne zusätzliche Manipulationen!

Nehmen wir an, Sie möchten in der unten stehenden Tabelle alle Details zu dem betreffenden Verkäufer (F2) abrufen, dann müssen Sie einen Bereich und nicht nur eine Spalte oder Zeile für die return_array Argument:

=XLOOKUP(F2, A2:A7, B2:D7)

Sie geben die Formel in die obere linke Zelle des Ergebnisbereichs ein, und Excel verschüttet die Ergebnisse automatisch in die angrenzenden leeren Zellen. In unserem Fall umfasst der Rückgabebereich (B2:D7) 3 Spalten ( Datum , Artikel und Betrag ), und alle drei Werte werden in den Bereich G2:I2 zurückgegeben.

Wenn Sie die Ergebnisse lieber vertikal in einer Spalte anordnen möchten, schachteln Sie XLOOKUP in die Funktion TRANSPOSE, um das zurückgegebene Array zu spiegeln:

=TRANSPOSE(XLOOKUP(G1, A2:A7, B2:D7))

In ähnlicher Weise können Sie eine ganze Datenspalte zurückgeben, beispielsweise die Betrag Verwenden Sie dazu die Zelle F1, die "Betrag" enthält, als lookup_value den Bereich A1:D1, der die Spaltenüberschriften enthält, als lookup_array und der Bereich A2:D7, der alle Daten enthält, als return_array .

=XLOOKUP(F1, A1:D1, A2:D7)

Hinweis: Da mehrere Werte in benachbarte Zellen eingefügt werden, sollten Sie darauf achten, dass rechts und unten genügend leere Zellen vorhanden sind. Wenn Excel nicht genügend leere Zellen findet, tritt der Fehler #SPILL! auf.

Tipp: XLOOKUP kann nicht nur mehrere Einträge zurückgeben, sondern diese auch durch andere Werte ersetzen, die Sie angeben. Ein Beispiel für eine solche Massenersetzung finden Sie hier: Wie man mit XLOOKUP mehrere Werte sucht und ersetzt.

XLOOKUP mit mehreren Kriterien

Ein weiterer großer Vorteil von XLOOKUP ist, dass es nativ mit Arrays umgehen kann. Dadurch können Sie mehrere Kriterien direkt in der lookup_array Argument:

Wie diese Formel funktioniert Das Ergebnis jedes Kriterientests ist ein Array mit TRUE- und FALSE-Werten. Die Multiplikation der Arrays wandelt TRUE und FALSE in 1 bzw. 0 um und ergibt das endgültige Lookup-Array. Wie Sie wissen, ergibt die Multiplikation mit 0 immer Null, so dass im Lookup-Array nur die Elemente, die alle Kriterien erfüllen, mit 1 dargestellt werden. Und da unser Lookup-Wert "1" ist, nimmt Excel die erste "1" in lookup_array (erste Übereinstimmung) und gibt den Wert aus return_array in der gleichen Position.

Um die Formel in Aktion zu sehen, ziehen wir einen Betrag aus D2:D10 ( return_array ) mit den folgenden Bedingungen:

• Kriterium1 (Datum) = G1
• Kriterium2 (Verkäufer) = G2
• Kriterium3 (Punkt) = G3

Mit Daten in A2:A10 ( kriterien_bereich1 ), Verkäufernamen in B2:B10 ( kriterien_bereich2 ) und Posten in C2:C10 ( kriterien_bereich3 ), nimmt die Formel diese Form an:

=XLOOKUP(1, (B2:B10=G1) * (A2:A10=G2) * (C2:C10=G3), D2:D10)

Obwohl die Excel-Funktion XLOOKUP Arrays verarbeitet, funktioniert sie wie eine reguläre Formel und wird mit einem üblichen Enter-Tastendruck abgeschlossen.

Die XLOOKUP-Formel mit mehreren Kriterien ist nicht auf "Gleich"-Bedingungen beschränkt. Sie können auch andere logische Operatoren verwenden. Um z. B. Bestellungen zu filtern, die an dem Datum in G1 oder früher getätigt wurden, setzen Sie "<=G1" in das erste Kriterium:

=XLOOKUP(1, (A2:A10<=G1) * (B2:B10=G2) * (C2:C10=G3), D2:D10)

Doppeltes XLOOKUP

Um einen Wert am Schnittpunkt einer bestimmten Zeile und Spalte zu finden, führen Sie die so genannte Doppelnachschlag oder Matrix-Suche Ja, Excel XLOOKUP kann das auch! Sie verschachteln einfach eine Funktion in eine andere:

Wie diese Formel funktioniert Die Formel basiert auf der Fähigkeit von XLOOKUP, eine ganze Zeile oder Spalte zurückzugeben. Die innere Funktion sucht nach ihrem Nachschlagewert und gibt eine Spalte oder Zeile mit zugehörigen Daten zurück. Dieses Array wird an die äußere Funktion als return_array .

In diesem Beispiel wollen wir die Verkäufe eines bestimmten Verkäufers in einem bestimmten Quartal ermitteln. Dazu geben wir die Nachschlagewerte in H1 (Name des Verkäufers) und H2 (Quartal) ein und führen ein zweiseitiges Xlookup mit der folgenden Formel durch:

=XLOOKUP(H1, A2:A6, XLOOKUP(H2, B1:E1, B2:E6))

Oder andersherum:

=XLOOKUP(H2, B1:E1, XLOOKUP(H1, A2:A6, B2:E6))

Dabei sind A2:A6 die Namen der Verkäufer, B1:E1 die Quartale (Spaltenüberschriften) und B2:E6 die Datenwerte.

Eine zweiseitige Suche kann auch mit einer INDEX-Abgleichsformel und auf einige andere Arten durchgeführt werden. Weitere Informationen finden Sie unter Zweiseitige Suche in Excel.

Wenn Fehler XLOOKUP

Wenn der Nachschlagewert nicht gefunden wird, gibt Excel XLOOKUP eine #N/A-Fehlermeldung zurück, die zwar für erfahrene Benutzer vertraut und verständlich ist, für Neulinge jedoch eher verwirrend sein kann. Um die Standardfehlernotation durch eine benutzerfreundliche Meldung zu ersetzen, geben Sie Ihren eigenen Text in das vierte Argument namens if_not_found .

Zurück zum allerersten Beispiel, das in diesem Tutorium besprochen wurde: Wenn jemand einen ungültigen Ozeannamen in E1 eingibt, wird ihm die folgende Formel ausdrücklich mitteilen, dass "keine Übereinstimmung gefunden wurde":

=XLOOKUP(E1, A2:A6, B2:B6, "Es wurde keine Übereinstimmung gefunden")

Anmerkungen:

• Die if_not_found Argument fängt nur #N/A-Fehler ab, nicht alle Fehler.
• #N/A-Fehler können auch mit IFNA und VLOOKUP behandelt werden, aber die Syntax ist etwas komplexer und eine Formel ist länger.

XLOOKUP unter Berücksichtigung der Groß-/Kleinschreibung

Standardmäßig behandelt die Funktion XLOOKUP Klein- und Großbuchstaben als dieselben Zeichen. Um die Groß- und Kleinschreibung zu berücksichtigen, verwenden Sie die Funktion EXACT für den Parameter lookup_array Argument:

Wie diese Formel funktioniert EXACT: Die Funktion EXACT vergleicht den Lookup-Wert mit jedem Wert im Lookup-Array und gibt TRUE zurück, wenn sie exakt gleich sind, einschließlich der Groß- und Kleinschreibung, andernfalls FALSE. Dieses Array logischer Werte geht in die lookup_array Als Ergebnis sucht XLOOKUP nach dem Wert TRUE im obigen Array und gibt eine Übereinstimmung im Rückgabe-Array zurück.

Um zum Beispiel den Preis von B2:B7 zu erhalten ( return_array ) für den Posten in E1 ( lookup_value) lautet die Formel in E2:

=XLOOKUP(TRUE, EXACT(E1, A2:A7), B2:B7, "Nicht gefunden")

Hinweis: Gibt es zwei oder mehr exakt gleiche Werte im Lookup-Array (einschließlich Groß- und Kleinschreibung), wird die erste gefundene Übereinstimmung zurückgegeben.

Excel XLOOKUP funktioniert nicht

Wenn Ihre Formel nicht richtig funktioniert oder zu Fehlern führt, liegt das höchstwahrscheinlich an den folgenden Gründen:

XLOOKUP ist in meinem Excel nicht verfügbar

Die Funktion XLOOKUP ist nicht abwärtskompatibel und steht nur in Excel für Microsoft 365 und Excel 2021 zur Verfügung, d. h. sie wird in früheren Versionen nicht angezeigt.

XLOOKUP liefert falsches Ergebnis

Wenn Ihre offensichtlich korrekte Xlookup-Formel einen falschen Wert zurückgibt, besteht die Möglichkeit, dass sich der Lookup- oder Rückgabebereich "verschoben" hat, als die Formel nach unten oder in den anderen Bereich kopiert wurde. Um dies zu verhindern, sollten Sie beide Bereiche immer mit absoluten Zellreferenzen (wie $A$2:$A$10) sperren.

XLOOKUP gibt #N/A Fehler zurück

Ein #N/A-Fehler bedeutet nur, dass der Suchwert nicht gefunden wurde. Um dies zu beheben, suchen Sie nach einer ungefähren Übereinstimmung oder informieren Sie Ihre Benutzer, dass keine Übereinstimmung gefunden wurde.

XLOOKUP gibt #VALUE-Fehler zurück

Ein #VALUE!-Fehler tritt auf, wenn die Lookup- und Return-Arrays inkompatible Dimensionen haben, z.B. ist es nicht möglich, in einem horizontalen Array zu suchen und Werte aus einem vertikalen Array zurückzugeben.

XLOOKUP gibt #REF-Fehler zurück

Ein #REF!-Fehler wird ausgelöst, wenn zwischen zwei verschiedenen Arbeitsmappen gesucht wird, von denen eine geschlossen ist. Um den Fehler zu beheben, öffnen Sie einfach beide Dateien.

Wie Sie soeben gesehen haben, verfügt XLOOKUP über viele großartige Funktionen, die es zu DER Funktion für fast jede Suche in Excel machen. Ich danke Ihnen für die Lektüre und hoffe, Sie nächste Woche in unserem Blog begrüßen zu dürfen!

Übungsheft zum Herunterladen

Excel XLOOKUP Formel Beispiele (.xlsx Datei)