ٹیوٹوریل میں XLOOKUP متعارف کرایا گیا ہے - ایکسل میں عمودی اور افقی تلاش کے لیے نیا فنکشن۔ بائیں تلاش، آخری میچ، متعدد معیارات کے ساتھ Vlookup اور بہت ساری چیزیں جن کو پورا کرنے کے لیے پہلے راکٹ سائنس کی ڈگری کی ضرورت ہوتی تھی اب ABC کی طرح آسان ہو گئے ہیں۔

جب بھی آپ کو Excel میں تلاش کرنے کی ضرورت ہو آپ کون سا فنکشن استعمال کریں گے؟ کیا یہ ایک سنگ بنیاد VLOOKUP ہے یا اس کا افقی بھائی HLOOKUP؟ زیادہ پیچیدہ صورت میں، کیا آپ کیننیکل INDEX MATCH امتزاج پر بھروسہ کریں گے یا Power Query پر کام کریں گے؟ اچھی خبر یہ ہے کہ آپ کے پاس مزید انتخاب نہیں ہے - یہ تمام طریقے ایک زیادہ طاقتور اور ورسٹائل جانشین، XLOOKUP فنکشن کے لیے راستہ بنا رہے ہیں۔

XLOOKUP کیسے بہتر ہے؟ کی طرح سے! یہ عمودی اور افقی طور پر، بائیں اور اوپر دیکھ سکتا ہے، متعدد معیارات کے ساتھ تلاش کر سکتا ہے، اور یہاں تک کہ ڈیٹا کی پوری کالم یا قطار واپس کر سکتا ہے، نہ کہ صرف ایک قدر۔ اس میں مائیکروسافٹ کو 3 دہائیوں سے زیادہ کا عرصہ لگا ہے، لیکن آخر کار وہ ایک مضبوط فنکشن ڈیزائن کرنے میں کامیاب ہو گئے ہیں جو VLOOKUP کی بہت سی مایوس کن غلطیوں اور کمزوریوں پر قابو پاتا ہے۔

کیچ کیا ہے؟ افسوس، ایک ہے. XLOOKUP فنکشن صرف Microsoft 365، Excel 2021، اور Excel کے لیے ویب میں دستیاب ہے۔

Excel XLOOKUP فنکشن - نحو اور استعمال کرتا ہے

XLOOKUP فنکشن ایکسل کسی مخصوص قدر کے لیے رینج یا ایک صف کو تلاش کرتا ہے اور دوسرے کالم سے متعلقہ قدر واپس کرتا ہے۔ یہ دونوں کو دیکھ سکتا ہے۔دلچسپی کے فروخت کنندہ (F2) سے متعلق تمام تفصیلات حاصل کریں۔ آپ کو return_array دلیل:

=XLOOKUP(F2, A2:A7, B2:D7)

آپ اوپر بائیں طرف فارمولہ درج کریں نتائج کی حد کا سیل، اور ایکسل خود بخود نتائج کو ملحقہ خالی خلیوں میں پھیلا دیتا ہے۔ ہمارے معاملے میں، واپسی کی صف (B2:D7) میں 3 کالم ( تاریخ ، آئٹم اور رقم ) شامل ہیں، اور تینوں قدریں رینج میں واپس آ جاتی ہیں۔ G2:I2.

اگر آپ نتائج کو عمودی طور پر کسی کالم میں ترتیب دینا چاہتے ہیں تو، Nest XLOOKUP کو TRANSPOSE فنکشن میں واپس آنے والی صف کو پلٹائیں:

=TRANSPOSE(XLOOKUP(G1, A2:A7, B2:D7))

اسی طرح کے انداز میں، آپ ڈیٹا کا ایک پورا کالم واپس کر سکتے ہیں، رقم کالم۔ اس کے لیے، سیل F1 استعمال کریں جس میں "رقم" بطور lookup_value ، رینج A1:D1 جس میں کالم ہیڈرز ہوں بطور lookup_array اور رینج A2:D7 جس میں کے بطور تمام ڈیٹا موجود ہو۔ return_array .

=XLOOKUP(F1, A1:D1, A2:D7)

نوٹ۔ چونکہ متعدد قدریں پڑوسی خلیوں میں آباد ہیں، اس لیے یقینی بنائیں کہ آپ کے پاس دائیں یا نیچے کافی خالی خلیات ہیں۔ اگر ایکسل کافی خالی سیل نہیں ڈھونڈ سکتا ہے، تو #SPILL! غلطی ہوتی ہے.

