Sa tutorial na ito, titingnan natin kung paano gamitin ang ISERROR na may VLOOKUP sa Excel para mapangasiwaan ang lahat ng uri ng mga error nang produktibo.

Ang VLOOKUP ay isa sa mga pinakanakalilitong Excel function na sinalanta na may maraming isyu. Alinmang talahanayan ang hinahanap mo, ang mga #N/A error ay isang pangkaraniwang tanawin, kung saan lumalabas din ang #NAME at #VALUE paminsan-minsan. Ang paggamit ng VLOOKUP sa ISERROR ay makakatulong sa iyong mahuli ang lahat ng posibleng error at mahawakan ang mga ito sa paraang pinakaangkop sa iyong sitwasyon.

Bakit nagbibigay ng error ang VLOOKUP?

Ang pinaka Ang karaniwang error sa mga formula ng VLOOKUP ay #N/A na nagaganap kapag hindi nakita ang isang lookup value. Ito ay maaaring mangyari dahil sa iba't ibang dahilan:

• Wala ang lookup value sa lookup array.
• Ang lookup value ay maling spelling.
• May nangunguna o trailing space sa lookup value o lookup column.
• Ang lookup column ay hindi ang pinakakaliwang column ng table array.

Bukod dito, maaari kang tumakbo sa isang #VALUE ! error, hal. kapag ang halaga ng paghahanap ay naglalaman ng higit sa 255 character. Kung sakaling may error sa spelling sa pangalan ng function, lalabas ang isang #NAME? error.

Para sa buong sanggunian, pakitingnan ang aming naunang post sa Bakit hindi gumagana ang Excel VLOOKUP.

KUNG ang formula ng ISERROR VLOOKUP ay palitan ang mga error ng custom na text

Upang itago ang lahat ng posibleng error na maaaring ma-trigger ng VLOOKUP, maaari mo itong ilagay sa loob ng IF ISERROR formulatulad nito:

Bilang halimbawa, hilahin natin ang mga pangalan ng mga paksa kung saan ang mga mag-aaral ng group A failed tests:

=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)

Bilang resulta, nakakakuha ka ng maraming #N/A error, na maaaring lumikha ng impression na sira ang formula.

Sa totoo lang, ang mga error na ito ay nagpapahiwatig lamang na ang ilan sa mga halaga ng paghahanap (A3:A14) ay hindi matatagpuan sa listahan ng paghahanap (D3:D9). Para malinaw na maihatid ang ideyang iyon, ilagay ang iyong VLOOKUP formula sa IF ISERROR construction:

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

Makakakuha ito ng mga error at ibabalik ang iyong custom na text message:

Mga tip at tala:

• Ang pangunahing bentahe ng formula na ito ay mahusay itong gumagana sa lahat ng bersyon ng Excel 2000 hanggang Excel 365. Sa mga modernong bersyon, mas simple at mas maraming compact na alternatibo ang available.
• Ang ISERROR function ay nakakakuha ng ganap na lahat ng error , gaya ng #N/A, #NAME, #VALUE, atbp. Kung sakaling gusto mong magpakita ng custom mensahe lang kapag hindi nakita ang value ng lookup (#N/A error), gamitin ang IF ISNA VLOOKUP (sa lahat ng bersyon) o IFNA VLOOKUP (sa Excel 2013 at mas bago).

ISERROR VLOOKUP sa ibalik ang blangkong cell kung error

Upang magkaroon ng blangkong cell kapag may naganap na error, kunin ang iyong formula na magbalik ng walang laman na string ("") sa halip na isang custom na text:

Sa aming kaso, ang formula ay kumukuha ng ganitong form:

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

Angang resulta ay eksaktong tulad ng inaasahan - isang blangkong cell kung ang pangalan ng mag-aaral ay hindi makita sa lookup table.

Tip. Sa katulad na paraan, maaari mong palitan ang mga error sa VLOOKUP ng mga zero, gitling o anumang iba pang karakter na gusto mo. Gamitin lang ang gustong character sa halip na isang walang laman na string.

KUNG ISERROR VLOOKUP Oo/Hindi formula

Sa ilang sitwasyon, maaaring may hinahanap ka ngunit sa halip na hilahin ang mga posporo gusto lang ibalik ang Oo (o ilang iba pang text kung ang nakita ang halaga ng paghahanap) at Hindi (kung hindi nakita ang halaga ng paghahanap). Upang magawa ito, maaari mong gamitin ang generic na formula na ito:

Sa aming sample na dataset, ipagpalagay na nais mong malaman kung sinong mga mag-aaral ang bumagsak sa pagsusulit at alin ang hindi. Upang magawa ito, ihatid ang pamilyar na ISERROR VLOOKUP na formula sa lohikal na pagsubok ng IF at sabihin ito sa output na "Hindi" kung ang halaga ay hindi nahanap (ISERROR VLOOKUP ay nagbabalik ng TRUE), "Oo" kung natagpuan (ISERROR VLOOKUP ay nagbabalik ng FALSE):

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", "Yes")

