Udžbenik predstavlja XLOOKUP - novu funkciju za okomito i vodoravno pretraživanje u Excelu. Pretraživanje lijevo, zadnje podudaranje, Vlookup s više kriterija i puno više stvari za koje je prije bila potrebna diploma raketne znanosti sada su postale jednostavne kao ABC.

Kad god trebate tražiti u Excelu , koju biste funkciju koristili? Je li to temeljni VLOOKUP ili njegov horizontalni brat HLOOKUP? U složenijem slučaju, hoćete li se osloniti na kanonsku kombinaciju INDEX MATCH ili povjeriti posao Power Queryju? Dobra je vijest da više nemate izbora - sve te metode otvaraju mjesto snažnijem i svestranijem nasljedniku, funkciji XLOOKUP.

Kako je XLOOKUP bolji? Na mnogo načina! Može gledati okomito i vodoravno, lijevo i gore, pretraživati ​​prema više kriterija, pa čak i vratiti cijeli stupac ili red podataka, a ne samo jednu vrijednost. Microsoftu je trebalo više od 3 desetljeća, ali konačno su uspjeli dizajnirati robusnu funkciju koja nadilazi mnoge frustrirajuće pogreške i slabosti VLOOKUP-a.

U čemu je caka? Jao, postoji jedan. Funkcija XLOOKUP dostupna je samo u programu Excel za Microsoft 365, Excel 2021 i Excel za web.

Funkcija XLOOKUP programa Excel - sintaksa i koristi

Funkcija XLOOKUP u Excel pretražuje raspon ili polje za određenu vrijednost i vraća povezanu vrijednost iz drugog stupca. Može tražiti obojedohvatiti sve detalje koji se odnose na prodavača od interesa (F2). Ono što trebate učiniti je navesti raspon, a ne jedan stupac ili redak, za argument return_array :

=XLOOKUP(F2, A2:A7, B2:D7)

Unesite formulu u gornjem lijevom kutu ćeliju raspona rezultata, a Excel automatski prelijeva rezultate u susjedne prazne ćelije. U našem slučaju, povratni niz (B2:D7) uključuje 3 stupca ( Datum , Stavka i Iznos ), a sve tri vrijednosti vraćaju se u raspon G2:I2.

Ako biste radije rezultate rasporedili okomito u stupac, ugniježdite XLOOKUP u funkciju TRANSPOSE da biste okrenuli vraćeni niz:

=TRANSPOSE(XLOOKUP(G1, A2:A7, B2:D7))

Na sličan način, možete vratiti cijeli stupac podataka, recimo stupac Količina . U tu svrhu koristite ćeliju F1 koja sadrži "Iznos" kao lookup_value , raspon A1:D1 koji sadrži zaglavlja stupaca kao lookup_array i raspon A2:D7 koji sadrži sve podatke kao return_array .

=XLOOKUP(F1, A1:D1, A2:D7)

Napomena. Budući da se više vrijednosti popunjava u susjedne ćelije, provjerite imate li dovoljno praznih ćelija desno ili dolje. Ako Excel ne može pronaći dovoljno praznih ćelija, #SPILL! dolazi do greške.

Savjet. XLOOKUP ne samo da može vratiti višestruke unose, već ih i zamijeniti drugim vrijednostima koje navedete. Primjer takve skupne zamjene može se pronaći ovdje: Kako pretraživati ​​i zamijeniti više vrijednosti s XLOOKUP-om.

XLOOKUP svišestruki kriteriji

Još jedna velika prednost XLOOKUP-a je da nativno rukuje nizovima. Zahvaljujući ovoj mogućnosti, možete procijeniti više kriterija izravno u argumentu lookup_array :

Kako funkcionira ova formula : Rezultat svakog testa kriterija je niz vrijednosti TRUE i FALSE. Množenje nizova pretvara TRUE i FALSE u 1 odnosno 0 i proizvodi konačno polje pretraživanja. Kao što znate, množenje s 0 uvijek daje nulu, tako da su u nizu pretraživanja samo stavke koje ispunjavaju sve kriterije predstavljene s 1. A budući da je naša vrijednost pretraživanja "1", Excel uzima prvu "1" u lookup_array (prvo podudaranje) i vraća vrijednost iz return_array na istoj poziciji.

