Šī pamācība iepazīstina ar XLOOKUP - jauno funkciju vertikālai un horizontālai meklēšanai programmā Excel. Kreisā meklēšana, pēdējā saskaņošana, Vlookup ar vairākiem kritērijiem un daudzas citas lietas, kuru izpildei agrāk bija nepieciešams raķešu zinātnes grāds, tagad ir tikpat vienkāršas kā ABC.

Kad jums ir nepieciešams meklēt Excel programmā, kuru funkciju jūs izmantosiet? Vai tas ir stūrakmens VLOOKUP vai tās horizontālais radinieks HLOOKUP? Sarežģītākā gadījumā jūs paļausieties uz kanonisko INDEX MATCH kombināciju vai uzticēsiet uzdevumu Power Query? Labā ziņa ir tāda, ka jums vairs nav jāizvēlas - visas šīs metodes ir atbrīvojušās spēcīgākai un daudzpusīgākai mantiniecei - funkcijai XLOOKUP.

Ar ko XLOOKUP ir labāka? Daudzējādā ziņā! Tā var meklēt vertikāli un horizontāli, pa kreisi un pa augšu, meklēt pēc vairākiem kritērijiem un pat atgriezt veselu datu sleju vai rindu, nevis tikai vienu vērtību. Uzņēmumam Microsoft bija nepieciešami vairāk nekā trīs gadu desmiti, taču beidzot ir izdevies izstrādāt stabilu funkciju, kas novērš daudzas nepatīkamas VLOOKUP kļūdas un trūkumus.

Kāds ir āķis? Diemžēl ir. XLOOKUP funkcija ir pieejama tikai Excel programmā Microsoft 365, Excel 2021 un Excel tīmeklī.

Excel XLOOKUP funkcija - sintakse un lietojums

XLOOKUP funkcija programmā Excel meklē diapazonā vai masīvā noteiktu vērtību un atgriež saistīto vērtību no citas kolonnas. Tā var meklēt gan vertikāli, gan horizontāli un veikt precīzu (noklusējuma), aptuvenu (tuvāko) vai aizstājējzīmju (daļēju) atbilstību.

XLOOKUP funkcijas sintakse ir šāda:

Pirmie trīs argumenti ir obligāti, bet pēdējie trīs nav obligāti.

• Lookup_value - meklējamā vērtība.
• Lookup_array - meklēšanas diapazonu vai masīvu.
• Return_array - diapazons vai masīvs, no kura jāatgriež vērtības.
• If_not_found [neobligāts] - vērtība, kas jāatgriež, ja nav atrasta neviena atbilstība. Ja netiek norādīts, tiek atgriezta #N/A kļūda.
• Match_mode [neobligāts] - veicamās atbilstības tips:
  • 0 vai izlaists (noklusējums) - precīza atbilstība. Ja nav atrasts, tiek atgriezta #N/A kļūda.
  • -1 - precīza atbilstība vai nākamā mazākā vērtība. Ja precīza atbilstība nav atrasta, tiek atgriezta nākamā mazākā vērtība.
  • 1 - precīza atbilstība vai nākamā lielākā vērtība. Ja precīza atbilstība nav atrasta, tiek atgriezta nākamā lielākā vērtība.
  • 2 - aizstājējzīmju atbilstība.
• Meklēšanas_režīms [pēc izvēles] - meklēšanas virziens:
  • 1 vai izlaists (noklusējuma iestatījums) - lai meklētu no pirmā līdz pēdējam.
  • -1 - lai meklētu apgrieztā secībā, no pēdējā uz pirmo.
  • 2 - bināra datu meklēšana augošā secībā.
  • -2 - bināra datu meklēšana dilstošā secībā.

  Saskaņā ar Microsoft sniegto informāciju, binārā meklēšana Tas ir īpašs algoritms, kas atrod meklēšanas vērtības pozīciju sakārtotā masīvā, salīdzinot to ar masīva vidējo elementu. Bināra meklēšana ir daudz ātrāka par parasto meklēšanu, taču tā pareizi darbojas tikai sakārtotiem datiem.

