Samouczek wprowadza XLOOKUP - nową funkcję do pionowego i poziomego wyszukiwania w Excelu. Wyszukiwanie po lewej stronie, ostatnie dopasowanie, Vlookup z wieloma kryteriami i wiele innych rzeczy, które kiedyś wymagały stopnia naukowego, aby osiągnąć, stały się teraz tak proste jak ABC.

Kiedykolwiek musisz szukać w Excelu, której funkcji byś użył? Czy jest to kamień węgielny VLOOKUP lub jego horyzontalne rodzeństwo HLOOKUP? W bardziej złożonym przypadku, polegasz na kanonicznej kombinacji INDEX MATCH lub powierzasz zadanie Power Query? Dobra wiadomość jest taka, że nie musisz już wybierać - wszystkie te metody ustępują miejsca bardziej potężnemu i wszechstronnemu następcy, funkcji XLOOKUP.

W jaki sposób XLOOKUP jest lepszy? Na wiele sposobów! Może patrzeć pionowo i poziomo, w lewo i powyżej, wyszukiwać za pomocą wielu kryteriów, a nawet zwracać całą kolumnę lub wiersz danych, a nie tylko jedną wartość. Microsoftowi zajęło to ponad 3 dekady, ale w końcu udało się zaprojektować solidną funkcję, która pokonuje wiele frustrujących błędów i słabości VLOOKUP.

Jaki jest haczyk - niestety, jest. Funkcja XLOOKUP jest dostępna tylko w Excelu dla Microsoft 365, Excelu 2021 i Excelu dla sieci.

Funkcja XLOOKUP w Excelu - składnia i zastosowania

Funkcja XLOOKUP w programie Excel wyszukuje zakres lub tablicę dla określonej wartości i zwraca powiązaną wartość z innej kolumny. Może szukać zarówno w pionie, jak i w poziomie oraz wykonywać dokładne dopasowanie (domyślnie), przybliżone (najbliższe) dopasowanie lub wieloznaczne (częściowe) dopasowanie.

Składnia funkcji XLOOKUP jest następująca:

Pierwsze 3 argumenty są wymagane, a ostatnie trzy są opcjonalne.

• Lookup_value - wartość, której należy szukać.
• Lookup_array - zakres lub tablicę, w której mają być wyszukiwane.
• Return_array - zakres lub tablicę, z której mają być zwrócone wartości.
• Jeśli_nie_znaleziono [opcjonalnie] - wartość, która ma zostać zwrócona, jeśli nie zostanie znalezione dopasowanie. Jeśli zostanie pominięta, zostanie zwrócony błąd #N/A.
• Tryb dopasowania [opcjonalnie] - typ dopasowania do wykonania:
  • 0 lub pominięty (domyślnie) - dokładne dopasowanie. Jeśli nie zostanie znaleziony, zwracany jest błąd #N/A.
  • -1 - dokładne dopasowanie lub następna mniejsza. Jeśli dokładne dopasowanie nie zostanie znalezione, zwracana jest następna mniejsza wartość.
  • 1 - dokładne dopasowanie lub następna większa wartość. Jeśli dokładne dopasowanie nie zostanie znalezione, zwracana jest następna większa wartość.
  • 2 - dopasowanie znaków wieloznacznych.
• Search_mode [opcjonalnie] - kierunek wyszukiwania:
  • 1 lub pominięty (domyślnie) - wyszukiwanie od pierwszego do ostatniego.
  • -1 - aby wyszukać w odwrotnej kolejności, od ostatniego do pierwszego.
  • 2 - wyszukiwanie binarne na danych posortowanych rosnąco.
  • -2 - wyszukiwanie binarne na danych posortowanych malejąco.

  Według Microsoftu, wyszukiwanie binarne Jest to specjalny algorytm, który znajduje pozycję szukanej wartości w posortowanej tablicy poprzez porównanie jej ze środkowym elementem tablicy. Szukanie binarne jest znacznie szybsze niż zwykłe szukanie, ale działa poprawnie tylko na posortowanych danych.

Podstawowa formuła XLOOKUP

Aby uzyskać więcej zrozumienia, zbudujmy formułę Xlookup w jej najprostszej formie, aby wykonać dokładny lookup. W tym celu będziemy potrzebować tylko pierwszych 3 argumentów.