ٹپ۔ XLOOKUP نہ صرف متعدد اندراجات واپس کر سکتا ہے بلکہ ان کو دوسری اقدار سے بھی بدل سکتا ہے جو آپ نے بتائی ہیں۔ اس طرح کی بڑی تعداد میں تبدیلی کی ایک مثال یہاں مل سکتی ہے: XLOOKUP کے ساتھ متعدد اقدار کو کیسے تلاش اور تبدیل کیا جائے۔

XLOOKUP کے ساتھایک سے زیادہ معیار

XLOOKUP کا ایک اور بڑا فائدہ یہ ہے کہ یہ صفوں کو مقامی طور پر ہینڈل کرتا ہے۔ اس قابلیت کی وجہ سے، آپ براہ راست lookup_array دلیل میں متعدد معیارات کا جائزہ لے سکتے ہیں:

یہ فارمولہ کیسے کام کرتا ہے : ہر معیار کے ٹیسٹ کا نتیجہ ایک صف ہے TRUE اور FALSE اقدار کا۔ صفوں کی ضرب بالترتیب TRUE اور FALSE کو 1 اور 0 میں تبدیل کرتی ہے، اور حتمی تلاش کی صف پیدا کرتی ہے۔ جیسا کہ آپ جانتے ہیں، 0 سے ضرب کرنے سے ہمیشہ صفر ملتا ہے، لہٰذا تلاش کی صف میں، صرف وہی آئٹمز جو تمام معیارات پر پورا اترتے ہیں 1 کی نمائندگی کرتے ہیں۔ اور چونکہ ہماری تلاش کی قدر "1" ہے، ایکسل <1 میں پہلا "1" لیتا ہے۔>lookup_array (پہلا میچ) اور اسی پوزیشن میں return_array سے قدر لوٹاتا ہے۔

فارمولے کو عمل میں دیکھنے کے لیے، آئیے D2:D10 (<1) سے ایک رقم نکالیں>return_array ) درج ذیل شرائط کے ساتھ:

• Criteria1 (تاریخ) = G1
• Criteria2 (سیلزپرسن) = G2
• Criteria3 (item) = G3

A2:A10 ( criteria_range1 ) میں تاریخوں کے ساتھ، B2:B10 ( criteria_range2 ) میں سیلز پرسن کے نام اور C2:C10 ( ) میں آئٹمز criteria_range3 )، فارمولہ یہ شکل اختیار کرتا ہے:

=XLOOKUP(1, (B2:B10=G1) * (A2:A10=G2) * (C2:C10=G3), D2:D10)

اگرچہ Excel XLOOKUP فنکشن صفوں کو پروسیس کرتا ہے، یہ ایک باقاعدہ فارمولے کے طور پر کام کرتا ہے اور معمول کے انٹر کے ساتھ مکمل ہوتا ہے۔کی اسٹروک۔

متعدد معیارات کے ساتھ XLOOKUP فارمولہ صرف "برابر" شرائط تک محدود نہیں ہے۔ آپ دوسرے منطقی آپریٹرز کو بھی استعمال کرنے کے لیے آزاد ہیں۔ مثال کے طور پر، G1 یا اس سے پہلے کی تاریخ پر کیے گئے آرڈرز کو فلٹر کرنے کے لیے، پہلے معیار میں "<=G1" ڈالیں:

=XLOOKUP(1, (A2:A10<=G1) * (B2:B10=G2) * (C2:C10=G3), D2:D10)

Double XLOOKUP

تلاش کرنے کے لیے ایک خاص قطار اور کالم کے چوراہے پر ایک قدر، نام نہاد ڈبل تلاش یا میٹرکس تلاش انجام دیں۔ جی ہاں، Excel XLOOKUP یہ بھی کر سکتا ہے! آپ صرف ایک فنکشن کو دوسرے کے اندر گھونسلا:

یہ فارمولہ کیسے کام کرتا ہے : فارمولہ XLOOKUP کی پوری قطار یا کالم واپس کرنے کی صلاحیت پر مبنی ہے۔ اندرونی فنکشن اپنی تلاش کی قدر تلاش کرتا ہے اور متعلقہ ڈیٹا کا کالم یا قطار واپس کرتا ہے۔ وہ صف return_array کے طور پر بیرونی فنکشن میں جاتی ہے۔

