টিউটোরিয়ালটি ব্যবহারের উদাহরণ সহ এক্সেল রিপ্লেস এবং সাবস্টিটিউট ফাংশন ব্যাখ্যা করে। দেখুন কিভাবে টেক্সট স্ট্রিং, সংখ্যা এবং তারিখ সহ রিপ্লেস ফাংশন ব্যবহার করতে হয় এবং কিভাবে একটি সূত্রের মধ্যে বেশ কয়েকটি REPLACE বা SUBSTITUTE ফাংশন নেস্ট করতে হয়।

গত সপ্তাহে আমরা এর মধ্যে FIND এবং SEARCH ফাংশন ব্যবহার করার বিভিন্ন উপায় নিয়ে আলোচনা করেছি আপনার এক্সেল ওয়ার্কশীট। আজ, আমরা একটি কক্ষের অবস্থানের উপর ভিত্তি করে পাঠ্য প্রতিস্থাপন করার জন্য বা বিষয়বস্তুর উপর ভিত্তি করে একটি পাঠ্য স্ট্রিংকে অন্যটির সাথে প্রতিস্থাপন করার জন্য আরও দুটি ফাংশনকে গভীরভাবে দেখব। আপনি হয়তো অনুমান করেছেন, আমি এক্সেল রিপ্লেস এবং সাবস্টিটিউট ফাংশন সম্পর্কে কথা বলছি।

এক্সেল রিপ্লেস ফাংশন

এক্সেলের রিপ্লেস ফাংশন আপনাকে এক বা একাধিক অদলবদল করতে দেয় একটি টেক্সট স্ট্রিং-এ অন্য অক্ষর বা অক্ষরগুলির একটি সেট সহ অক্ষর৷

যেমন আপনি দেখতে পাচ্ছেন, Excel REPLACE ফাংশনে 4টি আর্গুমেন্ট রয়েছে, যার সবকটিই প্রয়োজন৷

• Old_text - আসল পাঠ্য (বা আসল পাঠ্য সহ একটি ঘরের একটি রেফারেন্স) যেখানে আপনি কিছু অক্ষর প্রতিস্থাপন করতে চান৷
• স্টার্ট_সংখ্যা - পুরানো_পাঠ্যের মধ্যে প্রথম অক্ষরের অবস্থান যা আপনি প্রতিস্থাপন করতে চান।
• সংখ্যা_অক্ষর - আপনি প্রতিস্থাপন করতে চান এমন অক্ষরের সংখ্যা।
• নতুন_পাঠ - প্রতিস্থাপন পাঠ্য।

উদাহরণস্বরূপ, " সূর্য " শব্দটিকে " পুত্র " এ পরিবর্তন করতে, আপনি নিম্নলিখিতগুলি ব্যবহার করতে পারেনসূত্র:

=REPLACE("sun", 2, 1, "o")

এবং যদি আপনি কিছু কক্ষে মূল শব্দ রাখেন, A2 বলুন, আপনি পুরানো_টেক্সট আর্গুমেন্টে সংশ্লিষ্ট সেল রেফারেন্স সরবরাহ করতে পারেন:

=REPLACE(A2, 2, 1, "o")

নোট। যদি start_num বা num_chars আর্গুমেন্ট নেতিবাচক বা অ-সংখ্যাসূচক হয়, তাহলে একটি এক্সেল প্রতিস্থাপন সূত্র #VALUE প্রদান করে! ত্রুটি।

সাংখ্যিক মান সহ এক্সেল রিপ্লেস ফাংশন ব্যবহার করা

এক্সেলের রিপ্লেস ফাংশনটি টেক্সট স্ট্রিংগুলির সাথে কাজ করার জন্য ডিজাইন করা হয়েছে। অবশ্যই, আপনি এটি একটি পাঠ্য স্ট্রিং এর অংশ সাংখ্যিক অক্ষর প্রতিস্থাপন করতে ব্যবহার করতে পারেন, উদাহরণস্বরূপ:

=REPLACE(A2, 7, 4, "2016")

