De tutorial introduceert XLOOKUP - de nieuwe functie voor verticaal en horizontaal opzoeken in Excel. Links opzoeken, laatste overeenkomst, Vlookup met meerdere criteria en nog veel meer dingen waarvoor vroeger een raketwetenschappelijke graad nodig was om ze te bereiken, zijn nu zo eenvoudig als ABC.

Wanneer u in Excel moet opzoeken, welke functie gebruikt u dan? Is het de hoeksteen VLOOKUP of zijn horizontale broer HLOOKUP? In een complexer geval vertrouwt u op de canonieke combinatie INDEX MATCH of vertrouwt u de taak toe aan Power Query? Het goede nieuws is dat u niet meer hoeft te kiezen - al deze methoden maken plaats voor een krachtigere en veelzijdigere opvolger, de XLOOKUP-functie.

Hoe is XLOOKUP beter? Op vele manieren! Het kan verticaal en horizontaal kijken, naar links en naar boven, zoeken met meerdere criteria, en zelfs een hele kolom of rij met gegevens teruggeven, niet slechts één waarde. Het heeft Microsoft meer dan 3 decennia gekost, maar eindelijk zijn ze erin geslaagd een robuuste functie te ontwerpen die vele frustrerende fouten en zwakheden van VLOOKUP overwint.

De XLOOKUP-functie is alleen beschikbaar in Excel voor Microsoft 365, Excel 2021 en Excel voor het web.

Excel XLOOKUP functie - syntaxis en gebruik

De XLOOKUP-functie in Excel zoekt in een bereik of een matrix naar een opgegeven waarde en geeft de gerelateerde waarde in een andere kolom terug. De functie kan zowel verticaal als horizontaal opzoeken en een exacte (standaard), benaderende (dichtstbijzijnde) of jokerteken (gedeeltelijke) overeenkomst uitvoeren.

De syntaxis van de XLOOKUP-functie is als volgt:

De eerste 3 argumenten zijn verplicht en de laatste drie zijn facultatief.

• Lookup_value - de waarde waarnaar moet worden gezocht.
• Lookup_array - het bereik of de matrix waarin moet worden gezocht.
• Return_array - het bereik of de matrix waaruit de waarden moeten terugkomen.
• If_not_found [optioneel] - de waarde die moet worden geretourneerd als er geen overeenkomst wordt gevonden. Indien weggelaten, wordt een #N/A-fout geretourneerd.
• Match_mode [facultatief] - het type overeenkomst dat moet worden uitgevoerd:
  • 0 of weggelaten (standaard) - exacte overeenkomst. Indien niet gevonden, wordt een #N/A-fout geretourneerd.
  • -1 - exacte overeenkomst of volgende kleinere. Als er geen exacte overeenkomst wordt gevonden, wordt de volgende kleinere waarde geretourneerd.
  • 1 - exacte overeenkomst of de eerstvolgende grotere. Als er geen exacte overeenkomst wordt gevonden, wordt de eerstvolgende grotere waarde geretourneerd.
  • 2 - wildcard karakter match.
• Zoekmodus [facultatief] - de zoekrichting:
  • 1 of weggelaten (standaard) - om van eerste naar laatste te zoeken.
  • -1 - om in omgekeerde volgorde te zoeken, van laatste naar eerste.
  • 2 - binair zoeken op gegevens die oplopend gesorteerd zijn.
  • -2 - binair zoeken op aflopend gesorteerde gegevens.

  Volgens Microsoft, binaire zoektocht Het is een speciaal algoritme dat de positie van een lookup-waarde in een gesorteerde array vindt door deze te vergelijken met het middelste element van de array. Een binaire zoekopdracht is veel sneller dan een gewone zoekopdracht, maar werkt alleen correct op gesorteerde gegevens.

Basisformule XLOOKUP

Om meer inzicht te krijgen, bouwen we een Xlookup-formule in zijn eenvoudigste vorm om een exacte lookup uit te voeren. Hiervoor hebben we alleen de eerste 3 argumenten nodig.

Stel, u hebt een overzichtstabel met informatie over de vijf oceanen op aarde. U wilt de oppervlakte van een specifieke oceaan invoeren in F1 ( lookup_waarde ). Met de oceaannamen in A2:A6 ( lookup_array ) en gebieden in C2:C6 ( return_array ), gaat de formule als volgt:

=XLOOKUP(F1, A2:A6, C2:C6)

Vertaald in gewoon Engels zegt het: zoek de waarde F1 in A2:A6 en geef een waarde terug uit C2:C6 in dezelfde rij. Geen kolomindexnummers, geen sortering, geen andere belachelijke eigenaardigheden van Vlookup! Het werkt gewoon :)

XLOOKUP vs. VLOOKUP in Excel

Vergeleken met de traditionele VLOOKUP heeft XLOOKUP vele voordelen. In welk opzicht is het beter dan VLOOKUP? Hier is een lijst van de beste 10 functies die de deuren van elke andere opzoekfunctie in Excel wegblazen:

1. Verticaal en horizontaal opzoeken De XLOOKUP-functie dankt haar naam aan de mogelijkheid om zowel verticaal als horizontaal op te zoeken.
2. Kijk in elke richting: rechts, links, onder of boven Terwijl VLOOKUP alleen kan zoeken in de meest linkse kolom en HLOOKUP in de meest bovenste rij, kent XLOOKUP die beperkingen niet. De beruchte linkse lookup in Excel is niet meer vervelend!
3. Standaard exacte overeenkomst In de meeste situaties zult u op zoek zijn naar een exacte overeenkomst, en XLOOKUP geeft die standaard (in tegenstelling tot de VLOOKUP-functie die standaard een benaderende overeenkomst geeft). Natuurlijk kunt u XLOOKUP ook een benaderende overeenkomst laten uitvoeren als dat nodig is.
4. Gedeeltelijke overeenkomst met jokertekens Wanneer u slechts een deel van de zoekwaarde kent, en niet alles, is een jokerteken handig.
5. Zoeken in omgekeerde volgorde Vroeger moest u, om het laatste voorval te krijgen, de volgorde van uw brongegevens omkeren. Nu stelt u gewoon de zoekmodus argument op -1 om uw Xlookup-formule te dwingen vanaf de achterkant te zoeken en de laatste overeenkomst terug te geven.
6. Geef meerdere waarden terug Door te manipuleren met de return_array argument, kunt u een hele rij of kolom gegevens met betrekking tot uw lookup-waarde ophalen.
7. Zoeken met meerdere criteria Excel XLOOKUP verwerkt van nature arrays, wat het mogelijk maakt lookups uit te voeren met meerdere criteria.
8. Als de foutfunctionaliteit Traditioneel gebruiken we de IFNA-functie om #N/A-fouten op te vangen. XLOOKUP neemt deze functionaliteit op in de if_not_found argument waarmee u uw eigen tekst kunt uitvoeren als er geen geldige overeenkomst wordt gevonden.
9. Kolom invoegen/verwijderen Een van de meest irritante problemen met VLOOKUP is dat het toevoegen of verwijderen van kolommen een formule verbreekt, omdat de retourkolom wordt geïdentificeerd door zijn indexnummer. Met XLOOKUP geeft u het retourbereik op, niet het nummer, wat betekent dat u zoveel kolommen kunt invoegen en verwijderen als u nodig hebt zonder iets te verbreken.
10. Betere prestaties VLOOKUP kan uw werkbladen vertragen omdat het de hele tabel meeneemt in de berekeningen, waardoor veel meer cellen worden verwerkt dan eigenlijk nodig is. XLOOKUP verwerkt alleen de lookup en return arrays waar het echt van afhankelijk is.

Hoe XLOOKUP gebruiken in Excel - formulevoorbeelden

De volgende voorbeelden demonstreren de meest nuttige XLOOKUP functies in actie. Daarnaast ontdekt u een aantal niet-triviale toepassingen die uw Excel lookup vaardigheden naar een nieuw niveau tillen.

Kijk verticaal en horizontaal omhoog

Microsoft Excel had vroeger twee functies voor verschillende soorten opzoekingen, elk met hun eigen syntaxis en gebruiksregels: VLOOKUP om verticaal in een kolom te kijken en HLOOKUP om horizontaal in een rij te kijken.

