L'esercitazione introduce XLOOKUP, la nuova funzione per le ricerche verticali e orizzontali in Excel. Le ricerche a sinistra, l'ultima corrispondenza, le Vlookup con criteri multipli e molte altre cose che prima richiedevano una laurea in scienze missilistiche ora sono diventate facili come l'ABC.

Ogni volta che dovete fare una ricerca in Excel, quale funzione utilizzate? Il pilastro VLOOKUP o il suo fratello orizzontale HLOOKUP? In un caso più complesso, vi affiderete alla combinazione canonica INDEX MATCH o affiderete il lavoro a Power Query? La buona notizia è che non dovete più scegliere: tutti questi metodi stanno lasciando il posto a un successore più potente e versatile, la funzione XLOOKUP.

XLOOKUP è migliore in molti modi: può guardare in verticale e in orizzontale, a sinistra e in alto, effettuare ricerche con criteri multipli e persino restituire un'intera colonna o riga di dati, non solo un valore. Ci sono voluti oltre trent'anni per Microsoft, ma finalmente è riuscita a progettare una funzione robusta che supera molti errori e debolezze di VLOOKUP.

La funzione XLOOKUP è disponibile solo in Excel per Microsoft 365, Excel 2021 ed Excel per il Web.

Funzione XLOOKUP di Excel: sintassi e usi

La funzione XLOOKUP di Excel cerca in un intervallo o in una matrice un valore specificato e restituisce il relativo valore da un'altra colonna. Può cercare sia in verticale che in orizzontale ed eseguire una corrispondenza esatta (predefinita), approssimativa (più vicina) o con caratteri jolly (parziale).

La sintassi della funzione XLOOKUP è la seguente:

I primi 3 argomenti sono obbligatori e gli ultimi tre sono facoltativi.

• Valore_di_ricerca - il valore da cercare.
• Matrice_di_ricerca - l'intervallo o la matrice in cui cercare.
• Matrice_di_ritorno - l'intervallo o l'array da cui restituire i valori.
• Se_non_trovato [opzionale] - il valore da restituire se non viene trovata alcuna corrispondenza. Se omesso, viene restituito un errore #N/A.
• Modalità_di_partita [opzionale] - il tipo di corrispondenza da eseguire:
  • 0 o omesso (valore predefinito) - corrispondenza esatta. Se non viene trovato, viene restituito un errore #N/A.
  • -1 - corrispondenza esatta o valore successivo più piccolo. Se non viene trovata una corrispondenza esatta, viene restituito il valore successivo più piccolo.
  • 1 - corrispondenza esatta o valore superiore. Se non viene trovata una corrispondenza esatta, viene restituito il valore superiore.
  • 2 - corrispondenza di caratteri jolly.
• Modalità_di_ricerca [opzionale] - la direzione di ricerca:
  • 1 o omesso (valore predefinito) - per cercare dal primo all'ultimo.
  • -1 - per cercare in ordine inverso, dall'ultimo al primo.
  • 2 - ricerca binaria sui dati ordinati in modo crescente.
  • -2 - ricerca binaria su dati ordinati in modo decrescente.

  Secondo Microsoft, ricerca binaria è incluso per gli utenti avanzati. Si tratta di un algoritmo speciale che trova la posizione di un valore di ricerca all'interno di un array ordinato confrontandolo con l'elemento centrale dell'array. Una ricerca binaria è molto più veloce di una ricerca normale, ma funziona correttamente solo su dati ordinati.

Formula XLOOKUP di base

Per capire meglio, costruiamo una formula Xlookup nella sua forma più semplice per eseguire una ricerca esatta. Per questo, avremo bisogno solo dei primi 3 argomenti.

Supponiamo di avere una tabella riassuntiva con informazioni sui cinque oceani della Terra. Si vuole ottenere l'area di uno specifico oceano inserita in F1 ( valore_di_ricerca ). Con i nomi degli oceani in A2:A6 ( array_di_ricerca ) e le aree in C2:C6 ( matrice_di_ritorno ), la formula è la seguente:

=XLOOKUP(F1, A2:A6, C2:C6)