اس مثال کے لیے، ہم کسی خاص سیلز پرسن کی طرف سے ایک خاص سہ ماہی کے اندر سیلز تلاش کرنے جا رہے ہیں۔ اس کے لیے، ہم H1 (سیلزپرسن کا نام) اور H2 (کوارٹر) میں تلاش کی قدریں درج کرتے ہیں، اور درج ذیل فارمولے کے ساتھ دو طرفہ Xlookup کرتے ہیں:

=XLOOKUP(H1, A2:A6, XLOOKUP(H2, B1:E1, B2:E6))

یا دوسری طرف :

=XLOOKUP(H2, B1:E1, XLOOKUP(H1, A2:A6, B2:E6))

انڈیکس میچ فارمولے کے ساتھ اور ایک دو طرفہ تلاش بھی کی جا سکتی ہے۔چند دوسرے طریقے. مزید معلومات کے لیے، براہ کرم ایکسل میں دو طرفہ تلاش دیکھیں۔

اگر خرابی XLOOKUP

جب تلاش کی قدر نہیں ملتی ہے، تو Excel XLOOKUP ایک #N/A غلطی لوٹاتا ہے۔ ماہر صارفین کے لیے کافی مانوس اور قابل فہم، یہ نوزائیدہوں کے لیے زیادہ الجھن کا باعث ہو سکتا ہے۔ معیاری غلطی کے اشارے کو صارف کے موافق پیغام سے بدلنے کے لیے، اپنا متن 4th argument میں ٹائپ کریں جس کا نام if_not_found ہے۔

اس ٹیوٹوریل میں زیر بحث پہلی مثال پر واپس جائیں۔ اگر کوئی E1 میں سمندر کا غلط نام ڈالتا ہے تو درج ذیل فارمولہ انہیں واضح طور پر بتائے گا کہ "کوئی میچ نہیں ملا":

=XLOOKUP(E1, A2:A6, B2:B6, "No match is found")

نوٹس:

• if_not_found دلیل صرف #N/A غلطیوں کو پکڑتی ہے، تمام خرابیاں نہیں۔
• #N/A کی خرابیوں کو IFNA اور VLOOKUP کے ساتھ بھی سنبھالا جا سکتا ہے، لیکن نحو تھوڑا زیادہ پیچیدہ ہے اور ایک فارمولہ لمبا ہے۔

کیس حساس XLOOKUP

بطور ڈیفالٹ، XLOOKUP فنکشن چھوٹے اور بڑے حروف کو ایک ہی حروف کی طرح سمجھتا ہے۔ اسے کیس حساس بنانے کے لیے، lookup_array دلیل کے لیے EXACT فنکشن استعمال کریں:

یہ فارمولہ کیسے کام کرتا ہے : EXACT فنکشن تلاش کی صف میں ہر قدر کے مقابلے میں تلاش کی قدر کا موازنہ کرتا ہے اور اگر وہ بالکل یکساں ہوں تو TRUE لوٹاتا ہے جس میں لیٹر کیس بھی شامل ہے، دوسری صورت میں FALSE۔ منطقی اقدار کی یہ صف lookup_array پر جاتی ہے۔XLOOKUP کی دلیل۔ نتیجے کے طور پر، XLOOKUP مندرجہ بالا صف میں TRUE قدر تلاش کرتا ہے اور واپسی کی صف سے ایک مماثلت لوٹاتا ہے۔

مثال کے طور پر، B2:B7 ( return_array ) سے قیمت حاصل کرنے کے لیے E1 میں آئٹم ( lookup_value) ، E2 میں فارمولا ہے:

=XLOOKUP(TRUE, EXACT(E1, A2:A7), B2:B7, "Not found")

نوٹ۔ اگر تلاش کی صف میں دو یا زیادہ بالکل ایک جیسی قدریں ہیں (بشمول لیٹر کیس)، تو پہلا ملا ہوا میچ واپس کر دیا جاتا ہے۔ 6

XLOOKUP فنکشن پسماندہ مطابقت نہیں رکھتا ہے۔ یہ مائیکروسافٹ 365 اور ایکسل 2021 کے لیے صرف ایکسل میں دستیاب ہے، اور پہلے کے ورژن میں ظاہر نہیں ہوگا۔

XLOOKUP غلط نتیجہ دیتا ہے

