Tutorial ini memperkenalkan XLOOKUP - fungsi baru untuk pencarian vertikal dan horizontal di Excel. Pencarian kiri, pencocokan terakhir, Vlookup dengan beberapa kriteria, dan banyak lagi hal yang dulunya membutuhkan gelar sains roket untuk menyelesaikannya sekarang menjadi semudah ABC.

Kapan pun Anda perlu mencari di Excel, fungsi mana yang akan Anda gunakan? Apakah itu landasan VLOOKUP atau saudara kandung horizontalnya HLOOKUP? Dalam kasus yang lebih kompleks, apakah Anda akan mengandalkan kombinasi INDEX MATCH kanonik atau menyerahkan pekerjaan ke Power Query? Kabar baiknya adalah Anda tidak perlu memilih lagi - semua metode ini memberi jalan bagi penerus yang lebih kuat dan serbaguna, fungsi XLOOKUP.

Bagaimana XLOOKUP lebih baik? Dalam banyak hal! XLOOKUP bisa melihat secara vertikal dan horizontal, ke kiri dan ke atas, mencari dengan beberapa kriteria, dan bahkan mengembalikan seluruh kolom atau baris data, bukan hanya satu nilai. Microsoft membutuhkan waktu lebih dari 3 dekade, tetapi akhirnya mereka berhasil merancang fungsi yang kuat yang mengatasi banyak kesalahan dan kelemahan VLOOKUP yang membuat frustrasi.

Fungsi XLOOKUP hanya tersedia di Excel untuk Microsoft 365, Excel 2021, dan Excel untuk web.

Fungsi Excel XLOOKUP - sintaksis dan penggunaan

Fungsi XLOOKUP di Excel mencari rentang atau larik untuk nilai tertentu dan mengembalikan nilai terkait dari kolom lain. Ini dapat mencari secara vertikal dan horizontal dan melakukan pencocokan tepat (default), perkiraan (terdekat) cocok, atau pencocokan wildcard (sebagian).

Sintaks dari fungsi XLOOKUP adalah sebagai berikut:

3 argumen pertama diperlukan dan tiga argumen terakhir bersifat opsional.

• Lookup_value - nilai yang akan dicari.
• Lookup_array - range atau array tempat pencarian.
• Return_array - rentang atau larik untuk mengembalikan nilai.
• Jika_tidak_ditemukan [opsional] - nilai yang akan dikembalikan jika tidak ditemukan kecocokan. Jika dihilangkan, kesalahan #N/A akan dikembalikan.
• Match_mode [opsional] - tipe pencocokan yang akan dilakukan:
  • 0 atau dihilangkan (default) - pencocokan yang tepat. Jika tidak ditemukan, kesalahan #N/A akan dikembalikan.
  • -1 - sama persis atau lebih kecil berikutnya. Jika kecocokan yang tepat tidak ditemukan, nilai yang lebih kecil berikutnya akan dikembalikan.
  • 1 - sama persis atau lebih besar berikutnya. Jika kecocokan yang tepat tidak ditemukan, nilai yang lebih besar berikutnya akan dikembalikan.
  • 2 - pencocokan karakter wildcard.
• Search_mode [opsional] - arah pencarian:
  • 1 atau dihilangkan (default) - untuk mencari dari yang pertama sampai yang terakhir.
  • -1 - untuk mencari dalam urutan terbalik, dari terakhir ke pertama.
  • 2 - pencarian biner pada data yang diurutkan menaik.
  • -2 - pencarian biner pada data yang diurutkan menurun.

  Menurut Microsoft, pencarian biner Ini adalah algoritma khusus yang menemukan posisi nilai pencarian dalam larik yang diurutkan dengan membandingkannya dengan elemen tengah larik. Pencarian biner jauh lebih cepat daripada pencarian biasa tetapi bekerja dengan benar hanya pada data yang diurutkan.

Rumus dasar XLOOKUP

Untuk mendapatkan pemahaman lebih lanjut, mari kita buat rumus Xlookup dalam bentuknya yang paling sederhana untuk melakukan pencarian yang tepat. Untuk ini, kita hanya membutuhkan 3 argumen pertama.

