Σε αυτό το σεμινάριο, θα δούμε πώς μπορείτε να χρησιμοποιήσετε το ISERROR με το VLOOKUP στο Excel για να χειριστείτε παραγωγικά όλα τα είδη σφαλμάτων.

Το VLOOKUP είναι μία από τις πιο συγκεχυμένες συναρτήσεις του Excel που μαστίζεται από πολλά προβλήματα. Σε όποιον πίνακα και αν ψάχνετε, τα σφάλματα #N/A είναι ένα συνηθισμένο θέαμα, με τα #NAME και #VALUE να εμφανίζονται επίσης πού και πού. Η χρήση του VLOOKUP με το ISERROR μπορεί να σας βοηθήσει να εντοπίσετε όλα τα πιθανά σφάλματα και να τα χειριστείτε με τον πλέον κατάλληλο τρόπο για την περίπτωσή σας.

Γιατί το VLOOKUP εμφανίζει σφάλμα;

Το πιο συνηθισμένο σφάλμα στους τύπους VLOOKUP είναι #N/A Αυτό μπορεί να συμβεί για διάφορους λόγους:

• Η τιμή αναζήτησης δεν υπάρχει στον πίνακα αναζήτησης.
• Η τιμή αναζήτησης είναι λανθασμένη.
• Στην τιμή αναζήτησης ή στη στήλη αναζήτησης υπάρχουν κενά στην αρχή ή στο τέλος.
• Η στήλη αναζήτησης δεν είναι η πιο αριστερή στήλη του πίνακα.

Εκτός αυτού, μπορεί να πέσετε σε ένα #VALUE! σφάλμα, π.χ. όταν η τιμή αναζήτησης περιέχει περισσότερους από 255 χαρακτήρες. Σε περίπτωση που υπάρχει ορθογραφικό λάθος στο όνομα της συνάρτησης, ένα #NAME? θα εμφανιστεί σφάλμα.

Για πλήρη αναφορά, ανατρέξτε στην προηγούμενη δημοσίευσή μας σχετικά με το Γιατί το Excel VLOOKUP δεν λειτουργεί.

IF ISERROR Τύπος VLOOKUP για την αντικατάσταση σφαλμάτων με προσαρμοσμένο κείμενο

Για να αποκρύψετε όλα τα πιθανά σφάλματα που μπορεί να προκληθούν από το VLOOKUP, μπορείτε να το τοποθετήσετε μέσα στον τύπο IF ISERROR ως εξής:

Για παράδειγμα, ας πάρουμε τα ονόματα των θεμάτων στα οποία οι μαθητές της ομάδας Α απέτυχαν στις εξετάσεις:

=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)

Ως αποτέλεσμα, λαμβάνετε ένα σωρό σφάλματα #N/A, τα οποία μπορεί να δημιουργήσουν την εντύπωση ότι ο τύπος είναι κατεστραμμένος.

Στην πραγματικότητα, αυτά τα σφάλματα υποδεικνύουν απλώς ότι ορισμένες από τις τιμές αναζήτησης (A3:A14) δεν βρίσκονται στη λίστα αναζήτησης (D3:D9). Για να μεταφέρετε με σαφήνεια αυτή την ιδέα, ενσωματώστε τον τύπο VLOOKUP στην κατασκευή IF ISERROR:

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

Αυτό θα πιάσει τα σφάλματα και θα επιστρέψει το προσαρμοσμένο μήνυμα κειμένου σας:

Συμβουλές και σημειώσεις:

• Το κύριο πλεονέκτημα αυτής της φόρμουλας είναι ότι λειτουργεί όμορφα σε όλες οι εκδόσεις του Excel 2000 έως το Excel 365. Στις σύγχρονες εκδόσεις, υπάρχουν απλούστερες και πιο συμπαγείς εναλλακτικές λύσεις.
• Η συνάρτηση ISERROR συλλαμβάνει απολύτως όλα τα σφάλματα , όπως #N/A, #NAME, #VALUE κ.ά. Σε περίπτωση που θέλετε να εμφανίσετε ένα προσαρμοσμένο μήνυμα μόνο όταν δεν βρίσκεται μια τιμή αναζήτησης (σφάλμα #N/A), χρησιμοποιήστε το IF ISNA VLOOKUP (σε όλες τις εκδόσεις) ή το IFNA VLOOKUP (στο Excel 2013 και νεότερες εκδόσεις).