লক্ষ্য করুন যে আমরা "2016 " ডবল উদ্ধৃতিতে যেমন আপনি সাধারণত পাঠ্য মানগুলির সাথে করেন৷

একইভাবে, আপনি একটি সংখ্যার মধ্যে এক বা একাধিক সংখ্যা প্রতিস্থাপন করতে পারেন৷ উদাহরণস্বরূপ:

=REPLACE(A4, 4, 4,"6")

এবং আবার, আপনাকে প্রতিস্থাপনের মানটি ডবল কোট ("6") এ সংযুক্ত করতে হবে।

বিঃদ্রঃ. একটি Excel REPLACE সূত্র সর্বদা একটি টেক্সট স্ট্রিং প্রদান করে, সংখ্যা নয়। উপরের স্ক্রিনশটে, B2-তে প্রত্যাবর্তিত পাঠ্য মানের বাম প্রান্তিককরণটি লক্ষ্য করুন এবং A2-এ ডান-সারিবদ্ধ মূল সংখ্যার সাথে তুলনা করুন। এবং এটি একটি পাঠ্য মান হওয়ায় আপনি এটিকে অন্য গণনায় ব্যবহার করতে সক্ষম হবেন না যদি না আপনি এটিকে সংখ্যায় রূপান্তর করেন, উদাহরণস্বরূপ 1 দ্বারা গুণ করে বা কীভাবে পাঠ্যকে সংখ্যায় রূপান্তর করতে হয়-তে বর্ণিত অন্য কোনো পদ্ধতি ব্যবহার করে৷

উদাহরণস্বরূপ, আপনার A2 তারিখ আছে, বলুন 1-অক্টোবর-14, এবং আপনি " অক্টোবর " থেকে " নভেম্বর<পরিবর্তন করতে চান৷ 2>" সুতরাং, আপনি ফর্মুলা REPLACE(A2, 4, 3, "Nov") লিখুন যা এক্সেলকে বলে A2 কক্ষে 3টি অক্ষর প্রতিস্থাপন করতে 4র্থ অক্ষর দিয়ে শুরু করে… এবং নিম্নলিখিত ফলাফলটি পেয়েছে:

এটা কেন? কারণ "01-Oct-14" হল শুধুমাত্র অন্তর্নিহিত ক্রমিক সংখ্যার (41913) একটি চাক্ষুষ উপস্থাপনা যা তারিখটিকে উপস্থাপন করে৷ সুতরাং, আমাদের প্রতিস্থাপন সূত্র উপরের সিরিয়াল নম্বরের শেষ 3টি সংখ্যাকে " নভেম্বর " এ পরিবর্তন করে এবং পাঠ্য স্ট্রিংটি "419Nov" প্রদান করে।

এক্সেল রিপ্লেস ফাংশনটি সঠিকভাবে কাজ করার জন্য তারিখগুলি, আপনি টেক্সট ফাংশন ব্যবহার করে তারিখগুলিকে প্রথমে টেক্সট স্ট্রিংগুলিতে রূপান্তর করতে পারেন বা এক্সেলে তারিখকে কীভাবে টেক্সটে রূপান্তর করতে হয় তাতে প্রদর্শিত অন্য কোনও কৌশল ব্যবহার করে। বিকল্পভাবে, আপনি REPLACE ফাংশনের old_text আর্গুমেন্টে সরাসরি TEXT ফাংশন এম্বেড করতে পারেন:

=REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov")

দয়া করে মনে রাখবেন যে উপরের সূত্রটির ফলাফল হল একটি টেক্সট স্ট্রিং , এবং সেইজন্য এই সমাধানটি তখনই কাজ করে যদি আপনি পরবর্তী গণনার জন্য পরিবর্তিত তারিখগুলি ব্যবহার করার পরিকল্পনা না করেন। আপনার যদি টেক্সট স্ট্রিংয়ের পরিবর্তে তারিখের প্রয়োজন হয়, তাহলে DATEVALUE ফাংশন ব্যবহার করুনএক্সেল REPLACE ফাংশনটি তারিখে ফিরে এসেছে:

