In diesem Lernprogramm werden wir uns ansehen, wie man ISERROR mit VLOOKUP in Excel verwendet, um alle Arten von Fehlern produktiv zu behandeln.

VLOOKUP ist eine der verwirrendsten Excel-Funktionen, die mit vielen Problemen behaftet ist. Unabhängig davon, in welcher Tabelle Sie sich befinden, sind #N/A-Fehler ein häufiger Anblick, wobei auch #NAME und #VALUE hin und wieder auftauchen. Die Verwendung von VLOOKUP mit ISERROR kann Ihnen helfen, alle möglichen Fehler abzufangen und sie auf die für Ihre Situation am besten geeignete Weise zu behandeln.

Warum gibt VLOOKUP einen Fehler aus?

Der häufigste Fehler in VLOOKUP-Formeln ist #N/A die auftreten, wenn ein Suchwert nicht gefunden wird. Dies kann aus verschiedenen Gründen geschehen:

• Der Nachschlagewert existiert nicht in der Nachschlagematrix.
• Der Nachschlagewert ist falsch geschrieben.
• Der Nachschlagewert oder die Nachschlagespalte enthält führende oder nachfolgende Leerzeichen.
• Die Lookup-Spalte ist nicht die Spalte ganz links im Tabellen-Array.

Außerdem können Sie auf eine #WERT! Fehler, z. B. wenn der Nachschlagewert mehr als 255 Zeichen enthält. Bei einem Schreibfehler im Funktionsnamen wird ein #NAME? wird ein Fehler angezeigt.

Eine vollständige Referenz finden Sie in unserem früheren Beitrag über Warum Excel VLOOKUP nicht funktioniert.

IF ISERROR VLOOKUP-Formel zum Ersetzen von Fehlern durch eigenen Text

Um alle möglichen Fehler, die durch VLOOKUP ausgelöst werden können, zu verschleiern, können Sie es innerhalb der Formel IF ISERROR wie folgt platzieren:

Nehmen wir als Beispiel die Namen der Fächer, in denen die Schüler der Gruppe A die Prüfungen nicht bestanden haben:

=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)

Als Ergebnis erhalten Sie eine Reihe von #N/A-Fehlern, die den Eindruck erwecken könnten, dass die Formel fehlerhaft ist.

In Wirklichkeit zeigen diese Fehler nur an, dass einige der Lookup-Werte (A3:A14) nicht in der Lookup-Liste (D3:D9) gefunden werden. Um diese Idee klar zu vermitteln, verschachteln Sie Ihre VLOOKUP-Formel in der IF ISERROR-Konstruktion:

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Nein", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

Dadurch werden Fehler erkannt und Ihre individuelle Textnachricht zurückgegeben:

Tipps und Hinweise:

• Der Hauptvorteil dieser Formel besteht darin, dass sie gut funktioniert in alle Versionen In den modernen Versionen von Excel 2000 bis Excel 365 sind einfachere und kompaktere Alternativen verfügbar.
• Die Funktion ISERROR fängt absolut alle Fehler Wenn Sie eine benutzerdefinierte Meldung nur anzeigen möchten, wenn ein Suchwert nicht gefunden wird (#N/A-Fehler), verwenden Sie IF ISNA VLOOKUP (in allen Versionen) oder IFNA VLOOKUP (in Excel 2013 und höher).

ISERROR VLOOKUP, um bei einem Fehler eine leere Zelle zurückzugeben

Um eine leere Zelle zu erhalten, wenn ein Fehler auftritt, sorgen Sie dafür, dass Ihre Formel eine leere Zeichenfolge ("") anstelle eines benutzerdefinierten Textes zurückgibt:

In unserem Fall sieht die Formel folgendermaßen aus:

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

Das Ergebnis ist genau wie erwartet - eine leere Zelle, wenn der Name des Schülers nicht in der Nachschlagetabelle gefunden wird.

Tipp: In ähnlicher Weise können Sie VLOOKUP-Fehler durch Nullen, Bindestriche oder jedes andere Zeichen ersetzen. Verwenden Sie einfach das gewünschte Zeichen anstelle einer leeren Zeichenfolge.

IF ISERROR VLOOKUP Ja/Nein-Formel

Es gibt Situationen, in denen Sie nach etwas suchen, aber statt die Streichhölzer zu ziehen, einfach zurückkehren möchten Ja (oder einen anderen Text, wenn der Nachschlagewert gefunden wird) und Nein (wenn der Nachschlagewert nicht gefunden wird). Dazu können Sie diese allgemeine Formel verwenden:

Wenn Sie in unserem Beispieldatensatz wissen möchten, welche Schüler einen Test nicht bestanden haben und welche nicht, können Sie die bereits bekannte ISERROR VLOOKUP-Formel mit dem logischen Test von IF verbinden und ihr sagen, dass sie "Nein" ausgeben soll, wenn der Wert nicht gefunden wird (ISERROR VLOOKUP liefert TRUE), und "Ja", wenn er gefunden wird (ISERROR VLOOKUP liefert FALSE):

=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Nein", "Ja")

ISERROR VLOOKUP Alternativen

Die WENN-ISERROR-Kombination ist die älteste bewährte Technik, um Vlookup in Excel fehlerfrei durchzuführen. Im Laufe der Zeit haben sich neue Funktionen entwickelt, die einfachere Möglichkeiten bieten, dieselbe Aufgabe auszuführen. Im Folgenden werden wir andere mögliche Lösungen erörtern und wann sie am besten angewendet werden sollten.

IFERROR VLOOKUP

Verfügbar in Excel 2007 und höher

Seit der Version 2007 verfügt Excel über eine spezielle Funktion namens IFERROR, mit der eine Formel auf Fehler geprüft werden kann und bei einem Fehler ein eigener Text zurückgegeben wird (oder eine alternative Formel ausgeführt wird).

Die Formel in der Praxis lautet wie folgt:

=IFERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "Nein")