Da biste vidjeli formulu na djelu, povucimo iznos iz D2:D10 ( return_array ) sa sljedećim uvjetima:

• Kriterij1 (datum) = G1
• Kriterij2 (prodavač) = G2
• Kriterij3 (stavka) = G3

S datumima u A2:A10 ( criteria_range1 ), imenima prodavača u B2:B10 ( criteria_range2 ) i artiklima u C2:C10 ( kriterij_raspon3 ), formula ima ovaj oblik:

=XLOOKUP(1, (B2:B10=G1) * (A2:A10=G2) * (C2:C10=G3), D2:D10)

Iako funkcija Excel XLOOKUP obrađuje nizove, radi kao redovita formula i dovršava se uobičajenim Enterompritisak tipke.

XLOOKUP formula s višestrukim kriterijima nije ograničena na uvjete "jednako". Možete slobodno koristiti i druge logičke operatore. Na primjer, za filtriranje narudžbi napravljenih na datum u G1 ili ranije, stavite "<=G1" u prvi kriterij:

=XLOOKUP(1, (A2:A10<=G1) * (B2:B10=G2) * (C2:C10=G3), D2:D10)

Double XLOOKUP

Da biste pronašli vrijednost na sjecištu određenog retka i stupca, izvršite takozvano double lookup ili matrix lookup . Da, Excel XLOOKUP može i to! Jednostavno ugniježdite jednu funkciju u drugu:

Kako ova formula funkcionira : Formula se temelji na mogućnosti XLOOKUP-a da vrati cijeli red ili stupac. Unutarnja funkcija traži svoju vrijednost pretraživanja i vraća stupac ili redak povezanih podataka. Taj niz ide u vanjsku funkciju kao return_array .

Za ovaj primjer, pronaći ćemo prodaju koju je izvršio određeni prodavač unutar određenog kvartala. Za to unosimo vrijednosti traženja u H1 (ime prodavača) i H2 (četvrtina) i radimo dvosmjerni Xlookup sa sljedećom formulom:

=XLOOKUP(H1, A2:A6, XLOOKUP(H2, B1:E1, B2:E6))

Ili obrnuto :

=XLOOKUP(H2, B1:E1, XLOOKUP(H1, A2:A6, B2:E6))

Gdje su A2:A6 imena prodavača, B1:E1 četvrtine (zaglavlja stupaca), a B2:E6 vrijednosti podataka.

Dvosmjerno pretraživanje također se može izvršiti s formulom INDEX Match i u anekoliko drugih načina. Za više informacija pogledajte Dvosmjerno traženje u Excelu.

Ako se pojavi pogreška XLOOKUP

Kada vrijednost pretraživanja nije pronađena, Excel XLOOKUP vraća pogrešku #N/A. Prilično poznato i razumljivo stručnim korisnicima, moglo bi biti prilično zbunjujuće za početnike. Da biste standardnu ​​notaciju pogreške zamijenili porukom koja je jednostavna za korištenje, upišite vlastiti tekst u četvrti argument pod nazivom if_not_found .

Natrag na prvi primjer o kojem se govori u ovom vodiču. Ako netko unese nevažeći naziv oceana u E1, sljedeća formula će mu izričito reći da "Nije pronađeno podudaranje":

=XLOOKUP(E1, A2:A6, B2:B6, "No match is found")

Napomene:

• Argument if_not_found hvata samo pogreške #N/A, ne sve pogreške.
• Pogreške #N/A također se mogu obraditi pomoću IFNA i VLOOKUP, ali sintaksa je malo složenija, a formula duža.

XLOOKUP osjetljiv na velika i mala slova

Prema zadanim postavkama, funkcija XLOOKUP mala i velika slova tretira kao iste znakove. Kako biste razlikovali velika i mala slova, koristite funkciju EXACT za argument lookup_array :

