Das Tutorial erklärt die Excel-Funktionen ERSETZEN und SUBSTITUIEREN anhand von Anwendungsbeispielen. Sehen Sie, wie Sie die Funktion ERSETZEN mit Textzeichenfolgen, Zahlen und Datumsangaben verwenden und wie Sie mehrere Funktionen ERSETZEN oder SUBSTITUIEREN in einer Formel verschachteln können.

Letzte Woche haben wir verschiedene Möglichkeiten der Verwendung der Funktionen FINDEN und SUCHEN in Ihren Excel-Arbeitsblättern besprochen. Heute werden wir uns zwei weitere Funktionen genauer ansehen, mit denen Sie Text in einer Zelle auf der Grundlage seiner Position ersetzen oder eine Textzeichenfolge durch eine andere auf der Grundlage des Inhalts ersetzen können. Wie Sie vielleicht schon erraten haben, spreche ich über die Excel-Funktionen ERSETZEN und SUBSTITUIEREN.

Excel REPLACE-Funktion

Mit der REPLACE-Funktion in Excel können Sie ein oder mehrere Zeichen in einer Textzeichenfolge durch ein anderes Zeichen oder eine Reihe von Zeichen ersetzen.

Wie Sie sehen, hat die Excel-Funktion REPLACE 4 Argumente, von denen alle erforderlich sind.

• Alter_Text - den Originaltext (oder einen Verweis auf eine Zelle mit dem Originaltext), in dem Sie einige Zeichen ersetzen möchten.
• Start_num - die Position des ersten Zeichens in old_text, das ersetzt werden soll.
• Anzahl_Zeichen - die Anzahl der Zeichen, die Sie ersetzen möchten.
• Neuer_Text - den Ersatztext.

Zum Beispiel, um das Wort " Sonne " zu " Sohn " können Sie die folgende Formel verwenden:

=REPLACE("Sonne", 2, 1, "o")

Und wenn Sie das ursprüngliche Wort in eine Zelle, z. B. A2, einfügen, können Sie den entsprechenden Zellverweis im Argument old_text angeben:

=REPLACE(A2, 2, 1, "o")

Hinweis: Wenn das Argument start_num oder num_chars negativ oder nicht numerisch ist, gibt eine Excel-Ersetzungsformel den Fehler #VALUE! zurück.

Verwendung der Excel-Funktion REPLACE mit numerischen Werten

Die REPLACE-Funktion in Excel ist für die Arbeit mit Textzeichenfolgen konzipiert. Natürlich können Sie sie auch verwenden, um z. B. numerische Zeichen zu ersetzen, die Teil einer Textzeichenfolge sind:

=REPLACE(A2, 7, 4, "2016")

Beachten Sie, dass wir "2016" in doppelte Anführungszeichen setzen, wie Sie es normalerweise mit Textwerten tun.

Auf ähnliche Weise können Sie eine oder mehrere Ziffern innerhalb einer Zahl ersetzen, zum Beispiel:

=REPLACE(A4, 4, 4, "6")

Und auch hier müssen Sie den Ersatzwert in Anführungszeichen setzen ("6").

Hinweis: Eine REPLACE-Formel in Excel gibt immer ein Textfolge Achten Sie im obigen Screenshot auf die linke Ausrichtung des zurückgegebenen Textwerts in B2 und vergleichen Sie ihn mit der rechts ausgerichteten Originalzahl in A2. Da es sich um einen Textwert handelt, können Sie ihn nicht für andere Berechnungen verwenden, es sei denn, Sie konvertieren ihn zurück in eine Zahl, z. B. durch Multiplikation mit 1 oder mit einer anderen Methode, die in Wie man Text in Zahlen konvertiert beschrieben ist.

Verwendung der Excel-Funktion REPLACE mit Datumsangaben

Wie Sie soeben gesehen haben, funktioniert die Funktion REPLACE auch mit Zahlen, nur dass sie einen Textstring zurückgibt :) Wenn Sie daran denken, dass im internen Excel-System Datumsangaben als Zahlen gespeichert werden, können Sie versuchen, einige Ersetzen-Formeln für Datumsangaben zu verwenden. Die Ergebnisse wären ziemlich peinlich.