Auf den ersten Blick sieht es aus wie ein kürzeres Analogon der IF ISERROR VLOOKUP-Formel, es gibt jedoch einen wesentlichen Unterschied:

• IFERROR VLOOKUP geht davon aus, dass Sie immer das Ergebnis von VLOOKUP haben wollen, wenn es kein Fehler ist.
• IF ISERROR Mit VLOOKUP können Sie angeben, was im Falle eines Fehlers zurückgegeben werden soll und was, wenn kein Fehler vorliegt.

Weitere Einzelheiten finden Sie unter Verwendung von IFERROR mit VLOOKUP in Excel.

WENN ES SICH UM EIN VLOOKUP HANDELT

Funktioniert in Excel 2000 und höher

In Situationen, in denen nur #N/A abgefangen werden soll, ohne dass andere Fehler abgefangen werden, bietet sich die Funktion ISNA an. Die Syntax ist dieselbe wie bei IF ISERROR VLOOKUP:

Unter bestimmten Umständen kann diese scheinbar identische Formel jedoch zu unterschiedlichen Ergebnissen führen:

=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Nein", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))

In der Abbildung unten enthält Zelle A13 viele Leerzeichen am Ende, wodurch die Gesamtlänge des Nachschlagewerts 255 Zeichen überschreitet. Infolgedessen löst die Formel einen #VALUE!-Fehler aus, der Ihre Aufmerksamkeit auf diese Zelle lenkt und Sie auffordert, die Gründe zu untersuchen. ISERROR VLOOKUP würde in diesem Fall "Nein" zurückgeben, was das Problem nur verschleiern und ein völlig falsches Ergebnis liefern würde.

Wann zu verwenden:

Diese Formel eignet sich hervorragend für Situationen, in denen Sie einen Text nur dann anzeigen möchten, wenn ein Suchwert nicht gefunden wird, und die zugrunde liegenden Probleme mit der VLOOKUP-Formel selbst nicht verschleiern möchten, z. B. wenn der Name der Funktion falsch eingegeben wurde (#NAME?) oder der vollständige Pfad zur Sucharbeitsmappe nicht angegeben wurde (#VALUE!).

Weitere Informationen finden Sie unter ISNA-Funktion in Excel mit Formelbeispielen.

IFNA VLOOKUP

Verfügbar in Excel 2013 und höher

Sie ist ein moderner Ersatz für die IF ISNA-Kombination, mit der Sie #N/A-Fehler einfacher behandeln können.

Hier ist eine Kurzform unserer IF ISNA VLOOKUP-Formel:

=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "Nein")

Wann zu verwenden:

Es ist eine ideale Lösung, um #N/A-Fehler in modernen Versionen von Excel (2013 - 365) abzufangen und zu behandeln.

Ausführliche Informationen finden Sie in der Excel-Funktion IFNA.

XLOOKUP

Unterstützt in Excel 2021 und Excel 365

Aufgrund der eingebauten "Wenn-Fehler"-Funktionalität ist die XLOOKUP-Funktion der einfachste Weg, um in Excel ohne #N/A-Fehler nachzuschlagen. Geben Sie einfach Ihren benutzerfreundlichen Text in das optionale 4te Argument namens if_not_found .

Zum Beispiel:

=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "Nein")

Einschränkung: Es werden nur #N/A-Fehler erkannt, andere Typen werden ignoriert.

Weitere Informationen finden Sie unter XLOOKUP-Funktion in Excel.

Wie Sie sehen, bietet Excel eine ganze Reihe verschiedener Optionen, um VLOOKUP-Fehler zu beheben. Ich hoffe, dass dieses Tutorial Ihnen gezeigt hat, wie Sie diese effektiv nutzen können. Ich danke Ihnen für die Lektüre und hoffe, Sie nächste Woche in unserem Blog begrüßen zu dürfen!

Verfügbare Downloads

ISERROR mit VLOOKUP-Beispielen (.xlsx-Datei)