En este tutorial, veremos cómo utilizar el ISERROR con VLOOKUP en Excel para manejar todo tipo de errores de forma productiva.

VLOOKUP es una de las funciones más confusas de Excel, plagada de muchos problemas. Sea cual sea la tabla en la que esté buscando, los errores #N/A son habituales, con #NAME y #VALUE apareciendo también de vez en cuando. Utilizar VLOOKUP con ISERROR puede ayudarle a detectar todos los errores posibles y a gestionarlos de la forma más adecuada a su situación.

¿Por qué da error VLOOKUP?

El error más común en las fórmulas VLOOKUP es #N/A que se produce cuando no se encuentra un valor de búsqueda. Esto puede ocurrir por diferentes motivos:

• El valor de búsqueda no existe en la matriz de búsqueda.
• El valor de búsqueda está mal escrito.
• Hay espacios iniciales o finales en el valor de búsqueda o en la columna de búsqueda.
• La columna de búsqueda no es la columna situada más a la izquierda de la matriz de la tabla.

Además, puedes encontrarte con un #¡VALOR! por ejemplo, cuando el valor de búsqueda contiene más de 255 caracteres. En caso de que haya un error ortográfico en el nombre de la función, se mostrará un icono #¿NOMBRE? aparecerá un error.

Para una referencia completa, por favor vea nuestro post anterior sobre Por qué Excel VLOOKUP no funciona.

Fórmula IF ISERROR VLOOKUP para sustituir errores por texto personalizado

Para disimular todos los posibles errores que puede provocar VLOOKUP, puede colocarlo dentro de la fórmula IF ISERROR de la siguiente manera:

A modo de ejemplo, saquemos los nombres de las asignaturas en las que suspendieron los exámenes los alumnos del grupo A:

=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)

Como resultado, se obtiene un montón de errores #N/A, lo que puede dar la impresión de que la fórmula está corrupta.

En realidad, estos errores sólo indican que algunos de los valores de búsqueda (A3:A14) no se encuentran en la lista de búsqueda (D3:D9). Para transmitir claramente esta idea, anide su fórmula VLOOKUP en la construcción IF ISERROR:

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

Esto detectará errores y devolverá su mensaje de texto personalizado:

Consejos y notas:

• La principal ventaja de esta fórmula es que funciona muy bien en todas las versiones de Excel 2000 a Excel 365. En las versiones modernas, existen alternativas más sencillas y compactas.
• La función ISERROR atrapa absolutamente todos los errores , como #N/A, #NAME, #VALUE, etc. En caso de que desee mostrar un mensaje personalizado sólo cuando no se encuentre un valor de búsqueda (error #N/A), utilice el IF ISNA VLOOKUP (en todas las versiones) o IFNA VLOOKUP (en Excel 2013 y posteriores).

ISERROR VLOOKUP para devolver la celda en blanco en caso de error

Para tener una celda en blanco cuando se produce un error, haga que su fórmula devuelva una cadena vacía ("") en lugar de un texto personalizado:

En nuestro caso, la fórmula adopta esta forma:

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

El resultado es exactamente el esperado: una celda en blanco si no se encuentra el nombre del alumno en la tabla de búsqueda.

Sugerencia. De forma similar, puede sustituir los errores de VLOOKUP por ceros, guiones o cualquier otro carácter que desee. Sólo tiene que utilizar el carácter deseado en lugar de una cadena vacía.

IF ISERROR VLOOKUP Sí/No fórmula

En alguna situación, usted puede estar buscando algo, pero en lugar de tirar de los partidos sólo quieren volver Sí (o algún otro texto si se encuentra el valor de búsqueda) y No (si no se encuentra el valor de búsqueda). Para hacerlo, puede utilizar esta fórmula genérica:

En nuestro conjunto de datos de ejemplo, supongamos que desea saber qué alumnos suspendieron un examen y cuáles no. Para conseguirlo, sirva la ya familiar fórmula ISERROR VLOOKUP a la prueba lógica de IF y dígale que dé como salida "No" si no se encuentra el valor (ISERROR VLOOKUP devuelve TRUE), "Sí" si se encuentra (ISERROR VLOOKUP devuelve FALSE):

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", "Sí")