Tradotto in parole povere, dice: cerca il valore F1 in A2:A6 e restituisci un valore da C2:C6 nella stessa riga. Nessun indice di colonna, nessun ordinamento, nessun'altra ridicola stranezza di Vlookup. Funziona e basta :)

XLOOKUP vs. VLOOKUP in Excel

Rispetto al VLOOKUP tradizionale, XLOOKUP presenta molti vantaggi: in che cosa è migliore di VLOOKUP? Ecco un elenco delle 10 migliori caratteristiche che fanno saltare le porte a qualsiasi altra funzione di ricerca in Excel:

1. Ricerca verticale e orizzontale La funzione XLOOKUP deve il suo nome alla capacità di cercare sia in verticale che in orizzontale.
2. Guardare in qualsiasi direzione: a destra, a sinistra, in basso o in alto. Mentre VLOOKUP può cercare solo nella colonna più a sinistra e HLOOKUP nella riga più in alto, XLOOKUP non ha queste limitazioni. La famigerata ricerca a sinistra in Excel non è più un problema!
3. Corrispondenza esatta per impostazione predefinita Nella maggior parte dei casi, si cerca una corrispondenza esatta e XLOOKUP la restituisce per impostazione predefinita (a differenza della funzione VLOOKUP che ha come impostazione predefinita una corrispondenza approssimativa). Naturalmente, se necessario, è possibile far sì che XLOOKUP esegua anche una corrispondenza approssimativa.
4. Corrispondenza parziale con caratteri jolly Quando si conosce solo una parte del valore di ricerca, ma non tutto, la corrispondenza con i caratteri jolly è utile.
5. Ricerca in ordine inverso Prima, per ottenere l'ultima occorrenza, era necessario invertire l'ordine dei dati di origine. Ora, è sufficiente impostare il parametro modalità_ricerca a -1 per forzare la formula Xlookup a cercare dal retro e restituire l'ultima corrispondenza.
6. Restituzione di più valori Manipolando con il tasto matrice_di_ritorno è possibile estrarre un'intera riga o colonna di dati relativi al valore di ricerca.
7. Ricerca con più criteri . Excel XLOOKUP gestisce in modo nativo gli array, consentendo di eseguire ricerche con criteri multipli.
8. Se la funzionalità di errore Tradizionalmente si usa la funzione IFNA per intrappolare gli errori #N/A. XLOOKUP incorpora questa funzionalità nella funzione se_non_trovato che consente di produrre il proprio testo se non viene trovata una corrispondenza valida.
9. Inserimenti/cancellazioni di colonne Uno dei problemi più fastidiosi di VLOOKUP è che l'aggiunta o la rimozione di colonne interrompe una formula perché la colonna di ritorno è identificata dal suo numero di indice. Con XLOOKUP si fornisce l'intervallo di ritorno, non il numero, il che significa che si possono inserire e rimuovere tutte le colonne necessarie senza interrompere nulla.
10. Migliori prestazioni VLOOKUP potrebbe rallentare i fogli di lavoro perché include l'intera tabella nei calcoli, con il risultato di elaborare molte più celle di quelle effettivamente necessarie. XLOOKUP gestisce solo gli array di ricerca e di ritorno da cui dipende veramente.

Come utilizzare XLOOKUP in Excel - esempi di formule

Gli esempi che seguono mostrano le funzioni più utili di XLOOKUP in azione. Inoltre, scoprirete un paio di usi non banali che porteranno le vostre abilità di ricerca in Excel a un nuovo livello.

Guardare in alto in verticale e in orizzontale

In passato Microsoft Excel disponeva di due funzioni per i diversi tipi di ricerca, ciascuna con la propria sintassi e le proprie regole di utilizzo: VLOOKUP per cercare verticalmente in una colonna e HLOOKUP per cercare orizzontalmente in una riga.

La funzione XLOOKUP è in grado di eseguire entrambe le operazioni con la stessa sintassi. La differenza sta in ciò che si fornisce per gli array di ricerca e di ritorno.

Per il v-lookup, fornire le colonne:

=XLOOKUP(E1, A2:A6, B2:B6)

Per l'h-lookup, inserire le righe invece delle colonne:

=XLOOKUP(I1, B1:F1, B2:F2)

Ricerca a sinistra eseguita in modo nativo

Nelle versioni precedenti di Excel, la formula INDEX MATCH era l'unico modo affidabile per cercare a sinistra o in alto. Ora non è più necessario combinare due funzioni dove ne basterebbe una sola: basta specificare l'array di ricerca di destinazione e XLOOKUP lo gestirà senza problemi, indipendentemente dalla sua posizione.

Come esempio, aggiungiamo l'elemento Classifica a sinistra della nostra tabella di esempio. L'obiettivo è ottenere il rango dell'oceano inserito in F1. VLOOKUP sarebbe in difficoltà in questo caso, perché può restituire solo un valore da una colonna a destra della colonna di ricerca. Una formula Xlookup può essere utilizzata senza problemi:

=XLOOKUP(F1, B2:B6, A2:A6)

In modo analogo, si può guardare sopra quando si cerca orizzontalmente nelle righe.

XLOOKUP con corrispondenza esatta e approssimativa

Il comportamento della corrispondenza è controllato dal quinto parametro chiamato modalità_di_riscontro Per impostazione predefinita, viene eseguita una corrispondenza esatta.

Si prega di prestare attenzione al fatto che anche quando si sceglie una corrispondenza approssimativa ( modalità_di_riscontro impostato su 1 o -1), la funzione cercherà comunque una corrispondenza esatta per prima. La differenza sta in ciò che restituisce se non viene trovato un valore di ricerca esatto.

Argomento Match_mode:

• 0 o omesso - corrispondenza esatta; se non trovato - errore #N/A.
• -1 - se non viene trovato, il prossimo elemento più piccolo.
• 1 - se non viene trovata, il prossimo articolo più grande.

Corrispondenza esatta XLOOKUP

Questa è l'opzione che probabilmente si usa il 99% delle volte che si fanno ricerche in Excel. Poiché la corrispondenza esatta è il comportamento predefinito di XLOOKUP, è possibile omettere modalità_di_riscontro e fornire solo i primi 3 argomenti richiesti.

In alcune situazioni, tuttavia, una corrispondenza esatta non funziona. Uno scenario tipico è quello in cui la tabella di ricerca non contiene tutti i valori, ma piuttosto "pietre miliari" o "limiti" come sconti basati sulla quantità, commissioni basate sulle vendite, ecc.

La nostra tabella di ricerca di esempio mostra la correlazione tra i punteggi degli esami e i voti. Come si può vedere nella schermata sottostante, una corrispondenza esatta funziona solo quando il punteggio di un particolare studente corrisponde esattamente al valore della tabella di ricerca (come Christian nella riga 3). In tutti gli altri casi viene restituito un errore #N/A.

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6)

Per ottenere i voti invece degli errori #N/A, dobbiamo cercare una corrispondenza approssimativa, come mostrato nel prossimo esempio.

Corrispondenza approssimativa XLOOKUP

Per eseguire una ricerca approssimativa, impostare il parametro modalità_di_riscontro a -1 o 1, a seconda di come sono organizzati i dati.

Nel nostro caso, la tabella di ricerca elenca i limiti inferiori dei gradi. Quindi, impostiamo modalità_di_riscontro a -1 per cercare il valore successivo più piccolo quando non viene trovata una corrispondenza esatta:

=XLOOKUP(F11, $B$11:$B$15, $C$11:$C$15, ,-1)

Ad esempio, Brian ha un punteggio di 98 (F2). La formula cerca questo valore di ricerca in B2:B6, ma non lo trova. Quindi, cerca l'elemento successivo più piccolo e trova 90, che corrisponde al voto A:

Se la nostra tabella di ricerca contenesse i limiti superiori dei voti, imposteremmo modalità_di_riscontro a 1 per cercare l'elemento successivo più grande se la corrispondenza esatta non riesce:

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6, ,1)