XLOOKUP pamatformula

Lai iegūtu labāku izpratni, izveidosim Xlookup formulu tās vienkāršākajā formā, lai veiktu precīzu meklēšanu. Šim nolūkam mums būs nepieciešami tikai pirmie trīs argumenti.

Pieņemsim, ka jūsu rīcībā ir kopsavilkuma tabula ar informāciju par pieciem okeāniem uz Zemes. Jūs vēlaties iegūt konkrēta okeāna ievades laukumu F1 ( lookup_value ). Ar okeānu nosaukumiem A2:A6 ( lookup_array ) un apgabali C2:C6 ( return_array ) formula ir šāda:

=XLOOKUP(F1, A2:A6, C2:C6)

Tulkojot vienkāršā angļu valodā, tas nozīmē: meklēt vērtību F1 A2:A6 un atgriezt vērtību no C2:C6 tajā pašā rindā. Nav kolonnu indeksu numuru, nav šķirošanas, nav citu smieklīgu Vlookup dīvainību! Tas vienkārši darbojas :)

XLOOKUP pret VLOOKUP programmā Excel

Salīdzinot ar tradicionālo VLOOKUP, XLOOKUP ir daudz priekšrocību. Kādā ziņā tā ir labāka par VLOOKUP? Šeit ir saraksts ar 10 labākajām funkcijām, kas pārspēj jebkuru citu Excel meklēšanas funkciju:

1. Vertikālā un horizontālā meklēšana . XLOOKUP funkcija savu nosaukumu ieguva, pateicoties tās spējai meklēt gan vertikāli, gan horizontāli.
2. Skatieties jebkurā virzienā: pa labi, pa kreisi, pa kreisi, uz leju vai uz augšu. Kamēr VLOOKUP var meklēt tikai kreisajā slejā un HLOOKUP - augšējā rindā, XLOOKUP šādu ierobežojumu nav. Bēdīgi slavenā kreisā meklēšana programmā Excel vairs nav sāpīga!
3. Precīza atbilstība pēc noklusējuma . Lielākajā daļā gadījumu jūs meklēsiet precīzu atbilstību, un XLOOKUP pēc noklusējuma to atgriež (atšķirībā no VLOOKUP funkcijas, kas pēc noklusējuma izmanto aptuvenu atbilstību). Protams, ja nepieciešams, varat likt XLOOKUP veikt arī aptuvenu atbilstību.
4. Daļēja atbilstība ar aizstājējzīmēm Ja zināt tikai daļu no meklēšanas vērtības, bet ne visu, noder aizstājējzīmju sakritība.
5. Meklēt apgrieztā secībā . Agrāk, lai iegūtu pēdējo gadījumu, bija jāmaina avota datu secība. Tagad jūs vienkārši iestatāt parametru meklēšanas_režīms argumentu -1, lai piespiestu Xlookup formulu meklēt no aizmugures un atgrieztu pēdējo rezultātu.
6. Vairāku vērtību atgriešana . Manipulējot ar return_array argumentu, varat izvilkt visu datu rindu vai kolonnu, kas saistīta ar meklēšanas vērtību.
7. Meklēšana, izmantojot vairākus kritērijus . Excel XLOOKUP dabiski apstrādā masīvus, kas ļauj veikt meklēšanu ar vairākiem kritērijiem.
8. Ja kļūdu funkcionalitāte . Tradicionāli mēs izmantojam IFNA funkciju, lai izķertu #N/A kļūdas. XLOOKUP ietver šo funkciju if_not_found arguments, kas ļauj izvadīt savu tekstu, ja nav atrasta derīga atbilstība.
9. Kolonnu ievietošana/izdzēšana . Viena no kaitinošākajām VLOOKUP problēmām ir tā, ka kolonnu pievienošana vai noņemšana izjauc formulu, jo atgrieztā kolonna tiek identificēta pēc tās indeksa numura. Izmantojot XLOOKUP, jūs norādāt atgriešanas diapazonu, nevis numuru, kas nozīmē, ka varat ievietot un noņemt tik kolonnu, cik vien nepieciešams, neko neizjaucot.
10. Labāka veiktspēja . VLOOKUP var palēnināt darblapu darbību, jo aprēķinos tiek iekļauta visa tabula, kā rezultātā tiek apstrādāts daudz vairāk šūnu, nekā patiesībā ir nepieciešams. XLOOKUP apstrādā tikai tos meklēšanas un atgriešanas masīvus, no kuriem tas ir patiešām atkarīgs.

