विषयसूची
इस ट्यूटोरियल में, हम देखेंगे कि एक्सेल में VLOOKUP के साथ ISERROR का उपयोग कैसे करें ताकि सभी प्रकार की त्रुटियों को उत्पादक रूप से हैंडल किया जा सके।
VLOOKUP एक्सेल के सबसे भ्रमित करने वाले कार्यों में से एक है। कई मुद्दों के साथ। आप जिस भी तालिका में देख रहे हैं, #N/A त्रुटियां एक सामान्य दृश्य हैं, साथ ही #NAME और #VALUE भी कभी-कभी दिखाई देते हैं। ISERROR के साथ VLOOKUP का उपयोग करने से आपको सभी संभावित त्रुटियों को पकड़ने और उन्हें आपकी स्थिति के लिए सबसे उपयुक्त तरीके से संभालने में मदद मिल सकती है।
VLOOKUP त्रुटि क्यों दे रहा है?
सबसे अधिक VLOOKUP सूत्रों में सामान्य त्रुटि #N/A होती है जब लुकअप मान नहीं मिलता है। यह विभिन्न कारणों से हो सकता है:
- लुकअप ऐरे में लुकअप मान मौजूद नहीं है।
- लुकअप मान की वर्तनी गलत है।
- अग्रणी या हैं लुकअप मान या लुकअप कॉलम में अनुगामी रिक्तियाँ।
- लुकअप कॉलम तालिका सरणी का सबसे बाएँ स्तंभ नहीं है।
इसके अलावा, आप #VALUE में चला सकते हैं ! त्रुटि, उदा. जब लुकअप मान में 255 से अधिक वर्ण हों. यदि फ़ंक्शन के नाम में कोई वर्तनी त्रुटि है, तो एक #NAME? त्रुटि दिखाई देगी।
पूर्ण संदर्भ के लिए, कृपया हमारी पिछली पोस्ट देखें कि Excel VLOOKUP काम क्यों नहीं कर रहा है।
यदि कस्टम टेक्स्ट के साथ त्रुटियों को बदलने के लिए ISERROR VLOOKUP सूत्र
VLOOKUP द्वारा ट्रिगर की जा सकने वाली सभी संभावित त्रुटियों को छिपाने के लिए, आप इसे IF ISERROR सूत्र के अंदर रख सकते हैंइस तरह:
IF(ISERROR(VLOOKUP(…)), " text_if_error", VLOOKUP(…))उदाहरण के तौर पर, आइए उन विषयों के नाम खींचें जिनमें के छात्र समूह A विफल परीक्षण:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
परिणामस्वरूप, आपको #N/A त्रुटियों का एक गुच्छा मिल रहा है, जिससे यह आभास हो सकता है कि सूत्र दूषित है।
<0
वास्तव में, ये त्रुटियां केवल संकेत देती हैं कि कुछ लुकअप मान (A3:A14) लुकअप सूची (D3:D9) में नहीं पाए जाते हैं। उस विचार को स्पष्ट रूप से व्यक्त करने के लिए, IF ISERROR निर्माण में अपने VLOOKUP सूत्र को नेस्ट करें:
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
यह त्रुटियों को पकड़ लेगा और आपका कस्टम टेक्स्ट संदेश वापस कर देगा:
टिप्स और नोट्स:
- इस सूत्र का मुख्य लाभ यह है कि यह एक्सेल 2000 के एक्सेल 365 के सभी संस्करणों में अच्छी तरह से काम करता है। आधुनिक संस्करणों में, सरल और अधिक कॉम्पैक्ट विकल्प उपलब्ध हैं।
- ISERROR फ़ंक्शन पूरी तरह से सभी त्रुटियों को पकड़ता है, जैसे कि #N/A, #NAME, #VALUE, आदि। यदि आप एक कस्टम प्रदर्शित करना चाहते हैं केवल संदेश जब कोई लुकअप मान नहीं मिला (#N/A त्रुटि), IF ISNA VLOOKUP (सभी संस्करणों में) या IFNA VLOOKUP (Excel 2013 और बाद में) का उपयोग करें।
ISERROR VLOOKUP को त्रुटि होने पर रिक्त सेल वापस करें
त्रुटि होने पर रिक्त कक्ष प्राप्त करने के लिए, कस्टम पाठ के बजाय खाली स्ट्रिंग ("") वापस करने के लिए अपना सूत्र प्राप्त करें:
IF(ISERROR(VLOOKUP(…) ), "", VLOOKUP(…))हमारे मामले में, सूत्र इस रूप में होता है:
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
परिणाम बिल्कुल अपेक्षा के अनुरूप है - यदि छात्र का नाम लुकअप टेबल में नहीं मिलता है तो एक खाली सेल।
युक्ति। इसी तरह, आप VLOOKUP त्रुटियों को शून्य, डैश या किसी अन्य वर्ण से बदल सकते हैं जिसे आप पसंद करते हैं। खाली स्ट्रिंग के स्थान पर वांछित वर्ण का उपयोग करें।
IF ISERROR VLOOKUP हाँ/नहीं सूत्र
कुछ स्थितियों में, आप कुछ खोज रहे होंगे लेकिन मैचों को खींचने के बजाय केवल हां (या कुछ अन्य पाठ यदि लुकअप मान मिला है) और नहीं (यदि लुकअप मान नहीं मिला है)। इसे पूरा करने के लिए, आप इस सामान्य सूत्र का उपयोग कर सकते हैं:
IF(ISERROR(VLOOKUP(…)), " text_if_not_found ", " text_if_found ")हमारे में नमूना डेटासेट, मान लीजिए कि आप जानना चाहते हैं कि कौन से छात्र किसी परीक्षा में अनुत्तीर्ण हुए और कौन से नहीं। इसे पूरा करने के लिए, IF के तार्किक परीक्षण के लिए पहले से ही परिचित ISERROR VLOOKUP सूत्र की सेवा करें और यदि मान नहीं मिला (ISERROR VLOOKUP रिटर्न TRUE), तो "हाँ" (ISERROR VLOOKUP FALSE लौटाता है) आउटपुट को बताएं:
=IF(ISERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", "Yes")
ISERROR VLOOKUP विकल्प
IF ISERROR संयोजन एक्सेल में त्रुटियों के बिना Vlookup के लिए सबसे पुराना समय सिद्ध तकनीक है। समय के साथ, नए कार्य विकसित हुए, समान कार्य करने के आसान तरीके प्रदान किए। नीचे, हम अन्य संभावित समाधानों पर चर्चा करेंगे और जब प्रत्येक को लागू करना सबसे अच्छा होगा।
IFERROR VLOOKUP
Excel 2007 में उपलब्ध औरउच्चतर
संस्करण 2007 से शुरू करते हुए, एक्सेल में एक विशेष कार्य है, जिसका नाम IFERROR है, जो त्रुटियों के लिए एक सूत्र की जाँच करता है और यदि कोई त्रुटि पाई जाती है तो अपना स्वयं का पाठ लौटाता है (या एक वैकल्पिक सूत्र चलाता है)।
IFERROR(VLOOKUP(…), " text_if_error ")वास्तविक जीवन सूत्र इस प्रकार है:
=IFERROR(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "No")
पहली नजर में, यह IF ISERROR VLOOKUP सूत्र के एक छोटे एनालॉग जैसा दिखता है। हालाँकि, एक आवश्यक अंतर है:
- IFERROR VLOOKUP मानता है कि आप हमेशा VLOOKUP का परिणाम चाहते हैं यदि यह कोई त्रुटि नहीं है।
- IF ISERROR VLOOKUP आपको यह निर्दिष्ट करने देता है कि क्या करना है अगर कोई त्रुटि है और कोई त्रुटि नहीं है तो क्या होगा।
अधिक विवरण के लिए, कृपया एक्सेल में VLOOKUP के साथ IFERROR का उपयोग करना देखें।
IF ISNA VLOOKUP
Excel 2000 और बाद में काम करता है
ऐसी स्थिति में जब आप किसी अन्य त्रुटि को पकड़े बिना केवल #N/A को ट्रैप करना चाहते हैं, ISNA फ़ंक्शन काम आता है। सिंटैक्स IF ISERROR VLOOKUP के समान है:
IF(ISNA(VLOOKUP(…)), " text_if_error ", VLOOKUP(…))लेकिन कुछ निश्चित परिस्थितियों में, ऐसा प्रतीत होता है समान सूत्र भिन्न परिणाम उत्पन्न कर सकते हैं:
=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
नीचे दी गई छवि में, सेल A13 में बहुत सारे अनुगामी स्थान हैं, जिसके कारण लुकअप मान की कुल लंबाई 255 वर्णों से अधिक है। परिणामस्वरूप, सूत्र #VALUE! त्रुटि, उस सेल पर आपका ध्यान आकर्षित करना और कारणों की जांच करने के लिए प्रोत्साहित करना। इसेररइस मामले में VLOOKUP "नहीं" लौटाएगा, जो केवल समस्या को अस्पष्ट करेगा और बिल्कुल गलत परिणाम देगा।
कब उपयोग करें:
यह सूत्र ऐसी स्थिति में खूबसूरती से काम करता है जब आप केवल कुछ पाठ प्रदर्शित करना चाहते हैं जब कोई लुकअप मान नहीं मिलता है और VLOOKUP सूत्र के साथ ही अंतर्निहित समस्याओं को छिपाना नहीं चाहते हैं, उदा। जब फ़ंक्शन का नाम गलत टाइप किया गया हो (#NAME?) या लुकअप कार्यपुस्तिका का पूरा पथ निर्दिष्ट नहीं किया गया हो (#VALUE!).
अधिक जानकारी के लिए, कृपया सूत्र उदाहरणों के साथ Excel में ISNA फ़ंक्शन देखें.<3
IFNA VLOOKUP
Excel 2013 और उच्चतर में उपलब्ध
यह IF ISNA संयोजन का एक आधुनिक प्रतिस्थापन है जो आपको #N/A त्रुटियों को संभालने देता है एक आसान तरीका।
IFNA(VLOOKUP(…), " text_if_error ")यहाँ हमारे IF ISNA VLOOKUP फ़ॉर्मूला का संक्षिप्त रूप समतुल्य है:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "No")
कब उपयोग करें:
यह एक्सेल के आधुनिक संस्करणों (2013 - 365) में #N/A त्रुटियों को ट्रैप और हैंडल करने का एक आदर्श समाधान है।
पूर्ण विवरण के लिए, एक्सेल IFNA फ़ंक्शन देखें। , XLOOKUP फ़ंक्शन Excel में #N/A त्रुटियों के बिना खोजने का सबसे आसान तरीका है। बस, if_not_found नाम के वैकल्पिक चौथे तर्क में अपना उपयोगकर्ता-अनुकूल टेक्स्ट टाइप करें।
उदाहरण के लिए:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "No")
सीमा: यह अनदेखा करते हुए केवल #N/A त्रुटियों को पकड़ता हैअन्य प्रकार।
अधिक जानकारी के लिए, एक्सेल में XLOOKUP फ़ंक्शन देखें।
जैसा कि आप देखते हैं, एक्सेल VLOOKUP त्रुटियों को ठीक करने के लिए बहुत सारे विभिन्न विकल्प प्रदान करता है। उम्मीद है, इस ट्यूटोरियल ने उन्हें प्रभावी ढंग से उपयोग करने के तरीके पर कुछ प्रकाश डाला है। पढ़ने के लिए मैं आपको धन्यवाद देता हूं और आशा करता हूं कि अगले सप्ताह आप हमारे ब्लॉग पर मिलेंगे!
डाउनलोड उपलब्ध
VLOOKUP उदाहरणों के साथ ISERROR (.xlsx फ़ाइल)
