Tutorial menjelaskan fungsi REPLACE dan SUBSTITUTE Excel dengan contoh penggunaan. Lihat cara menggunakan fungsi REPLACE dengan string teks, angka dan tanggal, dan cara menyarangkan beberapa fungsi REPLACE atau SUBSTITUTE dalam satu rumus.

Minggu lalu kita telah membahas berbagai cara menggunakan fungsi FIND dan SEARCH dalam lembar kerja Excel Anda. Hari ini, kita akan melihat lebih dalam pada dua fungsi lain untuk mengganti teks dalam sel berdasarkan lokasinya atau mengganti satu string teks dengan yang lain berdasarkan konten. Seperti yang sudah Anda duga, saya berbicara tentang fungsi REPLACE dan SUBSTITUTE Excel.

Fungsi REPLACE Excel

Fungsi REPLACE di Excel memungkinkan Anda untuk menukar satu atau beberapa karakter dalam string teks dengan karakter lain atau sekumpulan karakter.

Seperti yang Anda lihat, fungsi REPLACE Excel memiliki 4 argumen, yang semuanya diperlukan.

• Old_text - teks asli (atau referensi ke sel dengan teks asli) di mana Anda ingin mengganti beberapa karakter.
• Start_num - posisi karakter pertama dalam old_text yang ingin Anda ganti.
• Num_chars - jumlah karakter yang ingin Anda ganti.
• New_text - teks pengganti.

Contohnya, untuk mengubah kata " matahari " menjadi " anak laki-laki ", Anda bisa menggunakan rumus berikut ini:

=REPLACE("sun", 2, 1, "o")

Dan jika Anda meletakkan kata asli di beberapa sel, katakanlah A2, Anda dapat menyediakan referensi sel yang sesuai dalam argumen old_text:

=REPLACE(A2, 2, 1, "o")

Catatan. Jika argumen start_num atau num_chars negatif atau non-numerik, rumus Excel Replace mengembalikan #VALUE! kesalahan.

Menggunakan fungsi REPLACE Excel dengan nilai numerik

Fungsi REPLACE di Excel dirancang untuk bekerja dengan string teks. Tentu saja, Anda dapat menggunakannya untuk mengganti karakter numerik yang merupakan bagian dari string teks, misalnya:

=REPLACE(A2, 7, 4, "2016")

Perhatikan bahwa kita mengapit "2016" dalam tanda kutip ganda seperti yang biasanya Anda lakukan dengan nilai teks.

Dengan cara yang sama, Anda bisa mengganti satu digit atau lebih dalam sebuah angka. Misalnya:

=REPLACE(A4, 4, 4, "6")

Dan lagi, Anda harus menyertakan nilai pengganti dalam tanda kutip ganda ("6").

Catatan. Rumus REPLACE Excel selalu mengembalikan string teks Pada tangkapan layar di atas, perhatikan perataan kiri dari nilai teks yang dikembalikan di B2, dan bandingkan dengan angka asli yang rata kanan di A2. Dan karena ini adalah nilai teks, Anda tidak akan dapat menggunakannya dalam penghitungan lain kecuali Anda mengonversinya kembali ke angka, misalnya dengan mengalikannya dengan 1 atau dengan menggunakan metode lain yang dijelaskan di Cara mengonversi teks ke angka.

Menggunakan fungsi REPLACE Excel dengan tanggal

Seperti yang baru saja Anda lihat, fungsi REPLACE berfungsi dengan baik dengan angka, kecuali mengembalikan string teks :) Mengingat bahwa dalam sistem internal Excel, tanggal disimpan sebagai angka, Anda dapat mencoba menggunakan beberapa rumus Replace pada tanggal. Hasilnya akan sangat memalukan.

Contohnya, Anda memiliki tanggal di A2, katakanlah 1-Oct-14, dan Anda ingin mengubah " Oktober " menjadi " Nov "Jadi, Anda menulis rumus REPLACE (A2, 4, 3, "Nov") yang memberi tahu Excel untuk mengganti 3 karakter di sel A2 yang dimulai dengan karakter ke-4... dan mendapatkan hasil sebagai berikut:

