ट्यूटोरियल उपयोग के उदाहरणों के साथ एक्सेल रिप्लेस और सब्स्टिट्यूट फ़ंक्शन की व्याख्या करता है। टेक्स्ट स्ट्रिंग्स, संख्याओं और तिथियों के साथ REPLACE फ़ंक्शन का उपयोग कैसे करें, और एक सूत्र के भीतर कई REPLACE या स्थानापन्न फ़ंक्शंस को कैसे नेस्ट करें, देखें।

पिछले सप्ताह हमने FIND और SEARCH फ़ंक्शंस का उपयोग करने के विभिन्न तरीकों पर चर्चा की आपकी एक्सेल वर्कशीट। आज, हम सेल में उसके स्थान के आधार पर पाठ को बदलने या सामग्री के आधार पर एक पाठ स्ट्रिंग को दूसरे के साथ बदलने के लिए दो अन्य कार्यों पर गहराई से विचार करेंगे। जैसा कि आपने अनुमान लगाया होगा, मैं एक्सेल रिप्लेस और सब्स्टिट्यूट कार्यों के बारे में बात कर रहा हूं। किसी अन्य वर्ण या वर्णों के सेट के साथ पाठ स्ट्रिंग में वर्ण।

जैसा कि आप देखते हैं, Excel REPLACE फ़ंक्शन में 4 तर्क हैं, जिनमें से सभी आवश्यक हैं।<3

• Old_text - मूल पाठ (या मूल पाठ वाले सेल का संदर्भ) जिसमें आप कुछ वर्णों को बदलना चाहते हैं।
• Start_num - पुराने_टेक्स्ट में पहले वर्ण की स्थिति जिसे आप बदलना चाहते हैं।
• Num_chars - आप जिन वर्णों को बदलना चाहते हैं। - प्रतिस्थापन पाठ।

उदाहरण के लिए, " सूर्य " शब्द को " पुत्र " में बदलने के लिए, आप निम्नलिखित का उपयोग कर सकते हैंसूत्र:

=REPLACE("sun", 2, 1, "o")

और यदि आप मूल शब्द को किसी सेल में रखते हैं, मान लीजिए A2, तो आप पुराने_टेक्स्ट तर्क में संबंधित सेल संदर्भ प्रदान कर सकते हैं:

=REPLACE(A2, 2, 1, "o") <3

ध्यान दें। यदि start_num या num_chars तर्क ऋणात्मक या गैर-संख्यात्मक है, तो Excel प्रतिस्थापन सूत्र #VALUE! त्रुटि।

संख्यात्मक मानों के साथ Excel REPLACE फ़ंक्शन का उपयोग करना

Excel में REPLACE फ़ंक्शन को टेक्स्ट स्ट्रिंग्स के साथ काम करने के लिए डिज़ाइन किया गया है। बेशक, आप इसका उपयोग उन संख्यात्मक वर्णों को बदलने के लिए कर सकते हैं जो टेक्स्ट स्ट्रिंग का हिस्सा हैं, उदाहरण के लिए:

=REPLACE(A2, 7, 4, "2016")

ध्यान दें कि हम "2016" संलग्न करते हैं " दोहरे उद्धरण चिह्नों में, जैसा कि आप आमतौर पर टेक्स्ट मानों के साथ करते हैं।

इसी तरह, आप एक संख्या के भीतर एक या अधिक अंक बदल सकते हैं। उदाहरण के लिए:

=REPLACE(A4, 4, 4,"6")

और फिर से, आपको प्रतिस्थापन मूल्य को दोहरे उद्धरण चिह्नों ("6") में संलग्न करना होगा।

टिप्पणी। एक्सेल रिप्लेस फॉर्मूला हमेशा टेक्स्ट स्ट्रिंग देता है, संख्या नहीं। ऊपर दिए गए स्क्रीनशॉट में, B2 में दिए गए पाठ मान के बाएँ संरेखण पर ध्यान दें, और इसकी तुलना A2 में दाईं ओर संरेखित मूल संख्या से करें। और क्योंकि यह एक पाठ मान है, आप इसे अन्य गणनाओं में तब तक उपयोग नहीं कर पाएंगे जब तक आप इसे वापस संख्या में परिवर्तित नहीं करते हैं, उदाहरण के लिए 1 से गुणा करके या पाठ को संख्या में कैसे परिवर्तित करें में वर्णित किसी अन्य विधि का उपयोग करके।