La formula cerca 98 e ancora una volta non lo trova. Questa volta cerca di trovare il valore immediatamente superiore e ottiene 100, che corrisponde al grado A:

Suggerimento: quando si copia una formula Xlookup in più celle, bloccare gli intervalli di ricerca o di ritorno con riferimenti assoluti alle celle (come $B$2:$B$6) per evitare che cambino.

XLOOKUP con corrispondenza parziale (caratteri jolly)

Per eseguire una ricerca di corrispondenza parziale, impostare l'opzione modalità_di_riscontro a 2, che indica alla funzione XLOOKUP di elaborare i caratteri jolly:

• Un asterisco (*) - rappresenta qualsiasi sequenza di caratteri.
• Un punto interrogativo (?) - rappresenta qualsiasi singolo carattere.

Per capire come funziona, si consideri il seguente esempio. Nella colonna A sono riportati alcuni modelli di smartphone e, nella colonna B, la loro capacità della batteria. Si è curiosi di conoscere la batteria di un certo smartphone. Il problema è che non si è sicuri di poter digitare il nome del modello esattamente come appare nella colonna A. Per ovviare a questo problema, si inserisce la parte che c'è sicuramente e si sostituisce la rimanentecon caratteri jolly.

Ad esempio, per ottenere informazioni sulla batteria dell'iPhone X, utilizzare questa formula:

=XLOOKUP("*iphone X*", A2:A8, B2:B8, ,2)

Oppure, inserire la parte nota del valore di ricerca in una cella e concatenare il riferimento alla cella con i caratteri jolly:

=XLOOKUP("*"&E1& "*", A2:A8, B2:B8, ,2)

XLOOKUP in ordine inverso per ottenere l'ultima occorrenza

Nel caso in cui la tabella contenga diverse occorrenze del valore di ricerca, a volte è necessario restituire il valore ultima partita Per farlo, configurare la formula Xlookup in modo che la ricerca avvenga in ordine inverso.

La direzione di ricerca è controllata dal 6° argomento denominato modalità_ricerca :

• 1 o omesso (valore predefinito) - ricerca dal primo all'ultimo valore, cioè dall'alto in basso con ricerca verticale o da sinistra a destra con ricerca orizzontale.
• -1 - ricerca in ordine inverso, dall'ultimo al primo valore.

A titolo di esempio, si vuole restituire l'ultima vendita effettuata da uno specifico addetto alle vendite. A tal fine, si mettono insieme i primi tre argomenti richiesti (G1 per valore_di_ricerca , B2:B9 per array_di_ricerca e D2:D9 per matrice_di_ritorno ) e inserire -1 nel quinto argomento:

=XLOOKUP(G1, B2:B9, D2:D9, , ,-1)

Semplice e diretto, non è vero?

XLOOKUP per restituire più colonne o righe

Un'altra caratteristica sorprendente di XLOOKUP è la capacità di restituire più di un valore relativo alla stessa corrispondenza, il tutto con la sintassi standard e senza manipolazioni aggiuntive!

Dalla tabella seguente, supponendo di voler recuperare tutti i dettagli relativi al venditore di interesse (F2), è necessario fornire un intervallo, non una singola colonna o riga, per il parametro matrice_di_ritorno argomento:

=XLOOKUP(F2, A2:A7, B2:D7)

Si inserisce la formula nella cella in alto a sinistra dell'intervallo dei risultati ed Excel riversa automaticamente i risultati nelle celle vuote adiacenti. Nel nostro caso, l'array di ritorno (B2:D7) comprende 3 colonne ( Data , Articolo e Importo ) e tutti e tre i valori vengono restituiti nell'intervallo G2:I2.

Se si preferisce disporre i risultati verticalmente in una colonna, annidare XLOOKUP nella funzione TRANSPOSE per capovolgere l'array restituito:

=TRANSPOSE(XLOOKUP(G1, A2:A7, B2:D7))

In modo simile, si può restituire un'intera colonna di dati, ad esempio la colonna Importo A questo scopo, utilizzare la cella F1 che contiene "Importo" come valore_di_ricerca , l'intervallo A1:D1 contenente le intestazioni delle colonne come array_di_ricerca e l'intervallo A2:D7 contenente tutti i dati come matrice_di_ritorno .