Załóżmy, że masz tabelę zbiorczą z informacjami o pięciu oceanach na Ziemi. Chcesz uzyskać powierzchnię konkretnego oceanu wprowadzonego w F1 ( lookup_value ). Z nazwami oceanów w A2:A6 ( lookup_array ) oraz obszary w C2:C6 ( tablica ), formuła przebiega następująco:

=XLOOKUP(F1, A2:A6, C2:C6)

Przetłumaczone na prosty angielski, mówi: wyszukaj wartość F1 w A2:A6 i zwróć wartość z C2:C6 w tym samym wierszu. Żadnych numerów indeksów kolumn, żadnego sortowania, żadnych innych śmiesznych dziwactw Vlookup! To po prostu działa :)

XLOOKUP a VLOOKUP w programie Excel

W porównaniu z tradycyjnym VLOOKUP, XLOOKUP ma wiele zalet. W czym jest lepszy od VLOOKUP? Oto lista 10 najlepszych cech, które wywalają drzwi z każdej innej funkcji lookup w Excelu:

1. Podgląd pionowy i poziomy . Funkcja XLOOKUP otrzymała swoją nazwę dzięki możliwości patrzenia w górę zarówno w pionie, jak i w poziomie.
2. Patrz w dowolnym kierunku: w prawo, w lewo, w dół lub w górę Podczas gdy VLOOKUP może wyszukiwać tylko w lewej kolumnie, a HLOOKUP w górnym wierszu, XLOOKUP nie ma takich ograniczeń. Notoryczny lewy lookup w Excelu nie jest już bolączką!
3. Dokładne dopasowanie domyślnie W większości sytuacji będziesz szukał dokładnego dopasowania, a XLOOKUP zwraca je domyślnie (w przeciwieństwie do funkcji VLOOKUP, która domyślnie ustawia dopasowanie przybliżone). Oczywiście, możesz uzyskać XLOOKUP, aby wykonać również dopasowanie przybliżone, jeśli jest to konieczne.
4. Częściowe dopasowanie z symbolami wieloznacznymi Gdy znasz tylko część wartości wyszukiwania, a nie całą, przydaje się dopasowanie wieloznaczne.
5. Wyszukiwanie w odwrotnej kolejności Wcześniej, aby uzyskać ostatnie wystąpienie, trzeba było odwrócić kolejność danych źródłowych. Teraz wystarczy ustawić opcję search_mode aby wymusić na formule Xlookup przeszukiwanie od tyłu i zwrócenie ostatniego dopasowania.
6. Zwróć wiele wartości . By manipulować z tablica argument, możesz wyciągnąć cały wiersz lub kolumnę danych związanych z twoją wartością lookup.
7. Wyszukiwanie za pomocą wielu kryteriów . Excel XLOOKUP obsługuje natywnie tablice, co umożliwia wykonanie lookupu z wieloma kryteriami.
8. Jeśli funkcjonalność błędu Tradycyjnie używamy funkcji IFNA do wychwytywania błędów #N/A. XLOOKUP zawiera tę funkcjonalność w jeśli_nie_znaleziono argument pozwalający na wyprowadzenie własnego tekstu, jeśli nie zostanie znalezione prawidłowe dopasowanie.
9. Wstawianie/usuwanie kolumn Jednym z najbardziej irytujących problemów z VLOOKUP jest to, że dodawanie lub usuwanie kolumn przerywa formułę, ponieważ kolumna zwrotna jest identyfikowana przez jej numer indeksu. Z XLOOKUP, dostarczasz zakres zwrotny, a nie numer, co oznacza, że możesz wstawić i usunąć tyle kolumn, ile potrzebujesz, bez łamania czegokolwiek.
10. Lepsza wydajność VLOOKUP może spowolnić pracę arkuszy, ponieważ uwzględnia w obliczeniach całą tabelę, co powoduje przetwarzanie znacznie większej liczby komórek niż jest to rzeczywiście potrzebne. XLOOKUP obsługuje tylko te tablice lookup i return, na których naprawdę zależy.

Jak używać XLOOKUP w Excelu - przykłady formuł

Poniższe przykłady demonstrują najbardziej przydatne funkcje XLOOKUP w działaniu. Dodatkowo odkryjesz kilka nietrywialnych zastosowań, które przeniosą Twoje umiejętności wyszukiwania w Excelu na nowy poziom.

Spójrz w górę pionowo i poziomo

Microsoft Excel miał kiedyś dwie funkcje dla różnych typów lookupów, z których każda miała swoją własną składnię i zasady użytkowania: VLOOKUP do szukania w pionie w kolumnie i HLOOKUP do szukania w poziomie w wierszu.