तारीखों के साथ एक्सेल रिप्लेस फ़ंक्शन का उपयोग करना

जैसा कि आपने अभी देखा है, रिप्लेस फ़ंक्शन इसके साथ ठीक काम करता हैसंख्याएँ, सिवाय इसके कि यह एक टेक्स्ट स्ट्रिंग लौटाता है :) यह याद रखते हुए कि आंतरिक एक्सेल सिस्टम में, दिनांक संख्याओं के रूप में संग्रहीत होते हैं, आप दिनांकों पर कुछ प्रतिस्थापन फ़ार्मुलों का उपयोग करने का प्रयास कर सकते हैं। परिणाम काफी शर्मनाक होंगे।

उदाहरण के लिए, आपके पास A2 में एक तारीख है, मान लीजिए 1-अक्टूबर-14, और आप " अक्टूबर " को " नवंबर<में बदलना चाहते हैं। 2>"। इसलिए, आप सूत्र REPLACE(A2, 4, 3, "Nov") लिखते हैं जो एक्सेल को सेल A2 में 3 वर्णों को चौथे वर्ण से शुरू करने के लिए कहता है ... और निम्नलिखित परिणाम प्राप्त करता है:

ऐसा क्यों है? क्योंकि "01-अक्टूबर-14" केवल अंतर्निहित सीरियल नंबर (41913) का एक दृश्य प्रतिनिधित्व है जो दिनांक का प्रतिनिधित्व करता है। इसलिए, हमारा रिप्लेस फॉर्मूला उपरोक्त सीरियल नंबर में अंतिम 3 अंकों को " Nov " में बदल देता है और टेक्स्ट स्ट्रिंग "419Nov" लौटाता है।

Excel REPLACE फ़ंक्शन को सही तरीके से काम करने के लिए प्राप्त करने के लिए तिथियाँ, आप पहले टेक्स्ट फ़ंक्शन या Excel में दिनांक को टेक्स्ट में कैसे बदलें में प्रदर्शित किसी अन्य तकनीक का उपयोग करके दिनांकों को टेक्स्ट स्ट्रिंग्स में कनवर्ट कर सकते हैं। वैकल्पिक रूप से, आप TEXT फ़ंक्शन को सीधे REPLACE फ़ंक्शन के old_text तर्क में एम्बेड कर सकते हैं:

=REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov")

कृपया याद रखें कि उपरोक्त सूत्र का परिणाम है a टेक्स्ट स्ट्रिंग , और इसलिए यह समाधान तभी काम करता है जब आप आगे की गणनाओं में संशोधित तिथियों का उपयोग करने की योजना नहीं बना रहे हैं। यदि आपको टेक्स्ट स्ट्रिंग्स के बजाय दिनांकों की आवश्यकता है, तो DATEVALUE फ़ंक्शन द्वारा लौटाए गए मानों को चालू करने के लिए उपयोग करेंExcel REPLACE फ़ंक्शन दिनांक पर वापस:

=DATEVALUE(REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov"))

नेस्टेड REPLACE फ़ंक्शन एक सेल में एकाधिक प्रतिस्थापन करने के लिए कार्य करता है

अक्सर, आपको एक से अधिक प्रतिस्थापन करने की आवश्यकता हो सकती है एक ही सेल। बेशक, आप एक प्रतिस्थापन कर सकते हैं, एक मध्यवर्ती परिणाम को एक अतिरिक्त कॉलम में आउटपुट कर सकते हैं, और फिर REPLACE फ़ंक्शन का फिर से उपयोग कर सकते हैं। हालांकि, नेस्टेड REPLACE फ़ंक्शन का उपयोग करना एक बेहतर और अधिक पेशेवर तरीका है जो आपको एक सूत्र के साथ कई प्रतिस्थापन करने देता है। इस संदर्भ में, "नेस्टिंग" का अर्थ एक फ़ंक्शन को दूसरे के भीतर रखना है।

निम्नलिखित उदाहरण पर विचार करें। मान लें कि आपके पास कॉलम A में "123456789" के रूप में स्वरूपित टेलीफोन नंबरों की एक सूची है और आप हाइफ़न जोड़कर उन्हें फ़ोन नंबरों की तरह दिखाना चाहते हैं। दूसरे शब्दों में, आपका लक्ष्य "123456789" को "123-456-789" में बदलना है।

पहला हाइफ़न डालना आसान है। आप एक सामान्य एक्सेल रिप्लेस सूत्र लिखते हैं जो शून्य वर्ण को एक हाइफ़न से बदल देता है, यानी एक सेल में चौथी स्थिति में एक हाइफ़न जोड़ता है:

=REPLACE(A2,4,0,"-")

के परिणाम उपरोक्त रिप्लेस फॉर्मूला इस प्रकार है:

ठीक है, और अब हमें 8वें स्थान पर एक और हाइफ़न डालने की आवश्यकता है। ऐसा करने के लिए, आप उपरोक्त सूत्र को किसी अन्य Excel REPLACE फ़ंक्शन में रखते हैं। अधिक सटीक रूप से, आप इसे अन्य फ़ंक्शन के old_text तर्क में एम्बेड करते हैं, ताकि दूसरा REPLACE फ़ंक्शन द्वारा लौटाए गए मान को संभाल सकेपहले REPLACE, और सेल A2 में मान नहीं:

=REPLACE(REPLACE(A2,4,0,"-"),8,0,"-")

परिणामस्वरूप, आपको वांछित स्वरूपण में फ़ोन नंबर मिलते हैं:

इसी तरह से, जहां उपयुक्त हो वहां आप आगे स्लैश (/) जोड़कर टेक्स्ट स्ट्रिंग्स को तारीखों जैसा बनाने के लिए नेस्टेड REPLACE फ़ंक्शन का उपयोग कर सकते हैं:

=(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

इसके अलावा, आप उपरोक्त REPLACE सूत्र को DATEVALUE फ़ंक्शन के साथ लपेटकर टेक्स्ट स्ट्रिंग को वास्तविक तिथियों में परिवर्तित कर सकते हैं:

=DATEVALUE(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

और स्वाभाविक रूप से, आप फ़ंक्शन की संख्या में सीमित नहीं हैं आप एक सूत्र में नेस्ट कर सकते हैं (Excel 2010, 2013 और 2016 के आधुनिक संस्करण 8192 वर्णों तक और सूत्र में 64 नेस्टेड फ़ंक्शंस तक की अनुमति देते हैं)।

उदाहरण के लिए, आप 3 नेस्टेड REPLACE फ़ंक्शंस का उपयोग कर सकते हैं A2 में कोई संख्या दिनांक और समय की तरह दिखाई देती है:

=REPLACE(REPLACE(REPLACE(REPLACE(A2,3,0,"/") ,6,0,"/"), 9,0, " "), 12,0, ":")

एक स्ट्रिंग को बदलना जो प्रत्येक सेल में एक अलग स्थिति में दिखाई देता है

अब तक, सभी उदाहरणों में हम एक समान प्रकृति के मूल्यों के साथ काम कर रहे हैं और उसी स्थिति में प्रतिस्थापन किए हैं प्रत्येक कोशिका में। लेकिन वास्तविक जीवन के कार्य अक्सर इससे कहीं अधिक जटिल होते हैं। आपके कार्यपत्रकों में, प्रतिस्थापित किए जाने वाले वर्ण आवश्यक रूप से प्रत्येक कक्ष में एक ही स्थान पर दिखाई नहीं दे सकते हैं, और इसलिए आपको पहले वर्ण की स्थिति का पता लगाना होगा जिसे प्रतिस्थापित किया जाना चाहिए। निम्नलिखित उदाहरण प्रदर्शित करेगा कि मैं किस बारे में बात कर रहा हूं।

मान लें कि आपके पास ईमेल की एक सूची हैकॉलम ए में पता और एक कंपनी का नाम "एबीसी" से बदलकर "बीसीए" हो गया है। इसलिए, आपको तदनुसार सभी क्लाइंट के ईमेल पते को अपडेट करना होगा।

लेकिन समस्या यह है कि क्लाइंट के नाम अलग-अलग लंबाई के होते हैं, और इसीलिए आप यह निर्दिष्ट नहीं कर सकते कि कंपनी का नाम कहां से शुरू होता है। दूसरे शब्दों में, आप नहीं जानते कि Excel REPLACE फ़ंक्शन के start_num तर्क में किस मान की आपूर्ति करनी है। इसका पता लगाने के लिए, स्ट्रिंग "@abc" में पहले वर्ण की स्थिति निर्धारित करने के लिए Excel FIND फ़ंक्शन का उपयोग करें:

=FIND("@abc",A2)

और फिर, start_num में उपरोक्त FIND फ़ंक्शन की आपूर्ति करें आपके REPLACE सूत्र का तर्क:

=REPLACE(A2, FIND("@abc",A2), 4, "@bca")

युक्ति। ईमेल पतों के नाम भाग में आकस्मिक प्रतिस्थापन से बचने के लिए हम अपने एक्सेल फाइंड एंड रिप्लेस फॉर्मूला में "@" शामिल करते हैं। बेशक, इस तरह के मैच होने की बहुत कम संभावना है, और फिर भी आप सुरक्षित पक्ष में रहना चाह सकते हैं।

जैसा कि आप निम्न स्क्रीनशॉट में देखते हैं, सूत्र को खोजने और बदलने में कोई समस्या नहीं है नए के साथ पुराना पाठ। हालांकि, यदि प्रतिस्थापित की जाने वाली टेक्स्ट स्ट्रिंग नहीं मिलती है, तो सूत्र #VALUE! त्रुटि:

और हम चाहते हैं कि सूत्र त्रुटि के बजाय मूल ईमेल पता लौटाए। तो, चलिए अपना FIND & IFERROR फ़ंक्शन में REPLACE फ़ॉर्मूला:

=IFERROR(REPLACE(A2, FIND("@abc",A2), 4, "@bca"),A2)

और यह बेहतर फ़ॉर्मूला पूरी तरह से काम करता है, है ना?

एक और व्यावहारिकREPLACE फ़ंक्शन का अनुप्रयोग सेल में पहले अक्षर को कैपिटलाइज़ करना है। जब भी आप नामों, उत्पादों और इसी तरह की किसी सूची से निपटते हैं, तो आप पहले अक्षर को अपरकेस में बदलने के लिए उपरोक्त लिंक सूत्र का उपयोग कर सकते हैं।

युक्ति। यदि आप मूल डेटा में प्रतिस्थापन करना चाहते हैं, तो Excel FIND और REPLACE संवाद का उपयोग करना एक आसान तरीका होगा। किसी दिए गए वर्ण या निर्दिष्ट वर्ण के साथ टेक्स्ट स्ट्रिंग।

एक्सेल सबस्टिट्यूट फ़ंक्शन का सिंटैक्स निम्नानुसार है:

• पाठ - मूल पाठ जिसमें आप वर्णों को प्रतिस्थापित करना चाहते हैं। एक परीक्षण स्ट्रिंग, सेल संदर्भ, या किसी अन्य सूत्र के परिणाम के रूप में आपूर्ति की जा सकती है।>New_text - Old_text को बदलने के लिए नया कैरेक्टर।
• Instance_num - Old_text की घटना जिसे आप बदलना चाहते हैं। यदि छोड़ दिया जाता है, तो पुराने पाठ की प्रत्येक पुनरावृत्ति नए पाठ में बदल जाएगी। अंतिम आर्ग्युमेंट में आप किस नंबर की आपूर्ति करते हैं इसके आधार पर:

=SUBSTITUTE(A2, "1", "2", 1) - "1" की पहली घटना को प्रतिस्थापित करता है"2".

=SUBSTITUTE(A2, "1", "2", 2) - "1" की दूसरी घटना को "2" से बदलें।

=SUBSTITUTE(A2, "1", "2") - "1" की सभी घटनाओं को "2" से बदलें।

व्यावहारिक रूप से, सबस्टिट्यूट फ़ंक्शन का उपयोग कोशिकाओं से अवांछित वर्णों को हटाने के लिए भी किया जाता है। वास्तविक जीवन के उदाहरणों के लिए, कृपया देखें:

• स्ट्रिंग से अक्षरों या शब्दों को कैसे हटाएं
• सेल्स से अवांछित वर्णों को कैसे हटाएं

नोट। एक्सेल में स्थानापन्न समारोह केस-संवेदी है। उदाहरण के लिए, निम्न सूत्र सेल A2 में अपरकेस "X" के सभी उदाहरणों को "Y" से बदल देता है, लेकिन यह लोअरकेस "x" के किसी भी उदाहरण को प्रतिस्थापित नहीं करेगा।

एक सूत्र के साथ कई मानों को प्रतिस्थापित करें (नेस्टेड स्थानापन्न)

जैसा कि एक्सेल रिप्लेस फ़ंक्शन के साथ होता है, आप एक समय में कई प्रतिस्थापन करने के लिए एक सूत्र के भीतर कई स्थानापन्न फ़ंक्शन को नेस्ट कर सकते हैं, अर्थात स्थानापन्न एक सूत्र के साथ कई वर्ण या सबस्ट्रिंग।

मान लें कि आपके पास सेल A2 में " PR1, ML1, T1 " जैसी टेक्स्ट स्ट्रिंग है, जहां "PR" का अर्थ "प्रोजेक्ट," ML है " का अर्थ है "मील का पत्थर" और "T" का अर्थ है "कार्य"। आप जो चाहते हैं वह तीन कोडों को पूर्ण नामों से बदलना है। इसे प्राप्त करने के लिए, आप 3 अलग-अलग स्थानापन्न सूत्र लिख सकते हैं:

=SUBSTITUTE(A2,"PR", "Project ")

=SUBSTITUTE(A2, "ML", "Milestone ")

=SUBSTITUTE(A2, "T", "Task ")

और फिर उन्हें एक दूसरे में नेस्ट करें:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2,"PR","Project "),"ML","Milestone "),"T","Task ")