De XLOOKUP-functie kan beide doen met dezelfde syntaxis. Het verschil zit in wat je opgeeft voor de opzoek- en terugbreng-arrays.

Voor v-lookup, kolommen aanleveren:

=XLOOKUP(E1, A2:A6, B2:B6)

Voer voor h-zoeken rijen in in plaats van kolommen:

=XLOOKUP(I1, B1:F1, B2:F2)

Links opzoeken op natuurlijke wijze

In eerdere versies van Excel was de INDEX MATCH formule de enige betrouwbare manier om naar links of naar boven te kijken. Nu hoef je niet langer twee functies te combineren waar één zou volstaan. Geef gewoon de doelzoekarray op, en XLOOKUP zal deze probleemloos verwerken, ongeacht de locatie.

Laten we als voorbeeld de Rang kolom links van onze voorbeeldtabel. Het doel is om de rang van de oceaaninvoer in F1 te krijgen. VLOOKUP zou hier struikelen omdat het alleen een waarde kan teruggeven van een kolom rechts van de opzoekkolom. Een Xlookup-formule kan dat gemakkelijk aan:

=XLOOKUP(F1, B2:B6, A2:A6)

Op soortgelijke wijze kunt u hierboven kijken als u horizontaal in rijen zoekt.

XLOOKUP met exacte en benaderende overeenkomst

Het wedstrijdgedrag wordt bepaald door het 5e argument genaamd match_mode Standaard wordt een exacte overeenkomst uitgevoerd.

Let erop dat zelfs wanneer u een overeenkomst bij benadering kiest ( match_mode ingesteld op 1 of -1), zoekt de functie nog steeds eerst naar een exacte overeenkomst. Het verschil zit in wat er wordt teruggegeven als er geen exacte opzoekwaarde wordt gevonden.

Match_mode argument:

• 0 of weggelaten - exacte overeenkomst; indien niet gevonden - #N/A fout.
• -1 - exacte match; indien niet gevonden - volgende kleinere item.
• 1 - exacte match; indien niet gevonden - volgende grotere item.

Exacte overeenkomst XLOOKUP

Dit is de optie die u waarschijnlijk 99% van de keren dat u opzoekingen doet in Excel gebruikt. Omdat een exacte overeenkomst het standaard gedrag van XLOOKUP is, kunt u het volgende weglaten match_mode en geef alleen de eerste 3 vereiste argumenten.

In sommige situaties zal een exacte overeenkomst echter niet werken. Een typisch scenario is wanneer uw opzoektabel niet alle waarden bevat, maar eerder "mijlpalen" of "grenzen" zoals op hoeveelheid gebaseerde kortingen, op verkoop gebaseerde commissies, enz.

Onze voorbeeldopzoektabel toont de correlatie tussen examenscores en cijfers. Zoals je in de schermafbeelding hieronder kunt zien, werkt een exacte overeenkomst alleen als de score van een bepaalde leerling exact overeenkomt met de waarde in de opzoektabel (zoals Christian in rij 3). In alle andere gevallen wordt een #N/A-fout teruggestuurd.

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6)

Om de cijfers te krijgen in plaats van #N/A fouten, moeten we zoeken naar een benaderende overeenkomst zoals in het volgende voorbeeld.

Geschatte overeenkomst XLOOKUP

Om bij benadering te zoeken, stelt u de match_mode argument op -1 of 1, afhankelijk van hoe uw gegevens zijn georganiseerd.

In ons geval bevat de opzoektabel de ondergrenzen van de rangen. We stellen dus match_mode op -1 om de volgende kleinere waarde te zoeken wanneer geen exacte overeenkomst wordt gevonden:

=XLOOKUP(F11, $B$11:$B$15, $C$11:$C$15, ,-1)

Bijvoorbeeld, Brian heeft de score 98 (F2). De formule zoekt naar deze opzoekwaarde in B2:B6 maar kan hem niet vinden. Dan zoekt hij naar het volgende kleinere item en vindt 90, wat overeenkomt met cijfer A:

Als onze opzoektabel de bovengrenzen van de rangen bevat, zouden we het volgende instellen match_mode op 1 om naar het volgende grotere item te zoeken als een exacte overeenkomst niet lukt:

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6, ,1)