Funkcja XLOOKUP może wykonać obie te funkcje z tą samą składnią. Różnica polega na tym, co podajesz dla tablic lookup i return.

W przypadku v-lookup, podaj kolumny:

=XLOOKUP(E1, A2:A6, B2:B6)

Dla h-lookup, wprowadź wiersze zamiast kolumn:

=XLOOKUP(I1, B1:F1, B2:F2)

Lewy lookup wykonywany natywnie

We wcześniejszych wersjach Excela formuła INDEX MATCH była jedynym niezawodnym sposobem na szukanie w lewo lub powyżej. Teraz nie trzeba już łączyć dwóch funkcji tam, gdzie wystarczyłaby jedna. Wystarczy podać docelową tablicę lookup, a XLOOKUP obsłuży ją bez problemu bez względu na jej położenie.

Jako przykład, dodajmy Ranga Celem jest uzyskanie rangi wejścia oceanu w F1. VLOOKUP potknąłby się tutaj, ponieważ może zwrócić tylko wartość z kolumny po prawej stronie kolumny lookup. Formuła Xlookup radzi sobie z tym z łatwością:

=XLOOKUP(F1, B2:B6, A2:A6)

W podobny sposób można spojrzeć powyżej podczas wyszukiwania poziomego w rzędach.

XLOOKUP z dopasowaniem dokładnym i przybliżonym

Zachowanie meczu jest kontrolowane przez piąty argument o nazwie tryb dopasowania Domyślnie wykonywane jest dopasowanie dokładne.

Proszę zwrócić uwagę, że nawet w przypadku wybrania dopasowania przybliżonego ( tryb dopasowania Różnica polega na tym, co funkcja zwraca, jeśli nie zostanie znaleziona dokładna wartość lookup.

Argument match_mode:

• 0 lub pominięte - dokładne dopasowanie; jeśli nie znaleziono - błąd #N/A.
• -1 - dokładne dopasowanie; jeśli nie znaleziono - następny mniejszy element.
• 1 - dokładne dopasowanie; jeśli nie znaleziono - następny większy element.

Dokładne dopasowanie XLOOKUP

Jest to opcja, której prawdopodobnie używasz w 99% przypadków wyszukiwania w Excelu. Ponieważ dokładne dopasowanie jest domyślnym zachowaniem XLOOKUP, możesz pominąć tryb dopasowania i dostarczyć tylko pierwsze 3 wymagane argumenty.

W niektórych sytuacjach jednak dokładne dopasowanie nie zadziała. Typowym scenariuszem jest, gdy twoja tabela lookup nie zawiera wszystkich wartości, ale raczej "kamienie milowe" lub "granice", takie jak rabaty oparte na ilości, prowizje oparte na sprzedaży itp.

Nasza przykładowa tabela lookup pokazuje korelację pomiędzy wynikami egzaminów a ocenami. Jak widać na poniższym zrzucie ekranu, dokładne dopasowanie działa tylko wtedy, gdy wynik konkretnego studenta dokładnie pasuje do wartości w tabeli lookup (jak Christian w wierszu 3). We wszystkich innych przypadkach zwracany jest błąd #N/A.

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6)

Aby uzyskać oceny zamiast błędów #N/A, musimy szukać przybliżonego dopasowania, jak pokazano w następnym przykładzie.

Przybliżone dopasowanie XLOOKUP

Aby wykonać przybliżone wyszukiwanie, należy ustawić tryb dopasowania argument na -1 lub 1, w zależności od tego, jak zorganizowane są twoje dane.

W naszym przypadku, tablica lookup zawiera dolne granice ocen. Ustawiamy więc tryb dopasowania do -1, aby szukać następnej mniejszej wartości, gdy nie zostanie znalezione dokładne dopasowanie:

=XLOOKUP(F11, $B$11:$B$15, $C$11:$C$15, ,-1)

Na przykład Brian ma ocenę 98 (F2). Formuła szuka tej wartości lookup w B2:B6, ale nie może jej znaleźć. Następnie szuka kolejnej mniejszej pozycji i znajduje 90, co odpowiada ocenie A:

Gdyby nasza tablica zawierała górne granice ocen, ustawilibyśmy tryb dopasowania do 1, aby wyszukać następny większy element, jeśli dokładne dopasowanie nie powiedzie się:

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6, ,1)

