Trong hướng dẫn này, chúng ta sẽ xem xét cách sử dụng hàm ISERROR với hàm VLOOKUP trong Excel để xử lý tất cả các loại lỗi một cách hiệu quả.

Vlookup là một trong những hàm khó hiểu nhất của Excel gây cản trở với nhiều vấn đề. Cho dù bạn đang xem bảng nào, lỗi #N/A là điều thường thấy, với #NAME và #VALUE thỉnh thoảng cũng xuất hiện. Sử dụng VLOOKUP với ISERROR có thể giúp bạn phát hiện tất cả các lỗi có thể xảy ra và xử lý chúng theo cách phù hợp nhất với tình huống của bạn.

Tại sao VLOOKUP lại báo lỗi?

Điều quan trọng nhất lỗi phổ biến trong công thức VLOOKUP là #N/A xảy ra khi không tìm thấy giá trị tra cứu. Điều này có thể xảy ra vì những lý do khác nhau:

• Giá trị tra cứu không tồn tại trong mảng tra cứu.
• Giá trị tra cứu bị sai chính tả.
• Có những từ dẫn đầu hoặc dấu cách ở cuối giá trị tra cứu hoặc cột tra cứu.
• Cột tra cứu không phải là cột ngoài cùng bên trái của mảng bảng.

Ngoài ra, bạn có thể chạy vào #VALUE ! lỗi, ví dụ: khi giá trị tra cứu chứa hơn 255 ký tự. Trong trường hợp có lỗi chính tả trong tên của hàm, lỗi #NAME? sẽ xuất hiện.

Để tham khảo đầy đủ, vui lòng xem bài đăng trước của chúng tôi về Tại sao Excel VLOOKUP không hoạt động.

Công thức IF ISERROR VLOOKUP để thay thế lỗi bằng văn bản tùy chỉnh

Để ẩn tất cả các lỗi có thể do VLOOKUP kích hoạt, bạn có thể đặt nó bên trong công thức IF ISERRORnhư thế này:

Ví dụ: hãy lấy tên của các môn học mà sinh viên của thử nghiệm không thành công nhóm A:

=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)

Kết quả là bạn gặp phải một loạt lỗi #N/A, điều này có thể tạo ấn tượng rằng công thức bị hỏng.

Thực tế, những lỗi này chỉ cho biết rằng một số giá trị tra cứu (A3:A14) không được tìm thấy trong danh sách tra cứu (D3:D9). Để truyền đạt rõ ràng ý tưởng đó, hãy lồng công thức VLOOKUP của bạn vào cấu trúc IF ISERROR:

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

Điều này sẽ bắt lỗi và trả về tin nhắn văn bản tùy chỉnh của bạn:

Mẹo và lưu ý:

• Ưu điểm chính của công thức này là nó hoạt động độc đáo trong tất cả các phiên bản của Excel 2000 đến Excel 365. Trong các phiên bản hiện đại, đơn giản hơn và có nhiều lựa chọn thay thế nhỏ gọn hơn.
• Hàm ISERROR bắt chắc chắn tất cả các lỗi , chẳng hạn như #N/A, #NAME, #VALUE, v.v. Trong trường hợp bạn muốn hiển thị tùy chỉnh chỉ khi không tìm thấy giá trị tra cứu (lỗi #N/A), hãy sử dụng IF ISNA VLOOKUP (trong tất cả các phiên bản) hoặc IFNA VLOOKUP (trong Excel 2013 trở lên).

ISERROR VLOOKUP để trả về ô trống nếu có lỗi

Để có ô trống khi xảy ra lỗi, hãy lấy công thức trả về chuỗi rỗng ("") thay vì văn bản tùy chỉnh:

Trong trường hợp của chúng ta, công thức có dạng sau:

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

Cáckết quả chính xác như mong đợi - một ô trống nếu tên của học sinh không được tìm thấy trong bảng tra cứu.

Mẹo. Theo cách tương tự, bạn có thể thay thế các lỗi VLOOKUP bằng số không, dấu gạch ngang hoặc bất kỳ ký tự nào khác mà bạn thích. Chỉ cần sử dụng ký tự mong muốn thay cho một chuỗi trống.

Công thức IF ISERROR VLOOKUP Có/Không

Trong một số trường hợp, bạn có thể đang tìm kiếm thứ gì đó nhưng thay vì kéo các kết quả khớp, bạn chỉ muốn trả về Có (hoặc một số văn bản khác nếu tìm thấy giá trị tra cứu) và Không (nếu không tìm thấy giá trị tra cứu). Để hoàn thành, bạn có thể sử dụng công thức chung sau:

Trong tập dữ liệu mẫu, giả sử bạn muốn biết học sinh nào trượt bài kiểm tra và học sinh nào không. Để thực hiện điều này, hãy đưa công thức ISERROR VLOOKUP đã quen thuộc vào kiểm tra logic của IF và yêu cầu công thức này xuất ra "Không" nếu không tìm thấy giá trị (ISERROR VLOOKUP trả về TRUE), "Có" nếu tìm thấy (ISERROR VLOOKUP trả về SAI):

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", "Yes")