Kā lietot XLOOKUP programmā Excel - formulu piemēri

Turpmākajos piemēros ir parādītas visnoderīgākās XLOOKUP funkcijas darbībā. Turklāt jūs atklāsiet dažus netriviālus izmantošanas veidus, kas pacels jūsu Excel meklēšanas prasmes jaunā līmenī.

Skatieties uz augšu vertikāli un horizontāli

Kādreiz Microsoft Excel bija divas funkcijas dažādiem meklēšanas veidiem, katrai no tām bija sava sintakse un lietošanas noteikumi: VLOOKUP, lai meklētu vertikāli slejā, un HLOOKUP, lai meklētu horizontāli rindā.

Ar XLOOKUP funkciju var veikt abas funkcijas, izmantojot to pašu sintaksi. Atšķirība ir tajā, ko izmantojat meklēšanas un atgriešanas masīviem.

V-izpētes nolūkā sniedziet kolonnas:

=XLOOKUP(E1, A2:A6, B2:B6)

Lai veiktu h-izpēti, kolonnu vietā ievadiet rindas:

=XLOOKUP(I1, B1:F1, B2:F2)

Dzīvi veikta kreisās meklēšanas funkcija

Agrākās Excel versijās INDEX MATCH formula bija vienīgais uzticamais veids, kā meklēt pa kreisi vai pa augšu. Tagad vairs nav nepieciešams apvienot divas funkcijas, ja pietiktu ar vienu. Vienkārši norādiet mērķa meklēšanas masīvu, un XLOOKUP to apstrādās bez problēmām neatkarīgi no tā atrašanās vietas.

Kā piemēru pievienosim Rangs Mērķis ir iegūt okeāna ievades rangu F1. VLOOKUP šeit kļūtu neveiksmīgs, jo tas var atgriezt tikai vērtību no kolonnas, kas atrodas pa labi no meklēšanas kolonnas. Xlookup formula ar to viegli tiek galā:

=XLOOKUP(F1, B2:B6, A2:A6)

Līdzīgā veidā varat skatīties augstāk, meklējot horizontāli rindās.

XLOOKUP ar precīzu un aptuvenu atbilstību

Saskaņošanas uzvedību kontrolē ar 5. argumentu, ko sauc par match_mode . Pēc noklusējuma tiek veikta precīza atbilstība.

Lūdzu, pievērsiet uzmanību, ka pat tad, ja izvēlaties aptuvenu atbilstību ( match_mode 1 vai -1), funkcija joprojām vispirms meklēs precīzu atbilstību. Atšķirība ir tajā, ko tā atgriež, ja precīza meklēšanas vērtība nav atrasta.

Match_mode arguments:

• 0 vai izlaists - precīza atbilstība; ja nav atrasts - #N/A kļūda.
• -1 - precīza atbilstība; ja nav atrasts - nākamais mazāks vienums.
• 1 - precīza atbilstība; ja nav atrasts - nākamais lielākais vienums.

Precīza atbilstība XLOOKUP

Šo opciju jūs, iespējams, izmantosiet 99 % gadījumu, kad veicat meklēšanu programmā Excel. Tā kā precīza atbilstība ir XLOOKUP noklusējuma iestatījums, varat izlaist match_mode un norādiet tikai pirmos 3 nepieciešamos argumentus.