Formuła szuka 98 i znów nie może go znaleźć. Tym razem próbuje znaleźć kolejną większą wartość i otrzymuje 100, co odpowiada stopniowi A:

Wskazówka. Podczas kopiowania formuły Xlookup do wielu komórek, zablokuj zakresy looku lub zwrotu za pomocą bezwzględnych odniesień do komórek (jak $B$2:$B$6), aby zapobiec ich zmianie.

XLOOKUP z dopasowaniem częściowym (symbole wieloznaczne)

Aby wykonać wyszukiwanie częściowe, ustaw tryb dopasowania na 2, co nakazuje funkcji XLOOKUP przetwarzanie znaków wieloznacznych:

• Gwiazdka (*) - reprezentuje dowolny ciąg znaków.
• Znak zapytania (?) - reprezentuje dowolny pojedynczy znak.

Aby zobaczyć jak to działa, proszę przeanalizować następujący przykład. W kolumnie A masz kilka modeli smartfonów, a w kolumnie B ich pojemność baterii. Jesteś ciekaw baterii pewnego smartfona. Problem polega na tym, że nie jesteś pewien, czy możesz wpisać nazwę modelu dokładnie tak, jak pojawia się ona w kolumnie A. Aby to przezwyciężyć, wpisz część, która na pewno tam jest i zastąp pozostałeznaki z symbolami wieloznacznymi.

Na przykład, aby uzyskać informacje o baterii iPhone'a X, użyj tego wzoru:

=XLOOKUP("*iphone X*", A2:A8, B2:B8, ,2)

Lub wprowadź znaną część wartości lookup w jakiejś komórce i konkatenuj odwołanie do komórki ze znakami wieloznacznymi:

=XLOOKUP("*"&E1& "*", A2:A8, B2:B8, ,2)

XLOOKUP w odwrotnej kolejności, aby uzyskać ostatnie wystąpienie

W przypadku, gdy tabela zawiera kilka wystąpień wartości lookup, może być konieczne zwrócenie wartości ostatni mecz Aby to zrobić, skonfiguruj swoją formułę Xlookup, aby wyszukiwać w odwrotnej kolejności.

Kierunek poszukiwań jest kontrolowany przez szósty argument o nazwie search_mode :

• 1 lub pominięty (domyślnie) - szuka od pierwszej do ostatniej wartości, czyli od góry do dołu przy wyszukiwaniu pionowym lub od lewej do prawej przy wyszukiwaniu poziomym.
• -1 - wyszukuje w odwrotnej kolejności od ostatniej do pierwszej wartości.

Jako przykład zwróćmy ostatnią sprzedaż dokonaną przez konkretnego sprzedawcę. W tym celu łączymy trzy pierwsze wymagane argumenty (G1 dla lookup_value , B2:B9 dla lookup_array oraz D2:D9 dla tablica ) i wstawić -1 do 5 argumentu:

=XLOOKUP(G1, B2:B9, D2:D9, , ,-1)

Proste i łatwe, prawda?

XLOOKUP, aby zwrócić wiele kolumn lub wierszy

Jeszcze jedną niesamowitą cechą XLOOKUP jest możliwość zwrócenia więcej niż jednej wartości odnoszącej się do tego samego dopasowania. Wszystko odbywa się przy użyciu standardowej składni i bez żadnych dodatkowych manipulacji!

Załóżmy, że chcemy pobrać z poniższej tabeli wszystkie szczegóły dotyczące interesującego nas sprzedawcy (F2). Należy podać zakres, a nie pojedynczą kolumnę lub wiersz, dla polecenia tablica argument:

=XLOOKUP(F2, A2:A7, B2:D7)

Formułę wpisujesz w lewej górnej komórce zakresu wyników, a Excel automatycznie rozsypuje wyniki do sąsiednich pustych komórek. W naszym przypadku tablica zwrotna (B2:D7) zawiera 3 kolumny ( Data , Pozycja oraz Kwota ), a wszystkie trzy wartości są zwracane do zakresu G2:I2.

Jeśli wolisz ułożyć wyniki pionowo w kolumnie, zagnieżdż XLOOKUP w funkcji TRANSPOSE, aby odwrócić zwróconą tablicę:

=TRANSPOSE(XLOOKUP(G1, A2:A7, B2:D7))

W podobny sposób można zwrócić całą kolumnę danych, np. Kwota W tym celu należy użyć komórki F1, która zawiera "Kwota" jako lookup_value , zakres A1:D1 zawierający nagłówki kolumn jako lookup_array oraz zakres A2:D7 zawierający wszystkie dane jako tablica .