اگر آپ کا واضح طور پر درست Xlookup فارمولہ غلط ویلیو دیتا ہے، تو امکانات ہیں کہ تلاش یا واپسی کی حد "شفٹ" ہو جاتی ہے جب فارمولے کو نیچے یا اس کے پار کاپی کیا جاتا تھا۔ ایسا ہونے سے روکنے کے لیے، ہمیشہ دونوں رینجز کو مطلق سیل حوالوں کے ساتھ مقفل کرنا یقینی بنائیں (جیسے $A$2:$A$10)۔

XLOOKUP #N/A خرابی لوٹاتا ہے

ایک #N /ایک غلطی کا مطلب صرف یہ ہے کہ تلاش کی قیمت نہیں ملی۔ اسے ٹھیک کرنے کے لیے، تخمینی مماثلت تلاش کرنے کی کوشش کریں یا اپنے صارفین کو مطلع کریں کہ کوئی مماثلت نہیں ملی۔

XLOOKUP #VALUE کی خرابی لوٹاتا ہے

A #VALUE! خرابی اس وقت ہوتی ہے اگر تلاش اور واپسی کی صفوں میں مطابقت نہ ہو۔طول و عرض مثال کے طور پر، افقی صف میں تلاش کرنا اور عمودی صف سے قدریں واپس کرنا ممکن نہیں ہے۔

XLOOKUP #REF کی خرابی لوٹاتا ہے

A #REF! دو مختلف ورک بک کے درمیان تلاش کرتے وقت غلطی پھینک دی جاتی ہے، جن میں سے ایک بند ہے۔ غلطی کو ٹھیک کرنے کے لیے، بس دونوں فائلوں کو کھولیں۔

جیسا کہ آپ نے ابھی دیکھا ہے، XLOOKUP میں بہت سی شاندار خصوصیات ہیں جو اسے Excel میں تقریبا کسی بھی تلاش کے لیے فنکشن بناتی ہیں۔ میں پڑھنے کے لیے آپ کا شکریہ ادا کرتا ہوں اور امید کرتا ہوں کہ آپ کو اگلے ہفتے ہمارے بلاگ پر ملوں گا!

ڈاؤن لوڈ کے لیے پریکٹس ورک بک

Excel XLOOKUP فارمولے کی مثالیں (.xlsx فائل)

XLOOKUP فنکشن کا نحو درج ذیل ہے:

پہلے 3 دلائل درکار ہیں اور آخری تین اختیاری ہیں۔

• Lookup_value - قدر تلاش کریں 11>
• if_not_found [اختیاری] - کوئی مماثلت نہ ملنے پر واپس کرنے کی قدر۔ اگر چھوڑ دیا جائے تو، ایک #N/A خرابی واپس آ جاتی ہے۔
• Match_mode [اختیاری] - انجام دینے کے لیے میچ کی قسم:
  • 0 یا چھوڑ دیا گیا (پہلے سے طے شدہ) - عین مطابق مماثلت . اگر نہیں ملا تو، ایک #N/A خرابی لوٹائی جاتی ہے۔
  • -1 - عین مطابق یا اگلی چھوٹی۔ اگر کوئی عین مطابق مماثلت نہیں ملتی ہے، تو اگلی چھوٹی قدر لوٹائی جاتی ہے۔
  • 1 - عین مطابق مماثلت یا اگلی بڑی۔ اگر کوئی عین مطابق مماثلت نہیں ملتی ہے، تو اگلی بڑی قدر واپس کر دی جاتی ہے۔
  • 2 - وائلڈ کارڈ کریکٹر میچ۔
• Search_mode [اختیاری] - تلاش کی سمت:
  • 1 یا چھوڑ دیا گیا (ڈیفالٹ) - پہلے سے آخری تک تلاش کرنے کے لیے۔
  • -1 - الٹ ترتیب میں تلاش کرنے کے لیے، آخری سے پہلے تک۔
  • 2 - ڈیٹا پر بائنری تلاش صعودی ترتیب سے ترتیب دی گئی ہے۔
  • -2 - ڈیٹا پر بائنری تلاش نزولی ترتیب سے ترتیب دی گئی ہے۔

  مائیکروسافٹ کے مطابق، بائنریتلاش اعلی درجے کے صارفین کے لیے شامل ہے۔ یہ ایک خاص الگورتھم ہے جو ترتیب شدہ سرنی کے اندر تلاش کی قدر کی پوزیشن کو صف کے درمیانی عنصر سے موازنہ کرکے تلاش کرتا ہے۔ ایک بائنری تلاش ایک عام تلاش کے مقابلے میں بہت تیز ہے لیکن صرف ترتیب شدہ ڈیٹا پر صحیح طریقے سے کام کرتی ہے۔

