გაკვეთილი განმარტავს Excel REPLACE და SUBSTITUTE ფუნქციებს გამოყენების მაგალითებით. იხილეთ, როგორ გამოვიყენოთ REPLACE ფუნქცია ტექსტური სტრიქონებით, რიცხვებითა და თარიღებით და როგორ მოვათავსოთ რამდენიმე REPLACE ან SUBSTITUTE ფუნქცია ერთ ფორმულაში.

გასულ კვირას განვიხილეთ FIND და SEARCH ფუნქციების გამოყენების სხვადასხვა გზები. თქვენი Excel სამუშაო ფურცლები. დღეს ჩვენ უფრო ღრმად განვიხილავთ ორ სხვა ფუნქციას, რათა შევცვალოთ ტექსტი უჯრედში მისი მდებარეობის მიხედვით ან შევცვალოთ ერთი ტექსტის სტრიქონი მეორით შინაარსის მიხედვით. როგორც მიხვდით, მე ვსაუბრობ Excel REPLACE და SUBSTITUTE ფუნქციებზე.

Excel REPLACE ფუნქცია

REPLACE ფუნქცია Excel-ში გაძლევთ საშუალებას შეცვალოთ ერთი ან რამდენიმე. სიმბოლოები ტექსტის სტრიქონში სხვა სიმბოლოთი ან სიმბოლოების სიმრავლით.

როგორც ხედავთ, Excel REPLACE ფუნქციას აქვს 4 არგუმენტი, რომელთაგან ყველა აუცილებელია.

• ძველი_ტექსტი - ორიგინალური ტექსტი (ან უჯრედის მითითება ორიგინალური ტექსტით), რომელშიც გსურთ შეცვალოთ რამდენიმე სიმბოლო.
• დაწყების_რიცხვი - პირველი სიმბოლოს პოზიცია ძველ_ტექსტში, რომლის შეცვლაც გსურთ.
• Num_chars - სიმბოლოების რაოდენობა, რომლის შეცვლაც გსურთ.
• New_text - შემცვლელი ტექსტი.

მაგალითად, სიტყვა " sun " " son "-ად შესაცვლელად, შეგიძლიათ გამოიყენოთ შემდეგიფორმულა:

=REPLACE("sun", 2, 1, "o")

და თუ თქვენ განათავსებთ ორიგინალ სიტყვას რომელიმე უჯრედში, ვთქვათ A2, შეგიძლიათ მიაწოდოთ შესაბამისი უჯრედის მითითება ძველი_ტექსტის არგუმენტში:

=REPLACE(A2, 2, 1, "o")

შენიშვნა. თუ არგუმენტი start_num ან num_chars არის უარყოფითი ან არაციფრული, Excel Replace ფორმულა აბრუნებს #VALUE-ს! შეცდომა.

Excel REPLACE ფუნქციის გამოყენება რიცხვითი მნიშვნელობებით

REPLACE ფუნქცია Excel-ში შექმნილია ტექსტის სტრიქონებთან მუშაობისთვის. რა თქმა უნდა, შეგიძლიათ გამოიყენოთ ის რიცხვითი სიმბოლოების ჩასანაცვლებლად, რომლებიც ტექსტური სტრიქონის ნაწილია, მაგალითად:

=REPLACE(A2, 7, 4, "2016")

გაითვალისწინეთ, რომ ჩვენ ვამაგრებთ „2016 წ. " ორმაგი ბრჭყალებით, როგორც ამას ჩვეულებრივ აკეთებთ ტექსტის მნიშვნელობებთან დაკავშირებით.

მსგავსი წესით, შეგიძლიათ შეცვალოთ ერთი ან მეტი ციფრი რიცხვში. მაგალითად:

=REPLACE(A4, 4, 4,"6")

და ისევ, თქვენ უნდა ჩართოთ ჩანაცვლების მნიშვნელობა ორმაგ ბრჭყალებში ("6").

Შენიშვნა. Excel REPLACE ფორმულა ყოველთვის აბრუნებს ტექსტის სტრიქონს და არა რიცხვს. ზემოთ მოცემულ ეკრანის სურათზე შენიშნეთ დაბრუნებული ტექსტის მნიშვნელობის მარცხენა გასწორება B2-ში და შეადარეთ იგი მარჯვნივ გასწორებულ ორიგინალ რიცხვს A2-ში. და რადგან ეს არის ტექსტური მნიშვნელობა, თქვენ ვერ შეძლებთ მის გამოყენებას სხვა გამოთვლებში, თუ არ დააბრუნებთ მას რიცხვად, მაგალითად, 1-ზე გამრავლებით ან სხვა მეთოდის გამოყენებით, რომელიც აღწერილია როგორ გადავიტანოთ ტექსტი რიცხვად.