=DATEVALUE(REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov"))

একটি কক্ষে একাধিক প্রতিস্থাপন করতে নেস্টেড রিপ্লেস ফাংশন

প্রায়শই, আপনাকে একাধিক প্রতিস্থাপন করতে হতে পারে একই কোষ। অবশ্যই, আপনি একটি প্রতিস্থাপন করতে পারেন, একটি অতিরিক্ত কলামে একটি মধ্যবর্তী ফলাফল আউটপুট করতে পারেন এবং তারপরে আবার REPLACE ফাংশনটি ব্যবহার করতে পারেন। যাইহোক, একটি ভাল এবং আরও পেশাদার উপায় হল নেস্টেড REPLACE ফাংশনগুলি ব্যবহার করা যা আপনাকে একটি সূত্রের সাথে একাধিক প্রতিস্থাপন করতে দেয়। এই প্রসঙ্গে, "নেস্টিং" মানে একটি ফাংশনকে অন্যটির মধ্যে স্থাপন করা৷

নিম্নলিখিত উদাহরণটি বিবেচনা করুন৷ ধরুন আপনার কাছে "123456789" কলামে টেলিফোন নম্বরগুলির একটি তালিকা রয়েছে যা "123456789" ফর্ম্যাট করা হয়েছে এবং আপনি হাইফেন যোগ করে সেগুলিকে ফোন নম্বরের মতো দেখতে চান৷ অন্য কথায়, আপনার লক্ষ্য হল "123456789" কে "123-456-789" এ পরিণত করা৷

প্রথম হাইফেন সন্নিবেশ করা সহজ৷ আপনি একটি সাধারণ এক্সেল প্রতিস্থাপন সূত্র লিখুন যা শূন্য অক্ষর কে একটি হাইফেন দিয়ে প্রতিস্থাপন করে, যেমন একটি কক্ষে 4র্থ অবস্থানে একটি হাইফেন যোগ করে:

=REPLACE(A2,4,0,"-")

এর ফলাফল উপরে প্রতিস্থাপন সূত্রটি নিম্নরূপ:

ঠিক আছে, এবং এখন আমাদের 8ম অবস্থানে আরও একটি হাইফেন সন্নিবেশ করাতে হবে। এটি করার জন্য, আপনি উপরের সূত্রটি অন্য এক্সেল রিপ্লেস ফাংশনের মধ্যে রাখুন। আরও স্পষ্টভাবে, আপনি এটিকে অন্য ফাংশনের old_text আর্গুমেন্টে এম্বেড করুন, যাতে দ্বিতীয় REPLACE ফাংশনটি দ্বারা প্রত্যাবর্তিত মানটি পরিচালনা করবেপ্রথমে REPLACE করুন, এবং সেল A2-এর মান নয়:

=REPLACE(REPLACE(A2,4,0,"-"),8,0,"-")

ফলে, আপনি ফোন নম্বরগুলি পছন্দসই বিন্যাসে পাবেন:

একই পদ্ধতিতে, যেখানে উপযুক্ত সেখানে ফরওয়ার্ড স্ল্যাশ (/) যোগ করে টেক্সট স্ট্রিংগুলিকে তারিখের মতো দেখতে নেস্টেড রিপ্লেস ফাংশন ব্যবহার করতে পারেন:

=(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

তাছাড়া, আপনি DATEVALUE ফাংশনের সাথে উপরের REPLACE সূত্রটি মোড়ানোর মাধ্যমে টেক্সট স্ট্রিংগুলিকে বাস্তব তারিখে রূপান্তর করতে পারেন:

=DATEVALUE(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

এবং স্বাভাবিকভাবেই, আপনি ফাংশনের সংখ্যায় সীমাবদ্ধ নন। আপনি একটি সূত্রের মধ্যে নেস্ট করতে পারেন (এক্সেল 2010, 2013 এবং 2016-এর আধুনিক সংস্করণগুলি একটি সূত্রে 8192টি অক্ষর এবং 64টি নেস্টেড ফাংশন পর্যন্ত অনুমতি দেয়)।

উদাহরণস্বরূপ, আপনি 3টি নেস্টেড রিপ্লেস ফাংশন ব্যবহার করতে পারেন তারিখ এবং সময়ের মত A2-এ একটি সংখ্যা প্রদর্শিত হবে:

=REPLACE(REPLACE(REPLACE(REPLACE(A2,3,0,"/") ,6,0,"/"), 9,0, " "), 12,0, ":")

প্রতিটি কক্ষে একটি ভিন্ন অবস্থানে প্রদর্শিত একটি স্ট্রিং প্রতিস্থাপন করা হচ্ছে

এখন পর্যন্ত, সমস্ত উদাহরণে আমরা একই প্রকৃতির মান নিয়ে কাজ করছি এবং একই অবস্থানে প্রতিস্থাপন করেছি প্রতিটি কক্ষে চালু। কিন্তু বাস্তব জীবনের কাজগুলি প্রায়শই তার চেয়ে বেশি জটিল। আপনার ওয়ার্কশীটে, প্রতিস্থাপন করা অক্ষরগুলি অগত্যা প্রতিটি কক্ষে একই জায়গায় উপস্থিত নাও হতে পারে, এবং তাই আপনাকে প্রথম অক্ষরের অবস্থান খুঁজে বের করতে হবে যা প্রতিস্থাপন করা উচিত। নিচের উদাহরণটি দেখাবে আমি কি বিষয়ে কথা বলছি।

ধরুন আপনার কাছে ইমেলের একটি তালিকা আছেA কলামে সম্বোধন। এবং একটি কোম্পানির নাম "ABC" থেকে পরিবর্তিত হয়েছে, বলুন, "BCA"। সুতরাং, আপনাকে সেই অনুযায়ী সমস্ত ক্লায়েন্টের ইমেল ঠিকানা আপডেট করতে হবে৷

কিন্তু সমস্যা হল ক্লায়েন্টের নামগুলি বিভিন্ন দৈর্ঘ্যের, এবং সেই কারণেই আপনি কোম্পানির নামটি ঠিক কোথায় শুরু হবে তা নির্দিষ্ট করতে পারবেন না৷ অন্য কথায়, Excel REPLACE ফাংশনের start_num আর্গুমেন্টে কোন মান সরবরাহ করতে হবে তা আপনি জানেন না। এটি খুঁজে বের করতে, "@abc" স্ট্রিং-এর প্রথম অক্ষরের অবস্থান নির্ধারণ করতে Excel FIND ফাংশন ব্যবহার করুন:

=FIND("@abc",A2)

এবং তারপর, start_num-এ উপরের FIND ফাংশনটি সরবরাহ করুন আপনার REPLACE সূত্রের যুক্তি:

=REPLACE(A2, FIND("@abc",A2), 4, "@bca")

টিপ। ইমেল ঠিকানাগুলির নামের অংশে দুর্ঘটনাজনিত প্রতিস্থাপন এড়াতে আমরা আমাদের এক্সেল খুঁজুন এবং প্রতিস্থাপন সূত্রে "@" অন্তর্ভুক্ত করি। অবশ্যই, এই ধরনের ম্যাচগুলি হওয়ার খুব কম সম্ভাবনা রয়েছে, এবং তারপরও আপনি নিরাপদে থাকতে চাইতে পারেন।

নিম্নলিখিত স্ক্রিনশটে আপনি যেমনটি দেখতে পাচ্ছেন, সূত্রটি খুঁজে পেতে এবং প্রতিস্থাপন করতে কোনও সমস্যা নেই নতুনের সাথে পুরানো লেখা। যাইহোক, যদি প্রতিস্থাপন করা টেক্সট স্ট্রিং পাওয়া না যায়, তাহলে সূত্রটি #VALUE! ত্রুটি:

এবং আমরা ত্রুটির পরিবর্তে মূল ইমেল ঠিকানাটি ফেরত দিতে চাই। সুতরাং, আসুন আমাদের FIND & IFERROR ফাংশনে REPLACE সূত্র:

=IFERROR(REPLACE(A2, FIND("@abc",A2), 4, "@bca"),A2)

এবং এই উন্নত সূত্রটি পুরোপুরি কাজ করে, তাই না?

24>

আরেকটি ব্যবহারিকREPLACE ফাংশনের প্রয়োগ হল একটি ঘরের প্রথম অক্ষরটি বড় করা। আপনি যখনই নাম, পণ্য এবং এর মতো একটি তালিকা নিয়ে কাজ করেন, আপনি উপরের-লিঙ্ক করা সূত্রটি ব্যবহার করতে পারেন প্রথম অক্ষরটিকে UPPERCASE এ পরিবর্তন করতে৷

টিপ৷ আপনি যদি মূল ডেটাতে প্রতিস্থাপন করতে চান, তাহলে একটি সহজ উপায় হল Excel FIND এবং REPLACE ডায়ালগ ব্যবহার করা।

Excel SUBSTITUTE ফাংশন

Excel-এ SUBSTITUTE ফাংশন এক বা একাধিক উদাহরণ প্রতিস্থাপন করে একটি নির্দিষ্ট অক্ষর(গুলি) সহ একটি প্রদত্ত অক্ষর বা পাঠ্য স্ট্রিং এর।

এক্সেল সাবস্টিটিউট ফাংশনের সিনট্যাক্স নিম্নরূপ:

প্রথম তিনটি আর্গুমেন্ট প্রয়োজন এবং শেষটি ঐচ্ছিক৷

• পাঠ্য - মূল পাঠ্য যেখানে আপনি অক্ষর প্রতিস্থাপন করতে চান৷ একটি পরীক্ষার স্ট্রিং, সেল রেফারেন্স, বা অন্য সূত্রের ফলাফল হিসাবে সরবরাহ করা যেতে পারে৷
• Old_text - যে অক্ষর(গুলি) আপনি প্রতিস্থাপন করতে চান৷
• নতুন_পাঠ - পুরানো_টেক্সট প্রতিস্থাপন করার জন্য নতুন অক্ষর যদি বাদ দেওয়া হয়, পুরানো পাঠ্যের প্রতিটি ঘটনা নতুন পাঠে পরিবর্তিত হবে৷

উদাহরণস্বরূপ, নীচের সমস্ত সূত্রগুলি A2 কক্ষে "2" এর সাথে "1" প্রতিস্থাপন করে, কিন্তু ভিন্ন ফলাফল দেয় আপনি শেষ আর্গুমেন্টে কোন সংখ্যাটি সরবরাহ করেন তার উপর নির্ভর করে:

=SUBSTITUTE(A2, "1", "2", 1) - "1" এর প্রথম উপস্থিতির পরিবর্তে"2"।

=SUBSTITUTE(A2, "1", "2", 2) - "2" এর সাথে "1" এর দ্বিতীয় উপস্থিতি প্রতিস্থাপন করে।

=SUBSTITUTE(A2, "1", "2") - "2" এর সাথে "1" এর সমস্ত উপস্থিতি প্রতিস্থাপন করে।

অভ্যাসে, SUBSTITUTE ফাংশনটি কোষ থেকে অবাঞ্ছিত অক্ষরগুলি সরানোর জন্যও ব্যবহৃত হয়। বাস্তব জীবনের উদাহরণের জন্য, অনুগ্রহ করে দেখুন:

• স্ট্রিং থেকে অক্ষর বা শব্দগুলি কীভাবে সরিয়ে ফেলা যায়
• কোষ থেকে অবাঞ্ছিত অক্ষরগুলি কীভাবে মুছবেন

নোট। এক্সেলের SUBSTITUTE ফাংশন হল কেস-সংবেদনশীল । উদাহরণ স্বরূপ, নিচের সূত্রটি A2 কক্ষে বড় হাতের "X"-এর সমস্ত দৃষ্টান্তকে "Y" দিয়ে প্রতিস্থাপন করে, কিন্তু এটি ছোট হাতের "x" এর কোনো উদাহরণ প্রতিস্থাপন করবে না।

একক সূত্র দিয়ে একাধিক মান প্রতিস্থাপন করুন (নেস্টেড সাবস্টিটিউটি)

যেমন এক্সেল রিপ্লেস ফাংশনের ক্ষেত্রে হয়, আপনি একটি ফর্মুলার মধ্যে একাধিক SUBSTITUTE ফাংশন নেস্ট করতে পারেন এক সময়ে একাধিক প্রতিস্থাপন করতে, যেমন বিকল্প একটি সূত্র সহ একাধিক অক্ষর বা সাবস্ট্রিং।

ধরুন আপনার সেল A2-এ " PR1, ML1, T1 " এর মতো একটি পাঠ্য স্ট্রিং আছে, যেখানে "PR" মানে "প্রজেক্ট, "ML " মানে "মাইলস্টোন" এবং "T" এর অর্থ হল "টাস্ক"। আপনি যা চান তা হল তিনটি কোডকে পূর্ণ নাম দিয়ে প্রতিস্থাপন করা। এটি অর্জনের জন্য, আপনি 3টি ভিন্ন SUBSTITUTE সূত্র লিখতে পারেন:

=SUBSTITUTE(A2,"PR", "Project ")

=SUBSTITUTE(A2, "ML", "Milestone ")

=SUBSTITUTE(A2, "T", "Task ")

এবং তারপর একে অপরের মধ্যে নেস্ট করুন:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2,"PR","Project "),"ML","Milestone "),"T","Task ")

