Tutorial ngajelaskeun fungsi Excel REPLACE sareng SUBSTITUTE sareng conto panggunaan. Tingali kumaha cara ngagunakeun fungsi REPLACE sareng string teks, angka sareng kaping, sareng kumaha nyarang sababaraha fungsi REPLACE atanapi SUBSTITUTE dina hiji rumus.

Minggu kamari urang ngabahas sababaraha cara ngagunakeun fungsi FIND sareng SEARCH dina hiji rumus. lembar kerja Excel anjeun. Dinten ieu, urang bakal nyandak katingal deeper di dua fungsi séjén pikeun ngaganti téks dina sél dumasar lokasina atawa ngagantikeun hiji string téks kalawan séjén dumasar kana eusi. Sakumaha anjeun tiasa bayangkeun, kuring nyarioskeun ngeunaan fungsi Excel REPLACE sareng SUBSTITUTE.

Fungsi Excel REPLACE

Pungsi REPLACE dina Excel ngamungkinkeun anjeun ngarobih hiji atanapi sababaraha karakter dina string téks kalawan karakter séjén atawa sakumpulan karakter.

Sakumaha nu katingali, pungsi Excel REPLACE boga 4 argumen, nu sadayana diperlukeun.

• Old_text - téks aslina (atawa rujukan ka sél jeung téks aslina) nu Anjeun hoyong ngaganti sababaraha karakter.
• Start_num - posisi karakter kahiji dina old_text nu Anjeun hoyong ngaganti.
• Num_chars - jumlah karakter nu Anjeun hoyong ngaganti.
• New_text - teks gaganti.

Contona, pikeun ngarobah kecap " panonpoé " jadi " anak ", anjeun tiasa nganggo ieu di handap.rumus:

=REPLACE("sun", 2, 1, "o")

Sareng upami anjeun nempatkeun kecap asli dina sababaraha sél, sebutkeun A2, anjeun tiasa nyayogikeun rujukan sél anu cocog dina argumen old_text:

=REPLACE(A2, 2, 1, "o")

Catetan. Upami argumen start_num atanapi num_chars négatip atanapi non-numerik, rumus Ganti Excel ngabalikeun #VALUE! kasalahan.

Ngagunakeun pungsi Excel REPLACE kalayan niléy numerik

Pungsi REPLACE dina Excel dirancang pikeun ngerjakeun string téks. Tangtu, Anjeun bisa make eta pikeun ngaganti karakter numerik nu mangrupa bagian tina string téks, contona:

=REPLACE(A2, 7, 4, "2016")

Perhatikeun yén urang ngalampirkeun "2016 " dina tanda petik ganda sakumaha biasana anjeun lakukeun ku nilai téks.

Ku cara nu sarupa, anjeun bisa ngaganti hiji atawa leuwih digit dina hiji angka. Contona:

=REPLACE(A4, 4, 4,"6")

Jeung deui, anjeun kudu ngalampirkeun nilai ngagantian dina tanda petik ganda ("6").

Catetan. Rumus Excel REPLACE sok ngabalikeun string téks , sanés angka. Dina screenshot di luhur, perhatikeun alignment kénca nilai téks balik dina B2, tur dibandingkeun jeung nomer aslina-Blok katuhu dina A2. Sareng kusabab éta mangrupikeun nilai téks, anjeun moal tiasa dianggo dina itungan sanés upami anjeun ngarobih deui kana nomer, contona ku ngalikeun 1 atanapi nganggo metode anu sanés anu dijelaskeun dina Kumaha ngarobih téks kana angka.

Ngagunakeun pungsi Excel REPLACE sareng kaping

Sapertos nu nembe katingal, pungsi REPLACE tiasa dianggo sarengangka, iwal eta mulih string téks :) Inget yen dina sistem Excel internal, kaping disimpen salaku angka, anjeun bisa coba ngagunakeun sababaraha Rumus Ganti dina kaping. Hasilna bakal rada ngerakeun.

Misalna, anjeun gaduh tanggal dina A2, sebutkeun 1-Oct-14, sareng anjeun hoyong ngarobih " Okt " janten " Nov ". Janten, anjeun nyerat rumus REPLACE (A2, 4, 3, "Nov") anu nyarioskeun Excel pikeun ngagentos 3 karakter dina sél A2 dimimitian ku karakter ka-4… sareng nampi hasil ieu:

Kunaon kitu? Kusabab "01-Oct-14" ngan ngagambarkeun visual tina jumlah serial kaayaan (41913) nu ngagambarkeun tanggal. Janten, rumus Ganti kami ngarobih 3 digit terakhir dina nomer séri di luhur janten " Nov " sareng ngabalikeun senar téks "419Nov".

Pikeun kéngingkeun fungsi Excel REPLACE tiasa dianggo kalayan leres. kaping, Anjeun bisa ngarobah kaping ka string téks kahiji ku ngagunakeun fungsi TEXT atawa téhnik séjén nunjukkeun dina Kumaha ngarobah tanggal kana téks dina Excel. Alternatipna, anjeun tiasa nampilkeun fungsi TEXT langsung dina argumen old_text tina fungsi REPLACE:

=REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov")

Punten émut yén hasil tina rumus di luhur nyaéta a string téks , sarta ku kituna solusi ieu jalan ngan lamun anjeun teu rencanana ngagunakeun kaping dirobah dina itungan salajengna. Upami anjeun peryogi kaping tinimbang senar téks, paké pungsi DATEVALUE pikeun ngaktipkeun nilai anu dipulangkeun kufungsi Excel REPLACE balik deui ka tanggal:

=DATEVALUE(REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov"))

Nested REPLACE pungsi pikeun ngalakukeun sababaraha ngagantian dina sél

Rasa sering, Anjeun bisa jadi kudu ngalakukeun leuwih ti hiji ngagantian dina sél anu sarua. Tangtu, Anjeun bisa ngalakukeun hiji ngagantian, kaluaran hasil panengah kana kolom tambahan, lajeng nganggo fungsi REPLACE deui. Nanging, cara anu langkung saé sareng langkung profésional nyaéta ngagunakeun fungsi REPLACE bersarang anu ngamungkinkeun anjeun ngalakukeun sababaraha panggantian kalayan rumus tunggal. Dina kontéks ieu, "nyarang" hartina nempatkeun hiji pungsi dina nu séjén.

Pertimbangkeun conto ieu di handap. Upami anjeun gaduh daptar nomer telepon dina kolom A anu diformat janten "123456789" sareng anjeun hoyong ngajantenkeunana langkung mirip nomer telepon ku cara nambihan tanda hubung. Dina basa sejen, tujuan anjeun pikeun ngarobah "123456789" jadi "123-456-789".

Nyelapkeun tanda hubung kahiji gampang. Anjeun nulis rumus Excel Ganti biasa nu ngaganti enol karakter ku hyphen, nyaéta nambahkeun hyphen dina posisi 4 dina sél:

=REPLACE(A2,4,0,"-")

Hasil tina di luhur Ganti rumusna kieu:

Oke, ayeuna urang kudu ngasupkeun hiji deui hyphen dina posisi ka-8. Jang ngalampahkeun ieu, anjeun nempatkeun rumus di luhur dina fungsi Excel REPLACE anu sanés. Langkung tepatna, anjeun nyelapkeun kana argumen old_text tina fungsi anu sanés, supados fungsi REPLACE kadua bakal nanganan nilai anu dipulangkeun kuGANTIKAN heula, sanés niléy dina sél A2:

=REPLACE(REPLACE(A2,4,0,"-"),8,0,"-")

Alhasil, anjeun nampi nomer telepon dina pormat anu dipikahoyong:

Ku cara nu sarua, Anjeun bisa maké fungsi REPLACE nested pikeun nyieun string téks siga tanggal ku cara nambahkeun garis miring (/) di mana luyu:

=(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

Salajengna, anjeun tiasa ngarobih string téks kana tanggal nyata ku mungkus rumus REPLACE di luhur sareng fungsi DATEVALUE:

=DATEVALUE(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

Jeung sacara alami, anjeun henteu terbatas dina jumlah fungsi. anjeun tiasa nyarang dina hiji rumus (versi modéren Excel 2010, 2013 sareng 2016 ngamungkinkeun dugi ka 8192 karakter sareng dugi ka 64 fungsi bersarang dina rumus).

Contona, anjeun tiasa nganggo 3 fungsi REPLACE nested pikeun gaduh nomer dina A2 némbongan sapertos tanggal sareng waktos:

=REPLACE(REPLACE(REPLACE(REPLACE(A2,3,0,"/") ,6,0,"/"), 9,0, " "), 12,0, ":")

Ngaganti string anu nembongan dina posisi anu béda dina unggal sél

Sajauh ieu, dina sagala conto urang geus kaayaan nilai nu sarupa jeung geus nyieun panggantian dina positi sarua. dina unggal sél. Tapi tugas real-hirup mindeng leuwih pajeulit batan éta. Dina lembar kerja anjeun, karakter anu bakal diganti moal merta muncul dina tempat anu sami dina unggal sél, ku kituna anjeun kedah manggihan posisi karakter munggaran anu kedah diganti. Conto di handap bakal nunjukkeun naon anu kuring nyarioskeun.

Anggap anjeun gaduh daptar emailalamat dina kolom A. Jeung ngaran hiji parusahaan geus robah tina "ABC" pikeun, sebutkeun, "BCA". Janten, anjeun kedah ngapdet sadaya alamat email para klien anu sasuai.

Tapi masalahna nyaéta nami klien panjangna béda-béda, sareng éta naha anjeun henteu tiasa netepkeun persis dimana nami perusahaan dimimitian. Dina basa sejen, anjeun teu nyaho naon nilai nyadiakeun dina start_num argumen fungsi Excel REPLACE. Pikeun mendakanana, paké fungsi Excel FIND pikeun nangtukeun posisi char munggaran dina senar "@abc":

=FIND("@abc",A2)

Terus, asupkeun fungsi FIND di luhur dina start_num argumen rumus REPLACE anjeun:

=REPLACE(A2, FIND("@abc",A2), 4, "@bca")

Tip. Kami ngalebetkeun "@" dina rumus Panggihan sareng Ganti Excel pikeun ngahindarkeun panggantian anu teu kahaja dina bagian nami alamat email. Tangtosna, aya kasempetan anu tipis pisan yén pertandingan sapertos kitu bakal kajantenan, sareng anjeun tetep hoyong janten aman.

Sapertos anu anjeun tingali dina screenshot di handap ieu, rumusna henteu aya masalah dina milarian sareng ngagentos éta. téks heubeul jeung nu anyar. Sanajan kitu, lamun string téks nu bakal diganti teu kapanggih, rumus mulih #VALUE! kasalahan:

Jeung kami hayang rumus mulangkeun alamat surélék aslina tinimbang kasalahan. Ku kituna, hayu urang ngalampirkeun kami manggihan & amp; GANTIKAN rumus dina fungsi IFERROR:

=IFERROR(REPLACE(A2, FIND("@abc",A2), 4, "@bca"),A2)

Sareng rumus anu ditingkatkeun ieu jalanna sampurna, sanés?

Praktisan sanésAplikasi tina fungsi REPLACE nyaéta pikeun ngapitalkeun hurup kahiji dina sél. Iraha waé anjeun ngurus daptar nami, produk, sareng anu sanés, anjeun tiasa nganggo rumus anu dihubungkeun di luhur pikeun ngarobih hurup kahiji janten UPPERCASE.

Tip. Upami anjeun hoyong ngagentos data asli, cara anu langkung gampang nyaéta nganggo dialog Excel FIND and REPLACE.

Fungsi SUBSTITUTE Excel

Fungsi SUBSTITUTE dina Excel ngagentos hiji atanapi langkung instansi. tina karakter atawa string téks nu tangtu kalawan karakter nu tangtu.

Sintaksis fungsi Excel SUBSTITUTE nyaéta kieu:

Tilu argumen anu munggaran diperyogikeun sareng anu terakhir opsional.

• Téks - téks aslina anu anjeun hoyong ngagantikeun karakter. Bisa disadiakeun salaku string tés, rujukan sél, atawa hasil tina rumus séjén.
• Old_text - karakter nu rék diganti.
• New_text - karakter anyar pikeun ngaganti old_text.
• Instance_num - kajadian tina old_text nu Anjeun hoyong ganti. Lamun dileungitkeun, unggal kajadian téks heubeul bakal dirobah jadi téks anyar.

Contona, sakabéh rumus di handap ngagantikeun "1" jeung "2" dina sél A2, tapi hasilna béda. gumantung kana angka nu anjeun nyadiakeun dina argumen panungtungan:

=SUBSTITUTE(A2, "1", "2", 1) - Ngagantikeun kajadian mimiti "1" kalawan"2".

=SUBSTITUTE(A2, "1", "2", 2) - Ngagantikeun kajadian kadua "1" ku "2".

=SUBSTITUTE(A2, "1", "2") - Ngagantikeun sakabeh kajadian "1" ku "2".

Dina prakna, fungsi SUBSTITUTE ogé dipaké pikeun miceun karakter nu teu dihoyongkeun tina sél. Pikeun conto kahirupan nyata, mangga tingali:

• Kumaha carana miceun karakter atawa kecap tina string
• Kumaha mupus karakter nu teu dihoyongkeun tina sél

Catetan. Fungsi SUBSTITUTE dina Excel nyaéta sénsitip-huruf . Contona, rumus di handap ieu ngagantikeun sakabeh instansi tina hurup gede "X" ku "Y" dina sél A2, tapi moal ngagantikeun sagala instansi tina hurup leutik "x".

Ganti sababaraha niléy ku rumus tunggal (NANTIKAN SARUNG)

Sapertos fungsi Excel REPLACE, anjeun tiasa nyarang sababaraha pungsi SUBSTITUTE dina hiji rumus pikeun ngalakukeun sababaraha substitusi sakaligus, nyaéta substitusi. sababaraha karakter atawa substrings kalawan rumus tunggal.

Misalna anjeun boga string téks kawas " PR1, ML1, T1 " dina sél A2, dimana "PR" nangtung pikeun "Proyék, "ML " singketan tina "Milestone" sareng "T" hartosna "Tugas". Anu anjeun pikahoyong nyaéta ngagentos tilu kode ku nami lengkep. Pikeun ngahontal ieu, anjeun tiasa nyerat 3 rumus SUBSTITUTE anu béda:

=SUBSTITUTE(A2,"PR", "Project ")

=SUBSTITUTE(A2, "ML", "Milestone ")

=SUBSTITUTE(A2, "T", "Task ")

Terus sarangkeunana:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2,"PR","Project "),"ML","Milestone "),"T","Task ")