Tomēr dažās situācijās precīza atbilstība nedarbosies. Tipisks scenārijs ir, ja jūsu meklēšanas tabulā nav iekļautas visas vērtības, bet gan "starpposma" vai "robežas", piemēram, atlaides atkarībā no daudzuma, komisijas maksas atkarībā no pārdošanas utt.

Mūsu meklēšanas tabulas paraugā ir parādīta korelācija starp eksāmenu rezultātiem un atzīmēm. Kā redzams zemāk redzamajā ekrānšāviņā, precīza atbilstība darbojas tikai tad, ja konkrēta skolēna rezultāts precīzi atbilst vērtībai meklēšanas tabulā (piemēram, Christian 3. rindā). Visos citos gadījumos tiek atgriezta kļūda #N/A.

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6)

Lai kļūdas #N/A vietā iegūtu pakāpes, mums ir jāmeklē aptuvena atbilstība, kā parādīts nākamajā piemērā.

Aptuvenais sakritības rādītājs XLOOKUP

Lai veiktu aptuvenu meklēšanu, iestatiet match_mode argumentu -1 vai 1 atkarībā no tā, kā ir organizēti dati.

Mūsu gadījumā meklēšanas tabulā ir norādītas pakāpju apakšējās robežas. Tātad mēs iestatām match_mode uz -1, lai meklētu nākamo mazāko vērtību, ja nav atrasta precīza atbilstība:

=XLOOKUP(F11, $B$11:$B$15, $C$11:$C$15, ,-1)

Piemēram, Brian ir vērtējums 98 (F2). Formula meklē šo meklēšanas vērtību B2:B6, bet nevar to atrast. Tad tā meklē nākamo mazāko elementu un atrod 90, kas atbilst A pakāpei:

Ja mūsu uzmeklēšanas tabulā būtu norādītas augšējās pakāpes robežas, mēs iestatītu. match_mode līdz 1, lai meklētu nākamo lielāko elementu, ja precīza atbilstība nav atrasta:

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6, ,1)

Formula meklē 98 un atkal to neatrod. Šoreiz tā mēģina atrast nākamo lielāko vērtību un iegūst 100, kas atbilst A pakāpei:

Padoms. Kopējot Xlookup formulu vairākās šūnās, bloķējiet meklēšanas vai atgriešanas diapazonus ar absolūtām šūnu atsaucēm (piemēram, $B$2:$B$6), lai novērstu to maiņu.

XLOOKUP ar daļēju atbilstību (aizstājējzīmes)

Lai veiktu daļējas atbilstības meklēšanu, iestatiet match_mode argumentu 2, kas uzdod XLOOKUP funkcijai apstrādāt aizstājējzīmes:

• Zvaigznīte (*) - apzīmē jebkuru rakstzīmju virkni.
• Jautājuma zīme (?) - apzīmē jebkuru atsevišķu rakstzīmi.

Lai redzētu, kā tas darbojas, aplūkojiet šādu piemēru. A slejā ir vairāki viedtālruņu modeļi, bet B slejā - to akumulatora ietilpība. Jūs interesē kāda konkrēta viedtālruņa akumulators. Problēma ir tā, ka neesat pārliecināts, vai varat ievadīt modeļa nosaukumu tieši tā, kā tas parādās A slejā. Lai to novērstu, ievadiet daļu, kas tur noteikti ir, un aizstāt pārējorakstzīmes ar aizstājējzīmēm.

Piemēram, lai iegūtu informāciju par iPhone X akumulatoru, izmantojiet šo formulu:

=XLOOKUP("*iphone X*", A2:A8, B2:B8, ,2)

Vai arī ievadiet zināmo meklēšanas vērtības daļu kādā šūnā un apvienojiet šūnas atsauci ar aizstājējzīmēm:

=XLOOKUP("*"&E1& "*", A2:A8, B2:B8, ,2)

XLOOKUP apgrieztā secībā, lai iegūtu pēdējo gadījumu