Excel REPLACE ფუნქციის გამოყენება თარიღებით

როგორც ახლახან ნახეთ, REPLACE ფუნქცია კარგად მუშაობსნომრები, გარდა იმისა, რომ ის აბრუნებს ტექსტის სტრიქონს :) გახსოვდეთ, რომ შიდა Excel სისტემაში თარიღები ინახება როგორც რიცხვები, შეგიძლიათ სცადოთ გამოიყენოთ Replace ფორმულები თარიღებზე. შედეგები საკმაოდ უხერხული იქნება.

მაგალითად, თქვენ გაქვთ თარიღი A2-ში, ვთქვათ 1-ოქტ-14, და გსურთ შეცვალოთ „ ოქტ “ „ ნოე ". ასე რომ, თქვენ წერთ ფორმულას REPLACE(A2, 4, 3, "ნოემბერი"), რომელიც ეუბნება Excel-ს შეცვალოს 3 სიმბოლო A2 უჯრედებში, დაწყებული მე-4 სიმბოლოთი... და მიიღეთ შემდეგი შედეგი:

რატომ არის ეს? რადგან "01-ოქტ-14" არის მხოლოდ ძირითადი სერიული ნომრის (41913) ვიზუალური წარმოდგენა, რომელიც წარმოადგენს თარიღს. ასე რომ, ჩვენი Replace ფორმულა ცვლის ზემოაღნიშნული სერიული ნომრის ბოლო 3 ციფრს " Nov " და აბრუნებს ტექსტის სტრიქონს "419Nov".

იმისთვის რომ Excel REPLACE ფუნქცია სწორად იმუშაოს. თარიღები, თქვენ შეგიძლიათ გადაიყვანოთ თარიღები ტექსტის სტრიქონებში ჯერ TEXT ფუნქციის ან ნებისმიერი სხვა ტექნიკის გამოყენებით, რომელიც ნაჩვენებია როგორ გადავიტანოთ თარიღი ტექსტად Excel-ში. ალტერნატიულად, თქვენ შეგიძლიათ ჩასვათ TEXT ფუნქცია პირდაპირ REPLACE ფუნქციის Old_text არგუმენტში:

=REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov")

გთხოვთ გახსოვდეთ, რომ ზემოაღნიშნული ფორმულის შედეგი არის ტექსტური სტრიქონი და, შესაბამისად, ეს გამოსავალი მუშაობს მხოლოდ იმ შემთხვევაში, თუ არ აპირებთ შეცვლილი თარიღების გამოყენებას შემდგომ გამოთვლებში. თუ თქვენ გჭირდებათ თარიღები და არა ტექსტის სტრიქონები, გამოიყენეთ DATEVALUE ფუნქცია დაბრუნებული მნიშვნელობებისExcel REPLACE ფუნქცია დაბრუნდა თარიღამდე:

=DATEVALUE(REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov"))

ჩასმული REPLACE ფუნქციები უჯრედში მრავალჯერადი ჩანაცვლების შესასრულებლად

საკმაოდ ხშირად, შეიძლება დაგჭირდეთ ერთზე მეტი ჩანაცვლება იგივე უჯრედი. რა თქმა უნდა, შეგიძლიათ გააკეთოთ ერთი ჩანაცვლება, გამოიყვანოთ შუალედური შედეგი დამატებით სვეტში და შემდეგ კვლავ გამოიყენოთ REPLACE ფუნქცია. თუმცა, უკეთესი და უფრო პროფესიონალური გზაა ჩანაცვლების ფუნქციების გამოყენება , რომელიც საშუალებას გაძლევთ შეასრულოთ რამდენიმე ჩანაცვლება ერთი ფორმულით. ამ კონტექსტში „ბუდე“ ნიშნავს ერთი ფუნქციის მეორეში განთავსებას.

განიხილეთ შემდეგი მაგალითი. დავუშვათ, რომ თქვენ გაქვთ სატელეფონო ნომრების სია A სვეტში დაფორმატებული, როგორც "123456789" და გსურთ, რომ ისინი უფრო დაემსგავსოთ ტელეფონის ნომრებს დეფისების დამატებით. სხვა სიტყვებით რომ ვთქვათ, თქვენი მიზანია გადააქციოთ "123456789" "123-456-789".

პირველი დეფისის ჩასმა მარტივია. თქვენ წერთ ჩვეულებრივ Excel Replace ფორმულას, რომელიც ცვლის ნულ სიმბოლოს დეფისით, ანუ ამატებს დეფისს მე-4 პოზიციაზე უჯრედში:

=REPLACE(A2,4,0,"-")

შედეგი ზემოთ ჩანაცვლების ფორმულა ასეთია:

კარგი და ახლა მე-8 პოზიციაზე კიდევ ერთი დეფისის ჩასმა გვჭირდება. ამისათვის თქვენ განათავსებთ ზემოთ მოცემულ ფორმულას სხვა Excel REPLACE ფუნქციაში. უფრო ზუსტად, თქვენ ჩასვით ის სხვა ფუნქციის არგუმენტში old_text , ასე რომ მეორე REPLACE ფუნქცია დაამუშავებს მნიშვნელობის დაბრუნებულ მნიშვნელობას.ჯერ REPLACE და არა მნიშვნელობა A2 უჯრედში:

=REPLACE(REPLACE(A2,4,0,"-"),8,0,"-")

შედეგად, თქვენ მიიღებთ ტელეფონის ნომრებს სასურველ ფორმატით:

მსგავსი წესით, შეგიძლიათ გამოიყენოთ ჩასმული REPLACE ფუნქციები, რათა ტექსტის სტრიქონები გამოიყურებოდეს თარიღების სახით, საჭიროების შემთხვევაში, წინ ხაზების (/) დამატებით:

=(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

უფრო მეტიც, თქვენ შეგიძლიათ ტექსტის სტრიქონები გადაიყვანოთ რეალურ თარიღებად ზემოთ REPLACE ფორმულის DATEVALUE ფუნქციით შეფუთვით:

=DATEVALUE(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

და ბუნებრივია, თქვენ არ ხართ შეზღუდული ფუნქციების რაოდენობაში. შეგიძლიათ ბუდეს ერთი ფორმულის ფარგლებში (Excel 2010, 2013 და 2016 თანამედროვე ვერსიები იძლევა 8192 სიმბოლოს და 64-მდე ჩადგმულ ფუნქციას ფორმულაში).

მაგალითად, შეგიძლიათ გამოიყენოთ 3 ჩასმული REPLACE ფუნქცია. აქვს რიცხვი A2-ში, როგორც თარიღი და დრო:

=REPLACE(REPLACE(REPLACE(REPLACE(A2,3,0,"/") ,6,0,"/"), 9,0, " "), 12,0, ":")

სტრიქონის ჩანაცვლება, რომელიც ჩნდება სხვადასხვა მდგომარეობაში თითოეულ უჯრედში

აქამდე, ყველა მაგალითში ჩვენ გვქონდა საქმე მსგავსი ხასიათის ღირებულებებთან და ჩავანაცვლეთ იგივე პოზიტით ჩართულია თითოეულ უჯრედში. მაგრამ რეალურ ცხოვრებაში დავალებები ხშირად ამაზე უფრო რთულია. თქვენს სამუშაო ფურცლებში შესასაცვლელი სიმბოლოები შეიძლება არ გამოჩნდეს ერთსა და იმავე ადგილას თითოეულ უჯრედში და ამიტომ მოგიწევთ იპოვოთ პირველი სიმბოლოს პოზიცია , რომელიც უნდა შეიცვალოს. შემდეგი მაგალითი გვიჩვენებს, რაზეც ვსაუბრობ.

დავუშვათ, რომ თქვენ გაქვთ ელფოსტის სიამისამართი A სვეტში. და ერთი კომპანიის სახელი შეიცვალა "ABC"-დან, ვთქვათ, "BCA". ასე რომ, თქვენ უნდა განაახლოთ ყველა კლიენტის ელ. ფოსტის მისამართი შესაბამისად.

მაგრამ პრობლემა ის არის, რომ კლიენტების სახელები სხვადასხვა სიგრძისაა და სწორედ ამიტომ ვერ მიუთითებთ ზუსტად სად იწყება კომპანიის სახელი. სხვა სიტყვებით რომ ვთქვათ, თქვენ არ იცით რა მნიშვნელობა უნდა მიაწოდოთ Excel REPLACE ფუნქციის start_num არგუმენტს. ამის გასარკვევად, გამოიყენეთ Excel FIND ფუნქცია პირველი სიმბოლოს პოზიციის დასადგენად სტრიქონში "@abc":

=FIND("@abc",A2)

და შემდეგ მიაწოდეთ ზემოთ FIND ფუნქცია start_num-ში. თქვენი REPLACE ფორმულის არგუმენტი:

=REPLACE(A2, FIND("@abc",A2), 4, "@bca")

რჩევა. ჩვენ ვიცავთ "@" ჩვენს Excel Find and Replace ფორმულაში, რათა თავიდან ავიცილოთ შემთხვევითი ჩანაცვლება ელ.ფოსტის მისამართების სახელის ნაწილში. რა თქმა უნდა, არსებობს ძალიან მცირე შანსი იმისა, რომ მოხდეს ასეთი დამთხვევები, და მაინც შეიძლება გინდოდეს იყოთ უსაფრთხო მხარეზე.

როგორც ხედავთ შემდეგ ეკრანის სურათზე, ფორმულას არ აქვს პრობლემა პოვნასთან და შეცვლასთან დაკავშირებით. ძველი ტექსტი ახლით. თუმცა, თუ შესაცვლელი ტექსტის სტრიქონი ვერ მოიძებნა, ფორმულა დააბრუნებს #VALUE-ს! შეცდომა:

და ჩვენ გვინდა, რომ ფორმულამ შეცდომის ნაცვლად დააბრუნოს ორიგინალური ელფოსტის მისამართი. მაშ ასე, დავურთოთ ჩვენი FIND & REPLACE ფორმულა IFERROR ფუნქციაში:

=IFERROR(REPLACE(A2, FIND("@abc",A2), 4, "@bca"),A2)

და ეს გაუმჯობესებული ფორმულა მშვენივრად მუშაობს, არა?

სხვა პრაქტიკულიREPLACE ფუნქციის გამოყენება არის უჯრედის პირველი ასოს დიდი ასოების დაწერა. როდესაც საქმე გაქვთ სახელების, პროდუქტების და მსგავსების ჩამონათვალთან, შეგიძლიათ გამოიყენოთ ზემოთ მიბმული ფორმულა, რათა შეცვალოთ პირველი ასო UPPERCASE-ზე.

რჩევა. თუ გსურთ ორიგინალურ მონაცემებში ჩანაცვლება, უფრო მარტივი გზა იქნება Excel FIND და REPLACE დიალოგის გამოყენება.

Excel SUBSTITUTE ფუნქცია

SUBSTITUTE ფუნქცია Excel-ში ცვლის ერთ ან მეტ ინსტანციას. მოცემული სიმბოლოს ან ტექსტის სტრიქონის მითითებული სიმბოლო(ებ)ით.

Excel SUBSTITUTE ფუნქციის სინტაქსი ასეთია:

პირველი სამი არგუმენტი აუცილებელია, ხოლო ბოლო არჩევითია.

• ტექსტი - ორიგინალური ტექსტი, რომელშიც გსურთ სიმბოლოების ჩანაცვლება. შეიძლება მიწოდებული იყოს სატესტო სტრიქონის, უჯრედის მითითების ან სხვა ფორმულის შედეგის სახით.
• ძველი_ტექსტი - სიმბოლო(ები), რომლის შეცვლაც გსურთ.
• New_text - ახალი სიმბოლო(ები), რომლითაც უნდა შეიცვალოს ძველი_ტექსტი.
• Instance_num - ძველი_ტექსტის გამოჩენა, რომლის შეცვლაც გსურთ. თუ გამოტოვებულია, ძველი ტექსტის ყველა შემთხვევა შეიცვლება ახალი ტექსტით.

მაგალითად, ყველა ქვემოთ მოყვანილი ფორმულა ანაცვლებს "1"-ს "2"-ით A2 უჯრედში, მაგრამ აბრუნებს განსხვავებულ შედეგებს. იმის მიხედვით, თუ რომელ რიცხვს აწვდით ბოლო არგუმენტში:

=SUBSTITUTE(A2, "1", "2", 1) - ცვლის "1"-ის პირველ გაჩენას"2".

=SUBSTITUTE(A2, "1", "2", 2) - ცვლის "1"-ის მეორე შემთხვევას "2".

=SUBSTITUTE(A2, "1", "2") - ცვლის "1"-ის ყველა შემთხვევას "2-ით".

პრაქტიკაში, SUBSTITUTE ფუნქცია ასევე გამოიყენება უჯრედებიდან არასასურველი სიმბოლოების მოსაშორებლად. რეალური მაგალითებისთვის იხილეთ:

• როგორ ამოიღოთ სიმბოლოები ან სიტყვები სტრიქონიდან
• როგორ წავშალოთ არასასურველი სიმბოლოები უჯრედებიდან

შენიშვნა. Excel-ში SUBSTITUTE ფუნქცია შემგრძნობიარეა . მაგალითად, შემდეგი ფორმულა ცვლის დიდი „X“-ის ყველა ეგზემპლარს „Y“-ით A2 უჯრედში, მაგრამ ის არ ჩაანაცვლებს მცირე „x“-ის არცერთ ეგზემპლარს.

შეცვალეთ მრავალი მნიშვნელობა ერთი ფორმულით (ჩასმული SUBSTITUTE)

როგორც ეს ხდება Excel REPLACE ფუნქციის შემთხვევაში, შეგიძლიათ ჩასვათ რამდენიმე SUBSTITUTE ფუნქცია ერთ ფორმულაში, რათა გააკეთოთ რამდენიმე ჩანაცვლება ერთდროულად, ე.ი. ჩანაცვლება. რამდენიმე სიმბოლო ან ქვესტრიქონი ერთი ფორმულით.

ვთქვათ, რომ გაქვთ ტექსტის სტრიქონი, როგორიცაა " PR1, ML1, T1 " უჯრედში A2, სადაც "PR" ნიშნავს "პროექტს, "ML. " ნიშნავს "Milestone" და "T" ნიშნავს "დავალებას". რაც გინდათ არის შეცვალოთ სამი კოდი სრული სახელებით. ამის მისაღწევად შეგიძლიათ დაწეროთ 3 განსხვავებული SUBSTITUTE ფორმულა:

=SUBSTITUTE(A2,"PR", "Project ")

=SUBSTITUTE(A2, "ML", "Milestone ")

=SUBSTITUTE(A2, "T", "Task ")

და შემდეგ მოათავსეთ ისინი ერთმანეთში:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2,"PR","Project "),"ML","Milestone "),"T","Task ")