Kako ova formula funkcionira : Funkcija EXACT uspoređuje traženu vrijednost sa svakom vrijednošću u traženom nizu i vraća TRUE ako su potpuno jednake uključujući velika i velika slova, FALSE u suprotnom. Ovaj niz logičkih vrijednosti ide u lookup_array argument XLOOKUP-a. Kao rezultat, XLOOKUP traži TRUE vrijednost u gornjem nizu i vraća podudaranje iz povratnog niza.

Na primjer, da biste dobili cijenu iz B2:B7 ( return_array ) za stavka u E1 ( lookup_value) , formula u E2 je:

=XLOOKUP(TRUE, EXACT(E1, A2:A7), B2:B7, "Not found")

Napomena. Ako postoje dvije ili više potpuno istih vrijednosti u nizu pretraživanja (uključujući velika i mala slova), vraća se prvo pronađeno podudaranje.

Excel XLOOKUP ne radi

Ako vaša formula ne radi ispravno ili dovodi do pogreške, to je najvjerojatnije zbog sljedećih razloga:

XLOOKUP nije dostupan u mom Excelu

Funkcija XLOOKUP nije kompatibilna s prethodnim verzijama. Dostupan je samo u Excelu za Microsoft 365 i Excel 2021 i neće se pojaviti u ranijim verzijama.

XLOOKUP vraća pogrešan rezultat

Ako vaša očito točna Xlookup formula vraća pogrešnu vrijednost, velike su šanse da se raspon traženja ili vraćanja "pomaknuo" kada je formula kopirana prema dolje ili poprijeko. Kako biste spriječili da se to dogodi, svakako uvijek zaključajte oba raspona s apsolutnim referencama ćelije (kao što je $A$2:$A$10).

XLOOKUP vraća pogrešku #N/A

An #N /Pogreška samo znači da tražena vrijednost nije pronađena. Da biste to popravili, pokušajte tražiti približno podudaranje ili obavijestite svoje korisnike da nije pronađeno podudaranje.

XLOOKUP vraća grešku #VALUE

A #VALUE! javlja se pogreška ako nizovi pretraživanja i povrata nisu kompatibilnidimenzije. Na primjer, nije moguće pretraživati ​​u vodoravnom nizu i vratiti vrijednosti iz okomitog niza.

XLOOKUP vraća #REF grešku

A #REF! javlja se pogreška prilikom traženja između dvije različite radne knjige, od kojih je jedna zatvorena. Da biste ispravili pogrešku, jednostavno otvorite obje datoteke.

Kao što ste upravo vidjeli, XLOOKUP ima mnogo sjajnih značajki koje ga čine funkcijom za gotovo svako pretraživanje u Excelu. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeći tjedan!

Vježbe za preuzimanje

Excel XLOOKUP primjeri formula (.xlsx datoteka)

Sintaksa funkcije XLOOKUP je sljedeća:

Prva 3 argumenta su obavezna, a zadnja tri su izborna.

• Lookup_value - vrijednost za traženje.
• Lookup_array - raspon ili niz gdje pretraživati.
• Return_array - raspon ili niz iz kojeg se vraćaju vrijednosti.
• If_not_found [izborno] - vrijednost koja se vraća ako se ne pronađe podudaranje. Ako je izostavljeno, vraća se pogreška #N/A.
• Match_mode [izborno] - vrsta podudaranja koju treba izvesti:
  • 0 ili izostavljeno (zadano) - točno podudaranje . Ako nije pronađeno, vraća se pogreška #N/A.
  • -1 - točno podudaranje ili sljedeće manje. Ako nije pronađeno točno podudaranje, vraća se sljedeća manja vrijednost.
  • 1 - točno podudaranje ili sljedeće veće. Ako nije pronađeno točno podudaranje, vraća se sljedeća veća vrijednost.
  • 2 - podudaranje zamjenskih znakova.