De formule zoekt naar 98 en kan het opnieuw niet vinden. Deze keer probeert hij de eerstvolgende grotere waarde te vinden en krijgt 100, wat overeenkomt met graad A:

Tip. Wanneer u een Xlookup-formule naar meerdere cellen kopieert, vergrendel dan de opzoek- of retourbereiken met absolute celverwijzingen (zoals $B$2:$B$6) om te voorkomen dat ze veranderen.

XLOOKUP met gedeeltelijke overeenkomst (jokertekens)

Om een gedeeltelijke zoekopdracht uit te voeren, stelt u de match_mode argument 2, waardoor de XLOOKUP-functie de jokertekens moet verwerken:

• Een asterisk (*) - staat voor een willekeurige reeks tekens.
• Een vraagteken (?) - staat voor een enkel teken.

Om te zien hoe het werkt, kunt u het volgende voorbeeld bekijken. In kolom A hebt u een aantal smartphonemodellen en in kolom B hun batterijcapaciteit. U bent nieuwsgierig naar de batterij van een bepaalde smartphone. Het probleem is dat u niet zeker weet of u de modelnaam precies zo kunt intypen als in kolom A. Om dit te ondervangen, voert u het deel in dat er zeker is en vervangt u het resterende deeltekens met jokertekens.

Om bijvoorbeeld informatie te krijgen over de batterij van de iPhone X, gebruik je deze formule:

=XLOOKUP("*iphone X*", A2:A8, B2:B8, ,2)

Of voer het bekende deel van de opzoekwaarde in een cel in en voeg de celverwijzing samen met de jokertekens:

=XLOOKUP("*"&E1&"*", A2:A8, B2:B8, ,2)

XLOOKUP in omgekeerde volgorde om het laatste optreden te krijgen

Indien uw tabel meerdere keren de opzoekwaarde bevat, kan het soms nodig zijn om de laatste wedstrijd Om dit te laten doen, configureert u uw Xlookup-formule om in omgekeerde volgorde te zoeken.

De zoekrichting wordt bepaald door het 6e argument, genaamd zoekmodus :

• 1 of weggelaten (standaard) - zoekt van de eerste naar de laatste waarde, d.w.z. van boven naar beneden met verticale lookup of van links naar rechts met horizontale lookup.
• -1 - zoekt in omgekeerde volgorde van de laatste naar de eerste waarde.

Laten we als voorbeeld de laatste verkoop van een specifieke verkoper teruggeven. Hiervoor stellen we de eerste drie vereiste argumenten samen (G1 voor lookup_waarde , B2:B9 voor lookup_array en D2:D9 voor return_array ) en zet -1 in het 5e argument:

=XLOOKUP(G1, B2:B9, D2:D9, , ,-1)

Eenvoudig en gemakkelijk, nietwaar?

XLOOKUP om meerdere kolommen of rijen terug te geven

Nog een verbazingwekkende eigenschap van XLOOKUP is de mogelijkheid om meer dan één waarde terug te geven met betrekking tot dezelfde overeenkomst. Dit gebeurt allemaal met de standaardsyntaxis en zonder extra manipulaties!

Stel dat u in de onderstaande tabel alle gegevens van de betreffende verkoper (F2) wilt opvragen. Wat u moet doen is een bereik opgeven, niet een enkele kolom of rij, voor de return_array argument:

=XLOOKUP(F2, A2:A7, B2:D7)

U voert de formule in in de cel linksboven van het resultatenbereik, en Excel morst de resultaten automatisch in aangrenzende lege cellen. In ons geval bevat de retourreeks (B2:D7) 3 kolommen ( Datum , Item en Bedrag ), en alle drie de waarden worden teruggegeven in het bereik G2:I2.

Als u de resultaten liever verticaal in een kolom rangschikt, nestelt u XLOOKUP in de functie TRANSPOSE om de geretourneerde matrix om te keren:

=TRANSPOSE(XLOOKUP(G1, A2:A7, B2:D7))

Op soortgelijke wijze kunt u een hele kolom gegevens teruggeven, bijvoorbeeld de Bedrag Gebruik hiervoor cel F1 die "Bedrag" bevat als lookup_waarde het bereik A1:D1 met de kolomkoppen als lookup_array en het bereik A2:D7 met alle gegevens als return_array .

