Satura rādītājs
Šajā pamācībā mēs aplūkosim, kā izmantot ISERROR ar VLOOKUP programmā Excel, lai produktīvi apstrādātu visu veidu kļūdas.
VLOOKUP ir viena no mulsinošākajām Excel funkcijām, ko apgrūtina daudzas problēmas. Lai kurā tabulā jūs skatītos, #N/A kļūdas ir bieži sastopamas, turklāt laiku pa laikam parādās arī #NAME un #VALUE. Izmantojot VLOOKUP ar ISERROR, varat noķert visas iespējamās kļūdas un apstrādāt tās jūsu situācijai vispiemērotākajā veidā.
Kāpēc VLOOKUP rada kļūdu?
Visbiežāk sastopamā kļūda VLOOKUP formulās ir šāda. #N/A Tas var notikt dažādu iemeslu dēļ:
- Pārlūkošanas vērtība neeksistē pārmeklēšanas masīvā.
- Pārlūkošanas vērtība ir nepareizi uzrakstīta.
- Pārlūkošanas vērtībā vai meklēšanas slejā ir sākuma vai beigu atstarpes.
- Pārlūkošanas sleja nav tabulas masīva kreisākā sleja.
Turklāt jūs varat saskarties ar #VALUE! kļūda, piemēram, ja meklēšanas vērtība satur vairāk nekā 255 rakstzīmes. Ja funkcijas nosaukumā ir pareizrakstības kļūda, tiek parādīta kļūda. #NAME? tiks parādīta kļūda.
Lai iegūtu pilnīgu atsauci, lūdzu, skatiet mūsu iepriekšējo ziņu par to, kāpēc Excel VLOOKUP nedarbojas.
IF ISERROR VLOOKUP formula, lai kļūdas aizstātu ar pielāgotu tekstu
Lai slēptu visas iespējamās kļūdas, ko var izraisīt VLOOKUP, to var ievietot formulas IF ISERROR iekšpusē šādi:
IF(ISERROR(VLOOKUP(...)), " text_if_error ", VLOOKUP(...))Kā piemēru izvilksim to priekšmetu nosaukumus, kuros A grupas skolēni nenokārtoja pārbaudes darbus:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
Rezultātā tiek parādītas vairākas #N/A kļūdas, kas var radīt iespaidu, ka formula ir bojāta.
Patiesībā šīs kļūdas tikai norāda, ka dažas no meklēšanas vērtībām (A3:A14) nav atrodamas meklēšanas sarakstā (D3:D9). Lai skaidri paustu šo domu, iestrādājiet VLOOKUP formulu IF ISERROR konstrukcijā:
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Nē", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
Tas novērsīs kļūdas un atgriezīs jūsu pielāgotu teksta ziņojumu:
Padomi un piezīmes:
- Šīs formulas galvenā priekšrocība ir tā, ka tā labi darbojas visas versijas Excel 2000 līdz Excel 365. Mūsdienu versijās ir pieejamas vienkāršākas un kompaktākas alternatīvas.
- ISERROR funkcija pārtver pilnīgi visas kļūdas Piemēram, #N/A, #NAME, #VALUE u. c. Ja vēlaties parādīt pielāgotu ziņojumu tikai tad, ja nav atrasta meklēšanas vērtība (#N/A kļūda), izmantojiet IF ISNA VLOOKUP (visās versijās) vai IFNA VLOOKUP (programmā Excel 2013 un jaunākās versijās).
ISERROR VLOOKUP, lai kļūdas gadījumā atgrieztu tukšu šūnu
Lai kļūdas gadījumā tiktu parādīta tukša šūna, formulā atgriezt tukšu virkni (""), nevis pielāgotu tekstu:
IF(ISERROR(VLOOKUP(...)), "", VLOOKUP(...))Mūsu gadījumā formula ir šāda:
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
Rezultāts ir tieši tāds, kā gaidīts - tukša šūna, ja skolēna vārds nav atrodams meklēšanas tabulā.
Padoms. Līdzīgā veidā varat aizstāt VLOOKUP kļūdas ar nullēm, domuzīmēm vai jebkuru citu rakstzīmi. Vienkārši tukšās rindas vietā izmantojiet vēlamo rakstzīmi.
IF ISERROR VLOOKUP Jā/Nē formula
Dažās situācijās jūs, iespējams, kaut ko meklējat, bet tā vietā, lai atrastu spēles, vienkārši vēlaties atgriezties. Jā (vai kādu citu tekstu, ja ir atrasta meklēšanas vērtība) un Nē (ja meklēšanas vērtība nav atrasta). Lai to izdarītu, varat izmantot šo vispārīgo formulu:
IF(ISERROR(VLOOKUP(...)), " text_if_not_found ", " text_if_found ")Pieņemsim, ka mūsu parauga datu kopā vēlaties uzzināt, kuri skolēni neizturēja testu un kuri nē. Lai to izdarītu, izmantojiet jau pazīstamo ISERROR VLOOKUP formulu ar loģisko testu IF un norādiet, lai tā izvadītu "Nē", ja vērtība nav atrasta (ISERROR VLOOKUP atgriež TRUE), "Jā", ja atrasta (ISERROR VLOOKUP atgriež FALSE):
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Nē", "Jā")
ISERROR VLOOKUP alternatīvas
IF ISERROR kombinācija ir senākais laika gaitā pārbaudītais paņēmiens, kā Excel programmā Vlookup bez kļūdām. Laika gaitā attīstījās jaunas funkcijas, kas nodrošina vieglākus veidus, kā veikt to pašu uzdevumu. Tālāk mēs aplūkosim citus iespējamos risinājumus un to, kad katru no tiem vislabāk izmantot.
IFERROR VLOOKUP
Pieejams programmā Excel 2007 un jaunākās versijās
Sākot ar 2007. versiju, programmā Excel ir īpaša funkcija IFERROR, kas ļauj pārbaudīt, vai formulā nav kļūdas, un atgriezt savu tekstu (vai palaist alternatīvu formulu), ja tiek atklāta kļūda.
IFERROR(VLOOKUP(...), " text_if_error ")Reālā formula ir šāda:
=IFERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "Nē")
No pirmā acu uzmetiena tas izskatās kā īsāks IF ISERROR VLOOKUP formulas analogs. Tomēr ir būtiska atšķirība:
- IFERROR VLOOKUP pieņem, ka jūs vienmēr vēlaties saņemt VLOOKUP rezultātu, ja tas nav kļūda.
- IF ISERROR VLOOKUP ļauj norādīt, kas jāatgriež, ja ir kļūda, un kas, ja nav kļūdas.
Sīkāku informāciju skatiet sadaļā IFERROR izmantošana ar VLOOKUP programmā Excel.
JA IR VLOOKUP
Darbojas programmā Excel 2000 un jaunākās versijās
Situācijās, kad vēlaties izķert tikai #N/A, neķerot citas kļūdas, noder funkcija ISNA. Sintakse ir tāda pati kā IF ISERROR VLOOKUP:
IF(ISNA(VLOOKUP(...)), " text_if_error ", VLOOKUP(...))Taču noteiktos apstākļos šī šķietami identiskā formula var dot atšķirīgus rezultātus:
=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Nē", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
Zemāk redzamajā attēlā A13 šūnā ir daudz atstarpju, kuru dēļ kopējais meklēšanas vērtības garums pārsniedz 255 rakstzīmes. Rezultātā formula izraisa #VALUE! kļūdu, pievēršot jūsu uzmanību šai šūnai un mudinot izpētīt iemeslus. ISERROR VLOOKUP šajā gadījumā atgrieztu "No", kas tikai aizēnotu problēmu un sniegtu pilnīgi nepareizu rezultātu.
Kad lietot:
Šī formula lieliski darbojas situācijās, kad vēlaties parādīt kādu tekstu tikai tad, ja nav atrasta meklēšanas vērtība, un nevēlaties maskēt problēmas, kas saistītas ar pašu VLOOKUP formulu, piemēram, ja ir kļūdaini ierakstīts funkcijas nosaukums (#NAME?) vai nav norādīts pilns ceļš uz meklēšanas darbgrāmatu (#VALUE!).
Lai iegūtu vairāk informācijas, skatiet ISNA funkciju programmā Excel ar formulas piemēriem.
IFNA VLOOKUP
Pieejams programmā Excel 2013 un jaunākās versijās
Tā ir moderna IF ISNA kombinācijas aizstājēja, kas ļauj vieglāk apstrādāt #N/A kļūdas.
IFNA(VLOOKUP(...), " text_if_error ")Šeit ir mūsu IF ISNA VLOOKUP formulas saīsinātais ekvivalents:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "Nē")
Kad lietot:
Tas ir ideāls risinājums #N/A kļūdu izķeršanai un apstrādei mūsdienu Excel versijās (2013 - 365).
Sīkāku informāciju skatiet sadaļā Excel IFNA funkcija.
XLOOKUP
Atbalsta Excel 2021 un Excel 365
Pateicoties iebūvētajai funkcijai "ja kļūda", XLOOKUP funkcija ir visvienkāršākais veids, kā meklēt bez #N/A kļūdām programmā Excel. Vienkārši ievadiet savu lietotājam draudzīgo tekstu izvēles 4. argumentā ar nosaukumu if_not_found .
Piemēram:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "Nē")
Ierobežojums: tā uztver tikai #N/A kļūdas, ignorējot citus tipus.
Lai uzzinātu vairāk, skatiet XLOOKUP funkciju programmā Excel.
Kā redzat, Excel piedāvā diezgan daudz dažādu iespēju, lai iegūtu VLOOKUP kļūdas. Cerams, ka šī pamācība ir parādījusi, kā tās efektīvi izmantot. Paldies, ka izlasījāt, un ceru, ka nākamnedēļ tiksimies mūsu blogā!
Pieejamās lejupielādes
ISERROR ar VLOOKUP piemēriem (.xlsx fails)