გაითვალისწინეთ, რომ ჩვენ დავამატეთ სივრცე ბოლოს ყოველი new_text არგუმენტი უკეთესისთვისკითხვადობა.

იმისათვის, რომ ისწავლოთ რამდენიმე მნიშვნელობის ერთდროულად ჩანაცვლების სხვა გზები, იხილეთ როგორ გავაკეთოთ მასობრივი პოვნა და ჩანაცვლება Excel-ში.

Excel REPLACE vs Excel SUBSTITUTE

Excel REPLACE და SUBSTITUTE ფუნქციები ძალიან ჰგავს ერთმანეთს იმით, რომ ორივე შექმნილია ტექსტის სტრიქონების გასაცვლელად. განსხვავებები ორ ფუნქციას შორის შემდეგია:

• SUBSTITUTE ცვლის მოცემული სიმბოლოს ან ტექსტის სტრიქონის ერთ ან მეტ მაგალითს . ასე რომ, თუ იცით ტექსტი, რომელიც უნდა შეიცვალოს, გამოიყენეთ Excel SUBSTITUTE ფუნქცია.
• REPLACE ცვლის სიმბოლოებს ტექსტის სტრიქონის მითითებულ პოზიციაში . ასე რომ, თუ იცით სიმბოლო(ებ)ის პოზიცია, რომელიც უნდა შეიცვალოს, გამოიყენეთ Excel REPLACE ფუნქცია.
• SUBSTITUTE ფუნქცია Excel-ში საშუალებას გაძლევთ დაამატოთ არასავალდებულო პარამეტრი (მაგალითის_რიცხვი), რომელიც განსაზღვრავს რომელი შემთხვევა<ძველი_ტექსტის 10> უნდა შეიცვალოს ახალი_ტექსტით.

ასე იყენებთ SUBSTITUTE და REPLACE ფუნქციებს Excel-ში. იმედია, ეს მაგალითები სასარგებლო იქნება თქვენი ამოცანების გადაჭრაში. მადლობას გიხდით წაკითხვისთვის და იმედი მაქვს, რომ მომავალ კვირას ვიხილავთ ჩვენს ბლოგზე!

ჩამოტვირთეთ სავარჯიშო სამუშაო წიგნი

REPLACE და SUBSTITUTE ფორმულის მაგალითები (.xlsx ფაილი)