Misalkan, Anda memiliki tabel ringkasan dengan informasi tentang lima samudra di Bumi. Anda ingin mendapatkan area dari input samudra tertentu dalam F1 ( lookup_value Dengan nama-nama samudra di A2:A6 ( lookup_array ) dan area di C2:C6 ( return_array ), rumusnya adalah sebagai berikut:

=XLOOKUP(F1, A2:A6, C2:C6)

Diterjemahkan ke dalam bahasa Inggris sederhana, dikatakan: cari nilai F1 di A2: A6 dan kembalikan nilai dari C2: C6 di baris yang sama. Tidak ada nomor indeks kolom, tidak ada penyortiran, tidak ada keunikan konyol lainnya dari Vlookup! Ini hanya berfungsi :)

XLOOKUP vs VLOOKUP di Excel

Dibandingkan dengan VLOOKUP tradisional, XLOOKUP memiliki banyak keunggulan. Dengan cara apa itu lebih baik dari VLOOKUP? Berikut adalah daftar 10 fitur terbaik yang mengalahkan fungsi pencarian lainnya di Excel:

1. Pencarian vertikal dan horizontal Fungsi XLOOKUP mendapatkan namanya karena kemampuannya untuk mencari baik secara vertikal maupun horizontal.
2. Lihat ke segala arah: kanan, kiri, bawah atau atas Sementara VLOOKUP hanya bisa mencari di kolom paling kiri dan HLOOKUP di baris paling atas, XLOOKUP tidak memiliki batasan seperti itu. Pencarian kiri yang terkenal buruk di Excel tidak lagi merepotkan!
3. Pencocokan yang tepat secara default Dalam kebanyakan situasi, anda akan mencari kecocokan yang tepat, dan XLOOKUP mengembalikannya secara default (tidak seperti fungsi VLOOKUP yang defaultnya adalah perkiraan kecocokan). Tentu saja, anda bisa mendapatkan XLOOKUP untuk melakukan perkiraan kecocokan juga jika diperlukan.
4. Kecocokan parsial dengan wildcard Bila Anda hanya mengetahui sebagian dari nilai pencarian, tidak semuanya, maka pencocokan wildcard akan sangat berguna.
5. Cari dalam urutan terbalik Sebelumnya, untuk mendapatkan kejadian terakhir, Anda harus membalik urutan data sumber Anda. Sekarang, Anda cukup mengatur search_mode argumen ke -1 untuk memaksa rumus Xlookup Anda mencari dari belakang dan mengembalikan kecocokan terakhir.
6. Kembalikan beberapa nilai Dengan memanipulasi dengan return_array argumen, Anda dapat menarik seluruh baris atau kolom data yang terkait dengan nilai pencarian Anda.
7. Cari dengan beberapa kriteria Excel XLOOKUP menangani array secara native, yang memungkinkan untuk melakukan pencarian dengan beberapa kriteria.
8. Jika fungsi kesalahan Secara tradisional, kita menggunakan fungsi IFNA untuk menjebak error #N/A. XLOOKUP menggabungkan fungsi ini dalam fungsi if_not_found argumen yang memungkinkan untuk mengeluarkan teks Anda sendiri jika tidak ditemukan kecocokan yang valid.
9. Penyisipan/penghapusan kolom Salah satu masalah yang paling menjengkelkan dengan VLOOKUP adalah bahwa menambahkan atau menghapus kolom akan merusak formula karena kolom yang dikembalikan diidentifikasi oleh nomor indeksnya. Dengan XLOOKUP, Anda menyediakan rentang pengembalian, bukan nomor, yang berarti Anda dapat memasukkan dan menghapus kolom sebanyak yang Anda butuhkan tanpa merusak apa pun.
10. Kinerja yang lebih baik VLOOKUP bisa memperlambat lembar kerja Anda karena menyertakan seluruh tabel dalam kalkulasi, yang mengakibatkan pemrosesan sel jauh lebih banyak daripada yang sebenarnya dibutuhkan. XLOOKUP hanya menangani lookup dan mengembalikan array yang benar-benar bergantung padanya.

Cara menggunakan XLOOKUP di Excel - contoh rumus

Contoh-contoh berikut mendemonstrasikan fitur-fitur XLOOKUP yang paling berguna dalam tindakan. Selain itu, Anda akan menemukan beberapa penggunaan non-sepele yang akan membawa keterampilan pencarian Excel Anda ke tingkat yang baru.

Lihat ke atas secara vertikal dan horizontal

Microsoft Excel dulu memiliki dua fungsi untuk jenis pencarian yang berbeda, masing-masing memiliki sintaks dan aturan penggunaannya sendiri: VLOOKUP untuk melihat secara vertikal dalam kolom dan HLOOKUP untuk melihat secara horizontal dalam satu baris.