بنیادی XLOOKUP فارمولہ

مزید تفہیم حاصل کرنے کے لیے، آئیے ایک Xlookup فارمولہ کو اس کی آسان ترین شکل میں بنائیں تاکہ درست تلاش کریں۔ اس کے لیے ہمیں صرف پہلے 3 دلائل کی ضرورت ہوگی۔

فرض کریں، آپ کے پاس زمین پر موجود پانچ سمندروں کے بارے میں معلومات کے ساتھ ایک خلاصہ ٹیبل ہے۔ آپ F1 ( lookup_value ) میں ایک مخصوص سمندری ان پٹ کا رقبہ حاصل کرنا چاہتے ہیں۔ A2:A6 ( lookup_array ) میں سمندروں کے ناموں اور C2:C6 ( return_array ) میں علاقوں کے ساتھ، فارمولہ مندرجہ ذیل ہے:

=XLOOKUP(F1, A2:A6, C2:C6)

سادہ انگریزی میں ترجمہ کیا گیا، یہ کہتا ہے: A2:A6 میں F1 قدر تلاش کریں اور اسی قطار میں C2:C6 سے ایک قدر واپس کریں۔ کوئی کالم انڈیکس نمبر نہیں، کوئی چھانٹی نہیں، Vlookup کے کوئی اور مضحکہ خیز نرالا نہیں! یہ صرف کام کرتا ہے :)

ایکسل میں XLOOKUP بمقابلہ VLOOKUP

روایتی VLOOKUP کے مقابلے میں، XLOOKUP کے بہت سے فوائد ہیں۔ یہ کس طرح سے VLOOKUP سے بہتر ہے؟ یہاں بہترین 10 خصوصیات کی فہرست ہے جو ایکسل میں کسی بھی دوسرے تلاش کے فنکشن کو بند کر دیتی ہیں:

1. عمودی اور افقی تلاش ۔ XLOOKUP فنکشن کو اس کا نام عمودی اور دونوں طرف دیکھنے کی صلاحیت کی وجہ سے ملاافقی طور پر۔
2. کسی بھی سمت دیکھیں: دائیں، بائیں، نیچے یا اوپر ۔ جبکہ VLOOKUP صرف بائیں کالم میں اور HLOOKUP کو سب سے اوپر والی قطار میں تلاش کر سکتا ہے، XLOOKUP میں ایسی کوئی پابندیاں نہیں ہیں۔ ایکسل میں بدنام زمانہ بائیں تلاش اب کوئی تکلیف نہیں ہے!
3. بطور ڈیفالٹ بالکل مماثل ۔ زیادہ تر حالات میں، آپ ایک عین مطابق مماثلت تلاش کر رہے ہوں گے، اور XLOOKUP اسے بطور ڈیفالٹ واپس کر دیتا ہے (VLOOKUP فنکشن کے برعکس جو کہ تخمینی مماثلت کے لیے ڈیفالٹ ہوتا ہے)۔ بلاشبہ، ضرورت پڑنے پر آپ ایک تخمینی مماثلت بھی انجام دینے کے لیے XLOOKUP حاصل کر سکتے ہیں۔
4. وائلڈ کارڈز کے ساتھ جزوی میچ ۔ جب آپ کو تلاش کی قیمت کا صرف کچھ حصہ معلوم ہوتا ہے، نہ کہ تمام، تو وائلڈ کارڈ میچ کام آتا ہے۔
5. الٹ ترتیب میں تلاش کریں ۔ اس سے پہلے، آخری واقعہ حاصل کرنے کے لیے، آپ کو اپنے سورس ڈیٹا کی ترتیب کو ریورس کرنا پڑتا تھا۔ اب، آپ اپنے Xlookup فارمولے کو پیچھے سے تلاش کرنے اور آخری میچ واپس کرنے پر مجبور کرنے کے لیے صرف search_mode دلیل کو -1 پر سیٹ کرتے ہیں۔
6. متعدد اقدار واپس کریں ۔ return_array دلیل کے ساتھ جوڑ توڑ کرکے، آپ اپنی تلاش کی قدر سے متعلق ڈیٹا کی ایک پوری قطار یا کالم کھینچ سکتے ہیں۔
7. متعدد معیار کے ساتھ تلاش کریں ۔ ایکسل XLOOKUP صفوں کو مقامی طور پر ہینڈل کرتا ہے، جس سے متعدد معیارات کے ساتھ تلاش کرنا ممکن ہو جاتا ہے۔
8. اگر ایرر فنکشنلٹی ۔ روایتی طور پر، ہم #N/A غلطیوں کو پھنسانے کے لیے IFNA فنکشن کا استعمال کرتے ہیں۔ XLOOKUP اس فعالیت کو میں شامل کرتا ہے۔ if_not_found دلیل جو آپ کے اپنے متن کو آؤٹ پٹ کرنے کی اجازت دیتی ہے اگر کوئی درست مماثلت نہیں ملتی ہے۔
9. کالم داخل کرنا/حذف کرنا ۔ VLOOKUP کے ساتھ سب سے زیادہ پریشان کن مسائل میں سے ایک یہ ہے کہ کالموں کو شامل کرنے یا ہٹانے سے ایک فارمولہ ٹوٹ جاتا ہے کیونکہ واپسی کالم کی شناخت اس کے انڈیکس نمبر سے ہوتی ہے۔ XLOOKUP کے ساتھ، آپ واپسی کی حد فراہم کرتے ہیں، نمبر نہیں، یعنی آپ کسی بھی چیز کو توڑے بغیر جتنے چاہیں کالم داخل اور ہٹا سکتے ہیں۔
10. بہتر کارکردگی ۔ VLOOKUP آپ کی ورک شیٹس کو سست کر سکتا ہے کیونکہ اس میں حساب میں پورا ٹیبل شامل ہوتا ہے، جس کے نتیجے میں درحقیقت ضرورت سے کہیں زیادہ سیلز پر کارروائی ہوتی ہے۔ XLOOKUP صرف تلاش اور واپسی کی صفوں کو ہینڈل کرتا ہے جس پر یہ واقعی منحصر ہے۔