• Način_pretraživanja [izborno] - smjer pretraživanja:
  • 1 ili izostavljeno (zadano) - za pretraživanje od prvog do zadnjeg.
  • -1 - za pretraživanje obrnutim redoslijedom, od zadnjeg prema prvom.
  • 2 - binarno pretraživanje podataka sortiranih uzlazno.
  • -2 - binarno pretraživanje podataka sortiranih silazno.

  Prema Microsoftu, binarnopretraživanje je uključeno za napredne korisnike. To je poseban algoritam koji pronalazi položaj tražene vrijednosti unutar sortiranog niza uspoređujući ga sa srednjim elementom niza. Binarno pretraživanje puno je brže od običnog pretraživanja, ali radi ispravno samo na sortiranim podacima.

Osnovna XLOOKUP formula

Da bismo bolje razumjeli, napravimo Xlookup formulu u najjednostavnijem obliku za izvođenje točnog pretraživanja. Za ovo će nam trebati samo prva 3 argumenta.

Pretpostavimo da imate tablicu sažetka s informacijama o pet oceana na Zemlji. Želite dobiti područje određenog unosa oceana u F1 ( lookup_value ). S nazivima oceana u A2:A6 ( lookup_array ) i područjima u C2:C6 ( return_array ), formula je sljedeća:

=XLOOKUP(F1, A2:A6, C2:C6)

Prevedeno na običan engleski, kaže: potražite vrijednost F1 u A2:A6 i vratite vrijednost iz C2:C6 u istom retku. Nema brojeva indeksa stupaca, nema sortiranja, nema drugih smiješnih čuda Vlookupa! Jednostavno radi :)

XLOOKUP naspram VLOOKUP-a u Excelu

U usporedbi s tradicionalnim VLOOKUP-om, XLOOKUP ima mnogo prednosti. Po čemu je bolji od VLOOKUP-a? Evo popisa 10 najboljih značajki koje otvaraju vrata bilo kojoj drugoj funkciji pretraživanja u Excelu:

1. Okomito i vodoravno pretraživanje . Funkcija XLOOKUP dobila je ime zbog svoje mogućnosti da gleda prema gore i okomito ivodoravno.
2. Gledajte u bilo kojem smjeru: desno, lijevo, dolje ili gore . Dok VLOOKUP može pretraživati ​​samo u krajnjem lijevom stupcu, a HLOOKUP u najvišem retku, XLOOKUP nema takvih ograničenja. Zloglasno lijevo pretraživanje u Excelu više nije problem!
3. Točno podudaranje prema zadanim postavkama . U većini situacija tražit ćete točno podudaranje, a XLOOKUP ga vraća prema zadanim postavkama (za razliku od funkcije VLOOKUP koja prema zadanim postavkama ima približno podudaranje). Naravno, možete natjerati XLOOKUP da izvede i približno podudaranje ako je potrebno.
4. Djelomično podudaranje sa zamjenskim znakovima . Kada znate samo dio tražene vrijednosti, a ne cijelu, podudaranje zamjenskih znakova je korisno.
5. Tražite obrnutim redoslijedom . Ranije, da biste dobili zadnje pojavljivanje, morali ste obrnuti redoslijed svojih izvornih podataka. Sada jednostavno postavite argument search_mode na -1 kako biste natjerali svoju Xlookup formulu da pretražuje odostraga i vrati zadnje podudaranje.
6. Vrati više vrijednosti . Manipuliranjem argumentom return_array možete izvući cijeli redak ili stupac podataka koji se odnose na vašu vrijednost traženja.
7. Tražite s više kriterija . Excel XLOOKUP nativno rukuje nizovima, što omogućuje traženje s više kriterija.
8. Funkcionalnost u slučaju pogreške . Tradicionalno koristimo funkciju IFNA za hvatanje pogrešaka #N/A. XLOOKUP uključuje ovu funkcionalnost u if_not_found argument koji dopušta ispis vašeg vlastitog teksta ako nije pronađeno valjano podudaranje.
9. Umetanja/brisanja stupaca . Jedan od najiritantnijih problema s VLOOKUP-om je taj što dodavanje ili uklanjanje stupaca prekida formulu jer se povratni stupac identificira svojim brojem indeksa. Uz XLOOKUP dajete raspon povrata, a ne broj, što znači da možete umetnuti i ukloniti onoliko stupaca koliko vam je potrebno, a da ništa ne pokvarite.
10. Bolje performanse . VLOOKUP bi mogao usporiti vaše radne listove jer uključuje cijelu tablicu u izračune, što rezultira obradom puno više ćelija nego što je stvarno potrebno. XLOOKUP obrađuje samo nizove pretraživanja i vraćanja o kojima doista ovisi.