Fungsi XLOOKUP dapat melakukan keduanya dengan sintaks yang sama. Perbedaannya adalah pada apa yang Anda sediakan untuk array pencarian dan pengembalian.

Untuk v-lookup, menyediakan kolom:

=XLOOKUP(E1, A2:A6, B2:B6)

Untuk h-lookup, masukkan baris, bukan kolom:

=XLOOKUP(I1, B1:F1, B2:F2)

Pencarian kiri dilakukan secara native

Dalam versi Excel sebelumnya, rumus INDEX MATCH adalah satu-satunya cara yang dapat diandalkan untuk melihat ke kiri atau di atas. Sekarang, Anda tidak perlu lagi menggabungkan dua fungsi di mana satu fungsi sudah cukup. Cukup tentukan array pencarian target, dan XLOOKUP akan menanganinya tanpa masalah terlepas dari lokasinya.

Sebagai contoh, mari kita tambahkan Pangkat Tujuannya adalah untuk mendapatkan peringkat input lautan di F1. VLOOKUP akan tersandung di sini karena hanya dapat mengembalikan nilai dari kolom di sebelah kanan kolom pencarian. Formula Xlookup dapat mengatasi dengan mudah:

=XLOOKUP(F1, B2:B6, A2:A6)

Dengan cara yang sama, Anda bisa melihat di atas ketika mencari secara horizontal dalam barisan.

XLOOKUP dengan pencocokan tepat dan perkiraan

Perilaku pencocokan dikendalikan oleh argumen ke-5 yang disebut match_mode Secara default, pencocokan persis dilakukan.

Harap perhatikan, bahwa bahkan apabila Anda memilih perkiraan kecocokan ( match_mode diatur ke 1 atau -1), fungsi masih akan mencari kecocokan persis terlebih dahulu. Perbedaannya adalah pada apa yang dikembalikannya jika nilai pencarian yang tepat tidak ditemukan.

Argumen Match_mode:

• 0 atau dihilangkan - sama persis; jika tidak ditemukan - kesalahan #N/A.
• -1 - sama persis; jika tidak ditemukan - item berikutnya yang lebih kecil.
• 1 - sama persis; jika tidak ditemukan - item berikutnya yang lebih besar.

Pencocokan yang tepat XLOOKUP

Ini adalah opsi yang mungkin Anda gunakan 99% dari waktu Anda melakukan pencarian di Excel. Karena pencocokan tepat adalah perilaku default XLOOKUP, Anda dapat menghilangkan match_mode dan hanya menyediakan 3 argumen pertama yang diperlukan.

Namun, dalam beberapa situasi, pencocokan persis tidak akan berhasil. Skenario tipikal adalah ketika tabel pencarian Anda tidak berisi semua nilai, melainkan "tonggak" atau "batas" seperti diskon berbasis kuantitas, komisi berbasis penjualan, dll.

Contoh tabel pencarian kami menunjukkan korelasi antara nilai ujian dan nilai. Seperti yang bisa anda lihat pada gambar di bawah ini, pencocokan yang tepat hanya bekerja ketika nilai dari siswa tertentu cocok dengan nilai dalam tabel pencarian dengan tepat (seperti Christian di baris 3). Dalam semua kasus lain, kesalahan #N/A dikembalikan.

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6)

Untuk mendapatkan nilai, bukannya kesalahan #N/A, kita perlu mencari perkiraan kecocokan seperti yang ditunjukkan dalam contoh berikut.

Perkiraan kecocokan XLOOKUP

Untuk melakukan pencarian perkiraan, tetapkan match_mode argumen ke -1 atau 1, tergantung pada bagaimana data Anda diatur.

Dalam kasus kita, tabel pencarian mencantumkan batas bawah nilai. Jadi, kita menetapkan match_mode ke -1 untuk mencari nilai yang lebih kecil berikutnya ketika kecocokan yang tepat tidak ditemukan:

=XLOOKUP(F11, $B$11:$B$15, $C$11:$C$15, ,-1)

Misalnya, Brian memiliki nilai 98 (F2). Rumus mencari nilai pencarian ini di B2:B6 tetapi tidak dapat menemukannya. Kemudian, rumus mencari item berikutnya yang lebih kecil dan menemukan 90, yang sesuai dengan nilai A:

Jika tabel pencarian kita berisi batas atas nilai, kita akan menetapkan match_mode ke 1 untuk mencari item yang lebih besar berikutnya jika kecocokan yang tepat gagal:

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6, ,1)