Karena "01-Oct-14" hanyalah representasi visual dari nomor seri yang mendasarinya (41913) yang mewakili tanggalnya. Jadi, rumus Replace kita mengubah 3 digit terakhir dalam nomor seri di atas menjadi " Nov " dan mengembalikan string teks "419Nov".

Untuk mendapatkan fungsi REPLACE Excel agar berfungsi dengan benar dengan tanggal, Anda dapat mengonversi tanggal menjadi string teks terlebih dahulu dengan menggunakan fungsi TEXT atau teknik lain yang ditunjukkan dalam Cara mengonversi tanggal menjadi teks di Excel. Alternatifnya, Anda dapat menyematkan fungsi TEXT secara langsung di argumen old_text dari fungsi REPLACE:

=REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov")

Harap diingat bahwa hasil dari rumus di atas adalah string teks Jika Anda memang membutuhkan tanggal daripada string teks, gunakan fungsi DATEVALUE untuk mengubah nilai yang dikembalikan oleh fungsi REPLACE Excel kembali ke tanggal:

=DATEVALUE(REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov"))

Fungsi REPLACE bersarang untuk melakukan beberapa penggantian dalam sel

Cukup sering, Anda mungkin perlu melakukan lebih dari satu penggantian di sel yang sama. Tentu saja, Anda bisa melakukan satu penggantian, mengeluarkan hasil antara ke dalam kolom tambahan, dan kemudian menggunakan fungsi REPLACE lagi. Namun, cara yang lebih baik dan lebih profesional adalah dengan menggunakan fungsi REPLACE bersarang yang memungkinkan Anda melakukan beberapa penggantian dengan satu formula. Dalam konteks ini, "nesting" berarti menempatkan satu fungsi di dalam fungsi lainnya.

Misalkan Anda memiliki daftar nomor telepon di kolom A yang diformat sebagai "123456789" dan Anda ingin membuatnya terlihat lebih seperti nomor telepon dengan menambahkan tanda hubung. Dengan kata lain, tujuan Anda adalah mengubah "123456789" menjadi "123-456-789".

Menyisipkan tanda hubung pertama itu mudah. Anda menulis rumus Excel Replace biasa yang menggantikan nol karakter dengan tanda hubung, yaitu menambahkan tanda hubung di posisi ke-4 dalam sel:

=REPLACE(A2,4,0,"-")

Hasil dari rumus Replace di atas adalah sebagai berikut:

Oke, dan sekarang kita perlu menyisipkan satu tanda hubung lagi di posisi ke-8. Untuk melakukan ini, Anda menempatkan rumus di atas di dalam fungsi REPLACE Excel lainnya. Lebih tepatnya, Anda menyematkannya dalam fungsi old_text argumen fungsi lainnya, sehingga fungsi REPLACE kedua akan menangani nilai yang dikembalikan oleh REPLACE pertama, dan bukan nilai di sel A2:

=REPLACE(REPLACE(A2,4,0,"-"),8,0,"-")

Hasilnya, Anda mendapatkan nomor telepon dalam format yang diinginkan:

Dengan cara yang sama, Anda bisa menggunakan fungsi REPLACE bersarang untuk membuat string teks terlihat seperti tanggal dengan menambahkan garis miring ke depan (/) di tempat yang sesuai:

=(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

Selain itu, Anda dapat mengonversi string teks menjadi tanggal nyata dengan membungkus rumus REPLACE di atas dengan fungsi DATEVALUE:

=DATEVALUE(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

Dan tentu saja, Anda tidak dibatasi dalam jumlah fungsi yang dapat Anda sarangkan dalam satu rumus (versi modern Excel 2010, 2013, dan 2016 mengizinkan hingga 8192 karakter dan hingga 64 fungsi bersarang dalam rumus).

Misalnya, Anda bisa menggunakan 3 fungsi REPLACE bersarang untuk membuat angka di A2 muncul seperti tanggal dan waktu:

=REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(A2,3,0,"/") ,6,0,"/"), 9,0, " "), 12,0, ":")

