Turinys
Šioje pamokoje apžvelgsime, kaip "Excel" programoje naudoti ISERROR su VLOOKUP ir produktyviai tvarkyti visų rūšių klaidas.
VLOOKUP yra viena painiausių "Excel" funkcijų, kurią kamuoja daugybė problemų. Kad ir kokioje lentelėje ieškotumėte, #N/A klaidos yra dažnas reiškinys, o #NAME ir #VALUE taip pat kartais pasirodo. Naudodami VLOOKUP su ISERROR galite sugauti visas galimas klaidas ir jas tvarkyti tinkamiausiu jūsų situacijai būdu.
Kodėl VLOOKUP pateikia klaidą?
Dažniausiai pasitaikanti VLOOKUP formulių klaida yra #N/A kai nerandama paieškos reikšmė. Taip gali atsitikti dėl įvairių priežasčių:
- Paieškos reikšmė neegzistuoja paieškos masyve.
- Paieškos reikšmė neteisingai parašyta.
- Paieškos reikšmėje arba paieškos stulpelyje yra pradinių arba galinių tarpų.
- Paieškos stulpelis nėra lentelės masyvo kairiausias stulpelis.
Be to, galite susidurti su #VALUE! pavyzdžiui, kai paieškos reikšmę sudaro daugiau nei 255 simboliai. Jei funkcijos pavadinime yra rašybos klaida, pateikiamas #NAME? atsiras klaida.
Išsamią nuorodą rasite mūsų ankstesniame pranešime Kodėl neveikia "Excel" VLOOKUP.
IF ISERROR VLOOKUP formulė klaidoms pakeisti pasirinktiniu tekstu
Norėdami užmaskuoti visas galimas klaidas, kurias gali sukelti VLOOKUP, galite ją įterpti į IF ISERROR formulę taip:
IF(ISERROR(VLOOKUP(...)), " text_if_error ", VLOOKUP(...))Kaip pavyzdį ištraukime dalykų, iš kurių A grupės mokiniai neišlaikė testų, pavadinimus:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
Dėl to gaunama daug #N/A klaidų, todėl gali susidaryti įspūdis, kad formulė yra sugadinta.
Iš tikrųjų šios klaidos tik rodo, kad kai kurių paieškos verčių (A3:A14) nerasta paieškos sąraše (D3:D9). Norėdami aiškiai išreikšti šią mintį, įterpkite VLOOKUP formulę į IF ISERROR konstrukciją:
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Ne", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
Taip bus užfiksuotos klaidos ir grąžintas pasirinktinis teksto pranešimas:
Patarimai ir pastabos:
- Pagrindinis šios formulės privalumas yra tas, kad ji puikiai veikia visos versijos nuo "Excel 2000" iki "Excel 365". Šiuolaikinėse versijose yra paprastesnių ir kompaktiškesnių alternatyvų.
- Funkcija ISERROR sugauna absoliučiai visos klaidos pavyzdžiui, #N/A, #NAME, #VALUE ir t. t. Jei norite rodyti pasirinktinį pranešimą tik tada, kai nerandama paieškos reikšmė (#N/A klaida), naudokite IF ISNA VLOOKUP (visose versijose) arba IFNA VLOOKUP (Excel 2013 ir vėlesnėse versijose).
ISERROR VLOOKUP grąžinti tuščią ląstelę, jei įvyko klaida
Jei norite, kad įvykus klaidai ląstelė būtų tuščia, pasirūpinkite, kad formulė grąžintų ne pasirinktinį tekstą, o tuščią eilutę (""):
IF(ISERROR(VLOOKUP(...)), "", VLOOKUP(...))Mūsų atveju formulė yra tokia:
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
Rezultatas yra būtent toks, kokio ir tikėtasi - tuščias langelis, jei mokinio vardo nerandama paieškos lentelėje.
Patarimas. Panašiai VLOOKUP klaidas galite pakeisti nuliais, brūkšneliais ar bet kuriuo kitu norimu simboliu. Tiesiog vietoj tuščios eilutės naudokite norimą simbolį.
IF ISERROR VLOOKUP Taip/Ne formulė
Kai kuriose situacijose galite ko nors ieškoti, bet užuot traukę atitikmenis, tiesiog norite grąžinti Taip (arba koks nors kitas tekstas, jei randama paieškos vertė) ir Ne (jei nerandama paieškos reikšmė). Norėdami tai padaryti, galite naudoti šią bendrąją formulę:
IF(ISERROR(VLOOKUP(...)), " text_if_not_found ", " text_if_found ")Tarkime, kad mūsų pavyzdiniame duomenų rinkinyje norite sužinoti, kurie mokiniai neišlaikė testo, o kurie ne. Norėdami tai padaryti, loginiam testui IF pritaikykite jau pažįstamą ISERROR VLOOKUP formulę ir nurodykite jai išvesti "Ne", jei reikšmė nerandama (ISERROR VLOOKUP grąžina TRUE), "Taip", jei randama (ISERROR VLOOKUP grąžina FALSE):
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Ne", "Taip")
ISERROR VLOOKUP alternatyvos
IF ISERROR derinys yra seniausias laiko patikrintas metodas, kaip "Excel" programoje "Vlookup" atlikti be klaidų. Laikui bėgant, atsirado naujų funkcijų, suteikiančių lengvesnių būdų atlikti tą pačią užduotį. Toliau aptarsime kitus galimus sprendimus ir kada kiekvieną iš jų geriausia taikyti.
IFERROR VLOOKUP
Galima naudoti "Excel 2007" ir naujesnėse versijose
Nuo 2007 m. versijos "Excel" turi specialią funkciją, pavadintą IFERROR, kuria galima patikrinti, ar formulėje nėra klaidų, ir grąžinti savo tekstą (arba paleisti alternatyvią formulę), jei aptikta kokia nors klaida.
IFERROR(VLOOKUP(...), " text_if_error ")Reali formulė yra tokia:
=IFERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "Ne")
Iš pirmo žvilgsnio ji atrodo kaip trumpesnis IF ISERROR VLOOKUP formulės analogas. Tačiau yra esminis skirtumas:
- IFERROR VLOOKUP daroma prielaida, kad visada norite gauti VLOOKUP rezultatą, jei jis nėra klaida.
- IF ISERROR VLOOKUP leidžia nurodyti, ką grąžinti, jei įvyko klaida, ir ką grąžinti, jei klaidos nėra.
Išsamesnės informacijos rasite skyriuje IFERROR naudojimas su VLOOKUP programoje "Excel".
JEI YRA VLOOKUP
Veikia "Excel 2000" ir vėlesnėse versijose
Jei norite užfiksuoti tik #N/A, bet nefiksuoti jokių kitų klaidų, praverčia funkcija ISNA. Sintaksė tokia pati kaip IF ISERROR VLOOKUP:
IF(ISNA(VLOOKUP(...)), " text_if_error ", VLOOKUP(...))Tačiau tam tikromis aplinkybėmis ši iš pirmo žvilgsnio identiška formulė gali duoti skirtingus rezultatus:
=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Ne", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
Toliau pateiktame paveikslėlyje A13 ląstelėje yra daug tarpų, dėl kurių bendras paieškos vertės ilgis viršija 255 simbolius. Dėl to formulė sukelia #VALUE! klaidą, atkreipiančią jūsų dėmesį į šią ląstelę ir skatinančią išsiaiškinti priežastis. ISERROR VLOOKUP šiuo atveju grąžintų "No", o tai tik užgožtų problemą ir duotų visiškai neteisingą rezultatą.
Kada naudoti:
Ši formulė puikiai tinka tais atvejais, kai norite rodyti tam tikrą tekstą tik tada, kai nerandama paieškos reikšmė, ir nenorite užmaskuoti esminių pačios VLOOKUP formulės problemų, pvz., kai klaidingai įrašomas funkcijos pavadinimas (#NAME?) arba nenurodomas visas paieškos sąsiuvinio kelias (#VALUE!).
Daugiau informacijos žr. "Excel" funkciją ISNA su formulės pavyzdžiais.
IFNA VLOOKUP
Galima naudoti "Excel 2013" ir naujesnėse versijose
Tai modernus IF ISNA kombinacijos pakaitalas, leidžiantis paprasčiau tvarkyti #N/A klaidas.
IFNA(VLOOKUP(...), " text_if_error ")Pateikiame sutrumpintą IF ISNA VLOOKUP formulės atitikmenį:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "Ne")
Kada naudoti:
Tai idealus sprendimas #N/A klaidoms šiuolaikinėse "Excel" versijose (2013 - 365) gaudyti ir tvarkyti.
Išsamią informaciją rasite "Excel" IFNA funkcijoje.
XLOOKUP
Palaikoma "Excel 2021" ir "Excel 365
Dėl integruotos funkcijos "if error" funkcija XLOOKUP yra paprasčiausias būdas ieškoti be #N/A klaidų "Excel" programoje. Tiesiog įveskite savo vartotojui patogų tekstą į pasirenkamą 4-ąjį argumentą, pavadintą if_not_found .
Pavyzdžiui:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "Ne")
Apribojimas: ji fiksuoja tik #N/A klaidas, ignoruodama kitų tipų klaidas.
Daugiau informacijos rasite "Excel" funkcijoje XLOOKUP.
Kaip matote, "Excel" suteikia gana daug įvairių galimybių, kaip išvengti VLOOKUP klaidų. Tikimės, kad ši pamoka šiek tiek paaiškino, kaip jas veiksmingai naudoti. Dėkoju, kad skaitėte, ir tikiuosi, kad kitą savaitę susitiksime mūsų tinklaraštyje!
Galimi atsisiuntimai
ISERROR su VLOOKUP pavyzdžiai (.xlsx failas)
