Inhoudsopgave
In deze zelfstudie bekijken we hoe u de ISERROR met VLOOKUP in Excel kunt gebruiken om allerlei soorten fouten productief af te handelen.
VLOOKUP is een van de meest verwarrende Excel-functies die geplaagd wordt door vele problemen. In welke tabel u ook kijkt, #N/A fouten komen vaak voor, met af en toe ook #NAME en #VALUE. Het gebruik van VLOOKUP met ISERROR kan u helpen alle mogelijke fouten op te vangen en ze af te handelen op een manier die het meest geschikt is voor uw situatie.
Waarom geeft VLOOKUP een foutmelding?
De meest voorkomende fout in VLOOKUP formules is #N/A wanneer een lookup-waarde niet wordt gevonden. Dit kan om verschillende redenen gebeuren:
- De lookup waarde bestaat niet in de lookup array.
- De opzoekwaarde is verkeerd gespeld.
- Er staan spaties voor of achter in de opzoekwaarde of opzoekkolom.
- De opzoekkolom is niet de meest linkse kolom van de tabel-array.
Bovendien kun je tegen een #WAARDE! fout, bijvoorbeeld wanneer de opzoekwaarde meer dan 255 tekens bevat. Als er een spelfout in de naam van de functie zit, wordt een #NAME? fout zal verschijnen.
Voor een volledige referentie, zie onze eerdere post over Waarom Excel VLOOKUP niet werkt.
IF ISERROR VLOOKUP-formule om fouten te vervangen door aangepaste tekst
Om alle mogelijke fouten te verhullen die door VLOOKUP kunnen worden veroorzaakt, kunt u deze als volgt in de IF ISERROR-formule plaatsen:
IF(ISERROR(VLOOKUP(...)), " tekst_als_fout ", VLOOKUP(...))Laten we als voorbeeld de namen nemen van de vakken waarin de leerlingen van groep A gezakt zijn:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
Daardoor krijgt u een hoop #N/A fouten, die de indruk kunnen wekken dat de formule corrupt is.
In werkelijkheid geven deze fouten slechts aan dat sommige van de lookup-waarden (A3:A14) niet worden gevonden in de lookup-lijst (D3:D9). Om dat idee duidelijk over te brengen, nestelt u uw VLOOKUP-formule in de IF ISERROR-constructie:
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
Dit vangt fouten op en stuurt uw aangepaste tekstbericht terug:
Tips en opmerkingen:
- Het belangrijkste voordeel van deze formule is dat ze mooi werkt in alle versies van Excel 2000 tot en met Excel 365. In moderne versies zijn eenvoudiger en compactere alternatieven beschikbaar.
- De ISERROR-functie vangt absoluut alle fouten zoals #N/A, #NAME, #VALUE, etc. Indien u alleen een aangepast bericht wilt weergeven wanneer een opzoekwaarde niet wordt gevonden (#N/A fout), gebruik dan de IF ISNA VLOOKUP (in alle versies) of IFNA VLOOKUP (in Excel 2013 en later).
ISERROR VLOOKUP om lege cel terug te geven indien fout
Om een lege cel te krijgen wanneer er een fout optreedt, moet uw formule een lege tekenreeks ("") teruggeven in plaats van een aangepaste tekst:
IF(ISERROR(VLOOKUP(...)), "", VLOOKUP(...))In ons geval neemt de formule de volgende vorm aan:
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
Het resultaat is precies zoals verwacht - een lege cel als de naam van de leerling niet voorkomt in de opzoektabel.
Tip: op soortgelijke wijze kunt u VLOOKUP-fouten vervangen door nullen, streepjes of elk ander gewenst teken. Gebruik gewoon het gewenste teken in plaats van een lege tekenreeks.
IF ISERROR VLOOKUP Ja/Nee-formule
In sommige situaties kunt u iets zoeken, maar in plaats van de lucifers te trekken, wilt u gewoon terugkeren Ja (of een andere tekst als de opzoekwaarde is gevonden) en Geen (als de opzoekwaarde niet wordt gevonden). Om het te laten doen, kunt u deze generieke formule gebruiken:
IF(ISERROR(VLOOKUP(...)), " tekst_indien_niet_gevonden ", " tekst_indien_gevonden ")Stel dat u in onze voorbeelddataset wilt weten welke studenten zijn gezakt voor een toets en welke niet. Daartoe dient u de reeds bekende formule ISERROR VLOOKUP toe aan de logische toets IF en zegt u dat deze formule "Nee" moet uitvoeren als de waarde niet wordt gevonden (ISERROR VLOOKUP geeft WAAR), "Ja" als deze wel wordt gevonden (ISERROR VLOOKUP geeft FALSE):
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Nee", "Ja")
ISERROR VLOOKUP alternatieven
De combinatie IF ISERROR is de oudste beproefde techniek om in Excel zonder fouten te Vlookup-en. In de loop der tijd zijn er nieuwe functies bijgekomen die eenvoudiger manieren bieden om dezelfde taak uit te voeren. Hieronder bespreken we andere mogelijke oplossingen en wanneer elk daarvan het best kan worden toegepast.
IFERROR VLOOKUP
Beschikbaar in Excel 2007 en hoger
Vanaf versie 2007 heeft Excel een speciale functie, genaamd IFERROR, om een formule op fouten te controleren en uw eigen tekst te retourneren (of een alternatieve formule uit te voeren) indien een fout wordt ontdekt.
IFERROR(VLOOKUP(...), " tekst_als_fout ")De echte formule is als volgt:
=IFERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "No")
Op het eerste gezicht lijkt het een kortere analogie van de formule IF ISERROR VLOOKUP. Er is echter een essentieel verschil:
- IFERROR VLOOKUP gaat ervan uit dat u altijd het resultaat van VLOOKUP wilt hebben als het geen fout is.
- IF ISERROR Met VLOOKUP kunt u aangeven wat moet worden teruggegeven als er een fout optreedt en wat als er geen fout optreedt.
Zie voor meer details IFERROR gebruiken met VLOOKUP in Excel.
IF ISNA VLOOKUP
Werkt in Excel 2000 en later
In situaties waarin u alleen #N/A wilt vangen zonder andere fouten op te vangen, komt de functie ISNA van pas. De syntaxis is dezelfde als die van IF ISERROR VLOOKUP:
ALS(ISNA(VLOOKUP(...)), " tekst_als_fout ", VLOOKUP(...))Maar onder bepaalde omstandigheden kan deze schijnbaar identieke formule andere resultaten opleveren:
=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
In de onderstaande afbeelding bevat cel A13 veel spaties, waardoor de totale lengte van de lookup-waarde meer dan 255 tekens bedraagt. Als gevolg daarvan veroorzaakt de formule een #VALUE! fout, waardoor uw aandacht op die cel wordt gevestigd en u wordt aangemoedigd de redenen te onderzoeken. ISERROR VLOOKUP zou in dit geval "Nee" opleveren, wat het probleem alleen maar zou verdoezelen en een absoluut verkeerd resultaat zou opleveren.
Wanneer te gebruiken:
Deze formule werkt prachtig in een situatie waarin u alleen wat tekst wilt weergeven wanneer een lookup-waarde niet wordt gevonden en u onderliggende problemen met de VLOOKUP-formule zelf niet wilt maskeren, bijvoorbeeld wanneer de naam van de functie verkeerd is getypt (#NAME?) of het volledige pad naar de lookup-werkmap niet is opgegeven (#VALUE!).
Zie voor meer informatie de ISNA-functie in Excel met formulevoorbeelden.
IFNA VLOOKUP
Beschikbaar in Excel 2013 en hoger
Het is een moderne vervanging van de IF ISNA-combinatie waarmee u #N/A-fouten gemakkelijker kunt afhandelen.
IFNA(VLOOKUP(...), " tekst_als_fout ")Hier is een steno equivalent van onze IF ISNA VLOOKUP formule:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "Nee")
Wanneer te gebruiken:
Het is een ideale oplossing om #N/A fouten op te vangen en af te handelen in moderne versies van Excel (2013 - 365).
Voor volledige details, zie Excel IFNA functie.
XLOOKUP
Ondersteund in Excel 2021 en Excel 365
Dankzij de ingebouwde "if error" functionaliteit is de XLOOKUP functie de eenvoudigste manier om op te zoeken zonder #N/A fouten in Excel. Typ gewoon uw gebruiksvriendelijke tekst in het optionele 4e argument genaamd if_not_found .
Bijvoorbeeld:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "No")
Beperking: Het vangt alleen #N/A fouten op, en negeert andere types.
Voor meer informatie, zie XLOOKUP functie in Excel.
Zoals u ziet, biedt Excel heel wat verschillende opties om VLOOKUP-fouten op te lossen. Hopelijk heeft deze handleiding enig licht geworpen op het effectief gebruik ervan. Ik dank u voor het lezen en hoop u volgende week op onze blog te zien!
Beschikbare downloads
ISERROR met VLOOKUP voorbeelden (.xlsx bestand)