Kako koristiti XLOOKUP u Excelu - primjeri formula

Sljedeći primjeri pokazuju najkorisnije XLOOKUP značajke na djelu. Osim toga, otkrit ćete nekoliko netrivijalnih upotreba koje će vaše vještine pretraživanja programa Excel podići na novu razinu.

Gledajte gore okomito i vodoravno

Microsoft Excel je nekada imao dvije funkcije za različito pretraživanje vrste, od kojih svaka ima vlastitu sintaksu i pravila upotrebe: VLOOKUP za okomito gledanje u stupcu i HLOOKUP za vodoravno gledanje u retku.

Funkcija XLOOKUP može raditi oboje s istom sintaksom. Razlika je u onome što dajete za nizove pretraživanja i povrata.

Za v-pretraživanje, navedite stupce:

=XLOOKUP(E1, A2:A6, B2:B6)

Zah-lookup, unesite retke umjesto stupaca:

=XLOOKUP(I1, B1:F1, B2:F2)

Lijevo pretraživanje izvedeno izvorno

U ranijim verzijama Excela, INDEX MATCH formula je bila jedini pouzdani način gledanja lijevo ili gore. Sada više ne morate kombinirati dvije funkcije gdje bi jedna bila dovoljna. Samo navedite ciljni niz traženja i XLOOKUP će njime upravljati bez problema bez obzira na njegovu lokaciju.

Kao primjer, dodajmo stupac Rank lijevo od naše ogledne tablice. Cilj je dobiti rang oceanskog unosa u F1. VLOOKUP bi se ovdje spotaknuo jer može vratiti samo vrijednost iz stupca desno od stupca za pretraživanje. Formula Xlookup s lakoćom se nosi s tim:

=XLOOKUP(F1, B2:B6, A2:A6)

Na sličan način možete pogledati iznad kada tražite vodoravno u redovima.

XLOOKUP s točnim i približnim podudaranjem

Ponašanje podudaranja kontrolira 5. argument koji se zove match_mode . Prema zadanim postavkama izvodi se točno podudaranje.

Obratite pozornost da čak i kada odaberete približno podudaranje ( match_mode postavljeno na 1 ili -1), funkcija će i dalje tražiti točno podudaranje utakmica prva. Razlika je u onome što vraća ako točna vrijednost pretraživanja nije pronađena.

Argument načina_podudaranja:

• 0 ili izostavljeno - točno podudaranje; ako nije pronađeno - greška #N/A.
• -1 - točno podudaranje; ako nije pronađeno - sljedeća manja stavka.
• 1 - točno podudaranje; ako se ne nađe- sljedeća veća stavka.

Točno podudaranje XLOOKUP

Ovo je opcija koju vjerojatno koristite 99% vremena kada tražite u Excelu. Budući da je točno podudaranje zadano ponašanje XLOOKUP-a, možete izostaviti match_mode i dati samo prva 3 potrebna argumenta.

U nekim situacijama, međutim, točno podudaranje neće funkcionirati. Tipičan scenarij je kada vaša tablica pretraživanja ne sadrži sve vrijednosti, već "prekretnice" ili "granice" kao što su popusti temeljeni na količini, provizije temeljene na prodaji itd.

Naš primjer tablice pretraživanja prikazuje korelaciju između rezultata ispita i ocjena. Kao što možete vidjeti na snimci zaslona u nastavku, točno podudaranje funkcionira samo kada rezultat određenog učenika točno odgovara vrijednosti u tablici pretraživanja (kao Christian u retku 3). U svim ostalim slučajevima vraća se pogreška #N/A.

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6)

Da bismo dobili ocjene umjesto pogrešaka #N/A, trebamo za traženje približnog podudaranja kao što je prikazano u sljedećem primjeru.

Približno podudaranje XLOOKUP