Mengganti string yang muncul di posisi berbeda di setiap sel

Sejauh ini, dalam semua contoh, kita telah berurusan dengan nilai-nilai yang serupa dan telah melakukan penggantian pada posisi yang sama di setiap sel. Tetapi tugas-tugas di kehidupan nyata sering kali lebih rumit dari itu. Dalam lembar kerja Anda, karakter yang akan diganti mungkin tidak selalu muncul di tempat yang sama di setiap sel, dan oleh karena itu Anda harus menemukan posisi karakter pertama Contoh berikut ini akan mendemonstrasikan apa yang saya bicarakan.

Misalkan Anda memiliki daftar alamat email di kolom A. Dan nama satu perusahaan telah berubah dari "ABC" menjadi, katakanlah, "BCA". Jadi, Anda harus memperbarui semua alamat email klien yang sesuai.

Tetapi masalahnya adalah bahwa nama klien memiliki panjang yang berbeda, dan itulah mengapa Anda tidak dapat menentukan dengan tepat di mana nama perusahaan dimulai. Dengan kata lain, Anda tidak tahu nilai apa yang harus disediakan dalam argumen start_num dari fungsi REPLACE Excel. Untuk mengetahuinya, gunakan fungsi Excel FIND untuk menentukan posisi char pertama dalam string "@abc":

=CARI ("@abc", A2)

Dan kemudian, berikan fungsi FIND di atas dalam argumen start_num dari rumus REPLACE kamu:

=REPLACE(A2, FIND("@abc",A2), 4, "@bca")

Tip. Kami menyertakan "@" dalam rumus Temukan dan Ganti Excel kami untuk menghindari penggantian yang tidak disengaja di bagian nama alamat email. Tentu saja, ada kemungkinan yang sangat kecil bahwa kecocokan seperti itu akan terjadi, dan Anda mungkin masih ingin berada di sisi yang aman.

Seperti yang Anda lihat di tangkapan layar berikut, rumus tidak memiliki masalah dengan menemukan dan mengganti teks lama dengan yang baru. Namun, jika string teks yang akan diganti tidak ditemukan, rumus mengembalikan kesalahan #VALUE!

Dan kita ingin rumusnya mengembalikan alamat email asli, bukan errornya. Jadi, mari kita lampirkan rumus FIND & REPLACE kita dalam fungsi IFERROR:

=IFERROR(REPLACE(A2, FIND("@abc",A2), 4, "@bca"),A2)

Dan formula yang lebih baik ini bekerja dengan sempurna, bukan?

Aplikasi praktis lain dari fungsi REPLACE adalah menggunakan huruf besar pada huruf pertama dalam sel. Setiap kali Anda berurusan dengan daftar nama, produk, dan sejenisnya, Anda dapat menggunakan rumus terkait di atas untuk mengubah huruf pertama menjadi UPPERCASE.

Tip. Jika Anda ingin melakukan penggantian pada data asli, cara yang lebih mudah adalah menggunakan dialog Excel FIND and REPLACE.

Fungsi SUBSTITUTE Excel

Fungsi SUBSTITUTE di Excel menggantikan satu atau lebih contoh karakter atau string teks tertentu dengan karakter tertentu.

Sintaks dari fungsi Excel SUBSTITUTE adalah sebagai berikut:

Tiga argumen pertama diperlukan dan yang terakhir adalah opsional.

• Teks - teks asli di mana Anda ingin mengganti karakter. Dapat diberikan sebagai string tes, referensi sel, atau hasil dari rumus lain.
• Old_text - karakter yang ingin Anda ganti.
• New_text - karakter baru untuk menggantikan old_text dengan.
• Instance_num - kejadian old_text yang ingin Anda ganti. Jika dihilangkan, setiap kejadian teks lama akan diubah ke teks baru.