=XLOOKUP(F1, A1:D1, A2:D7)

Opmerking. Omdat meerdere waarden in aangrenzende cellen worden ingevuld, moet u ervoor zorgen dat u voldoende lege cellen rechts of beneden heeft. Als Excel niet genoeg lege cellen kan vinden, treedt een #SPILL! foutmelding op.

Tip. XLOOKUP kan niet alleen meerdere waarden teruggeven, maar ze ook vervangen door andere waarden die u opgeeft. Een voorbeeld van zo'n bulkvervanging vindt u hier: Hoe meerdere waarden zoeken en vervangen met XLOOKUP.

XLOOKUP met meerdere criteria

Een ander groot voordeel van XLOOKUP is dat het van nature arrays verwerkt. Door deze mogelijkheid kunt u meerdere criteria direct in de lookup_array argument:

Hoe deze formule werkt Het resultaat van elke criteriatest is een array van TRUE en FALSE waarden. De vermenigvuldiging van de arrays zet TRUE en FALSE om in respectievelijk 1 en 0, en produceert de uiteindelijke lookup array. Zoals u weet, geeft vermenigvuldiging met 0 altijd nul, dus in de lookup array worden alleen de items die aan alle criteria voldoen vertegenwoordigd door 1. En omdat onze lookup waarde "1" is, neemt Excel de eerste "1" in lookup_array (eerste overeenkomst) en geeft de waarde terug van return_array in dezelfde positie.

Om de formule in actie te zien, halen we een bedrag uit D2:D10 ( return_array ) met de volgende voorwaarden:

• Criteria1 (datum) = G1
• Criteria2 (verkoper) = G2
• Criteria3 (item) = G3

Met data in A2:A10 ( criteria_bereik1 ), namen van verkopers in B2:B10 ( criteria_bereik2 ) en posten in C2:C10 ( criteria_bereik3 ), neemt de formule deze vorm aan:

=XLOOKUP(1, (B2:B10=G1) * (A2:A10=G2) * (C2:C10=G3), D2:D10)

Hoewel de Excel XLOOKUP-functie arrays verwerkt, werkt zij als een gewone formule en wordt zij voltooid met een gebruikelijke Enter-toetsaanslag.

De XLOOKUP formule met meerdere criteria is niet beperkt tot "gelijk aan" voorwaarden. Het staat u vrij om ook andere logische operatoren te gebruiken. Om bijvoorbeeld bestellingen te filteren die zijn gedaan op de datum in G1 of eerder, zet u "<=G1" in het eerste criterium:

=XLOOKUP(1, (A2:A10<=G1) * (B2:B10=G2) * (C2:C10=G3), D2:D10)

Dubbele XLOOKUP

Om een waarde te vinden op het snijpunt van een bepaalde rij en kolom, voert u de zgn. dubbele lookup of matrixopzoeking Ja, Excel XLOOKUP kan dat ook! Je nestelt gewoon de ene functie in de andere:

Hoe deze formule werkt : De formule is gebaseerd op de mogelijkheid van XLOOKUP om een hele rij of kolom terug te geven. De binnenste functie zoekt naar zijn opzoekwaarde en geeft een kolom of rij gerelateerde gegevens terug. Die reeks gaat naar de buitenste functie als de return_array .

Voor dit voorbeeld gaan we de verkopen vinden van een bepaalde verkoper binnen een bepaald kwartaal. Hiervoor voeren we de lookup-waarden in H1 (naam verkoper) en H2 (kwartaal) in, en doen we een tweezijdige Xlookup met de volgende formule:

=XLOOKUP(H1, A2:A6, XLOOKUP(H2, B1:E1, B2:E6))

Of andersom:

=XLOOKUP(H2, B1:E1, XLOOKUP(H1, A2:A6, B2:E6))

Waarbij A2:A6 de namen van de verkopers zijn, B1:E1 de kwartieren (kolomkoppen), en B2:E6 de gegevenswaarden.

Een bidirectionele lookup kan ook worden uitgevoerd met een INDEX Match formule en op enkele andere manieren. Voor meer informatie, zie Bidirectionele lookup in Excel.