Da biste izvršili približno traženje, postavite argument match_mode na -1 ili 1 , ovisno o tome kako su vaši podaci organizirani.

U našem slučaju, pregledna tablica navodi donje granice ocjena. Dakle, postavili smo match_mode na -1 za traženje sljedeće manje vrijednosti kada nije pronađeno točno podudaranje:

=XLOOKUP(F11, $B$11:$B$15, $C$11:$C$15, ,-1)

Na primjer, Brian ima rezultat od 98 (F2). Formula traži ovu vrijednost pretraživanja u B2:B6ali ne može ga pronaći. Zatim traži sljedeću manju stavku i pronalazi 90, što odgovara ocjeni A:

Kad bi naša tablica pretraživanja sadržavala gornje granice ocjena, postavili bismo match_mode do 1 za traženje sljedeće veće stavke ako točno podudaranje ne uspije:

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6, ,1)

Formula traži 98 i opet ga ne može pronaći. Ovaj put pokušava pronaći sljedeću veću vrijednost i dobiva 100, što odgovara ocjeni A:

Savjet. Kada kopirate formulu Xlookup u više ćelija, zaključajte raspone pretraživanja ili povrata s apsolutnim referencama ćelija (kao što je $B$2:$B$6) kako biste spriječili njihovu promjenu.

XLOOKUP s djelomičnim podudaranjem (zamjenski znakovi)

Da biste izvršili traženje djelomičnog podudaranja, postavite argument match_mode na 2, što nalaže funkciji XLOOKUP da obradi zamjenske znakove:

• Zvjezdica (*) - predstavlja bilo koji niz znakova.
• Upitnik (?) - predstavlja bilo koji pojedinačni znak.

Da vidite kako radi , razmotrite sljedeći primjer. U stupcu A imate nekoliko modela pametnih telefona, au stupcu B njihov kapacitet baterije. Zanima vas baterija određenog pametnog telefona. Problem je u tome što niste sigurni možete li upisati naziv modela točno onako kako se pojavljuje u stupcu A. Da biste to riješili, unesite dio koji je definitivno tamo i zamijenite preostale znakove zamjenskim znakovima.

Na primjer, dobitiinformacije o bateriji iPhonea X, upotrijebite ovu formulu:

=XLOOKUP("*iphone X*", A2:A8, B2:B8, ,2)

Ili unesite poznati dio tražene vrijednosti u neku ćeliju i spojite referencu ćelije sa zamjenskim znakovima:

=XLOOKUP("*"&E1&"*", A2:A8, B2:B8, ,2)

XLOOKUP obrnutim redoslijedom da biste dobili zadnje pojavljivanje

U slučaju da vaša tablica sadrži nekoliko pojavljivanja vrijednosti pretraživanja, ponekad ćete možda trebati za vraćanje zadnjeg podudaranja . Da biste to učinili, konfigurirajte Xlookup formulu za pretraživanje obrnutim redoslijedom.

Smjerom pretraživanja upravlja 6. argument pod nazivom search_mode :

• 1 ili izostavljeno (zadano) - pretražuje od prve do zadnje vrijednosti, tj. od vrha do dna s okomitim pretraživanjem ili slijeva nadesno s vodoravnim pretraživanjem.
• -1 - pretražuje obrnutim redoslijedom od zadnje do prve vrijednosti .

Kao primjer, vratimo posljednju prodaju koju je obavio određeni prodavač. Za ovo smo sastavili prva tri potrebna argumenta (G1 za lookup_value , B2:B9 za lookup_array i D2:D9 za return_array ) i stavili - 1 u 5. argumentu:

=XLOOKUP(G1, B2:B9, D2:D9, , ,-1)

Izravno i jednostavno, zar ne?

XLOOKUP za vraćanje više stupaca ili redaka

Još jedna nevjerojatna značajka XLOOKUP-a je njegova sposobnost vraćanja više od jedne vrijednosti koja se odnosi na isto podudaranje. Sve se radi standardnom sintaksom i bez ikakvih dodatnih manipulacija!

Iz donje tablice, pretpostavimo da želite