Rumus mencari 98 dan lagi-lagi tidak bisa menemukannya. Kali ini, rumus ini mencoba mencari nilai berikutnya yang lebih besar dan mendapatkan 100, yang sesuai dengan nilai A:

Tip. Saat menyalin rumus Xlookup ke beberapa sel, kunci pencarian atau kembalikan rentang dengan referensi sel absolut (seperti $ B $ 2: $ B $ 6) untuk mencegahnya berubah.

XLOOKUP dengan pencocokan parsial (wildcard)

Untuk melakukan pencarian kecocokan parsial, tetapkan match_mode argumen ke 2, yang menginstruksikan fungsi XLOOKUP untuk memproses karakter wildcard:

• Tanda bintang (*) - mewakili urutan karakter apa pun.
• Tanda tanya (?) - mewakili karakter tunggal apa pun.

Untuk melihat cara kerjanya, silakan perhatikan contoh berikut ini. Di kolom A, Anda memiliki beberapa model smartphone dan, di kolom B, kapasitas baterainya. Anda penasaran dengan baterai smartphone tertentu. Masalahnya, Anda tidak yakin bisa mengetikkan nama model persis seperti yang muncul di kolom A. Untuk mengatasinya, masukkan bagian yang sudah pasti ada dan ganti sisanya.karakter dengan wildcard.

Misalnya, untuk mendapatkan informasi tentang baterai iPhone X, gunakan rumus ini:

=XLOOKUP("*iphone X*", A2:A8, B2:B8, ,2)

Atau, masukkan bagian yang diketahui dari nilai pencarian di beberapa sel dan gabungkan referensi sel dengan karakter wildcard:

=XLOOKUP("*"&E1& "*", A2:A8, B2:B8, ,2)

XLOOKUP dalam urutan terbalik untuk mendapatkan kejadian terakhir

Jika tabel Anda berisi beberapa kemunculan nilai pencarian, terkadang Anda mungkin perlu mengembalikan nilai pertandingan terakhir Untuk menyelesaikannya, konfigurasikan rumus Xlookup Anda untuk mencari dalam urutan terbalik.

Arah pencarian dikontrol menjadi argumen ke-6 bernama search_mode :

• 1 atau dihilangkan (default) - mencari dari nilai pertama hingga terakhir, yaitu dari atas ke bawah dengan pencarian vertikal atau dari kiri ke kanan dengan pencarian horizontal.
• -1 - mencari dalam urutan terbalik dari nilai terakhir ke nilai pertama.

Sebagai contoh, mari kita kembalikan penjualan terakhir yang dilakukan oleh tenaga penjualan tertentu. Untuk ini, kita mengumpulkan tiga argumen pertama yang diperlukan (G1 untuk lookup_value , B2:B9 untuk lookup_array dan D2:D9 untuk return_array ) dan meletakkan -1 pada argumen ke-5:

=XLOOKUP(G1, B2:B9, D2:D9, , ,-1)

Lugas dan mudah, bukan?

XLOOKUP untuk mengembalikan beberapa kolom atau baris

Satu lagi fitur menakjubkan dari XLOOKUP adalah kemampuannya untuk mengembalikan lebih dari satu nilai yang berkaitan dengan kecocokan yang sama. Semua dilakukan dengan sintaks standar dan tanpa manipulasi tambahan!

Dari tabel di bawah ini, seandainya Anda ingin mengambil semua detail yang berkaitan dengan wiraniaga yang diinginkan (F2). Yang perlu Anda lakukan adalah menyediakan rentang, bukan kolom atau baris tunggal, untuk return_array argumen:

=XLOOKUP(F2, A2:A7, B2:D7)

Anda memasukkan rumus di sel kiri atas dari rentang hasil, dan Excel secara otomatis menumpahkan hasilnya ke dalam sel kosong yang berdekatan. Dalam kasus kami, larik kembali (B2: D7) mencakup 3 kolom ( Tanggal , Barang dan Jumlah ), dan ketiga nilai dikembalikan ke dalam kisaran G2:I2.

Jika Anda lebih suka mengatur hasil secara vertikal dalam kolom, sarangkan XLOOKUP ke dalam fungsi TRANSPOSE untuk membalik larik yang dikembalikan:

=TRANSPOSE(XLOOKUP(G1, A2:A7, B2:D7))