=XLOOKUP(F1, A1:D1, A2:D7)

Nota: poiché più valori vengono popolati nelle celle vicine, assicuratevi di avere un numero sufficiente di celle vuote a destra o in basso. Se Excel non riesce a trovare un numero sufficiente di celle vuote, si verifica un errore #SPILL!

Suggerimento: XLOOKUP può non solo restituire più voci, ma anche sostituirle con altri valori specificati dall'utente. Un esempio di sostituzione massiva è riportato qui: Come cercare e sostituire più valori con XLOOKUP.

XLOOKUP con più criteri

Un altro grande vantaggio di XLOOKUP è che gestisce gli array in modo nativo. Grazie a questa capacità, è possibile valutare più criteri direttamente nel metodo array_di_ricerca argomento:

Come funziona questa formula Il risultato di ogni test dei criteri è una matrice di valori VERO e FALSO. La moltiplicazione delle matrici converte VERO e FALSO rispettivamente in 1 e 0 e produce la matrice di ricerca finale. Come si sa, la moltiplicazione per 0 dà sempre zero, quindi nella matrice di ricerca solo gli elementi che soddisfano tutti i criteri sono rappresentati da 1. E poiché il nostro valore di ricerca è "1", Excel prende il primo "1" nella matrice di ricerca. array_di_ricerca (prima corrispondenza) e restituisce il valore di matrice_di_ritorno nella stessa posizione.

Per vedere la formula in azione, estraiamo un importo da D2:D10 ( matrice_di_ritorno ) con le seguenti condizioni:

• Criteri1 (data) = G1
• Criteri2 (venditore) = G2
• Criteri3 (voce) = G3

Con date in A2:A10 ( criterio_range1 ), i nomi dei venditori in B2:B10 ( criterio_range2 ) e gli elementi in C2:C10 ( criterio_range3 ), la formula assume questa forma:

=XLOOKUP(1, (B2:B10=G1) * (A2:A10=G2) * (C2:C10=G3), D2:D10)

Anche se la funzione XLOOKUP di Excel elabora gli array, funziona come una normale formula e viene completata con la consueta pressione del tasto Invio.

La formula XLOOKUP con criteri multipli non si limita alle condizioni "uguale a", ma consente di utilizzare anche altri operatori logici. Ad esempio, per filtrare gli ordini effettuati in data G1 o precedente, inserire "<=G1" nel primo criterio:

=XLOOKUP(1, (A2:A10<=G1) * (B2:B10=G2) * (C2:C10=G3), D2:D10)

Doppio XLOOKUP

Per trovare un valore all'intersezione di una determinata riga e colonna, si esegue il cosiddetto doppia ricerca o ricerca della matrice Sì, Excel XLOOKUP può fare anche questo: è sufficiente annidare una funzione all'interno di un'altra:

Come funziona questa formula La formula si basa sulla capacità di XLOOKUP di restituire un'intera riga o colonna. La funzione interna cerca il suo valore di ricerca e restituisce una colonna o una riga di dati correlati. Questa matrice viene inviata alla funzione esterna come array matrice_di_ritorno .

In questo esempio, vogliamo trovare le vendite effettuate da un particolare venditore in un determinato trimestre. A tale scopo, inseriamo i valori di ricerca in H1 (nome del venditore) e H2 (trimestre) ed eseguiamo un Xlookup a due vie con la seguente formula:

=XLOOKUP(H1, A2:A6, XLOOKUP(H2, B1:E1, B2:E6))

O il contrario:

=XLOOKUP(H2, B1:E1, XLOOKUP(H1, A2:A6, B2:E6))

Dove A2:A6 sono i nomi dei venditori, B1:E1 sono i trimestri (intestazioni di colonna) e B2:E6 sono i valori dei dati.

Una ricerca bidirezionale può essere eseguita anche con una formula di corrispondenza INDICE e in altri modi. Per ulteriori informazioni, vedere Ricerca bidirezionale in Excel.