=XLOOKUP(F1, A1:D1, A2:D7)

Uwaga. Ponieważ wiele wartości jest wypełnianych w sąsiednich komórkach, upewnij się, że masz wystarczająco dużo pustych komórek po prawej stronie lub w dół. Jeśli Excel nie może znaleźć wystarczająco dużo pustych komórek, pojawia się błąd #SPILL!

Wskazówka. XLOOKUP może nie tylko zwrócić wiele wpisów, ale także zastąpić je innymi wartościami, które określisz. Przykład takiego zbiorczego zastąpienia znajdziesz tutaj: Jak wyszukać i zastąpić wiele wartości za pomocą XLOOKUP.

XLOOKUP z wieloma kryteriami

Kolejną dużą zaletą XLOOKUP jest to, że obsługuje on natywnie tablice. Dzięki tej możliwości można oceniać wiele kryteriów bezpośrednio w lookup_array argument:

Jak działa ta formuła Wynik każdego testu kryterialnego jest tablicą wartości TRUE i FALSE. Mnożenie tablic przekształca TRUE i FALSE odpowiednio na 1 i 0 i daje ostateczną tablicę lookup. Jak wiadomo, mnożenie przez 0 zawsze daje zero, więc w tablicy lookup tylko pozycje spełniające wszystkie kryteria są reprezentowane przez 1. A ponieważ naszą wartością lookup jest "1", Excel bierze pierwszą "1" w lookup_array (pierwsze dopasowanie) i zwraca wartość z tablica w tej samej pozycji.

Aby zobaczyć formułę w działaniu, wyciągnijmy kwotę z D2:D10 ( tablica ) z następującymi warunkami:

• Kryterium1 (data) = G1
• Kryterium2 (sprzedawca) = G2
• Kryteria3 (pozycja) = G3

Z datami w A2:A10 ( kryteria_zakresu1 ), nazwy sprzedawców w B2:B10 ( kryteria_zakresu2 ) oraz pozycje w C2:C10 ( kryteria_zakresu3 ), wzór przyjmuje taki kształt:

=XLOOKUP(1, (B2:B10=G1) * (A2:A10=G2) * (C2:C10=G3), D2:D10)

Chociaż funkcja XLOOKUP w Excelu przetwarza tablice, działa jak zwykła formuła i jest zakończona zwykłym naciśnięciem klawisza Enter.

Formuła XLOOKUP z wieloma kryteriami nie jest ograniczona do warunków "równych". Możesz swobodnie używać również innych operatorów logicznych. Na przykład, aby filtrować zamówienia wykonane w dniu w G1 lub wcześniejszym, umieść "<=G1" w pierwszym kryterium:

=XLOOKUP(1, (A2:A10<=G1) * (B2:B10=G2) * (C2:C10=G3), D2:D10)

Podwójny XLOOKUP

Aby znaleźć wartość na przecięciu pewnego wiersza i kolumny, wykonaj tzw. podwójne spojrzenie lub przeglądanie matrycy Tak, Excel XLOOKUP też to potrafi! Po prostu zagnieżdżasz jedną funkcję wewnątrz drugiej:

Jak działa ta formuła Formuła opiera się na zdolności XLOOKUP do zwracania całego wiersza lub kolumny. Funkcja wewnętrzna wyszukuje wartość lookup i zwraca kolumnę lub wiersz powiązanych danych. Ta tablica trafia do funkcji zewnętrznej jako tablica .

W tym przykładzie zamierzamy znaleźć sprzedaż dokonaną przez konkretnego sprzedawcę w ciągu określonego kwartału. W tym celu wprowadzamy wartości lookup w H1 (nazwa sprzedawcy) i H2 (kwartał), i wykonujemy dwukierunkowy Xlookup z następującą formułą:

=XLOOKUP(H1, A2:A6, XLOOKUP(H2, B1:E1, B2:E6))

Albo na odwrót:

=XLOOKUP(H2, B1:E1, XLOOKUP(H1, A2:A6, B2:E6))

Gdzie A2:A6 to nazwy sprzedawców, B1:E1 to kwatery (nagłówki kolumn), a B2:E6 to wartości danych.

Dwukierunkowy lookup można również wykonać za pomocą formuły INDEX Match oraz na kilka innych sposobów. Więcej informacji można znaleźć w artykule Dwukierunkowy lookup w Excelu.