Dengan cara yang sama, Anda bisa mengembalikan seluruh kolom data, katakanlah kolom Jumlah Untuk ini, gunakan sel F1 yang berisi "Jumlah" sebagai lookup_value , kisaran A1:D1 yang berisi tajuk kolom sebagai lookup_array dan kisaran A2:D7 yang berisi semua data sebagai return_array .

=XLOOKUP(F1, A1:D1, A2:D7)

Catatan. Karena beberapa nilai diisi ke dalam sel tetangga, pastikan Anda memiliki cukup sel kosong di sebelah kanan atau bawah. Jika Excel tidak dapat menemukan sel kosong yang cukup, kesalahan #SPILL! terjadi.

XLOOKUP tidak hanya dapat mengembalikan beberapa entri tetapi juga menggantinya dengan nilai lain yang anda tentukan. Contoh penggantian massal seperti itu dapat ditemukan di sini: Cara mencari dan mengganti beberapa nilai dengan XLOOKUP.

XLOOKUP dengan beberapa kriteria

Keuntungan besar lainnya dari XLOOKUP adalah bahwa XLOOKUP menangani array secara native. Karena kemampuan ini, Anda dapat mengevaluasi beberapa kriteria secara langsung di dalam lookup_array argumen:

Bagaimana formula ini bekerja Hasil dari setiap uji kriteria adalah sebuah larik nilai TRUE dan FALSE. Perkalian dari larik-larik tersebut mengubah TRUE dan FALSE menjadi masing-masing 1 dan 0, dan menghasilkan larik pencarian akhir. Seperti yang Anda ketahui, perkalian dengan 0 selalu menghasilkan nol, jadi dalam larik pencarian, hanya item yang memenuhi semua kriteria yang diwakili oleh 1. Dan karena nilai pencarian kita adalah "1", Excel mengambil "1" pertama dalam larik pencarian. lookup_array (kecocokan pertama) dan mengembalikan nilai dari return_array di posisi yang sama.

Untuk melihat rumus dalam tindakan, mari kita tarik jumlah dari D2:D10 ( return_array ) dengan kondisi berikut ini:

• Kriteria1 (tanggal) = G1
• Kriteria2 (tenaga penjual) = G2
• Kriteria3 (item) = G3

Dengan tanggal di A2:A10 ( criteria_range1 ), nama wiraniaga di B2:B10 ( criteria_range2 ) dan item-item dalam C2:C10 ( criteria_range3 ), rumusnya berbentuk seperti ini:

=XLOOKUP(1, (B2:B10=G1) * (A2:A10=G2) * (C2:C10=G3), D2:D10)

Meskipun fungsi Excel XLOOKUP memproses array, fungsi ini berfungsi sebagai rumus biasa dan diselesaikan dengan penekanan tombol Enter biasa.

Rumus XLOOKUP dengan beberapa kriteria tidak terbatas pada kondisi "sama dengan". Anda juga bebas menggunakan operator logika lainnya. Misalnya, untuk memfilter pesanan yang dibuat pada tanggal di G1 atau sebelumnya, letakkan "<=G1" di kriteria pertama:

=XLOOKUP(1, (A2:A10<=G1) * (B2:B10=G2) * (C2:C10=G3), D2:D10)

XLOOKUP ganda

Untuk menemukan nilai pada perpotongan baris dan kolom tertentu, lakukan apa yang disebut pencarian ganda atau pencarian matriks Yap, Excel XLOOKUP juga bisa melakukan itu! Anda cukup menyarangkan satu fungsi di dalam fungsi lainnya:

Bagaimana formula ini bekerja Fungsi dalam mencari nilai pencariannya dan mengembalikan kolom atau baris data terkait. Larik itu masuk ke fungsi luar sebagai fungsi return_array .

Untuk contoh ini, kita akan menemukan penjualan yang dilakukan oleh tenaga penjualan tertentu dalam kuartal tertentu. Untuk ini, kita memasukkan nilai pencarian di H1 (nama tenaga penjualan) dan H2 (kuartal), dan melakukan Xlookup dua arah dengan rumus berikut:

=XLOOKUP(H1, A2:A6, XLOOKUP(H2, B1:E1, B2:E6))

Atau sebaliknya:

=XLOOKUP(H2, B1:E1, XLOOKUP(H1, A2:A6, B2:E6))

Di mana A2:A6 adalah nama-nama wiraniaga, B1:E1 adalah perempat (tajuk kolom), dan B2:E6 adalah nilai data.