Misalnya, semua rumus di bawah ini mengganti "1" dengan "2" di sel A2, tetapi mengembalikan hasil yang berbeda tergantung pada nomor mana yang Anda berikan di argumen terakhir:

=SUBSTITUTE(A2, "1", "2", 1) - Mengganti kejadian pertama dari "1" dengan "2".

=SUBSTITUTE(A2, "1", "2", 2) - Mengganti kejadian kedua dari "1" dengan "2".

=SUBSTITUTE(A2, "1", "2") - Mengganti semua kemunculan "1" dengan "2".

Dalam praktiknya, fungsi SUBSTITUTE juga digunakan untuk menghapus karakter yang tidak diinginkan dari sel. Untuk contoh kehidupan nyata, silakan lihat:

• Cara menghapus karakter atau kata dari string
• Cara menghapus karakter yang tidak diinginkan dari sel

Catatan. Fungsi SUBSTITUTE di Excel adalah peka huruf besar-kecil Misalnya, rumus berikut menggantikan semua contoh huruf besar "X" dengan "Y" di sel A2, tetapi tidak akan menggantikan contoh apa pun dari huruf kecil "x".

Mengganti beberapa nilai dengan satu rumus (SUBSTITUTE bersarang)

Seperti halnya dengan fungsi REPLACE Excel, Anda dapat menyarangkan beberapa fungsi SUBSTITUTE dalam satu rumus untuk melakukan beberapa substitusi sekaligus, yaitu mengganti beberapa karakter atau substring dengan satu rumus.

Seandainya Anda memiliki string teks seperti " PR1, ML1, T1 " di sel A2, di mana "PR" adalah singkatan dari "Project," ML "adalah singkatan dari" Milestone "dan" T "berarti" Task ". Yang Anda inginkan adalah mengganti ketiga kode tersebut dengan nama lengkap. Untuk mencapainya, Anda dapat menulis 3 rumus SUBSTITUTE yang berbeda:

=SUBSTITUTE(A2, "PR", "Proyek")

=SUBSTITUTE(A2, "ML", "Milestone")

=SUBSTITUTE(A2, "T", "Tugas")

Dan kemudian menyarangkan mereka satu sama lain:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2, "PR", "Proyek"), "ML", "Milestone"), "T", "Tugas")

Perhatikan bahwa kita telah menambahkan spasi di akhir setiap argumen new_text untuk keterbacaan yang lebih baik.

Untuk mempelajari cara lain untuk mengganti beberapa nilai sekaligus, silakan lihat Bagaimana melakukan pencarian dan penggantian massal di Excel.

Excel REPLACE vs Excel SUBSTITUTE

Fungsi REPLACE dan SUBSTITUTE Excel sangat mirip satu sama lain karena keduanya dirancang untuk menukar string teks. Perbedaan antara kedua fungsi tersebut adalah sebagai berikut:

• SUBSTITUTE menggantikan satu atau lebih contoh dari karakter tertentu atau string teks. Jadi, jika Anda tahu teks yang akan diganti, gunakan fungsi Excel SUBSTITUTE.
• REPLACE mengubah karakter dalam karakter tertentu posisi Jadi, jika Anda mengetahui posisi karakter yang akan diganti, gunakan fungsi REPLACE Excel.
• Fungsi SUBSTITUTE di Excel memungkinkan penambahan parameter opsional (instance_num) yang menentukan yang mana kejadian dari old_text harus diubah ke new_text.

Beginilah cara Anda menggunakan fungsi SUBSTITUTE dan REPLACE di Excel. Mudah-mudahan, contoh-contoh ini terbukti berguna dalam menyelesaikan tugas Anda. Saya berterima kasih telah membaca dan berharap untuk melihat di blog kami minggu depan!

Unduh buku kerja latihan

REPLACE dan SUBSTITUTE contoh rumus (file .xlsx)