If Error XLOOKUP

Gdy wartość szukana nie zostanie znaleziona, Excel XLOOKUP zwraca błąd #N/A. Dość dobrze znany i zrozumiały dla biegłych użytkowników, może być raczej mylący dla nowicjuszy. Aby zastąpić standardową notację błędu komunikatem przyjaznym dla użytkownika, wpisz własny tekst do czwartego argumentu o nazwie jeśli_nie_znaleziono .

Wracając do pierwszego przykładu omawianego w tym poradniku. Jeśli ktoś wprowadzi nieprawidłową nazwę oceanu w E1, poniższa formuła wyraźnie powie mu, że "Nie znaleziono dopasowania":

=XLOOKUP(E1, A2:A6, B2:B6, "Nie znaleziono dopasowania")

Uwagi:

• Na stronie jeśli_nie_znaleziono argument wychwytuje tylko błędy #N/A, nie wszystkie błędy.
• Błędy #N/A mogą być również obsługiwane za pomocą IFNA i VLOOKUP, ale składnia jest nieco bardziej skomplikowana, a formuła dłuższa.

Rozróżnianie wielkości liter XLOOKUP

Domyślnie funkcja XLOOKUP traktuje małe i duże litery jako te same znaki. Aby rozróżniać wielkość liter, należy użyć funkcji EXACT dla funkcji lookup_array argument:

Jak działa ta formuła Funkcja EXACT porównuje wartość lookup z każdą wartością w tablicy lookup i zwraca TRUE, jeśli są dokładnie takie same, łącznie z wielkością liter, FALSE w przeciwnym wypadku. Ta tablica wartości logicznych trafia do lookup_array W rezultacie XLOOKUP szuka wartości TRUE w powyższej tablicy i zwraca dopasowanie z tablicy zwrotnej.

Na przykład, aby uzyskać cenę od B2:B7 ( tablica ) dla pozycji w E1 ( lookup_value) , wzór w E2 to:

=XLOOKUP(TRUE, EXACT(E1, A2:A7), B2:B7, "Nie znaleziono")

Uwaga. Jeżeli w tablicy lookup znajdują się dwie lub więcej dokładnie takich samych wartości (z uwzględnieniem wielkości liter), to zwracane jest pierwsze znalezione dopasowanie.

Excel XLOOKUP nie działa

Jeśli Twoja formuła nie działa prawidłowo lub powoduje błąd, najprawdopodobniej jest to spowodowane następującymi przyczynami:

XLOOKUP nie jest dostępny w moim Excelu

Funkcja XLOOKUP nie jest kompatybilna wstecz, jest dostępna tylko w Excelu dla Microsoft 365 i Excelu 2021, nie pojawi się we wcześniejszych wersjach.

XLOOKUP zwraca błędny wynik

Jeśli Twoja oczywiście poprawna formuła Xlookup zwraca błędną wartość, istnieje prawdopodobieństwo, że zakres lookup lub zwrotu "przesunął się", gdy formuła została skopiowana w dół lub w poprzek. Aby temu zapobiec, upewnij się, że zawsze blokujesz oba zakresy za pomocą bezwzględnych odniesień do komórek (jak $A$2:$A$10).

XLOOKUP zwraca błąd #N/A

Błąd #N/A oznacza po prostu, że wartość lookup nie została znaleziona. Aby to naprawić, spróbuj wyszukać przybliżone dopasowanie lub poinformuj swoich użytkowników, że nie znaleziono dopasowania.

XLOOKUP zwraca błąd #VALUE

Błąd #VALUE! pojawia się, jeżeli tablica wyszukiwania i tablica zwrotna mają niekompatybilne wymiary. Na przykład nie jest możliwe wyszukiwanie w tablicy poziomej i zwracanie wartości z tablicy pionowej.

XLOOKUP zwraca błąd #REF

Błąd #REF! jest rzucany podczas przeglądania pomiędzy dwoma różnymi skoroszytami, z których jeden jest zamknięty. Aby naprawić błąd, wystarczy otworzyć oba pliki.

Jak właśnie zobaczyłeś, XLOOKUP ma wiele niesamowitych cech, które sprawiają, że jest to funkcja dla prawie każdego lookupu w Excelu. Dziękuję za przeczytanie i mam nadzieję, że zobaczymy się na naszym blogu w przyszłym tygodniu!

Zeszyt ćwiczeń do pobrania

Przykłady formuły XLOOKUP w Excelu (plik .xlsx)