ایکسل میں XLOOKUP کا استعمال کیسے کریں - فارمولہ مثالیں

مندرجہ ذیل مثالیں سب سے زیادہ کارآمد XLOOKUP خصوصیات کو عملی طور پر ظاہر کرتی ہیں۔ مزید برآں، آپ کو کچھ ایسے غیر معمولی استعمالات دریافت ہوں گے جو آپ کے ایکسل کی تلاش کی مہارت کو ایک نئی سطح پر لے جائیں گے۔

عمودی اور افقی طور پر دیکھیں

مائیکروسافٹ ایکسل مختلف تلاش کے لیے دو افعال رکھتا تھا۔ اقسام، ہر ایک کا اپنا نحو اور استعمال کے اصول ہیں: کالم میں عمودی طور پر دیکھنے کے لیے VLOOKUP اور قطار میں افقی طور پر دیکھنے کے لیے HLOOKUP۔

XLOOKUP فنکشن ایک ہی نحو کے ساتھ دونوں کام کر سکتا ہے۔ فرق اس میں ہے کہ آپ تلاش اور واپسی کی صفوں کے لیے کیا فراہم کرتے ہیں۔

v-lookup کے لیے، کالم فراہم کریں:

=XLOOKUP(E1, A2:A6, B2:B6)

کے لیےh-lookup، کالم کی بجائے قطاریں درج کریں:

=XLOOKUP(I1, B1:F1, B2:F2)

بائیں تلاش مقامی طور پر انجام دی گئی

ایکسل کے پہلے ورژن میں، INDEX MATCH فارمولہ بائیں یا اوپر دیکھنے کا واحد قابل اعتماد طریقہ تھا۔ اب، آپ کو دو فنکشنز کو اکٹھا کرنے کی ضرورت نہیں ہے جہاں ایک کافی ہو گا۔ بس ٹارگٹ تلاش کرنے والی صف کی وضاحت کریں، اور XLOOKUP اس کے مقام سے قطع نظر اسے بغیر کسی دشواری کے ہینڈل کرے گا۔

مثال کے طور پر، آئیے اپنے نمونے کی میز کے بائیں جانب Rank کالم شامل کریں۔ مقصد F1 میں سمندری ان پٹ کا درجہ حاصل کرنا ہے۔ VLOOKUP یہاں ٹھوکر کھائے گا کیونکہ یہ صرف تلاش کے کالم کے دائیں طرف کالم سے ایک قدر واپس کر سکتا ہے۔ ایک Xlookup فارمولہ آسانی کے ساتھ مقابلہ کرتا ہے:

=XLOOKUP(F1, B2:B6, A2:A6)