Ja jūsu tabulā ir vairāki meklēšanas vērtības atkārtojumi, dažkārt var būt nepieciešams atgriezt pēdējais mačs . Lai to izdarītu, konfigurējiet Xlookup formulu, lai meklētu apgrieztā secībā.

Meklēšanas virziens tiek kontrolēts ar 6. argumentu ar nosaukumu meklēšanas_režīms :

• 1 vai izlaists (noklusējums) - meklē no pirmās līdz pēdējai vērtībai, t. i., no augšas uz leju ar vertikālu meklēšanu vai no kreisās uz labo ar horizontālu meklēšanu.
• -1 - meklēšana apgrieztā secībā no pēdējās līdz pirmajai vērtībai.

Piemēram, atgriezīsim pēdējo konkrēta pārdevēja veikto pārdošanu. Šim nolūkam mēs apkopojam pirmos trīs nepieciešamos argumentus (G1 par lookup_value , B2:B9 attiecībā uz lookup_array un D2:D9 return_array ) un 5. argumentā ierakstiet -1:

=XLOOKUP(G1, B2:B9, D2:D9, , ,-1)

Vienkārši un viegli, vai ne?

XLOOKUP, lai atgrieztu vairākas kolonnas vai rindas

Vēl viena pārsteidzoša XLOOKUP funkcija ir tā spēja atgriezt vairāk nekā vienu vērtību, kas attiecas uz vienu un to pašu atbilstību. Tas viss tiek darīts, izmantojot standarta sintaksi un bez papildu manipulācijām!

Pieņemsim, ka no turpmāk dotās tabulas vēlaties iegūt visu informāciju, kas attiecas uz interesējošo pārdevēju (F2). Jums ir jānorāda diapazons, nevis viena sleja vai rinda, lai iegūtu informāciju par return_array arguments:

=XLOOKUP(F2, A2:A7, B2:D7)

Ievadiet formulu rezultātu diapazona augšējā kreisajā šūnā, un Excel automātiski izlej rezultātus blakus esošajās tukšajās šūnās. Mūsu gadījumā atgriešanas masīvs (B2:D7) ietver 3 kolonnas ( Datums , Prece un Summa ), un visas trīs vērtības tiek atgrieztas diapazonā G2:I2.

Ja vēlaties rezultātus vertikāli sakārtot slejā, ievietojiet XLOOKUP funkciju TRANSPOSE, lai apgrieztu iegūto masīvu:

=TRANSPOZĪCIJA(XLOOKUP(G1, A2:A7, B2:D7))

Līdzīgā veidā varat atgriezt visu datu sleju, piemēram, šādu. Summa Šim nolūkam izmantojiet šūnas F1, kurā ir "Summa" kā lookup_value , diapazonu A1:D1, kas satur kolonnu galvenes, kā lookup_array un diapazonu A2:D7, kurā visi dati ir šādi return_array .

=XLOOKUP(F1, A1:D1, A2:D7)

Piezīme. Tā kā blakus esošajās šūnās tiek ievadītas vairākas vērtības, pārliecinieties, vai ir pietiekami daudz tukšu šūnu pa labi vai uz leju. Ja Excel nevar atrast pietiekami daudz tukšu šūnu, rodas #SPILL! kļūda.

Padoms. XLOOKUP var ne tikai atgriezt vairākus ierakstus, bet arī aizstāt tos ar citām norādītajām vērtībām. Šādas masveida aizstāšanas piemēru var atrast šeit: Kā meklēt un aizstāt vairākas vērtības ar XLOOKUP.

XLOOKUP ar vairākiem kritērijiem

Vēl viena liela XLOOKUP priekšrocība ir tā, ka tas dabiski apstrādā masīvus. Pateicoties šai iespējai, varat novērtēt vairākus kritērijus tieši vienkopus. lookup_array arguments:

Kā darbojas šī formula : Katra kritēriju testa rezultāts ir TRUE un FALSE vērtību masīvs. Masu reizināšana pārvērš TRUE un FALSE attiecīgi par 1 un 0 un iegūst galīgo meklēšanas masīvu. Kā zināms, reizinot ar 0, vienmēr iegūst nulli, tāpēc meklēšanas masīvā tikai tie elementi, kas atbilst visiem kritērijiem, tiek attēloti ar 1. Un, tā kā mūsu meklēšanas vērtība ir "1", Excel ņem pirmo "1", kas ir "1". lookup_array (pirmā atbilstība) un atgriež vērtību no return_array tajā pašā pozīcijā.

Lai aplūkotu formulas darbību, ņemsim summu no D2:D10 ( return_array ) ar šādiem nosacījumiem:

• Kritērijs1 (datums) = G1
• Kritērijs2 (pārdevējs) = G2
• Kritērijs3 (postenis) = G3

Ar datumiem A2:A10 ( kritērijs_range1 ), pārdevēju vārdi B2:B10 ( kritērijs_range2 ) un C2:C10 pozīcijas ( kritērijs_range3 ), formula ir šāda:

=XLOOKUP(1, (B2:B10=G1) * (A2:A10=G2) * (C2:C10=G3), D2:D10)

Lai gan Excel XLOOKUP funkcija apstrādā masīvus, tā darbojas kā parasta formula un tiek pabeigta ar parasto Enter taustiņa nospiešanu.

XLOOKUP formula ar vairākiem kritērijiem neaprobežojas tikai ar nosacījumiem "vienāds ar". Jūs varat brīvi izmantot arī citus loģiskos operatorus. Piemēram, lai filtrētu pasūtījumus, kas veikti datumā G1 vai agrāk, pirmajā kritērijā ierakstiet "<=G1":

=XLOOKUP(1, (A2:A10<=G1) * (B2:B10=G2) * (C2:C10=G3), D2:D10)

Dubultā XLOOKUP

Lai atrastu vērtību konkrētas rindas un kolonnas krustpunktā, veiciet t. s. dubultā meklēšana vai matricas meklēšana Jā, arī Excel XLOOKUP to var izdarīt! Vienkārši ievietojiet vienu funkciju citā:

Kā darbojas šī formula : Formulas pamatā ir XLOOKUP spēja atgriezt veselu rindu vai kolonnu. Iekšējā funkcija meklē meklē meklēšanas vērtību un atgriež saistīto datu kolonnu vai rindu. Šis masīvs tiek nodots ārējai funkcijai kā return_array .

Šajā piemērā mēs meklēsim pārdošanas apjomus, ko konkrēts pārdevējs veicis noteiktā ceturksnī. Šim nolūkam H1 (pārdevēja vārds) un H2 (ceturksnis) ierakstām meklēšanas vērtības un veicam divvirzienu Xlookup ar šādu formulu:

=XLOOKUP(H1, A2:A6, XLOOKUP(H2, B1:E1, B2:E6))

Vai otrādi:

=XLOOKUP(H2, B1:E1, XLOOKUP(H1, A2:A6, B2:E6))

Kur A2:A6 ir pārdevēju vārdi, B1:E1 ir ceturtdaļas (kolonnu virsraksti) un B2:E6 ir datu vērtības.

Divvirzienu meklēšanu var veikt arī ar INDEX sakritības formulu un dažiem citiem veidiem. Lai iegūtu vairāk informācijas, skatiet sadaļu Divvirzienu meklēšana programmā Excel.

Ja kļūda XLOOKUP

Ja meklēšanas vērtība nav atrasta, Excel XLOOKUP atgriež kļūdu #N/A. Tas ir diezgan pazīstams un saprotams pieredzējušiem lietotājiem, taču iesācējiem tas var būt diezgan mulsinoši. Lai aizstātu standarta kļūdas pierakstu ar lietotājam draudzīgu ziņojumu, ievadiet savu tekstu 4. argumentā ar nosaukumu if_not_found .

Atgriezīsimies pie pirmā piemēra, kas aplūkots šajā pamācībā. Ja kāds E1 ievadīs nederīgu okeāna nosaukumu, ar šādu formulu tiks skaidri paziņots, ka "Nav atrasts neviens sakritības variants":

