Содржина
Во ова упатство, ќе погледнеме како да го користиме ISERROR со VLOOKUP во Excel за продуктивно да се справиме со сите видови грешки.
VLOOKUP е една од најзбунувачките функции на Excel што ги мачат со многу прашања. Во која табела и да гледате, грешките # N/A се вообичаена слика, а #NAME и #VALUE исто така се појавуваат сега и тогаш. Користењето VLOOKUP со ISERROR може да ви помогне да ги уловите сите можни грешки и да се справите со нив на начин најсоодветен за вашата ситуација.
Зошто VLOOKUP дава грешка?
Најмногу вообичаената грешка во формулите VLOOKUP е #N/A што се појавува кога не е пронајдена вредност за пребарување. Ова може да се случи поради различни причини:
- Вредноста за пребарување не постои во низата за пребарување.
- Вредноста за пребарување е погрешно напишана.
- Постојат водечки или задоцнети празни места во бараната вредност или колоната за пребарување.
- Колоната за пребарување не е најлевата колона од низата табели.
Покрај тоа, може да наидете на #VALUE ! грешка, на пр. кога вредноста за пребарување содржи повеќе од 255 знаци. Во случај да има правописна грешка во името на функцијата, ќе се појави грешка #NAME? .
За целосна референца, погледнете ја нашата претходна објава за Зошто Excel VLOOKUP не работи.
IF ISERROR VLOOKUP формула за замена на грешките со прилагоден текст
За да се прикријат сите можни грешки што може да се активираат со VLOOKUP, можете да ја ставите во формулата IF ISERRORвака:
IF(ISERROR(VLOOKUP(…)), " text_if_error", VLOOKUP(...))Како пример, да ги повлечеме имињата на предметите во кои учениците на неуспешни тестови од групата А:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
Како резултат на тоа, добивате еден куп #N/A грешки, што може да создаде впечаток дека формулата е корумпирана.
Навистина, овие грешки само покажуваат дека некои од вредностите за пребарување (A3:A14) не се пронајдени во списокот за пребарување (D3:D9). За јасно да ја пренесете таа идеја, вметнете ја формулата VLOOKUP во конструкцијата IF ISERROR:
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
Ова ќе фати грешки и ќе ја врати вашата приспособена текстуална порака:
Совети и забелешки:
- Главната предност на оваа формула е што работи убаво во сите верзии на Excel 2000 преку Excel 365. Во модерните верзии, поедноставно и достапни се покомпактни алтернативи.
- Функцијата ISERROR ги фаќа апсолутно сите грешки , како што се #N/A, #NAME, #VALUE, итн. Во случај да сакате да прикажете приспособено порака само кога не е пронајдена вредност за пребарување (# N/A грешка), користете го IF ISNA VLOOKUP (во сите верзии) или IFNA VLOOKUP (во Excel 2013 и подоцна).
ISERROR VLOOKUP за да вратете ја празна ќелија ако е грешка
За да имате празна ќелија кога ќе се појави грешка, побарајте ја вашата формула да врати празна низа („“) наместо приспособен текст:
IF(ISERROR(VLOOKUP(…) ), "", VLOOKUP(...))Во нашиот случај, формулата ја има оваа форма:
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
Theрезултатот е точно како што се очекуваше - празна ќелија ако името на ученикот не се најде во табелата за пребарување.
Совет. На сличен начин, можете да ги замените грешките во VLOOKUP со нули, цртички или кој било друг знак што ви се допаѓа. Само користете го саканиот знак наместо празна низа.
АКО ISERROR VLOOKUP Да/Не формула
Во некоја ситуација, можеби барате нешто, но наместо да ги повлечете совпаѓањата, само сакате да вратите Да (или некој друг текст ако е пронајдена вредноста за пребарување) и Не (ако не е пронајдена вредноста за пребарување). За да го направите тоа, можете да ја користите оваа генеричка формула:
IF(ISERROR(VLOOKUP(…)), " text_if_not_found ", " text_if_found ")Во нашата примерок на податоци, да претпоставиме дека сакате да знаете кои ученици паднале на тест, а кои не. За да го постигнете ова, послужете ја веќе познатата формула ISERROR VLOOKUP на логичкиот тест на IF и кажете ѝ да даде „Не“ ако вредноста не е пронајдена (ISERROR VLOOKUP враќа TRUE), „Да“ ако е пронајдена (ISERROR VLOOKUP враќа FALSE):
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", "Yes")
ISERROR VLOOKUP алтернативи
Комбинацијата IF ISERROR е најстарата време докажана техника за Vlookup без грешки во Excel. Со текот на времето, еволуираа нови функции, обезбедувајќи полесни начини за извршување на истата задача. Подолу, ќе разговараме за други можни решенија и кога секое е најдобро да се примени.
IFERROR VLOOKUP
Достапно во Excel 2007 иповисоко
Почнувајќи од верзијата 2007 година, Excel има специјална функција, наречена IFERROR, за проверка на формулата за грешки и враќање на ваш сопствен текст (или извршување алтернативна формула) доколку се открие некоја грешка.
IFERROR(VLOOKUP(…), " text_if_error ")Реалната формула е следна:
=IFERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "No")
На прв поглед, изгледа како пократок аналог на формулата IF ISERROR VLOOKUP. Сепак, постои суштинска разлика:
- IFERROR VLOOKUP претпоставува дека секогаш го сакате резултатот од VLOOKUP ако тоа не е грешка.
- IF ISERROR VLOOKUP ви овозможува да одредите што да вратете ако има грешка и што ако нема грешка.
За повеќе детали, видете Користење IFERROR со VLOOKUP во Excel.
IF ISNA VLOOKUP
Работи во Excel 2000 и подоцна
Во ситуација кога сакате да заробите само #N/A без да фатите други грешки, функцијата ISNA ви е добро. Синтаксата е иста како онаа на IF ISERROR VLOOKUP:
IF(ISNA(VLOOKUP(…)), " text_if_error ", VLOOKUP(...))Но, под одредени околности, ова навидум идентична формула може да даде различни резултати:
=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
На сликата подолу, ќелијата A13 содржи многу празни места поради кои вкупната должина на вредноста на пребарувањето надминува 255 знаци. Како резултат на тоа, формулата активира # ВРЕДНОСТ! грешка, привлекувајќи го вашето внимание на таа ќелија и охрабрувајќи да ги истражите причините. ISERRORVLOOKUP ќе врати „Не“ во овој случај, што само ќе го прикрие проблемот и ќе донесе апсолутно погрешен резултат.
Кога да се користи:
Оваа формула работи убаво во ситуација кога сакате да прикажете некој текст само кога не е пронајдена вредност за пребарување и не сакате да ги маскирате основните проблеми со самата формула VLOOKUP, на пр. кога името на функцијата е погрешно напишано (#NAME?) или не е наведена целосната патека до работната книга за пребарување (#VALUE!).
За повеќе информации, погледнете ја функцијата ISNA во Excel со примери на формула.
IFNA VLOOKUP
Достапно во Excel 2013 и понова верзија
Тоа е модерна замена на комбинацијата IF ISNA што ви овозможува да се справите со #N/A грешки во полесен начин.
IFNA(VLOOKUP(…), " text_if_error ")Еве стенографија еквивалент на нашата формула IF ISNA VLOOKUP:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "No")
Кога да се користи:
Тоа е идеално решение за заробување и справување со #N/A грешки во модерните верзии на Excel (2013 - 365).
За целосни детали, видете ја функцијата Excel IFNA.
XLOOKUP
Поддржано во Excel 2021 и Excel 365
Поради неговата вградена функционалност „ако е грешка“ , функцијата XLOOKUP е најлесниот начин за пребарување без #N/A грешки во Excel. Едноставно, напишете го вашиот кориснички текст во изборниот 4-ти аргумент со име if_not_found .
На пример:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "No")
Ограничување: ги фаќа само #N/A грешките, игнорирајќидруги типови.
За повеќе информации, проверете ја функцијата XLOOKUP во Excel.
Како што гледате, Excel обезбедува доста различни опции за да ги пренасочите грешките во VLOOKUP. Се надеваме дека ова упатство фрли малку светлина за тоа како ефективно да ги користите. Ви благодарам што прочитавте и се надевам дека ќе се видиме на нашиот блог следната недела!
Достапни преземања
ISERROR со примери на VLOOKUP (датотека .xlsx)