اسی طرح، آپ قطاروں میں افقی طور پر تلاش کرتے وقت اوپر دیکھ سکتے ہیں۔

XLOOKUP قطعی اور تخمینی مماثلت کے ساتھ

میچ کے رویے کو match_mode نامی 5ویں دلیل کے ذریعے کنٹرول کیا جاتا ہے۔ پہلے سے طے شدہ طور پر، ایک عین مطابق مماثلت انجام دی جاتی ہے۔

براہ کرم اس بات پر توجہ دیں کہ جب آپ ایک تخمینی مماثلت ( match_mode 1 یا -1 پر سیٹ کریں) کا انتخاب کرتے ہیں، تب بھی فنکشن بالکل درست تلاش کرے گا۔ پہلے میچ. فرق اس بات میں ہے کہ اگر کوئی درست تلاش کی قیمت نہیں ملتی ہے تو یہ کیا لوٹاتا ہے۔

Match_mode argument:

• 0 یا چھوڑ دیا گیا - عین مطابق میچ؛ اگر نہیں ملا - #N/A خرابی۔
• -1 - عین مطابق مماثلت؛ اگر نہیں ملا تو - اگلی چھوٹی آئٹم۔
• 1 - عین مطابق مماثلت؛ اگر نہیں ملا- اگلا بڑا آئٹم۔

بالکل مماثل XLOOKUP

یہ وہ آپشن ہے جو آپ Excel میں تلاش کرنے کے وقت کا 99% استعمال کرتے ہیں۔ چونکہ ایک عین مطابق مماثلت XLOOKUP کا ڈیفالٹ رویہ ہے، اس لیے آپ match_mode کو چھوڑ سکتے ہیں اور صرف پہلے 3 مطلوبہ دلائل فراہم کر سکتے ہیں۔

بعض حالات میں، تاہم، عین مطابق میچ کام نہیں کرے گا۔ ایک عام منظر نامہ وہ ہوتا ہے جب آپ کی تلاش کی میز تمام اقدار پر مشتمل نہیں ہوتی ہے، بلکہ "سنگ میل" یا "باؤنڈز" جیسے مقدار پر مبنی چھوٹ، سیلز پر مبنی کمیشن وغیرہ۔ امتحان کے اسکور اور گریڈ کے درمیان۔ جیسا کہ آپ نیچے دیے گئے اسکرین شاٹ میں دیکھ سکتے ہیں، عین مطابق مماثلت صرف اس وقت کام کرتی ہے جب کسی خاص طالب علم کا سکور تلاش کی میز میں موجود قدر سے بالکل میل کھاتا ہے (جیسے قطار 3 میں عیسائی)۔ دیگر تمام معاملات میں، ایک #N/A خرابی واپس آ جاتی ہے۔

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6)

#N/A غلطیوں کے بجائے گریڈ حاصل کرنے کے لیے، ہمیں ضرورت ہے ایک تخمینی مماثلت تلاش کرنے کے لیے جیسا کہ اگلی مثال میں دکھایا گیا ہے۔

تقریبا میچ XLOOKUP

ایک تخمینی تلاش کرنے کے لیے، match_mode دلیل کو -1 یا 1 پر سیٹ کریں۔ ، اس بات پر منحصر ہے کہ آپ کا ڈیٹا کیسے منظم ہے۔

ہمارے معاملے میں، تلاش کی میز درجات کی نچلی حدوں کی فہرست بناتی ہے۔ لہذا، ہم نے اگلی چھوٹی قدر تلاش کرنے کے لیے match_mode کو -1 پر سیٹ کیا ہے جب کوئی عین مطابق مماثلت نہیں ملتی ہے:

=XLOOKUP(F11, $B$11:$B$15, $C$11:$C$15, ,-1)

مثال کے طور پر، برائن کا اسکور ہے 98 (F2)۔ فارمولہ اس تلاش کی قدر کو B2:B6 میں تلاش کرتا ہے۔لیکن اسے نہیں مل سکتا. پھر، یہ اگلی چھوٹی آئٹم کو تلاش کرتا ہے اور 90 تلاش کرتا ہے، جو کہ گریڈ A:

اگر ہماری تلاش کی میز میں درجات کی اوپری حدود پر مشتمل ہے، تو ہم سیٹ کریں گے match_mode اگلے بڑے آئٹم کو تلاش کرنے کے لیے اگر کوئی عین مطابق مماثلت ناکام ہوجاتی ہے:

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6, ,1)