ISERROR VLOOKUP για να επιστρέφει κενό κελί σε περίπτωση σφάλματος

Για να έχετε ένα κενό κελί όταν εμφανίζεται ένα σφάλμα, βάλτε τον τύπο σας να επιστρέφει μια κενή συμβολοσειρά ("") αντί για ένα προσαρμοσμένο κείμενο:

Στην περίπτωσή μας, ο τύπος έχει την εξής μορφή:

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

Το αποτέλεσμα είναι ακριβώς το αναμενόμενο - ένα κενό κελί εάν το όνομα του μαθητή δεν βρίσκεται στον πίνακα αναζήτησης.

Συμβουλή. Με παρόμοιο τρόπο, μπορείτε να αντικαταστήσετε τα σφάλματα VLOOKUP με μηδενικά, παύλες ή οποιονδήποτε άλλο χαρακτήρα θέλετε. Απλώς χρησιμοποιήστε τον επιθυμητό χαρακτήρα στη θέση μιας κενής συμβολοσειράς.

IF ISERROR VLOOKUP Τύπος Ναι/Όχι

Σε ορισμένες περιπτώσεις, μπορεί να ψάχνετε για κάτι, αλλά αντί να τραβήξετε τους αγώνες θέλετε απλά να επιστρέψετε Ναι (ή κάποιο άλλο κείμενο αν βρεθεί η τιμή αναζήτησης) και Όχι (αν η τιμή αναζήτησης δεν βρεθεί). Για να το κάνετε αυτό, μπορείτε να χρησιμοποιήσετε αυτόν τον γενικό τύπο:

Στο σύνολο δεδομένων του δείγματός μας, ας υποθέσουμε ότι θέλετε να μάθετε ποιοι μαθητές απέτυχαν σε ένα τεστ και ποιοι όχι. Για να το πετύχετε αυτό, σερβίρετε τον ήδη γνωστό τύπο ISERROR VLOOKUP στον λογικό έλεγχο IF και πείτε του να βγάλει "Όχι" αν δεν βρεθεί η τιμή (το ISERROR VLOOKUP επιστρέφει TRUE), "Ναι" αν βρεθεί (το ISERROR VLOOKUP επιστρέφει FALSE):

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Όχι", "Ναι")

Εναλλακτικές λύσεις ISERROR VLOOKUP

Ο συνδυασμός IF ISERROR είναι η παλαιότερη δοκιμασμένη στο χρόνο τεχνική για να κάνετε Vlookup χωρίς σφάλματα στο Excel. Με την πάροδο του χρόνου, νέες συναρτήσεις εξελίχθηκαν, παρέχοντας ευκολότερους τρόπους για να εκτελέσετε την ίδια εργασία. Παρακάτω, θα συζητήσουμε άλλες πιθανές λύσεις και πότε είναι καλύτερο να εφαρμόζεται η καθεμία.

IFERROR VLOOKUP

Διαθέσιμο στο Excel 2007 και νεότερες εκδόσεις

Από την έκδοση 2007, το Excel διαθέτει μια ειδική συνάρτηση, που ονομάζεται IFERROR, για να ελέγχει έναν τύπο για σφάλματα και να επιστρέφει το δικό σας κείμενο (ή να εκτελεί έναν εναλλακτικό τύπο) εάν εντοπιστεί κάποιο σφάλμα.

Ο πραγματικός τύπος έχει ως εξής:

=IFERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "Όχι")

Εκ πρώτης όψεως, μοιάζει με ένα συντομότερο ανάλογο του τύπου IF ISERROR VLOOKUP. Ωστόσο, υπάρχει μια ουσιαστική διαφορά:

• IFERROR Το VLOOKUP υποθέτει ότι θέλετε πάντα το αποτέλεσμα του VLOOKUP αν δεν είναι σφάλμα.
• IF ISERROR Το VLOOKUP σάς επιτρέπει να καθορίσετε τι θα επιστρέφει σε περίπτωση σφάλματος και τι σε περίπτωση που δεν υπάρχει σφάλμα.

Για περισσότερες λεπτομέρειες, ανατρέξτε στην ενότητα Χρήση του IFERROR με το VLOOKUP στο Excel.