Se errore XLOOKUP

Quando il valore di ricerca non viene trovato, Excel XLOOKUP restituisce un errore di tipo #N/A. Sebbene sia abbastanza familiare e comprensibile per gli utenti esperti, potrebbe essere piuttosto confuso per i principianti. Per sostituire la notazione di errore standard con un messaggio di facile comprensione, digitare il proprio testo nel quarto argomento denominato se_non_trovato .

Torniamo al primo esempio discusso in questa esercitazione. Se qualcuno inserisce un nome di oceano non valido in E1, la formula seguente gli dirà esplicitamente che "Non è stata trovata alcuna corrispondenza":

=XLOOKUP(E1, A2:A6, B2:B6, "Nessuna corrispondenza trovata")

Note:

• Il se_non_trovato L'argomento intrappola solo gli errori #N/A, non tutti gli errori.
• Gli errori #N/A possono essere gestiti anche con IFNA e VLOOKUP, ma la sintassi è un po' più complessa e la formula è più lunga.

XLOOKUP sensibile alle maiuscole

Per impostazione predefinita, la funzione XLOOKUP considera le lettere minuscole e maiuscole come gli stessi caratteri. Per renderla sensibile alle maiuscole e alle minuscole, utilizzare la funzione EXACT per il parametro array_di_ricerca argomento:

Come funziona questa formula La funzione EXACT confronta il valore di lookup con ogni valore dell'array di lookup e restituisce VERO se sono esattamente uguali, comprese le lettere maiuscole, FALSO altrimenti. Questo array di valori logici va alla funzione array_di_ricerca di XLOOKUP. Come risultato, XLOOKUP cerca il valore TRUE nell'array precedente e restituisce una corrispondenza nell'array di ritorno.

Ad esempio, per ottenere il prezzo da B2:B7 ( matrice_di_ritorno ) per l'elemento in E1 ( lookup_value) , la formula in E2 è:

=XLOOKUP(TRUE, EXACT(E1, A2:A7), B2:B7, "Non trovato")

Nota: se nell'array di ricerca sono presenti due o più valori esattamente uguali (comprese le lettere maiuscole), viene restituita la prima corrispondenza trovata.

Excel XLOOKUP non funziona

Se la vostra formula non funziona bene o dà luogo a errori, molto probabilmente ciò è dovuto ai seguenti motivi:

XLOOKUP non è disponibile nel mio Excel

La funzione XLOOKUP non è retrocompatibile: è disponibile solo in Excel per Microsoft 365 e Excel 2021 e non compare nelle versioni precedenti.

XLOOKUP restituisce un risultato errato

Se la formula Xlookup, ovviamente corretta, restituisce un valore errato, è probabile che l'intervallo di ricerca o di ritorno si sia "spostato" quando la formula è stata copiata verso il basso o verso l'altro. Per evitare che ciò accada, assicuratevi di bloccare sempre entrambi gli intervalli con riferimenti di cella assoluti (come $A$2:$A$10).

XLOOKUP restituisce un errore #N/A

Un errore #N/A significa semplicemente che il valore di ricerca non è stato trovato. Per risolvere il problema, provare a cercare una corrispondenza approssimativa o informare gli utenti che non è stata trovata alcuna corrispondenza.

XLOOKUP restituisce l'errore #VALORE

Un errore #VALUE! si verifica se gli array di ricerca e di restituzione hanno dimensioni incompatibili. Ad esempio, non è possibile cercare in un array orizzontale e restituire valori da un array verticale.

XLOOKUP restituisce un errore #REF

Viene lanciato un errore #REF! quando si cerca tra due diverse cartelle di lavoro, una delle quali è chiusa. Per risolvere l'errore, è sufficiente aprire entrambi i file.

Come avete appena visto, XLOOKUP ha molte caratteristiche straordinarie che la rendono la funzione ideale per quasi tutte le ricerche in Excel. Vi ringrazio per la lettura e spero di vedervi sul nostro blog la prossima settimana!

Eserciziario da scaricare

Esempi di formula XLOOKUP di Excel (file .xlsx)