Các lựa chọn thay thế ISERROR VLOOKUP

Sự kết hợp IF ISERROR là kỹ thuật lâu đời nhất đã được chứng minh để Vlookup không có lỗi trong Excel. Theo thời gian, các chức năng mới đã phát triển, cung cấp các cách dễ dàng hơn để thực hiện cùng một nhiệm vụ. Dưới đây, chúng ta sẽ thảo luận về các giải pháp khả thi khác và thời điểm tốt nhất để áp dụng từng giải pháp.

VLOOKUP IFERROR

Có sẵn trong Excel 2007 vàcao hơn

Kể từ phiên bản 2007, Excel có một chức năng đặc biệt, tên là IFERROR, để kiểm tra lỗi trong công thức và trả về văn bản của riêng bạn (hoặc chạy một công thức thay thế) nếu phát hiện thấy bất kỳ lỗi nào.

Công thức thực tế như sau:

=IFERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "No")

Thoạt nhìn, nó trông giống như một dạng tương tự ngắn hơn của công thức IF ISERROR VLOOKUP. Tuy nhiên, có một điểm khác biệt cơ bản:

• IFERROR VLOOKUP giả định rằng bạn luôn muốn kết quả của VLOOKUP nếu đó không phải là lỗi.
• IF ISERROR VLOOKUP cho phép bạn chỉ định những gì cần làm trả về nếu có lỗi và nếu không có lỗi thì sao.

Để biết thêm chi tiết, vui lòng xem Sử dụng IFERROR với VLOOKUP trong Excel.

IF ISNA VLOOKUP

Hoạt động trong Excel 2000 trở lên

Trong trường hợp bạn chỉ muốn bẫy #N/A mà không bắt bất kỳ lỗi nào khác, hàm ISNA sẽ rất hữu ích. Cú pháp giống như cú pháp IF ISERROR VLOOKUP:

Nhưng trong một số trường hợp nhất định, điều này dường như công thức giống hệt nhau có thể tạo ra các kết quả khác nhau:

=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

Trong hình ảnh bên dưới, ô A13 chứa nhiều khoảng trắng ở cuối vì tổng độ dài của giá trị tra cứu vượt quá 255 ký tự. Kết quả là công thức kích hoạt lỗi #VALUE! lỗi, thu hút sự chú ý của bạn đến ô đó và khuyến khích điều tra nguyên nhân. ISERRORVLOOKUP sẽ trả về "Không" trong trường hợp này, điều này sẽ chỉ che khuất vấn đề và đưa ra kết quả hoàn toàn sai.

Khi nào nên sử dụng:

Công thức này hoạt động tuyệt vời trong trường hợp khi bạn chỉ muốn hiển thị một số văn bản khi không tìm thấy giá trị tra cứu và không muốn che dấu các vấn đề tiềm ẩn bằng chính công thức VLOOKUP, ví dụ: khi tên của hàm bị nhập sai (#NAME?) hoặc đường dẫn đầy đủ đến sổ làm việc tra cứu không được chỉ định (#VALUE!).

Để biết thêm thông tin, vui lòng xem hàm ISNA trong Excel với các ví dụ về công thức.

IFNA VLOOKUP

Có sẵn trong Excel 2013 trở lên

Đây là sự thay thế hiện đại của tổ hợp IF ISNA cho phép bạn xử lý lỗi #N/A trong một cách dễ dàng hơn.

Đây là cách viết tắt tương đương với công thức IF ISNA VLOOKUP của chúng tôi:

=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "No")

Khi nào nên sử dụng:

Đó là giải pháp lý tưởng để bẫy và xử lý lỗi #N/A trong các phiên bản Excel hiện đại (2013 - 365).

Để biết đầy đủ thông tin chi tiết, hãy xem Hàm IFNA của Excel.

XLOOKUP

Được hỗ trợ trong Excel 2021 và Excel 365

Do chức năng "if error" có sẵn , hàm XLOOKUP là cách dễ nhất để tra cứu mà không bị lỗi #N/A trong Excel. Chỉ cần nhập văn bản thân thiện với người dùng của bạn vào đối số thứ 4 tùy chọn có tên if_not_found .

Ví dụ:

=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "No")

Hạn chế: Nó chỉ bắt lỗi #N/A, bỏ quacác loại khác.

Để biết thêm thông tin, hãy xem chức năng XLOOKUP trong Excel.

Như bạn thấy, Excel cung cấp khá nhiều tùy chọn khác nhau để khắc phục lỗi VLOOKUP. Hy vọng rằng, hướng dẫn này đã làm sáng tỏ cách sử dụng chúng một cách hiệu quả. Tôi cảm ơn bạn đã đọc và hy vọng sẽ gặp bạn trên blog của chúng tôi vào tuần tới!

Các bản tải xuống có sẵn

ISERROR với ví dụ về VLOOKUP (tệp .xlsx)