ISERROR VLOOKUP na mga alternatibo

Ang IF ISERROR na kumbinasyon ay ang pinakalumang napatunayang pamamaraan sa Vlookup nang walang mga error sa Excel. Sa paglipas ng panahon, umusbong ang mga bagong function, na nagbibigay ng mas madaling paraan upang maisagawa ang parehong gawain. Sa ibaba, tatalakayin natin ang iba pang posibleng solusyon at kung kailan pinakamahusay na mailapat ang bawat isa.

IFERROR VLOOKUP

Available sa Excel 2007 atmas mataas

Simula sa bersyon 2007, may espesyal na function ang Excel, pinangalanang IFERROR, upang suriin ang isang formula para sa mga error at ibalik ang iyong sariling text (o magpatakbo ng alternatibong formula) kung may nakitang error.

Ang formula sa totoong buhay ay ang sumusunod:

=IFERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "No")

Sa unang tingin, mukhang isang mas maikling analogue ng IF ISERROR VLOOKUP formula. Gayunpaman, mayroong mahalagang pagkakaiba:

• Ipinagpapalagay ng IFERROR VLOOKUP na palagi mong gusto ang resulta ng VLOOKUP kung hindi ito isang error.
• KUNG hinahayaan ka ng ISERROR VLOOKUP na tukuyin kung ano ang gagawin ibalik kung error at paano kung walang error.

Para sa higit pang mga detalye, pakitingnan ang Paggamit ng IFERROR sa VLOOKUP sa Excel.

KUNG ISNA VLOOKUP

Gumagana sa Excel 2000 at mas bago

Sa sitwasyon kung saan gusto mong ma-trap lang ang #N/A nang hindi nakakakuha ng anumang iba pang mga error, ang ISNA function ay madaling gamitin. Ang syntax ay kapareho ng sa IF ISERROR VLOOKUP:

Ngunit sa ilang partikular na pangyayari, ito ay tila ang magkaparehong formula ay maaaring makagawa ng magkakaibang mga resulta:

=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

Sa larawan sa ibaba, ang cell A13 ay naglalaman ng maraming trailing space dahil kung saan ang kabuuang haba ng halaga ng paghahanap ay lumampas sa 255 character. Bilang resulta, ang formula ay nagti-trigger ng #VALUE! error, iginuhit ang iyong pansin sa cell na iyon at hinihikayat na siyasatin ang mga dahilan. ISERRORAng VLOOKUP ay magbabalik ng "Hindi" sa kasong ito, na magpapalabo lamang sa isyu at maghahatid ng ganap na maling resulta.

Kailan gagamitin:

Ang formula na ito gumagana nang maganda sa isang sitwasyon kung saan gusto mong magpakita ng ilang text lang kapag hindi nakita ang isang lookup value at ayaw mong itago ang mga pinagbabatayan na problema sa mismong formula ng VLOOKUP, hal. kapag ang pangalan ng function ay mali ang type (#NAME?) o ang buong path sa lookup workbook ay hindi tinukoy (#VALUE!).

Para sa higit pang impormasyon, pakitingnan ang ISNA function sa Excel na may mga halimbawa ng formula.

IFNA VLOOKUP

Available sa Excel 2013 at mas mataas

Isa itong modernong kapalit ng kumbinasyon ng IF ISNA na nagbibigay-daan sa iyong pangasiwaan ang mga #N/A error sa isang mas madaling paraan.

Narito ang shorthand na katumbas ng aming IF ISNA VLOOKUP formula:

=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "No")

Kailan gagamitin:

Isa itong perpektong solusyon para ma-trap at mahawakan ang mga #N/A error sa mga modernong bersyon ng Excel (2013 - 365).

Para sa buong detalye, tingnan ang Excel IFNA function.

XLOOKUP

Sinusuportahan sa Excel 2021 at Excel 365

Dahil sa inbuilt na functionality na "if error" , ang XLOOKUP function ay ang pinakamadaling paraan upang maghanap nang walang #N/A error sa Excel. I-type lang ang iyong user-friendly na text sa opsyonal na ika-4 na argumento na pinangalanang if_not_found .

Halimbawa:

=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "No")

Limitasyon: Nakakakuha lang ito ng #N/A na mga error, hindi pinapansiniba pang mga uri.

Para sa higit pang impormasyon, tingnan ang XLOOKUP function sa Excel.

Tulad ng nakikita mo, ang Excel ay nagbibigay ng maraming iba't ibang mga opsyon upang makakuha ng rig sa mga error sa VLOOKUP. Sana, ang tutorial na ito ay nagbigay ng kaunting liwanag sa kung paano epektibong gamitin ang mga ito. Salamat sa pagbabasa at umaasa akong makita ka sa aming blog sa susunod na linggo!

Mga available na download

ISERROR na may mga halimbawa ng VLOOKUP (.xlsx file)