Dalam tutorial ini, kita akan melihat bagaimana menggunakan ISERROR dengan VLOOKUP di Excel untuk menangani semua jenis kesalahan secara produktif.

VLOOKUP adalah salah satu fungsi Excel yang paling membingungkan yang diganggu dengan banyak masalah. Tabel mana pun yang Anda lihat, kesalahan #N/A adalah pemandangan umum, dengan #NAME dan #VALUE juga muncul sesekali. Menggunakan VLOOKUP dengan ISERROR dapat membantu Anda menangkap semua kemungkinan kesalahan dan menanganinya dengan cara yang paling sesuai dengan situasi Anda.

Mengapa VLOOKUP memberikan error?

Kesalahan paling umum dalam rumus VLOOKUP adalah #N/A terjadi apabila nilai pencarian tidak ditemukan. Hal ini bisa terjadi karena alasan yang berbeda:

• Nilai pencarian tidak ada dalam array pencarian.
• Nilai pencarian salah eja.
• Terdapat spasi di depan atau di belakang dalam nilai pencarian atau kolom pencarian.
• Kolom pencarian bukan kolom paling kiri dari larik tabel.

Selain itu, Anda bisa mengalami #VALUE! error, misalnya, ketika nilai pencarian mengandung lebih dari 255 karakter. Jika ada kesalahan ejaan dalam nama fungsi, maka akan muncul #NAME? kesalahan akan muncul.

Untuk referensi lengkap, silakan lihat posting kami sebelumnya tentang Mengapa Excel VLOOKUP tidak berfungsi.

IF ISERROR VLOOKUP rumus untuk mengganti kesalahan dengan teks kustom

Untuk menyamarkan semua kemungkinan error yang bisa dipicu oleh VLOOKUP, kamu bisa menempatkannya di dalam rumus IF ISERROR seperti ini:

Sebagai contoh, mari kita tarik nama-nama mata pelajaran di mana para siswa kelompok A gagal dalam tes:

=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)

Hasilnya, anda mendapatkan banyak error #N/A, yang mungkin menciptakan kesan bahwa rumusnya rusak.

Sebenarnya, error ini hanya mengindikasikan bahwa beberapa nilai pencarian (A3:A14) tidak ditemukan dalam daftar pencarian (D3:D9). Untuk menyampaikan ide tersebut dengan jelas, sarangkan rumus VLOOKUPmu dalam konstruksi IF ISERROR:

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Tidak", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

Ini akan menangkap kesalahan dan mengembalikan pesan teks khusus Anda:

Kiat dan catatan:

• Keuntungan utama dari formula ini adalah bahwa formula ini bekerja dengan baik dalam semua versi Excel 2000 hingga Excel 365. Dalam versi modern, tersedia alternatif yang lebih sederhana dan lebih ringkas.
• Fungsi ISERROR menangkap benar-benar semua kesalahan , seperti #N/A, #NAME, #VALUE, dll. Jika Anda ingin menampilkan pesan khusus hanya ketika nilai pencarian tidak ditemukan (kesalahan #N/A), gunakan IF ISNA VLOOKUP (di semua versi) atau IFNA VLOOKUP (di Excel 2013 dan yang lebih baru).

ISERROR VLOOKUP untuk mengembalikan sel kosong jika terjadi kesalahan

Untuk mendapatkan cell kosong ketika terjadi error, buat rumusmu mengembalikan string kosong ("") alih-alih teks kustom:

Dalam kasus kita, rumusnya mengambil bentuk ini:

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

Hasilnya persis seperti yang diharapkan - sel kosong jika nama siswa tidak ditemukan dalam tabel pencarian.

Tip. Dengan cara yang sama, Anda dapat mengganti kesalahan VLOOKUP dengan nol, tanda hubung, atau karakter lain yang Anda suka. Cukup gunakan karakter yang diinginkan sebagai pengganti string kosong.

JIKA ISERROR VLOOKUP Ya/Tidak rumus

Dalam beberapa situasi, Anda mungkin mencari sesuatu, tetapi alih-alih menarik korek api, Anda hanya ingin kembali Ya (atau beberapa teks lain jika nilai pencarian ditemukan) dan Tidak (jika nilai pencarian tidak ditemukan). Untuk menyelesaikannya, Anda dapat menggunakan rumus umum ini:

Dalam contoh dataset kita, misalkan kamu ingin mengetahui siswa mana yang gagal dalam suatu tes dan mana yang tidak. Untuk mencapai hal ini, sajikan rumus ISERROR VLOOKUP yang sudah dikenal ke tes logika IF dan katakan padanya untuk mengeluarkan output "No" jika nilainya tidak ditemukan (ISERROR VLOOKUP mengembalikan TRUE), "Yes" jika ditemukan (ISERROR VLOOKUP mengembalikan FALSE):

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", "Yes")