=XLOOKUP(E1, A2:A6, B2:B6, "Nav atrasta atbilstība")

Piezīmes:

• Portāls if_not_found arguments izķer tikai #N/A kļūdas, nevis visas kļūdas.
• Kļūdas #N/A var apstrādāt arī ar IFNA un VLOOKUP, taču sintakse ir nedaudz sarežģītāka un formula ir garāka.

Lietošanai lietoto burtu un atbilžu XLOOKUP

Pēc noklusējuma XLOOKUP funkcija mazos un lielos burtus uzskata par vienādām rakstzīmēm. Ja vēlaties, lai tā ņemtu vērā mazos un lielos burtus, izmantojiet EXACT funkciju, lai lookup_array arguments:

Kā darbojas šī formula : EXACT funkcija salīdzina meklēšanas vērtību ar katru vērtību meklēšanas masīvā un atgriež TRUE, ja tās ir pilnīgi vienādas, ieskaitot burtu burtu lielumu, un FALSE pretējā gadījumā. Šis loģisko vērtību masīvs tiek nosūtīts uz lookup_array XLOOKUP arguments. Rezultātā XLOOKUP meklē TRUE vērtību iepriekš minētajā masīvā un atgriež atbilstību no atgrieztā masīva.

Piemēram, lai iegūtu cenu no B2:B7 ( return_array ) attiecībā uz E1 pozīciju ( lookup_value) , E2 formula ir šāda:

=XLOOKUP(TRUE, EXACT(E1, A2:A7), B2:B7, "Nav atrasts")

Piezīme. Ja meklēšanas masīvā ir divas vai vairākas pilnīgi vienādas vērtības (ieskaitot burtu burtu lielumu), tiek atgriezta pirmā atrastā atbilstība.

Excel XLOOKUP nedarbojas

Ja jūsu formula nedarbojas pareizi vai ir kļūdaina, visticamāk, tas ir šādu iemeslu dēļ:

XLOOKUP nav pieejams manā programmā Excel

XLOOKUP funkcija nav atpakaļsaderīga. Tā ir pieejama tikai Excel programmā Microsoft 365 un Excel 2021, un tā nav pieejama iepriekšējās versijās.

XLOOKUP atgriež nepareizu rezultātu

Ja jūsu acīmredzami pareizā Xlookup formula atgriež nepareizu vērtību, pastāv iespēja, ka meklēšanas vai atgriešanas diapazons "pārvietojies", kad formula tika kopēta uz leju vai pāri. Lai to novērstu, vienmēr bloķējiet abus diapazonus ar absolūtām šūnu atsaucēm (piemēram, $A$2:$A$10).

XLOOKUP atgriež #N/A kļūdu

Kļūda #N/A nozīmē, ka meklēšanas vērtība nav atrasta. Lai to novērstu, mēģiniet meklēt aptuvenu atbilstību vai informējiet lietotājus, ka atbilstība nav atrasta.

XLOOKUP atgriež #VALUE kļūdu

Kļūda #VALUE! rodas, ja meklēšanas un atgriešanas masīviem ir nesaderīgi izmēri. Piemēram, nav iespējams meklēt horizontālā masīvā un atgriezt vērtības no vertikāla masīva.

XLOOKUP atgriež #REF kļūdu

Kļūda #REF! tiek izmesta, kad tiek meklēts starp divām dažādām darbgrāmatām, no kurām viena ir slēgta. Lai novērstu kļūdu, vienkārši atveriet abus failus.

Kā jūs tikko redzējāt, XLOOKUP ir daudz lielisku funkciju, kas padara to par funkciju gandrīz jebkurai meklēšanai programmā Excel. Paldies, ka izlasījāt, un ceru, ka nākamnedēļ tiksimies mūsu blogā!

Prakses darba burtnīca lejupielādei

Excel XLOOKUP formulas piemēri (.xlsx fails)