Sie haben z. B. ein Datum in A2, z. B. 1-Okt-14, und Sie möchten " Okt. " zu " Nov. "Sie schreiben also die Formel REPLACE(A2, 4, 3, "Nov"), die Excel anweist, 3 Zeichen in der Zelle A2 zu ersetzen, beginnend mit dem vierten Zeichen... und erhalten das folgende Ergebnis:

Warum? Weil "01-Oct-14" nur eine visuelle Darstellung der zugrunde liegenden Seriennummer (41913) ist, die das Datum darstellt. Unsere Ersetzungsformel ändert also die letzten 3 Ziffern der oben genannten Seriennummer in " Nov. " und gibt die Textzeichenfolge "419Nov" zurück.

Damit die REPLACE-Funktion von Excel korrekt mit Datumsangaben arbeitet, können Sie Datumsangaben zunächst mit der TEXT-Funktion oder einer anderen Technik, die in Wie man in Excel Datumsangaben in Text umwandelt gezeigt wird, in Textzeichenfolgen umwandeln. Alternativ können Sie die TEXT-Funktion direkt in das Argument old_text der REPLACE-Funktion einbetten:

=REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov")

Bitte beachten Sie, dass das Ergebnis der obigen Formel ein Textfolge Wenn Sie Datumsangaben anstelle von Textstrings benötigen, verwenden Sie die Funktion DATEVALUE, um die von der Excel-Funktion REPLACE zurückgegebenen Werte wieder in Datumsangaben umzuwandeln:

=DATEVALUE(REPLACE(TEXT(A2, "tt-mmm-jj"), 4, 3, "Nov"))

Verschachtelte REPLACE-Funktionen für mehrere Ersetzungen in einer Zelle

Es kann vorkommen, dass Sie mehr als eine Ersetzung in derselben Zelle vornehmen müssen. Natürlich könnten Sie eine Ersetzung vornehmen, ein Zwischenergebnis in einer zusätzlichen Spalte ausgeben und dann erneut die Funktion REPLACE verwenden. Eine bessere und professionellere Methode ist jedoch die Verwendung von verschachtelte REPLACE-Funktionen In diesem Zusammenhang bedeutet "Verschachtelung", dass eine Funktion innerhalb einer anderen platziert wird.

Nehmen wir folgendes Beispiel: Angenommen, Sie haben eine Liste von Telefonnummern in Spalte A, die als "123456789" formatiert ist, und Sie möchten sie durch Hinzufügen von Bindestrichen so umgestalten, dass sie wie Telefonnummern aussehen. Mit anderen Worten, Ihr Ziel ist es, "123456789" in "123-456-789" zu verwandeln.

Das Einfügen des ersten Bindestrichs ist einfach: Sie schreiben eine gewöhnliche Excel-Ersetzungsformel, die Folgendes ersetzt Null Zeichen mit einem Bindestrich, d.h. fügt einen Bindestrich an der 4. Stelle in einer Zelle ein:

=REPLACE(A2,4,0,"-")

Das Ergebnis der obigen Ersetzungsformel lautet wie folgt:

Okay, und jetzt müssen wir einen weiteren Bindestrich an der 8. Position einfügen. Dazu platzieren Sie die obige Formel innerhalb einer anderen REPLACE-Funktion von Excel. Genauer gesagt, Sie betten sie in die alter_text Argument der anderen Funktion, so dass die zweite REPLACE-Funktion den von der ersten REPLACE-Funktion zurückgegebenen Wert verarbeitet und nicht den Wert in Zelle A2:

=REPLACE(REPLACE(A2,4,0,"-"),8,0,"-")

Als Ergebnis erhalten Sie die Rufnummern in der gewünschten Formatierung:

In ähnlicher Weise können Sie verschachtelte REPLACE-Funktionen verwenden, um Textstrings wie Datumsangaben aussehen zu lassen, indem Sie an den entsprechenden Stellen einen Schrägstrich (/) hinzufügen:

=(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

Darüber hinaus können Sie Textstrings in reale Datumsangaben umwandeln, indem Sie die obige REPLACE-Formel mit der DATEVALUE-Funktion umschließen:

=DATENWERT(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

Und natürlich sind Sie in der Anzahl der Funktionen, die Sie in einer Formel verschachteln können, nicht eingeschränkt (die modernen Versionen von Excel 2010, 2013 und 2016 erlauben bis zu 8192 Zeichen und bis zu 64 verschachtelte Funktionen in einer Formel).

Sie können zum Beispiel 3 verschachtelte REPLACE-Funktionen verwenden, um eine Zahl in A2 wie Datum und Uhrzeit erscheinen zu lassen:

=REPLACE(REPLACE(REPLACE(REPLACE(A2,3,0,"/") ,6,0,"/"), 9,0, " "), 12,0, ":")

Ersetzen einer Zeichenfolge, die in jeder Zelle an einer anderen Stelle erscheint

Bisher haben wir uns in allen Beispielen mit ähnlichen Werten befasst und die Ersetzungen an der gleichen Stelle in jeder Zelle vorgenommen. In der Praxis sind die Aufgaben jedoch oft komplizierter. In Ihren Arbeitsblättern kommen die zu ersetzenden Zeichen nicht unbedingt an der gleichen Stelle in jeder Zelle vor, und Sie müssen daher die Position des ersten Zeichens finden Das folgende Beispiel zeigt, wovon ich spreche.

Angenommen, Sie haben eine Liste von E-Mail-Adressen in Spalte A. Und der Name eines Unternehmens hat sich von "ABC" in, sagen wir, "BCA" geändert. Sie müssen also alle E-Mail-Adressen der Kunden entsprechend aktualisieren.

Das Problem ist jedoch, dass die Kundennamen unterschiedlich lang sind und Sie deshalb nicht genau angeben können, wo der Firmenname beginnt. Mit anderen Worten, Sie wissen nicht, welchen Wert Sie in das start_num-Argument der Excel-Funktion REPLACE eingeben müssen. Um dies herauszufinden, verwenden Sie die Excel-Funktion FIND, um die Position des ersten Zeichens in der Zeichenfolge "@abc" zu bestimmen:

=FIND("@abc",A2)

Und dann geben Sie die obige FIND-Funktion in das start_num-Argument Ihrer REPLACE-Formel ein:

=REPLACE(A2, FIND("@abc",A2), 4, "@bca")

Tipp: Wir fügen das "@" in unsere Excel-Formel zum Suchen und Ersetzen ein, um versehentliche Ersetzungen im Namensteil von E-Mail-Adressen zu vermeiden. Natürlich ist die Wahrscheinlichkeit, dass solche Übereinstimmungen auftreten, sehr gering, und dennoch möchten Sie vielleicht auf Nummer sicher gehen.

Wie Sie im folgenden Screenshot sehen, kann die Formel den alten Text problemlos finden und durch den neuen ersetzen. Wenn die zu ersetzende Textzeichenfolge jedoch nicht gefunden wird, gibt die Formel den Fehler #VALUE! zurück:

Und wir möchten, dass die Formel die ursprüngliche E-Mail-Adresse anstelle des Fehlers zurückgibt. Schließen wir also unsere FIND & REPLACE-Formel in die IFERROR-Funktion ein:

=IFERROR(REPLACE(A2, FIND("@abc",A2), 4, "@bca"),A2)

Und diese verbesserte Formel funktioniert perfekt, nicht wahr?

Eine weitere praktische Anwendung der Funktion ERSETZEN ist die Großschreibung des ersten Buchstabens in einer Zelle. Wann immer Sie mit einer Liste von Namen, Produkten usw. arbeiten, können Sie die oben verlinkte Formel verwenden, um den ersten Buchstaben in GROSSBUCHSTABEN zu ändern.

Tipp: Wenn Sie die Ersetzungen in den Originaldaten vornehmen möchten, ist es einfacher, das Excel-Dialogfeld FINDEN und ERSETZEN zu verwenden.

Excel-Funktion SUBSTITUTE

Die Funktion SUBSTITUTE in Excel ersetzt ein oder mehrere Instanzen eines bestimmten Zeichens oder einer Textkette durch ein oder mehrere angegebene Zeichen.

Die Syntax der Excel-Funktion SUBSTITUTE lautet wie folgt:

Die ersten drei Argumente sind erforderlich, das letzte ist optional.

• Text - der ursprüngliche Text, in dem Sie Zeichen ersetzen möchten. Kann als Testzeichenfolge, Zellreferenz oder als Ergebnis einer anderen Formel angegeben werden.
• Alter_Text - das/die Zeichen, die Sie ersetzen möchten.
• Neuer_Text - das/die neue(n) Zeichen, durch die old_text ersetzt werden soll.
• Instanz_num - das Vorkommen von old_text, das ersetzt werden soll. Wird dies nicht angegeben, wird jedes Vorkommen des alten Textes durch den neuen Text ersetzt.

Zum Beispiel ersetzen alle folgenden Formeln "1" durch "2" in Zelle A2, liefern aber unterschiedliche Ergebnisse, je nachdem, welche Zahl Sie im letzten Argument angeben:

=SUBSTITUTE(A2, "1", "2", 1) - Ersetzt das erste Vorkommen von "1" durch "2".

=SUBSTITUTE(A2, "1", "2", 2) - Ersetzt das zweite Vorkommen von "1" durch "2".

=SUBSTITUTE(A2, "1", "2") - Ersetzt alle Vorkommnisse von "1" durch "2".

In der Praxis wird die Funktion SUBSTITUTE auch verwendet, um unerwünschte Zeichen aus Zellen zu entfernen (siehe Beispiele aus der Praxis):

• Zeichen oder Wörter aus einer Zeichenfolge entfernen
• So löschen Sie unerwünschte Zeichen aus Zellen

Hinweis: Die Funktion SUBSTITUTE in Excel lautet Groß- und Kleinschreibung Die folgende Formel ersetzt zum Beispiel alle Instanzen des Großbuchstabens "X" durch "Y" in Zelle A2, aber sie ersetzt keine Instanzen des Kleinbuchstabens "x".

Ersetzen mehrerer Werte durch eine einzige Formel (verschachteltes SUBSTITUTE)

Wie bei der Excel-Funktion ERSETZEN können Sie mehrere SUBSTITUTE-Funktionen in einer einzigen Formel verschachteln, um mehrere Ersetzungen auf einmal vorzunehmen, d. h. mehrere Zeichen oder Teilzeichen mit einer einzigen Formel zu ersetzen.

Angenommen, Sie haben eine Zeichenkette wie " PR1, ML1, T1 " in Zelle A2, wobei "PR" für "Projekt", "ML" für "Meilenstein" und "T" für "Aufgabe" steht. Sie möchten die drei Codes durch die vollständigen Namen ersetzen. Um dies zu erreichen, können Sie 3 verschiedene SUBSTITUTE-Formeln schreiben:

=SUBSTITUTE(A2, "PR", "Projekt ")

=SUBSTITUTE(A2, "ML", "Meilenstein ")

=SUBSTITUTE(A2, "T", "Aufgabe ")

Und dann verschachteln Sie sie ineinander:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2, "PR", "Projekt "), "ML", "Meilenstein "), "T", "Vorgang ")