ध्यान दें कि हमने अंत में एक स्पेस जोड़ा है बेहतर के लिए प्रत्येक new_text तर्कपठनीयता।

एक समय में कई मानों को बदलने के अन्य तरीके सीखने के लिए, कृपया देखें कि एक्सेल में मास फाइंड और रिप्लेस कैसे करें।

एक्सेल रिप्लेस बनाम .एक्सेल स्थानापन्न

Excel REPLACE और स्थानापन्न कार्य एक दूसरे के समान हैं जिसमें दोनों को टेक्स्ट स्ट्रिंग्स को स्वैप करने के लिए डिज़ाइन किया गया है। दो कार्यों के बीच के अंतर इस प्रकार हैं:

• सबस्टिट्यूट एक दिए गए वर्ण या पाठ स्ट्रिंग के एक या अधिक उदाहरण को बदलता है। इसलिए, यदि आप जानते हैं कि टेक्स्ट को बदला जाना है, तो एक्सेल सबस्टिट्यूट फ़ंक्शन का उपयोग करें। इसलिए, यदि आप बदले जाने वाले वर्णों की स्थिति जानते हैं, तो एक्सेल रिप्लेस फ़ंक्शन का उपयोग करें। 10> पुराने_टेक्स्ट को नए_टेक्स्ट में बदला जाना चाहिए।

इस तरह आप एक्सेल में सबस्टिट्यूट और रिप्लेस फ़ंक्शन का उपयोग करते हैं। आशा है कि ये उदाहरण आपके कार्यों को हल करने में उपयोगी सिद्ध होंगे। मैं आपको पढ़ने के लिए धन्यवाद देता हूं और अगले सप्ताह हमारे ब्लॉग पर देखने की आशा करता हूं!

अभ्यास कार्यपुस्तिका डाउनलोड करें

प्रतिस्थापन और स्थानापन्न सूत्र उदाहरण (.xlsx फ़ाइल)