Alternativas a ISERROR VLOOKUP

La combinación IF ISERROR es la técnica más antigua probada en el tiempo para hacer Vlookup sin errores en Excel. Con el tiempo, nuevas funciones evolucionaron, proporcionando formas más fáciles de realizar la misma tarea. A continuación, discutiremos otras soluciones posibles y cuándo es mejor aplicar cada una.

IFERROR VLOOKUP

Disponible en Excel 2007 y versiones posteriores

A partir de la versión 2007, Excel dispone de una función especial, denominada IFERROR, para comprobar si hay errores en una fórmula y devolver su propio texto (o ejecutar una fórmula alternativa) si se detecta algún error.

La fórmula en la vida real es la siguiente:

=IFERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "No")

A primera vista, parece un análogo más corto de la fórmula IF ISERROR VLOOKUP. Sin embargo, hay una diferencia esencial:

• IFERROR VLOOKUP asume que siempre quieres el resultado de VLOOKUP si no es un error.
• IF ISERROR VLOOKUP le permite especificar qué devolver si un error y qué si no hay error.

Para obtener más detalles, consulte Uso de IFERROR con VLOOKUP en Excel.

SI ES UN VLOOKUP

Funciona en Excel 2000 y versiones posteriores

En situaciones en las que se desea atrapar sólo #N/A sin atrapar ningún otro error, la función ISNA es muy útil. La sintaxis es la misma que la de IF ISERROR VLOOKUP:

Pero en determinadas circunstancias, esta fórmula aparentemente idéntica puede producir resultados diferentes:

=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

En la imagen de abajo, la celda A13 contiene muchos espacios al final, por lo que la longitud total del valor de búsqueda supera los 255 caracteres. Como resultado, la fórmula provoca un error #¡VALOR! llamando tu atención sobre esa celda y animándote a investigar las razones. ISERROR VLOOKUP devolvería "No" en este caso, lo que sólo ocultaría el problema y ofrecería un resultado absolutamente erróneo.

Cuándo utilizarlo:

Esta fórmula funciona perfectamente en situaciones en las que se desea mostrar algún texto sólo cuando no se encuentra un valor de búsqueda y no se desea enmascarar problemas subyacentes con la propia fórmula VLOOKUP, por ejemplo, cuando el nombre de la función está mal escrito (#NAME?) o no se especifica la ruta completa al libro de trabajo de búsqueda (#VALUE!).

Para más información, consulte la función ISNA en Excel con ejemplos de fórmulas.

IFNA VLOOKUP

Disponible en Excel 2013 y versiones posteriores

Es un reemplazo moderno de la combinación IF ISNA que le permite manejar errores #N/A de una manera más fácil.

He aquí un equivalente abreviado de nuestra fórmula IF ISNA VLOOKUP:

=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "No")

Cuándo utilizarlo:

Es una solución ideal para atrapar y manejar errores #N/A en versiones modernas de Excel (2013 - 365).

Para más detalles, consulte la función IFNA de Excel.

XLOOKUP

Compatible con Excel 2021 y Excel 365

Debido a su funcionalidad "si error" incorporada, la función XLOOKUP es la forma más fácil de buscar sin errores #N/A en Excel. Simplemente, escriba su texto de usuario en el 4º argumento opcional llamado if_not_found .

Por ejemplo:

=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "No")

Limitación: Sólo detecta errores #N/A, ignorando otros tipos.

Para más información, consulte la función XLOOKUP en Excel.

Como ves, Excel proporciona un montón de opciones diferentes para conseguir solucionar los errores de VLOOKUP. Espero que este tutorial haya arrojado algo de luz sobre cómo utilizarlas eficazmente. Te doy las gracias por leer y ¡espero verte en nuestro blog la semana que viene!

Descargas disponibles

Ejemplos de ISERROR con VLOOKUP (archivo .xlsx)