Beachten Sie, dass wir zur besseren Lesbarkeit am Ende jedes new_text-Arguments ein Leerzeichen hinzugefügt haben.

Weitere Möglichkeiten, mehrere Werte gleichzeitig zu ersetzen, finden Sie unter Suchen und Ersetzen in Excel.

Excel REPLACE vs. Excel SUBSTITUTE

Die Excel-Funktionen REPLACE und SUBSTITUTE sind einander sehr ähnlich, da sie beide dazu dienen, Textzeichenfolgen auszutauschen. Die Unterschiede zwischen den beiden Funktionen sind folgende:

• SUBSTITUTE ersetzt eine oder mehrere Instanzen Wenn Sie also den zu ersetzenden Text kennen, können Sie die Excel-Funktion SUBSTITUTE verwenden.
• REPLACE ändert Zeichen in einem angegebenen Position Wenn Sie also die Position der zu ersetzenden Zeichen kennen, können Sie die Excel-Funktion REPLACE verwenden.
• Die Funktion SUBSTITUTE in Excel ermöglicht das Hinzufügen eines optionalen Parameters (instance_num), der angibt, welche Vorkommen von old_text sollte in new_text geändert werden.

So verwenden Sie die Funktionen SUBSTITUTE und REPLACE in Excel. Ich hoffe, dass diese Beispiele bei der Lösung Ihrer Aufgaben hilfreich sind. Ich danke Ihnen für die Lektüre und hoffe, dass wir uns nächste Woche in unserem Blog wiedersehen!

Download Arbeitsbuch für die Praxis

Beispiele für REPLACE- und SUBSTITUTE-Formeln (.xlsx-Datei)