فارمولہ 98 کو تلاش کرتا ہے اور دوبارہ اسے تلاش نہیں کرسکتا۔ اس بار، یہ اگلی بڑی قدر تلاش کرنے کی کوشش کرتا ہے اور گریڈ A:

ٹپ کے مطابق 100 حاصل کرتا ہے۔ ایک سے زیادہ سیلز میں ایک Xlookup فارمولے کو کاپی کرتے وقت، ان کو تبدیل کرنے سے روکنے کے لیے مطلق سیل حوالوں (جیسے $B$2:$B$6) کے ساتھ تلاش یا واپسی کی رینجز کو لاک کریں۔

جزوی میچ کے ساتھ XLOOKUP (وائلڈ کارڈز)

جزوی میچ تلاش کرنے کے لیے، match_mode دلیل کو 2 پر سیٹ کریں، جو XLOOKUP فنکشن کو وائلڈ کارڈ کے حروف پر کارروائی کرنے کی ہدایت کرتا ہے:

• ایک ستارہ (*) - حروف کی کسی بھی ترتیب کو ظاہر کرتا ہے۔
• ایک سوالیہ نشان (؟) - کسی ایک حرف کی نمائندگی کرتا ہے۔

یہ دیکھنے کے لیے کہ یہ کیسے کام کرتا ہے ، براہ کرم مندرجہ ذیل مثال پر غور کریں۔ کالم A میں، آپ کے پاس اسمارٹ فون کے چند ماڈلز ہیں اور، کالم B میں، ان کی بیٹری کی صلاحیت۔ آپ کسی خاص اسمارٹ فون کی بیٹری کے بارے میں جاننا چاہتے ہیں۔ مسئلہ یہ ہے کہ آپ کو یقین نہیں ہے کہ آپ ماڈل کا نام بالکل اسی طرح ٹائپ کر سکتے ہیں جیسا کہ کالم A میں نظر آتا ہے۔ اس پر قابو پانے کے لیے، وہ حصہ درج کریں جو یقینی طور پر موجود ہے اور باقی حروف کو وائلڈ کارڈز سے بدل دیں۔

مثال کے طور پر، حاصل کرناآئی فون ایکس کی بیٹری کے بارے میں معلومات کے لیے یہ فارمولہ استعمال کریں:

=XLOOKUP("*iphone X*", A2:A8, B2:B8, ,2)

یا، کسی سیل میں تلاش کی قدر کا معلوم حصہ داخل کریں اور سیل کے حوالہ کو وائلڈ کارڈ کے حروف کے ساتھ جوڑیں:<3 13 آخری میچ واپس کرنے کے لیے۔ اسے مکمل کرنے کے لیے، الٹ ترتیب میں تلاش کرنے کے لیے اپنے Xlookup فارمولے کو ترتیب دیں۔

تلاش کی سمت کو search_mode :

• 1 نامی 6 ویں دلیل کے طور پر کنٹرول کیا جاتا ہے۔ یا چھوڑ دیا گیا (پہلے سے طے شدہ) - پہلی سے آخری قدر تک تلاش کرتا ہے، یعنی عمودی تلاش کے ساتھ اوپر سے نیچے تک یا افقی تلاش کے ساتھ بائیں سے دائیں تک۔
• -1 - آخری سے پہلی قدر تک الٹ ترتیب میں تلاش کرتا ہے۔ .

مثال کے طور پر، آئیے ایک مخصوص سیلز پرسن کی طرف سے کی گئی آخری فروخت واپس کرتے ہیں۔ اس کے لیے، ہم نے پہلے تین مطلوبہ دلائل جمع کیے ( lookup_value کے لیے G1، lookup_array کے لیے B2:B9، اور D2:D9 return_array کے لیے) اور ڈالیں۔ 5 ویں دلیل میں 1:

=XLOOKUP(G1, B2:B9, D2:D9, , ,-1)

سیدھا اور آسان، ہے نا؟

26>

متعدد کالم یا قطاریں واپس کرنے کے لیے XLOOKUP

XLOOKUP کی ایک اور حیرت انگیز خصوصیت ایک ہی میچ سے متعلق ایک سے زیادہ ویلیو واپس کرنے کی صلاحیت ہے۔ سب کچھ معیاری نحو کے ساتھ اور بغیر کسی اضافی ہیرا پھیری کے کیا جاتا ہے!

نیچے دیے گئے جدول سے، فرض کریں کہ آپ چاہتے ہیں