ISERROR VLOOKUP alternatif

Kombinasi IF ISERROR adalah teknik tertua yang telah terbukti waktu untuk Vlookup tanpa kesalahan di Excel. Seiring waktu, fungsi-fungsi baru berevolusi, memberikan cara yang lebih mudah untuk melakukan tugas yang sama. Di bawah ini, kami akan membahas solusi lain yang mungkin dan kapan masing-masing paling baik diterapkan.

IFERROR VLOOKUP

Tersedia di Excel 2007 dan yang lebih tinggi

Dimulai dengan versi 2007, Excel memiliki fungsi khusus, bernama IFERROR, untuk memeriksa kesalahan rumus dan mengembalikan teks Anda sendiri (atau menjalankan rumus alternatif) jika ada kesalahan yang terdeteksi.

Rumus kehidupan nyata adalah sebagai berikut:

=IFERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "Tidak")

Pada pandangan pertama, ini terlihat seperti analogi yang lebih pendek dari rumus IF ISERROR VLOOKUP. Namun, ada perbedaan esensial:

• IFERROR VLOOKUP mengasumsikan bahwa kamu selalu menginginkan hasil dari VLOOKUP jika tidak error.
• IF ISERROR VLOOKUP memungkinkan Anda menentukan apa yang akan dikembalikan jika ada kesalahan dan bagaimana jika tidak ada kesalahan.

Untuk detail lebih lanjut, silakan lihat Menggunakan IFERROR dengan VLOOKUP di Excel.

JIKA ISNA VLOOKUP

Bekerja di Excel 2000 dan yang lebih baru

Dalam situasi ketika anda ingin menjebak hanya #N/A tanpa menangkap error lainnya, fungsi ISNA sangat berguna. Sintaksnya sama dengan IF ISERROR VLOOKUP:

Tetapi, dalam keadaan tertentu, formula yang tampaknya identik ini bisa memberikan hasil yang berbeda:

=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Tidak", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

Pada gambar di bawah ini, cell A13 berisi banyak spasi di belakangnya karena total panjang nilai pencariannya melebihi 255 karakter. Hasilnya, rumus tersebut memicu error #VALUE! error, menarik perhatianmu ke cell tersebut dan mendorongmu untuk menyelidiki alasannya. ISERROR VLOOKUP akan mengembalikan "No" dalam kasus ini, yang hanya akan mengaburkan masalah dan memberikan hasil yang benar-benar salah.

Kapan digunakan:

Rumus ini bekerja dengan baik dalam situasi ketika Anda ingin menampilkan beberapa teks hanya ketika nilai pencarian tidak ditemukan dan tidak ingin menutupi masalah mendasar dengan rumus VLOOKUP itu sendiri, misalnya ketika nama fungsi salah ketik (#NAME?) atau jalur lengkap ke buku kerja pencarian tidak ditentukan (#VALUE!).

Untuk informasi lebih lanjut, silakan lihat fungsi ISNA di Excel dengan contoh rumus.

IFNA VLOOKUP

Tersedia di Excel 2013 dan yang lebih tinggi

Ini adalah pengganti modern dari kombinasi IF ISNA yang memungkinkan Anda menangani error #N/A dengan cara yang lebih mudah.

Berikut adalah padanan singkat dari rumus IF ISNA VLOOKUP kita:

=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "Tidak")

Kapan digunakan:

Ini adalah solusi ideal untuk menjebak dan menangani kesalahan # N / A dalam versi modern Excel (2013 - 365).

Untuk detail selengkapnya, lihat fungsi IFNA Excel.

XLOOKUP

Didukung di Excel 2021 dan Excel 365

Karena fungsionalitas "jika kesalahan" bawaannya, fungsi XLOOKUP adalah cara termudah untuk mencari tanpa kesalahan # N / A di Excel. Cukup, ketikkan teks ramah pengguna Anda di argumen opsional ke-4 bernama if_not_found .

Contohnya:

=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "Tidak")

Batasan: Ini hanya menangkap kesalahan #N/A, mengabaikan jenis lainnya.

Untuk informasi lebih lanjut, lihat fungsi XLOOKUP di Excel.

Seperti yang Anda lihat, Excel menyediakan cukup banyak opsi berbeda untuk mengatasi kesalahan VLOOKUP. Semoga tutorial ini telah menjelaskan cara menggunakannya secara efektif. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!

Unduhan yang tersedia

ISERROR dengan contoh VLOOKUP (file .xlsx)