লক্ষ্য করুন যে আমরা এর শেষে একটি স্থান যোগ করেছি প্রতিটি নতুন_টেক্সট আর্গুমেন্ট ভালো করার জন্যপঠনযোগ্যতা৷

এক সময়ে একাধিক মান প্রতিস্থাপন করার অন্যান্য উপায়গুলি শিখতে, অনুগ্রহ করে দেখুন কিভাবে Excel-এ ভর খুঁজে এবং প্রতিস্থাপন করতে হয়৷

Excel REPLACE বনাম এক্সেল সাবস্টিটিউট

এক্সেল রিপ্লেস এবং সাবস্টিটিউট ফাংশন একে অপরের সাথে খুব মিল যে উভয়ই টেক্সট স্ট্রিংগুলিকে অদলবদল করার জন্য ডিজাইন করা হয়েছে। দুটি ফাংশনের মধ্যে পার্থক্য নিম্নরূপ:

• SUBSTITUTE একটি প্রদত্ত অক্ষর বা একটি টেক্সট স্ট্রিং এর এক বা একাধিক ইনস্ট্যান্স প্রতিস্থাপন করে। সুতরাং, যদি আপনি জানেন যে পাঠ্যটি প্রতিস্থাপন করতে হবে, তবে এক্সেল সাবস্টিটিউট ফাংশনটি ব্যবহার করুন।
• REPLACE একটি পাঠ্য স্ট্রিংয়ের একটি নির্দিষ্ট অবস্থান এ অক্ষর পরিবর্তন করে। সুতরাং, যদি আপনি প্রতিস্থাপন করা অক্ষর(গুলি) এর অবস্থান জানেন তবে এক্সেল REPLACE ফাংশনটি ব্যবহার করুন৷
• এক্সেলের SUBSTITUTE ফাংশনটি একটি ঐচ্ছিক প্যারামিটার (instance_num) যোগ করার অনুমতি দেয় যা নির্দিষ্ট করে যে কোনটি ঘটনা<পুরানো_পাঠের 10> নতুন_টেক্সট পরিবর্তন করা উচিত।

এভাবে আপনি এক্সেল-এ SUBSTITUTE এবং REPLACE ফাংশন ব্যবহার করেন। আশা করি, এই উদাহরণগুলি আপনার কাজগুলি সমাধানে কার্যকর প্রমাণিত হবে। আমি পড়ার জন্য আপনাকে ধন্যবাদ এবং আশা করি আগামী সপ্তাহে আমাদের ব্লগে দেখতে পাব!

অভ্যাস ওয়ার্কবুক ডাউনলোড করুন

প্রতিস্থাপন এবং প্রতিস্থাপন সূত্র উদাহরণ (.xlsx ফাইল)