Pencarian dua arah juga dapat dilakukan dengan rumus INDEX Match dan dengan beberapa cara lain. Untuk informasi lebih lanjut, silakan lihat Pencarian dua arah di Excel.

Jika Kesalahan XLOOKUP

Ketika nilai pencarian tidak ditemukan, Excel XLOOKUP mengembalikan error #N/A. Cukup familiar dan mudah dimengerti oleh pengguna ahli, mungkin agak membingungkan bagi pemula. Untuk mengganti notasi error standar dengan pesan yang ramah pengguna, ketik teks Anda sendiri ke argumen ke-4 bernama if_not_found .

Kembali ke contoh pertama yang dibahas dalam tutorial ini. Jika seseorang memasukkan nama samudra yang tidak valid di E1, rumus berikut akan secara eksplisit memberi tahu mereka bahwa "Tidak ada kecocokan yang ditemukan":

=XLOOKUP(E1, A2:A6, B2:B6, "Tidak ditemukan kecocokan")

Catatan:

• The if_not_found argumen hanya menjebak kesalahan #N/A, tidak semua kesalahan.
• Error #N/A juga bisa ditangani dengan IFNA dan VLOOKUP, tetapi sintaksnya sedikit lebih kompleks dan rumusnya lebih panjang.

XLOOKUP peka huruf besar-kecil

Secara default, fungsi XLOOKUP memperlakukan huruf kecil dan huruf besar sebagai karakter yang sama. Untuk membuatnya peka huruf besar-kecil, gunakan fungsi EXACT untuk lookup_array argumen:

Bagaimana formula ini bekerja Fungsi EXACT membandingkan nilai pencarian terhadap setiap nilai dalam larik pencarian dan mengembalikan TRUE jika mereka persis sama termasuk huruf besar, FALSE jika tidak. lookup_array Sebagai hasilnya, XLOOKUP mencari nilai TRUE dalam larik di atas dan mengembalikan kecocokan dari larik yang dikembalikan.

Misalnya, untuk mendapatkan harga dari B2:B7 ( return_array ) untuk item di E1 ( lookup_value) , rumus dalam E2 adalah:

=XLOOKUP(TRUE, EXACT(E1, A2:A7), B2:B7, "Tidak ditemukan")

Catatan. Jika ada dua atau lebih nilai yang sama persis dalam larik pencarian (termasuk kasus huruf), kecocokan pertama yang ditemukan akan dikembalikan.

Excel XLOOKUP tidak berfungsi

Jika rumus Anda tidak bekerja dengan benar atau hasilnya error, kemungkinan besar itu karena alasan berikut:

XLOOKUP tidak tersedia di Excel saya

Fungsi XLOOKUP tidak kompatibel ke belakang. Ini hanya tersedia di Excel untuk Microsoft 365 dan Excel 2021, dan tidak akan muncul di versi sebelumnya.

XLOOKUP mengembalikan hasil yang salah

Jika rumus Xlookup Anda yang jelas-jelas benar mengembalikan nilai yang salah, kemungkinan besar pencarian atau rentang pengembalian "bergeser" saat rumus disalin ke bawah atau ke seberang. Untuk mencegah hal ini terjadi, pastikan untuk selalu mengunci kedua rentang dengan referensi sel absolut (seperti $ A $ 2: $ A $ 10).

XLOOKUP mengembalikan kesalahan #N/A

Kesalahan #N/A hanya berarti nilai pencarian tidak ditemukan. Untuk memperbaikinya, cobalah mencari perkiraan kecocokan atau informasikan kepada pengguna Anda bahwa tidak ada kecocokan yang ditemukan.

XLOOKUP mengembalikan kesalahan #VALUE

Kesalahan #VALUE! terjadi jika larik pencarian dan pengembalian memiliki dimensi yang tidak kompatibel. Misalnya, tidak mungkin untuk mencari dalam larik horizontal dan mengembalikan nilai dari larik vertikal.

XLOOKUP mengembalikan kesalahan #REF

Kesalahan #REF! dilemparkan saat mencari di antara dua buku kerja yang berbeda, salah satunya ditutup. Untuk memperbaiki kesalahan, cukup buka kedua file.

Seperti yang baru saja Anda lihat, XLOOKUP memiliki banyak fitur luar biasa yang menjadikannya fungsi untuk hampir semua pencarian di Excel. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!

Buku kerja latihan untuk diunduh

Contoh rumus Excel XLOOKUP (file .xlsx)