Perhatikeun yén kami geus nambahkeun spasi dina tungtung unggal argumen new_text pikeun hadékabaca.

Pikeun diajar cara séjén pikeun ngagentos sababaraha nilai dina hiji waktu, mangga tingali Kumaha cara milarian massal sareng ngagentos dina Excel.

Excel REPLACE vs. Excel SUBSTITUTE

Pungsi Excel REPLACE sareng SUBSTITUTE mirip pisan sareng anu sanés sabab duanana dirancang pikeun ngagentos senar téks. Beda antara dua pungsi ieu kieu:

• SUBSTITUTE ngagantikeun hiji atawa leuwih instance karakter atawa string téks nu tangtu. Janten, upami anjeun terang téks anu bakal diganti, paké pungsi Excel SUBSTITUTE.
• GANTIKAN ngarobah karakter dina posisi tina string téks. Janten, upami anjeun terang posisi karakter anu bakal diganti, paké pungsi Excel REPLACE.
• Fungsi SUBSTITUTE dina Excel ngamungkinkeun nambahkeun parameter opsional (instance_num) anu nangtukeun mana kajadian old_text kudu dirobah jadi new_text.

Kieu kumaha anjeun nganggo fungsi SUBSTITUTE sareng REPLACE dina Excel. Mudah-mudahan conto-conto ieu bakal mangpaat dina ngarengsekeun tugas anjeun. Abdi ngahaturkeun nuhun pikeun maca sareng mugia tiasa ningali dina blog urang minggu payun!

Unduh buku latihan latihan

GANTIKAN sareng GANTIKAN conto rumus (file .xlsx)