Tabl cynnwys
Yn y tiwtorial hwn, byddwn yn edrych ar sut i ddefnyddio'r ISERROR gyda VLOOKUP yn Excel i drin pob math o wallau yn gynhyrchiol.
VLOOKUP yw un o swyddogaethau Excel mwyaf dryslyd gyda llawer o faterion. Pa bynnag dabl rydych chi'n edrych ynddo, mae gwallau #N/A yn olwg gyffredin, gyda #NAME a #VALUE hefyd yn ymddangos nawr ac yn y man. Gall defnyddio VLOOKUP gydag ISERROR eich helpu i ddal pob gwall posibl a'u trin yn y ffordd fwyaf priodol i'ch sefyllfa.
Y mwyaf gwall cyffredin mewn fformiwlâu VLOOKUP yw #N/A yn digwydd pan na chanfyddir gwerth chwilio. Gall hyn ddigwydd am resymau gwahanol:
- Nid yw'r gwerth am-edrych yn bodoli yn yr arae am-edrych.
- Mae'r gwerth am-edrych wedi ei gamsillafu.
- Mae blaen neu bylchau llusgo yn y gwerth chwilio neu'r golofn chwilio.
- Nid y golofn chwilio yw'r golofn ar y chwith o'r arae tabl.
Hefyd, gallwch redeg i #VALUE ! gwall, e.e. pan fydd y gwerth chwilio yn cynnwys mwy na 255 o nodau. Rhag ofn bod gwall sillafu yn enw'r ffwythiant, bydd gwall #NAME? yn ymddangos.
Am gyfeiriad llawn, gweler ein postiad cynharach ar Pam nad yw Excel VLOOKUP yn gweithio.
Fformiwla VLOOKUP OS ISERROR i ddisodli gwallau gyda thestun addasiedig
I guddio pob gwall posib y gellir ei sbarduno gan VLOOKUP, gallwch ei osod y tu mewn i fformiwla IF ISERRORfel hyn:
IF(ISERROR(VLOOKUP(…)), " text_if_error", VLOOKUP(…))Fel enghraifft, gadewch i ni dynnu enwau'r pynciau y mae myfyrwyr o profion grŵp A wedi methu:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
O'r herwydd, rydych chi'n cael criw o #N/A gwallau, a allai greu argraff bod y fformiwla'n llwgr.
<0
Mewn gwirionedd, mae'r gwallau hyn yn dangos nad yw rhai o'r gwerthoedd chwilio (A3:A14) i'w cael yn y rhestr chwilio (D3:D9). I gyfleu'r syniad hwnnw'n glir, nythwch eich fformiwla VLOOKUP yn y lluniad IF ISERROR:
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
Bydd hyn yn dal gwallau ac yn dychwelyd eich neges destun arferol:
Awgrymiadau a nodiadau:
- Prif fantais y fformiwla hon yw ei bod yn gweithio'n dda ym mhob fersiwn o Excel 2000 trwy Excel 365. Mewn fersiynau modern, symlach ac mae dewisiadau amgen mwy cryno ar gael.
- Mae'r ffwythiant ISERROR yn dal hollol wallau , megis # N/A, #NAME, #VALUE, ac ati. neges dim ond pan na chanfyddir gwerth chwilio (#N/A gwall), defnyddiwch y IF ISNA VLOOKUP (ym mhob fersiwn) neu IFNA VLOOKUP (yn Excel 2013 ac yn ddiweddarach).
ISERROR VLOOKUP i dychwelyd cell wag os gwall
I gael cell wag pan fydd gwall yn digwydd, mynnwch eich fformiwla i ddychwelyd llinyn gwag ("") yn lle testun wedi'i addasu:
IF(ISERROR(VLOOKUP(…)) ), "", VLOOKUP(…))Yn ein hachos ni, mae'r fformiwla ar y ffurf hon:
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
Ycanlyniad yn union fel y disgwylir - cell wag os na cheir enw'r myfyriwr yn y tabl chwilio.
Awgrym. Yn yr un modd, gallwch ddisodli gwallau VLOOKUP gyda sero, dashes neu unrhyw gymeriad arall yr ydych yn ei hoffi. Defnyddiwch y cymeriad a ddymunir yn lle llinyn gwag.
OS ISERROR VLOOKUP Ie/Nac oes fformiwla
Mewn rhyw sefyllfa, efallai eich bod yn chwilio am rywbeth ond yn lle tynnu'r matsys dim ond eisiau dychwelyd Ie (neu destun arall os yw'r darganfyddir gwerth chwilio) a Na (os na ddarganfyddir y gwerth chwilio). Er mwyn ei wneud, gallwch ddefnyddio'r fformiwla generig hon:
IF(ISERROR(VLOOKUP(…)), " text_if_not_found ", " text_if_found ")Yn ein set ddata sampl, mae'n debyg eich bod am wybod pa fyfyrwyr a fethodd brawf a pha rai na wnaeth. I gyflawni hyn, gwasanaethwch y fformiwla ISERROR VLOOKUP sydd eisoes yn gyfarwydd i brawf rhesymegol IF a dywedwch wrtho i allbynnu "Na" os na chanfyddir y gwerth (mae ISERROR VLOOKUP yn dychwelyd TRUE), "Ie" os canfyddir (ISERROR VLOOKUP yn dychwelyd ANGHYWIR):
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", "Yes")
dewisiadau amgen ISERROR VLOOKUP
Cyfuniad IF ISERROR yw'r dechneg amser profedig hynaf i Vlookup heb wallau yn Excel. Dros amser, datblygodd swyddogaethau newydd, gan ddarparu ffyrdd haws o gyflawni'r un dasg. Isod, byddwn yn trafod atebion posibl eraill a phryd mae'n well cymhwyso pob un.
IFERROR VLOOKUP
Ar gael yn Excel 2007 auwch
Gan ddechrau gyda fersiwn 2007, mae gan Excel swyddogaeth arbennig, o'r enw IFERROR, i wirio fformiwla am wallau a dychwelyd eich testun eich hun (neu redeg fformiwla amgen) os canfyddir unrhyw wall.
IFERROR(VLOOKUP(…), " text_if_error ")Mae'r fformiwla bywyd go iawn fel a ganlyn:
=IFERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "No")
- IFERROR Mae VLOOKUP yn cymryd yn ganiataol eich bod bob amser eisiau canlyniad VLOOKUP os nad yw'n wall.
- IFERROR VLOOKUP yn gadael i chi nodi beth i'w wneud dychwelyd os yw gwall a beth os nad oes gwall.
Am ragor o fanylion, gweler Defnyddio IFERROR gyda VLOOKUP yn Excel.
IF ISNA VLOOKUP
Yn gweithio yn Excel 2000 ac yn ddiweddarach
Mewn sefyllfa pan fyddwch chi eisiau trapio # Dd/G yn unig heb ddal unrhyw wallau eraill, mae swyddogaeth ISNA yn ddefnyddiol. Mae'r gystrawen yr un fath â chystrawen IF ISERROR VLOOKUP:
IF(ISNA(VLOOKUP(…)), " text_if_error", VLOOKUP(…))Ond o dan rai amgylchiadau, mae'n debyg bod hyn yn gall fformiwla union yr un fath gynhyrchu canlyniadau gwahanol:
=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
Yn y ddelwedd isod, mae cell A13 yn cynnwys digon o fylchau llusgo oherwydd mae cyfanswm hyd y gwerth chwilio yn fwy na 255 nod. O ganlyniad, mae'r fformiwla yn sbarduno #VALUE! gwall, gan dynnu eich sylw at y gell honno a'ch annog i ymchwilio i'r rhesymau. ISERRORByddai VLOOKUP yn dychwelyd "Na" yn yr achos hwn, a fyddai ond yn cuddio'r mater ac yn rhoi canlyniad cwbl anghywir.
Pryd i ddefnyddio:
Y fformiwla hon yn gweithio'n hyfryd mewn sefyllfa pan fyddwch am arddangos rhywfaint o destun dim ond pan na cheir gwerth am-edrych ac nad ydych am guddio problemau sylfaenol gyda'r fformiwla VLOOKUP ei hun, e.e. pan fydd enw'r ffwythiant wedi'i gamdeipio (#NAME?) neu pan nad yw'r llwybr llawn i'r llyfr gwaith chwilio wedi'i nodi (#VALUE!).
Am ragor o wybodaeth, gweler swyddogaeth ISNA yn Excel gydag enghreifftiau o fformiwla.<3
IFNA VLOOKUP
Ar gael yn Excel 2013 ac uwch
Mae'n amnewidiad modern o'r cyfuniad IF ISNA sy'n eich galluogi i drin # gwallau Dd/G yn ffordd haws.
IFNA(VLOOKUP(…), " text_if_error ")Dyma law fer sy'n cyfateb i'n fformiwla IF ISNA VLOOKUP:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "No")
Pryd i ddefnyddio:
Mae'n ateb delfrydol i faglu a thrin gwallau #N/A mewn fersiynau modern o Excel (2013 - 365).
Am fanylion llawn, gweler ffwythiant Excel IFNA.
XLOOKUP
Cefnogwyd yn Excel 2021 ac Excel 365
Oherwydd ei swyddogaeth "os gwall" mewnol , y swyddogaeth XLOOKUP yw'r ffordd hawsaf i edrych i fyny heb wallau # N/A yn Excel. Yn syml, teipiwch eich testun hawdd ei ddefnyddio yn y 4edd arg ddewisol o'r enw if_not_found .
Er enghraifft:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "No")
Cyfyngiad: Dim ond gwallau #N/A y mae'n eu dal, gan anwybyddumathau eraill.
Am ragor o wybodaeth, edrychwch ar swyddogaeth XLOOKUP yn Excel.
Fel y gwelwch, mae Excel yn darparu cryn dipyn o opsiynau gwahanol i gael rig i wallau VLOOKUP. Gobeithio bod y tiwtorial hwn wedi taflu rhywfaint o oleuni ar sut i'w defnyddio'n effeithiol. Diolch i chi am ddarllen a gobeithio eich gweld ar ein blog wythnos nesaf!
Ar gael i'w lawrlwytho
ISERROR gydag enghreifftiau VLOOKUP (ffeil .xlsx)