IF ISNA VLOOKUP

Λειτουργεί στο Excel 2000 και μεταγενέστερα

Σε περίπτωση που θέλετε να παγιδεύσετε μόνο το #N/A χωρίς να πιάσετε άλλα σφάλματα, η συνάρτηση ISNA είναι χρήσιμη. Η σύνταξη είναι η ίδια με αυτή της IF ISERROR VLOOKUP:

Αλλά υπό ορισμένες συνθήκες, αυτή η φαινομενικά πανομοιότυπη φόρμουλα μπορεί να παράγει διαφορετικά αποτελέσματα:

=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

Στην παρακάτω εικόνα, το κελί A13 περιέχει πολλά κενά στο τέλος, εξαιτίας των οποίων το συνολικό μήκος της τιμής αναζήτησης υπερβαίνει τους 255 χαρακτήρες. Ως αποτέλεσμα, ο τύπος ενεργοποιεί ένα σφάλμα #VALUE!, εφιστώντας την προσοχή σας σε αυτό το κελί και ενθαρρύνοντας να διερευνήσετε τους λόγους. Το ISERROR VLOOKUP θα επέστρεφε "Όχι" σε αυτή την περίπτωση, το οποίο απλώς θα συσκοτίζει το ζήτημα και θα παρέδιδε ένα απολύτως λανθασμένο αποτέλεσμα.

Πότε να το χρησιμοποιήσετε:

Αυτός ο τύπος λειτουργεί θαυμάσια σε μια κατάσταση όπου θέλετε να εμφανίσετε κάποιο κείμενο μόνο όταν δεν βρίσκεται μια τιμή αναζήτησης και δεν θέλετε να καλύψετε υποκείμενα προβλήματα με τον ίδιο τον τύπο VLOOKUP, π.χ. όταν το όνομα της συνάρτησης είναι λάθος (#NAME?) ή όταν δεν καθορίζεται η πλήρης διαδρομή προς το βιβλίο εργασίας αναζήτησης (#VALUE!).

Για περισσότερες πληροφορίες, ανατρέξτε στη λειτουργία ISNA στο Excel με παραδείγματα τύπων.

IFNA VLOOKUP

Διαθέσιμο στο Excel 2013 και νεότερες εκδόσεις

Πρόκειται για μια σύγχρονη αντικατάσταση του συνδυασμού IF ISNA που σας επιτρέπει να χειρίζεστε τα σφάλματα #N/A με ευκολότερο τρόπο.

Ακολουθεί ένα ισοδύναμο σε συντομογραφία του τύπου IF ISNA VLOOKUP:

=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "Όχι")

Πότε να το χρησιμοποιήσετε:

Είναι μια ιδανική λύση για την παγίδευση και τον χειρισμό σφαλμάτων #N/A στις σύγχρονες εκδόσεις του Excel (2013 - 365).

Για πλήρεις λεπτομέρειες, ανατρέξτε στη λειτουργία Excel IFNA.

XLOOKUP

Υποστηρίζεται στο Excel 2021 και στο Excel 365

Λόγω της ενσωματωμένης λειτουργίας "αν σφάλμα", η συνάρτηση XLOOKUP είναι ο ευκολότερος τρόπος για να κάνετε αναζήτηση χωρίς σφάλματα #N/A στο Excel. Απλά, πληκτρολογήστε το φιλικό προς το χρήστη κείμενό σας στο προαιρετικό 4ο όρισμα με όνομα if_not_found .

Για παράδειγμα:

=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "No")

Περιορισμός: Συλλαμβάνει μόνο σφάλματα #N/A, αγνοώντας άλλους τύπους.

Για περισσότερες πληροφορίες, ανατρέξτε στη λειτουργία XLOOKUP στο Excel.

Όπως βλέπετε, το Excel παρέχει αρκετές διαφορετικές επιλογές για να αντιμετωπίσετε τα σφάλματα VLOOKUP. Ελπίζω ότι αυτό το σεμινάριο έριξε λίγο φως στο πώς να τις χρησιμοποιήσετε αποτελεσματικά. Σας ευχαριστώ για την ανάγνωση και ελπίζω να σας δω στο blog μας την επόμενη εβδομάδα!

Διαθέσιμες λήψεις

Παραδείγματα ISERROR με VLOOKUP (.xlsx αρχείο)