Als fout XLOOKUP

Wanneer de opzoekwaarde niet wordt gevonden, geeft Excel XLOOKUP een #N/A foutmelding. Hoewel dit bekend en begrijpelijk is voor ervaren gebruikers, kan het nogal verwarrend zijn voor nieuwelingen. Om de standaard foutmelding te vervangen door een gebruiksvriendelijke boodschap, typ je je eigen tekst in het 4e argument genaamd if_not_found .

Terug naar het allereerste voorbeeld dat in deze tutorial is besproken. Als iemand een ongeldige oceaannaam invoert in E1, zal de volgende formule hem expliciet vertellen dat "Er is geen overeenkomst gevonden":

=XLOOKUP(E1, A2:A6, B2:B6, "Geen overeenkomst gevonden")

Opmerkingen:

• De if_not_found argument vangt alleen #N/A-fouten op, niet alle fouten.
• #N/A fouten kunnen ook worden behandeld met IFNA en VLOOKUP, maar de syntaxis is iets ingewikkelder en een formule is langer.

Hoofdlettergevoelige XLOOKUP

Standaard behandelt de XLOOKUP-functie kleine letters en hoofdletters als dezelfde tekens. Om de functie hoofdlettergevoelig te maken, gebruikt u de EXACT-functie voor de lookup_array argument:

Hoe deze formule werkt De functie EXACT vergelijkt de lookup-waarde met elke waarde in de lookup-array en geeft WAAR als ze exact hetzelfde zijn, inclusief het hoofdlettergebruik, anders ONWAAR. Deze array van logische waarden gaat naar de lookup_array argument van XLOOKUP. Als resultaat zoekt XLOOKUP naar de TRUE waarde in de bovenstaande array en retourneert een overeenkomst in de return array.

Bijvoorbeeld, om de prijs te krijgen van B2:B7 ( return_array ) voor het item in E1 ( lookup_value) is de formule in E2:

=XLOOKUP(TRUE, EXACT(E1, A2:A7), B2:B7, "Niet gevonden")

Opmerking. Als er twee of meer exact dezelfde waarden in de opzoek-array staan (inclusief het hoofdlettergebruik), wordt de eerst gevonden overeenkomst teruggegeven.

Excel XLOOKUP werkt niet

Als uw formule niet goed werkt of een fout oplevert, komt dat waarschijnlijk door de volgende redenen:

XLOOKUP is niet beschikbaar in mijn Excel

De XLOOKUP-functie is niet achterwaarts compatibel. Ze is alleen beschikbaar in Excel voor Microsoft 365 en Excel 2021, en verschijnt niet in eerdere versies.

XLOOKUP geeft verkeerd resultaat

Als uw duidelijk correcte Xlookup-formule een verkeerde waarde oplevert, is de kans groot dat het opzoek- of retourbereik is "verschoven" toen de formule naar beneden of naar de overkant werd gekopieerd. Om dit te voorkomen, moet u beide bereiken altijd vergrendelen met absolute celverwijzingen (zoals $A$2:$A$10).

XLOOKUP geeft #N/A foutmelding

Een #N/A-fout betekent gewoon dat de opzoekwaarde niet is gevonden. Om dit op te lossen, probeert u naar een benaderende overeenkomst te zoeken of informeert u uw gebruikers dat er geen overeenkomst is gevonden.

XLOOKUP geeft #VALUE foutmelding

Er treedt een #VALUE! fout op indien de opzoek- en retour-arrays onverenigbare afmetingen hebben. Het is bijvoorbeeld niet mogelijk te zoeken in een horizontale array en waarden terug te geven uit een verticale array.

XLOOKUP geeft #REF foutmelding

Er wordt een #REF! fout gegooid bij het opzoeken tussen twee verschillende werkmappen, waarvan er één gesloten is. Om de fout te herstellen, opent u gewoon beide bestanden.

Zoals je zojuist hebt gezien, heeft XLOOKUP veel geweldige functies die het DE functie maken voor bijna elke lookup in Excel. Ik dank je voor het lezen en hoop je volgende week op onze blog te zien!

Praktijk werkboek om te downloaden

Excel XLOOKUP formule voorbeelden (.xlsx bestand)